Passwort anzeigen

BigRox

Hallo,
ich möchte ein GUI mit einem Input- und einem Button-Control zur Eingabe eines Passwort erstellen.

Das Passwort gib ich ins Input-Control ein und jedes eingegebene Zeichen soll da nur als ein Punkt angezeigt werden.
Alles kein Problem, $ES_PASSWORD als Style angeben und schon funktioniert das.
Nun möchte ich aber auch noch erreichen, dass in dem Input-Control das Passwort im Klartext angezeigt wird, wenn ich auf den Button klicke.
Also, den Style vom Input-Control ändern, dass Passwort wider ins Control schreiben und das sollte eigentlich auch funktionieren, tut es aber nicht, es bleibt bei den angezeigten Punkten.
Irgendetwas mache ich da wohl falsch.

Hier mal mein Testscript:

Spoiler anzeigen

AutoIt v3 Script (neu) (3).au3

Am schönste wäre es natürlich, wenn das Passwort wieder als Punkte angezeigt wird, wenn man den Button wieder "loslässt".
Aber das müsst man auch noch mit dem ButtonUp-Ereignis o.ä. irgendwie hinbekommen.

MfG:
BigRox

**Kanashius**

Ich hab mich mal daran versucht:

Ich hab es hinbekommen den Style zu ändern, es hat aber nichts geändert. Deshalb geh ich mal davon aus, dass dieser Satz aus der Hilfe zu GuiCtrlSetStyle für $ES_PASSWORD gilt:
"Some styles cannot be changed dynamically, check MSDN documentation. $CBS_UPPERCASE combo style is one example."

Von daher bleibt vermutlich nur der Workaround, zwei Controls zu erstellen und miteinander auszutauschen:

AutoIt

#include <WinAPI.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>

Global $iWidth = 800, $iHeight = 600, $iSpace = 10
Local $hGui = GUICreate("Test", $iWidth, $iHeight)
Local $iInputWidth = $iWidth-$iSpace*3-100
Local $hInputPW = GUICtrlCreateInput("", $iSpace, $iSpace,$iInputWidth, 25, $ES_PASSWORD)
Local $hInputPWShow = GUICtrlCreateInput("", $iSpace, $iSpace,$iInputWidth, 25)
GUICtrlSetState($hInputPWShow, $GUI_HIDE)
Local $hButton = GUICtrlCreateButton("SHOW", $iSpace*2+($iInputWidth), $iSpace, 100, 25)
GUISetState(@SW_SHOW, $hGui)

While True
	Local $iMsg = GUIGetMsg()
	If $iMsg=-3 Then Exit
	If $iMsg=$hButton Then _switchInput($hInputPW, $hInputPWShow)
WEnd

Func _switchInput($hInput, $hInputShow)
	If BitAND(GUICtrlGetState($hInput), $GUI_SHOW) Then
		GUICtrlSetData($hInputShow, GUICtrlRead($hInput))
		GUICtrlSetState($hInput, $GUI_HIDE)
		GUICtrlSetState($hInputShow, $GUI_SHOW)
	Else
		GUICtrlSetData($hInput, GUICtrlRead($hInputShow))
		GUICtrlSetState($hInputShow, $GUI_HIDE)
		GUICtrlSetState($hInput, $GUI_SHOW)
	EndIf
EndFunc

#cs
Func _switchInput($hInput)
	Local $iStyle = GUICtrlGetStyle($hInput)[0]
	ConsoleWrite("Res: "&$ES_PASSWORD&" >> "&BitAND($iStyle, $ES_PASSWORD)&@crlf)
	If BitAND($iStyle, $ES_PASSWORD) Then
		ConsoleWrite("ON: "&BitXOR($iStyle, $ES_PASSWORD)&@crlf)
		GUICtrlSetStyle($hInput, BitXOR($iStyle, $ES_PASSWORD))
	Else
		ConsoleWrite("OFF: "&BitOr($iStyle, $ES_PASSWORD)&@crlf)
		GUICtrlSetStyle($hInput, BitOr($iStyle, $ES_PASSWORD))
	EndIf
EndFunc

; #FUNCTION# ====================================================================================================================
; Name ..........: GUICtrlGetStyle
; Description ...: Retrieves the Styles/ExStyles value(s) of a control.
; Syntax ........: GUICtrlGetStyle($hWnd)
; Parameters ....: $hWnd                - Control ID/Handle to the control
; Return values .: $aArray[2] = [Style, ExStyle]
; Author ........: guinness
; Example .......: Yes
; ===============================================================================================================================
Func GUICtrlGetStyle($hWnd)
    If Not IsHWnd($hWnd) Then
        $hWnd = GUICtrlGetHandle($hWnd)
    EndIf
    Local $aReturn = [_WinAPI_GetWindowLong($hWnd, $GWL_STYLE), _WinAPI_GetWindowLong($hWnd, $GWL_EXSTYLE)]
    Return $aReturn
EndFunc   ;==>GUICtrlGetStyle
#ce

Alles anzeigen

Ich hab meine Versuch, den Style dynamisch zu wechseln mal drin gelassen. Vielleicht kann den mal jemand bei anderen Styles gebrauchen.

Ich hoffe das hilft dir weiter

**water**

Hier gibt's ein paar super Ideen.

**Musashi**

Zitat von Kanashius

Ich hab es hinbekommen den Style zu ändern, es hat aber nichts geändert.

Hier ein Beispiel aus dem EN-Forum, bei dem GUICtrlSendMsg() statt GUICtrlSetStyle() verwendet wird :

C

; Source from : https://www.autoitscript.com/forum/topic/128360-change-a-gui-input-to-password/#comment-890778

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $Form1     = GUICreate("Example", 200, 80, 216, 148)
Global $Input     = GUICtrlCreateInput("", 8, 8, 145, 21, BitOR($ES_PASSWORD, $ES_AUTOHSCROLL))
Global $Checkbox1 = GUICtrlCreateCheckbox("Show password", 8, 32, 145, 25)
GUISetState(@SW_SHOW)

;Retrieve the ASCII value of the default password char
$DefaultPassChar = GUICtrlSendMsg($Input, $EM_GETPASSWORDCHAR, 0, 0)

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Checkbox1
			If (GUICtrlRead($Checkbox1) = $GUI_CHECKED) Then
				GUICtrlSendMsg($Input, $EM_SETPASSWORDCHAR, 0, 0)
			Else
				GUICtrlSendMsg($Input, $EM_SETPASSWORDCHAR, $DefaultPassChar, 0)
			EndIf
			GUICtrlSetState($Input, $GUI_FOCUS) ; Input needs focus to redraw characters
	EndSwitch
WEnd

Alles anzeigen

(Edit)

water : War gerade Abendessen und habe deinen Link mit den Superideen vor dem Absenden nicht gesehen .

**water**

Zitat von Musashi

War gerade Abendessen und habe deinen Link mit den Superideen vor dem Absenden nicht gesehen .

Ich hab zwar meist keine Ahnung, aber Suchen und Finden funktioniert noch super

**Schnuffel**

ich hätte 2 Controls genommen und je nach Klick auf sichtbar unsichtbar geschaltet.

Ein Control mit $ES_Password und eins ohne

**Andy**

Zitat von Kanashius

Von daher bleibt vermutlich nur der Workaround, zwei Controls zu erstellen und miteinander auszutauschen:

Haha...so ging es mir auch...nach einer Stunde rumprobieren den Style zu ändern habe ich es dann so gemacht:

BigRox So lange der Mousecursor über dem Button ist und gedrückt bleibt, so lange wird der Klartext angezeigt

C

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>




Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)

Global $idButton, $idGUI_Msg, $idInp_Passwort0, $idInp_Passwort1, $idBtn_PWAnzeigen, $ggci, $gui

$gui = GUICreate("Include-Datei suchen:", 830, 261, -1, -1, BitOR($WS_CAPTION, $WS_SYSMENU))
GUISetBkColor(0x3680FF)
GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEButton")




$idInp_Passwort0 = GUICtrlCreateInput("", 226, 31, 380, 36)
GUICtrlSetFont(-1, 16, 800, 0, "Times New Roman")
GUICtrlSetState($idInp_Passwort0, $GUI_HIDE)
$idInp_Passwort1 = GUICtrlCreateInput("", 226, 31, 380, 36, $ES_PASSWORD)
GUICtrlSetFont(-1, 16, 800, 0, "Times New Roman")
;GUICtrlSetData(-1, "Das ist aber schön.")

$idBtn_PWAnzeigen = GUICtrlCreateButton("Passwort anzeigen.", 65, 130, 220, 40)
GUICtrlSetFont(-1, 14, 400, 0, "Times New Roman")
GUICtrlSetBkColor(-1, 0x2FF130)


GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, "PWAnzeigen")
GUISetState(@SW_SHOW)



While 1
    Sleep(100)
WEnd


Func PWAnzeigen()

    $ggci = GUIGetCursorInfo($gui)
    If $ggci[4] = $idBtn_PWAnzeigen Then
        GUICtrlSetData($idInp_Passwort0, GUICtrlRead($idInp_Passwort1))
        GUICtrlSetState($idInp_Passwort1, $GUI_HIDE)
        GUICtrlSetState($idInp_Passwort0, $GUI_SHOW)
        While _IsPressed("01")                   ;_WinAPI_Mouse_Event ( $MOUSEEVENTF_LEFTDOWN)
            Sleep(10)
        WEnd
        GUICtrlSetState($idInp_Passwort0, $GUI_HIDE)
        GUICtrlSetState($idInp_Passwort1, $GUI_SHOW)
    EndIf
EndFunc                                          ;==>PWAnzeigen

Func CLOSEButton()
    MsgBox($MB_OK, "GUI Event", 'Passwort: "' & GUICtrlRead($idInp_Passwort1) & '"' & @CRLF & @CRLF & "Das Programm wird jetzt beendet.")
    GUIDelete()
    Exit
EndFunc                                          ;==>CLOSEButton

Alles anzeigen

Zitat von water

Ich hab zwar meist keine Ahnung, aber Suchen und Finden funktioniert noch super

Du Glücklicher...Suchen funktioniert bei mir EINWANDFREI.....nur mit dem Finden habe ich Probleme...

**water**

Zitat von Andy

Du Glücklicher...Suchen funktioniert bei mir EINWANDFREI.....nur mit dem Finden habe ich Probleme...

BigRox

Hallo an alle,
das sind ja richtig viele gute Vorschläge zu meinem Problem.

Deshalb DANKE DAFÜR

Jetz habe ich erst einmal einiges zum ausprobieren.

MfG:
BigRox

Passwort anzeigen

Ähnliche Themen

Automatischer Login via Edge nicht möglich