Eingabe(such)feld mit Löschmöglichkeit

GML

Ein gutes neues Jahr vorab als Erstes!

Ich bitte um Schwarmwissen. Gibt es eine Möglichkeit ein solches Eingabefeld zu erzeugen (UDF, Funktion ...)?

oder geht das "nur zu Fuß" mit label, getdata, ctrlread und icon über das label/getdata legen? Ein Hinweis in die Richtung genügt mir völlig, ich möchte nur nicht ein Phantom suchen das es vielleicht gar nicht gibt.

Die Möglichkeit durch reinklicken den "Feld"-Inhalt zu löschen habe ich, möchte aber den Inhalt bestehen lassen (um Erweiterungen bzw. Korrekturen am Suchbegriff vornehmen zu können) und nur beim Klick auf das X den Inhalt komplett löschen.

Danke

LG

**Alina**

Moin GML.

Ich gehe jetzt einmal davon aus, dass das "Suchfeld" ein Inputfeld ist.
Dann kannst Du so lösen.

Spoiler anzeigen

GUICtrlSetData($input,"")

Kann aber sein das ich Dich nicht richtig verstanden habe. Hast Du bereits ein Script geschrieben, wäre es gut, wenn Du uns dieses zeigst.

GML

Im Moment hab ich nicht viel mehr als eine Idee ... bzw. Wunsch wies aussehen soll. Ich überlege mir gerne vorher bevor ich loslege um dann nicht hintennach (siehe Icon-Auflösungsproblem etwas weiter unten) draufzukommen das hätte besser gehen können

Das Eingabefeld ist ein GUICtrlCreateEdit. Die erste Idee war eine Funktion die mit GUICtrlCreateEdit arbeitet und das oben im Bild gezeigte aus einzelnen Elementen zusammensetzt. Also GUICtrlCreateEdit, die dafür übergebene Länge um yy verkürzen, ein Label mit der Länge yy anhängen und mit dem X anzeigen - ob da ein Icon geschickt ist weiß ich nicht, wäre zwar optisch schöner, dann müßte ich aber auf unterschiedliche BS-Auflösungen reagieren denke ich - ev. ist der Buchstabe X (oder ev. ein Sonderzeichen?) mit einem leicht grauen Hintergrund besser und das direkt nach dem GUICtrlCreateEdit angezeigt so das der Eindruck EINES Eingabebereiches entsteht.

In html wäre das: ✖ HTML code ✖ oder ✕ für ✕ statt eines Icons ... oder überhaupt eine Funktion mit grünem OK-Haken, rotem Löschkreuz, Fragezeichen ..... träum ...

Mir geht es nicht so um ein konkretes Beispiel sondern ob die Idee(n) Vor- und Nachteile haben.

oh-ha

In etwa so?

Code

#include <GuiConstants.au3>
$Gui = GuiCreate("Test", 260, 100)
GUICtrlCreateLabel("", 15, 39, 230, 20, $SS_SUNKEN)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlSetBkColor(-1, 0xFFFFFF)
$icon = GUICtrlCreateIcon("shell32.dll", 15, 18, 41, 16, 16)
GUICtrlCreateInput("", 45, 42, 190, 14, -1, $WS_EX_TOOLWINDOW)
GUISetState()
While 1
   $Msg = GUIGetMsg()
   Switch $Msg
       Case -3
           Exit
        Case $icon 
            MsgBox(0,0,0)
          Case Else
   EndSwitch
WEnd

Alles anzeigen

GML

Sapristi!

Oh ja, das ist so in etwa wie ich mir das vorgestellt habe. Ob das Symbol jetzt vorne oder hinten wäre, wäre egal.

Herzlichen Dank, damit kann ich experimentieren bzw. mir das anpassen (versuchen )

Danke an alle Kopfzerbrecher

LG

**Kanashius**

Es ist auch moeglich, einen Hintergrundtext zu setzen, der automatisch beim reinklicken weggeht:

AutoIt

$iInputSearch=GUICtrlCreateInput("",10,10,100)
GUICtrlSendMsg(-1, 0x1501, 0, "Suchen ...")

Das Icon brauchst du aber dann trotzdem noch anders.

MfG, Kanashius.

**Schnuffel**

hier mein Ansatz:

AutoIt

#include <GuiConstants.au3>
$hGui = GuiCreate("Test", 260, 100)
GUICtrlCreateLabel("", 15, 39, 230, 20, $SS_SUNKEN)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlSetBkColor(-1, 0xFFFFFF)
$hIcon = GUICtrlCreateIcon("shell32.dll", 15, 18, 41, 16, 16)
$hInput = GUICtrlCreateInput("", 45, 42, 195, 14, -1, $WS_EX_TOOLWINDOW)
GUICtrlSetState(-1, 32)
$hSuchen = GUICtrlCreateLabel('Suchen ...', 45, 42, 195, 16)
GUICtrlSetState(-1, 16)
GUICtrlSetColor(-1, 0xCFCFCF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$hButton = GUICtrlCreateButton('OK',15,70, 120, 20)

GUIRegisterMsg(0x0111, "WM_COMMAND_KillFocus")
GUISetState()
While 1
   $Msg = GUIGetMsg()
   Switch $Msg
       Case -3
           Exit
   EndSwitch
WEnd

Func WM_COMMAND_KillFocus($hWnd, $Msg, $wParam, $lParam)
    $nNotifyCode = BitShift($wParam, 16)
    $nID = BitAnd($wParam, 0x0000FFFF)
    Switch $nNotifyCode
		Case 0
			IF $nID = $hSuchen Or $nID = $hIcon Then
				GUICtrlSetState($hSuchen, 32)
				GUICtrlSetState($hInput, 16 + 256)
			EndIf
		Case 512
			IF $nID = $hInput Then
				GUICtrlSetState($hSuchen, 16)
				GUICtrlSetState($hInput, 32)
			EndIf
    EndSwitch
EndFunc

Alles anzeigen

**Schnuffel**

nachdem ich die erste Anforderung nicht vollständig gelesen hatte, hier noch eine Variante die dem Wunsch eher entspricht:

AutoIt

#include <GuiConstants.au3>
$hGui = GuiCreate("Test", 260, 100)
GUICtrlCreateLabel("", 15, 39, 230, 20, $SS_SUNKEN)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlSetBkColor(-1, 0xFFFFFF)
$hX = GUICtrlCreateLabel("X", 232, 39, 20, 18)
GUICtrlSetFont(-1, 12, 0, 0, "Consolas")
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetColor(-1, 0x9F2F2F)
$hInput = GUICtrlCreateInput("", 20, 42, 205, 14, -1, $WS_EX_TOOLWINDOW)
GUICtrlSetState(-1, 32)
$hSuchen = GUICtrlCreateLabel('Suchen ...', 20, 42, 195, 16)
GUICtrlSetState(-1, 16)
GUICtrlSetColor(-1, 0xCFCFCF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$hButton = GUICtrlCreateButton('OK',15,70, 120, 20)

GUIRegisterMsg(0x0111, "WM_COMMAND_Suchen")
GUISetState()
While 1
   $Msg = GUIGetMsg()
   Switch $Msg
       Case -3
           Exit
   EndSwitch
WEnd

Func WM_COMMAND_Suchen($hWnd, $Msg, $wParam, $lParam)
    $nNotifyCode = BitShift($wParam, 16)
    $nID = BitAnd($wParam, 0x0000FFFF)
	ConsoleWrite($nNotifyCode & @CRLF)

    Switch $nNotifyCode
		Case 0
			Switch $nID
				Case $hSuchen
					GUICtrlSetData($hInput, '')
					GUICtrlSetState($hSuchen, 32)
					GUICtrlSetState($hInput, 16 + 256)
				Case $hX
					GUICtrlSetData($hInput, '')
					GUICtrlSetState($hSuchen, 16)
					GUICtrlSetState($hInput, 32)
			EndSwitch
    EndSwitch
EndFunc

Alles anzeigen

GML

So eine ähnliche Variante hab ich auch versucht.

Danke!

LG