Festgelegten Ordner in den aktuell ausgewählten Ordner kopieren

o0Julia0o

hi, ich möchte den Ordner: E:\Info\#Im in den Ordner kopieren, den ich aktuell angewählt habe. Der Inhalt vom Ordner E:\Info\#Im soll natürlich mit kopiert werden. Und falls im aktuell ausgewählem Ordner bereits ein Ordner #Im existiert soll dessen Inhalt nur überschrieben werden mit den Dateien die noch fehlen im Vergleich zum Quellordnerinhalt: E:\Info\#Im. Das ganze soll mit dem hotkey strg+alt+g passieren. So klappt es schonmal nicht ;):

AutoIt

#include <File.au3>

; Definiere den absoluten Pfad für den Quellordner
Local $sourceFolder = "E:\Info\#Im" ; Ändere diesen Pfad auf den absoluten Pfad des #Im-Ordners

; Setze den Hotkey Strg + Alt + G
HotKeySet("^!g", "CopyFilesHotkey")

; Halte das Skript am Laufen, bis der Benutzer es beendet
While 1
	Sleep(100)    ; Warte in einer Schleife
WEnd

Func CopyFilesHotkey()
	; Überprüfen, ob ein Zielordner ausgewählt ist
	Local $targetFolder = GetSelectedFolder()
	If $targetFolder = "" Then
		MsgBox(0, "Fehler", "Kein Zielordner ausgewählt oder der ausgewählte Ordner ist ungültig.")
		Return
	EndIf
	; Überprüfen, ob der Quellordner existiert
	If Not FileExists($sourceFolder) Then
		MsgBox(0, "Fehler", "Der Quellordner existiert nicht: " & $sourceFolder)
		Return
	EndIf
	; Überprüfen, ob der Zielordner bereits existiert
	If Not FileExists($targetFolder) Then
		; Wenn der Zielordner nicht existiert, erstelle ihn
		DirCreate($targetFolder)
	EndIf
	; Kopiere den #Im-Ordner in den ausgewählten Zielordner
	Local $targetImFolder = $targetFolder & "\#Im"
	FileCopy($sourceFolder, $targetImFolder, 1)    ; 1 = Überschreibe, wenn der Ordner bereits existiert
EndFunc   ;==>CopyFilesHotkey

Func GetSelectedFolder()
	Local $hWnd = WinGetHandle("[ACTIVE]")    ; Aktives Fenster ermitteln
	If Not IsHWnd($hWnd) Then Return ""
	; Simuliere das Drücken von Strg + C, um den Pfad des ausgewählten Ordners in die Zwischenablage zu kopieren
	Send("^{c}")
	Sleep(100)    ; Warten, um sicherzustellen, dass der Pfad kopiert wurde
	; Lese den Inhalt der Zwischenablage
	Local $clipboardContent = ClipGet()
	If StringLen($clipboardContent) > 0 Then
		Return StringTrimRight($clipboardContent, 1)        ; Trim newline character
	EndIf
	Return ""
EndFunc   ;==>GetSelectedFolder

Alles anzeigen

Wie geht das richtig?

**SOLVE-SMART**

Hi und willkommen im Forum o0Julia0o 👋 .

Zitat von o0Julia0o

[...] ich möchte den Ordner: E:\Info\#Im in den Ordner kopieren, den ich aktuell angewählt habe [...]

Was meinst du mit aktuell angewählt? Sprichst du vom Windows Explorer den du offen hast?
Dort bist du mit der Maus auf irgend einem Ordner und möchtest in diesen per Hotkey den "#Im" Ordner samt Inhalt kopieren?
Richtig soweit? Denn so etwa sieht dein Code (KI generiert sicherlich) aus.

Aber warum 🤔 ? Weißt du nicht sowieso von welchen Ordner du in welchen Ordner kopieren möchtest? Also ich verstehe nicht was dir das Skript bringt, wenn du einfach per Windows Explorer copy und paste genau dies auch machen kannst? Da wirst du doch gefragt ob du die bereits vorhandenen Dateien überschreiben willst oder nicht.

Mal anders gefragt:
Wie häufig möchtest du dies etwa ausführen, für wie viel verschiedene Ordner (sonst brauchst du den Hotkey ja auch nicht)?

💡 Wenn du mehr Informationen teilst, was dein Ziel insgesamt ist, kann es sehr gut möglich sein, dass wir einen ganz anderen Vorschlag bringen können, an den du ggf. noch nicht gedacht hast. Deinen Code reviewe ich jetzt (in der Nacht) nicht mehr. Morgen früh gegebenenfalls.

Viele Grüße
Sven

**SOLVE-SMART**

Um dein Szenario für mich und die anderen etwas besser nachzustellen und testen zu können, hier ein kleines Skript was eine ähnliche Ordnerstruktur mit dummy Daten/Dateien anlegt. Wenn wir von der gleichen Struktur ausgehen, wird es einfacher konkret darüber zu reden ob das finale Skript/Programm sich so verhält wie du es dir dann vorstellst.

AutoIt

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y

_Main()

Func _Main()
    _CreateTestFolderAndFileStructure()
EndFunc

Func _CreateTestFolderAndFileStructure()
    Local Const $sRootFolder = 'C:\tmp\'
    Local Const $aList[] = _
        [ _
            'source-folder\Info\#Im\file1.txt', _
            'source-folder\Info\#Im\file2.png', _
            'source-folder\Info\#Im\file3.mp3', _
            'source-folder\Info\#Im\subfolder1\fileA.txt', _
            'source-folder\Info\#Im\subfolder1\fileB.jpg', _
            'source-folder\Info\#Im\subfolder1\fileC.wav', _
            'source-folder\Info\#Im\subfolder1\subfolder2\fileD.xlsx', _
            'source-folder\Info\#Im\subfolder1\subfolder2\fileE.bmp', _
            'source-folder\Info\#Im\subfolder1\subfolder2\fileF.pdf', _
            'target-folder\#Im\file1.txt', _
            'target-folder\#Im\subfolder1\fileA.txt', _
            'target-folder\#Im\subfolder1\subfolder2\fileD.xlsx', _
            'target-folder\AAA.png', _
            'target-folder\subfolder1\BBB.jpg', _
            'target-folder\subfolder1\subfolder2\CCC.bmp' _
        ]

    For $sFile In $aList
        _CreateFile($sRootFolder & $sFile, 'dummy content')
        If @error Then
            ConsoleWrite(StringFormat( _
                'Oops! Handle this unexpected behavior for file "%s"\n', $sFile))
        EndIf
    Next
EndFunc

Func _CreateFile($sFile, $sText)
    Local Const $iUtf8WithoutBomWriteCreateMode = 256 + 2 + 8

    Local $hFile = FileOpen($sFile, $iUtf8WithoutBomWriteCreateMode)
    If $hFile == -1 Then
        Return SetError(1)
    EndIf

    If FileWrite($hFile, $sText) == 0 Then
        Return SetError(1)
    EndIf

    FileClose($hFile)
EndFunc

Alles anzeigen

Das Ergebnis sieht dann so aus:

Code

C:\tmp>tree /A /F
Auflistung der Ordnerpfade für Volume System
Volumeseriennummer : 00000128 DEC4:8BF9
C:.
+---source-folder
|   \---Info
|       \---#Im
|           |   file1.txt
|           |   file2.png
|           |   file3.mp3
|           |
|           \---subfolder1
|               |   fileA.txt
|               |   fileB.jpg
|               |   fileC.wav
|               |
|               \---subfolder2
|                       fileD.xlsx
|                       fileE.bmp
|                       fileF.pdf
|
\---target-folder
    |   AAA.png
    |
    +---#Im
    |   |   file1.txt
    |   |
    |   \---subfolder1
    |       |   fileA.txt
    |       |
    |       \---subfolder2
    |               fileD.xlsx
    |
    \---subfolder1
        |   BBB.jpg
        |
        \---subfolder2
                CCC.bmp

Alles anzeigen

Viele Grüße
Sven

**Moombas**

Auch möchte ich hier nochmal (auch wenn autoit das gerne "intern" korrigiert) darauf hinweisen das in deinem Programm eine Vermischung von Local und Global variablen passiert und keine saubere Zuweisung vorhanden ist.

Zudem ist die "simulierung des Tastendrucks Strg+C vollkommen unnötig (sollte man aus dem Handle holen) und nur weil man ein Fenster selektiert hat, heißt das nicht, das man die Adresszeile ausgewählt hat, was in deinem Code bedeutet das Strg+C entweder leer ist oder ganz was anderes enthält und zusätzlich auch noch ggf. für den User wichtiges in der Zwischenablage überschreibt.

Auch noch was hinzuzufügen, das DirCreate kann Filecopy auch (siehe Hilfe).
Daher würde mein aktueller Ansatz so aussehen ~~(Bin auf W11 und bekomme aber immer nur den 1. OrdnerTab raus, nicht den gerade aktiven, ggf. kann da wer anders ansetzen der das besser kann~~

AutoIt

Opt('MustDeclareVars', 1)

#include <FileConstants.au3>
#include <StringConstants.au3>

; Setze den Hotkey Strg + G, da Strg+Alt+G bei mir nicht funktionierte
HotKeySet('^g', "CopyFilesHotkey")
HotKeySet('{Esc}', "Cancel")

; Halte das Skript am Laufen, bis der Benutzer es beendet
While 1
	Sleep(100)    ; Warte in einer Schleife
WEnd

Func Cancel()
	Exit
EndFunc

Func CopyFilesHotkey()
Local Const $sourceFolder = 'E:\Info\#Im'
Local Const $targetFolder = GetSelectedFolder()
	; Überprüfen, ob ein Zielordner ausgewählt ist
	If IsBool($targetFolder) Then
		MsgBox(0, "Fehler", "Kein Zielordner ausgewählt oder der ausgewählte Ordner ist ungültig.")
		Return -1
	EndIf
	; Überprüfen, ob der Quellordner existiert
	If Not FileExists($sourceFolder) Then
		MsgBox(0, "Fehler", "Der Quellordner existiert nicht: " & $sourceFolder)
		Return -2
	EndIf

	; Kopiere den #Im-Ordner in den ausgewählten Zielordner und erstelle den Ordner falls noch nicht vorhanden
	Return FileCopy($sourceFolder, $targetFolder & "\#Im", $FC_OVERWRITE + $FC_CREATEPATH)
EndFunc   ;==>CopyFilesHotkey

Func GetSelectedFolder()
	Local $hWnd = WinGetHandle("[ACTIVE]")    ; Aktives Fenster ermitteln
	If Not IsHWnd($hWnd) Then Return -1
	Return _ExplorerGetItem($hWnd)
EndFunc   ;==>GetSelectedFolder


Func _ExplorerGetItem($hWnd)
    If Not IsHWnd($hWnd) Then Return -1
    Local $oSHFolderView

    $oSHFolderView = _ObjectSHFolderViewFromWin($hWnd)
    If @error Then Return -2


	If IsObj($oSHFolderView) Then

		Return $oSHFolderView.Folder.Self.Path
	Else
		Return -3
	EndIf
EndFunc   ;==>_ExplorerWinGetSelectedItems

; ==========================================================================================================================

; Func _ObjectSHFolderViewFromWin($hWnd)
;
; Returns an 'ShellFolderView' Object for the given Window handle
;
; Author: Ascend4nt, based on code by KaFu, klaus.s
; ==========================================================================================================================

Func _ObjectSHFolderViewFromWin($hWnd)
Local $DeepestFolder
    If Not IsHWnd($hWnd) Then Return SetError(1,0,0)
    Local $oShell,$oShellWindows,$oIEObject,$oSHFolderView[]

; Shell Object
    $oShell=ObjCreate("Shell.Application")
    If Not IsObj($oShell) Then Return SetError(2,0,0)

;   Get a 'ShellWindows Collection' object
    $oShellWindows = $oShell.Windows()
    If Not IsObj($oShellWindows) Then Return SetError(3,0,0)

;   Iterate through the collection - each of type 'InternetExplorer' Object

     For $oIEObject In $oShellWindows
        If $oIEObject.HWND = $hWnd Then
            ; InternetExplorer->Document = ShellFolderView object
            $oSHFolderView=$oIEObject.Document
            If IsObj($oSHFolderView) Then
				$DeepestFolder = StringRegExp($oSHFolderView.Folder.Self.Path, '([[:alpha:]]:.*\\|\\{2}.*\\|.*\/)(.*)\b', $STR_REGEXPARRAYMATCH)[1]
				If StringInStr(WinGetTitle($hWnd), $DeepestFolder) then Return $oSHFolderView
;~ 				Return SetError(4,0,0)
			Endif
        EndIf
    Next
    Return SetError(-1,0,0)
EndFunc

Alles anzeigen

**Moombas**

Ich habe mein Skript nochmal angepasst, da der Ordnername des aktiven Tab im Titel angezeigt wird, nehme ich das als Referenz um den richtigen Ordner zu bekommen. Das kopieren an sich ist hierbei noch ungetestet.

o0Julia0o

Zitat von SOLVE-SMART

Hi und willkommen im Forum o0Julia0o 👋 .
Was meinst du mit aktuell angewählt? Sprichst du vom Windows Explorer den du offen hast?
Dort bist du mit der Maus auf irgend einem Ordner und möchtest in diesen per Hotkey den "#Im" Ordner samt Inhalt kopieren?
Richtig soweit? Denn so etwa sieht dein Code (KI generiert sicherlich) aus.
Aber warum 🤔 ? Weißt du nicht sowieso von welchen Ordner du in welchen Ordner kopieren möchtest? Also ich verstehe nicht was dir das Skript bringt, wenn du einfach per Windows Explorer copy und paste genau dies auch machen kannst? Da wirst du doch gefragt ob du die bereits vorhandenen Dateien überschreiben willst oder nicht.
Mal anders gefragt:
Wie häufig möchtest du dies etwa ausführen, für wie viel verschiedene Ordner (sonst brauchst du den Hotkey ja auch nicht)?

Ja exakt. Den Ordner wo ich mit der Maus im Windows Explorer gerade reingeklickt habe. Dann drücke ich den shortcut und der Ordner wird mir kopiert. Ich kenne den Ort wovon ich kopieren möchte, aber ich muss dann nicht erst dorthin navigieren und den Ordner markieren und kopieren auswählen. Es spart halt viel Zeit, da das öfter vorkokmmt. Ich starte das script dann, per compilierter script-exe. Und danach nutze ich das dann halt häufig. Aber zwischendrin landen andere Dinge in der Zwischenablage. Daher der Hotkey. Und vielen Dank. Ich habe nur Mittagspause, wollte nur eben schonmal antworten.

o0Julia0o

Danke! Habe es jetzt mal ausgeteste und es passiert einfach nichts, wenn ich strg + alt + g drücke. Und der Quellpfad ist vorhanden und er enthält auch Dateien: E:\Info\#Im

Ich habe es aus AutoIt und mit compilierter exe probiert. Ich wähle einen Ordner an und drücke den Shortcut. Nichts passiert.

**SOLVE-SMART**

o0Julia0o im Skript von Moombas steht:

AutoIt

; Setze den Hotkey Strg + G, da Strg+Alt+G bei mir nicht funktionierte
HotKeySet('^g', "CopyFilesHotkey")

----------------------------

Ansonsten: Wenn ich intensiver darüber nachdenken würde, würde ich es sehr wahrscheinlich anders machen 😅 . Doch du hast eine spezifischen Anforderung beschrieben, die nicht generisch sein muss (im Moment), daher folgt ein kleines Beispiel welches funktioniert.

Doch zunächst zu deinen Ansatz Moombas :
Ich habe ihn nur kurz getestet ohne zu analysieren und es klappt leider nicht. Es stimmt was mit FileCopy() nicht. Des Weiteren berücksichtigst du (glaube ich) nicht, dass die vorhandenen Dateien im Zielordner nicht überschrieben werden sollen. Wenn du allerdings die Flags dazu weg lässt, wird gar nichts kopiert. Teste gern mal ausführlich - gern auch mit dem Testdaten Skript von mir oben, wenn du magst.

💡 Das folgende sollte dem entsprechen o0Julia0o wie du es beschrieben hast:

AutoIt

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y

HotKeySet('^!g', '_Copy')
HotKeySet('{ESC}', '_Exit')

While True
    Sleep(100)
WEnd

Func _Exit()
    Exit
EndFunc

Func _Copy()
    ; Assumption: You clicked ones the target folder
    ; by mouse (on Windows Explorer).
    Send('^{c}')

    Local Const $sSourceFolder = 'C:\tmp\source-folder\Info\#Im'
    Local Const $aFolderMatch = StringRegExp($sSourceFolder, "([^\\]+)$", 1)
    If @error Or Not IsArray($aFolderMatch) Then
        ConsoleWrite('Oops! Handle this unexpected behavior.' & @CRLF)
        Return
    EndIf

    Local Const $sFolder = $aFolderMatch[0]

    Local $sTargetFolder = ClipGet()
    If $sTargetFolder == '' Or StringRegExp($sTargetFolder, '[a-z|A-Z]:\\') == 0 Then
        ConsoleWrite('Oops! Handle this unexpected behavior.' & @CRLF)
        Return
    EndIf

    $sTargetFolder = $sTargetFolder & '\' & $sFolder

    ConsoleWrite('Source: ' & $sSourceFolder & @CRLF)
    ConsoleWrite('Target: ' & $sTargetFolder & @CRLF)

    Run(StringFormat('robocopy "%s" "%s" /E /XO', $sSourceFolder, $sTargetFolder), '', @SW_HIDE)
    ConsoleWrite('Done!' & @CRLF)
EndFunc

Alles anzeigen

Testing (reproduction steps):

Führe das Testdaten-Skript (Ordner- und Dateistruktur erstellen) oben aus.
Navigiere im Windows Explorer nach C:\tmp\target-folder\#Im\subfolder1.
Bearbeite dort fileA.txt in dem du den "dummy content" einfach durch einen anderen Text ersetzt. Datei speichern.
Navigiere im Windows Explorer nach C:\tmp\target-folder.
Selektiere den Ordner mit einen Klick.
Drücke Tastenkombi. STRG+ALT+G.
Schaue dir den Ordner C:\tmp\target-folder\#Im genau an. Es sollten statt "3 Dateien, 2 Ordner" nun "9 Dateien, 2 Ordner" in den Ordnereigenschaften zu sehen sein.
Schaue dir die bearbeitete Datei an, diese hat deinen neuen Text und wurde nicht überschrieben.

Ich habe bewusst nicht mit FileCopy() gearbeitet, da es in keiner meiner Konstellationen für genau das beschriebene Szenario funktioniert hat. Auch DirCopy() half nicht. Somit bin ich auf's gute alte "robocopy" was seit Windows Vista (glaube ich) Standard ist, ausgewichen.

Viele Grüße
Sven

----------------------------

Update1:
Es wird bewusst kein intensives error handling gemacht und auch keine UNC-Pfade berücksichtigt (kleiner lieber "wink" an AspirinJunkie 😚 😂), da ich davon ausgehe, dass einmalig im Windows Explorer auf den Zielordner geklickt wird und dann der HotKey getriggert wird. Daher meine Einschätzung das es nicht generisch bzw. robuster sein muss.

Update 2:
Das man das Ergebnis von robocopy auswerten und ggf. berücksichtigen sollte (Fehler beim kopieren), wäre ein sinnvolles TODO 🤝 .

**AspirinJunkie**

Zitat von SOLVE-SMART

(kleiner lieber "wink" an AspirinJunkie 😚 😂),

Naja da ich schonmal angesprochen wurde, hab ich mir dann doch schon bisschen Gedanken gemacht darüber.
Mir ist dabei vor allem der Aspekt aufgestoßen, dass das Erkennen der aktuell ausgewählten Ordner evtl. etwas wacklig sein könnte.
Nun ist es jedoch so, dass man die ausgewählten Dateien eines Explorerfensters auch robust ermitteln kann.

Vielleicht könnt ihr daher ja folgendes zumindest als Grundkonstrukt verwenden?:

AutoIt

#include <Array.au3>
#include <WinAPIShPath.au3>


Global $mSelExpFiles = _getSelectExplorerFiles(False)

For $sPath in MapKeys($mSelExpFiles)
	$aSelected = $mSelExpFiles[$sPath]
	_ArrayDisplay($aSelected, $sPath)
Next


; #FUNCTION# ====================================================================================================================
; Name ..........: _getSelectExplorerFiles()
; Description ...: Returns a map of currently opened explorers with the opened path as key and an array with the selected files as value
; Syntax ........: _getSelectExplorerFiles($bFullpath = True)
; Parameters ....: bFullpath - [Boolean]
;                            ↳ true: the full path of the selected files are returned
;                            ↳ false: only the names of the selected files are returned
; Return value ..: Success: [Map]: opened path as key and an array with the selected files as value (@extended = number of returned founds)
;                  Failure: Null and set @error to:
;                           | 1: error during open Shell.Application
; Author ........: AspirinJunkie
; Modified.......: 2025-03-07
; Remarks .......: If you have opened the same path several times: you're out of luck - it will only be returned once ;-)
; Related .......: _WinAPI_PathCreateFromUrl()
; Link ..........: https://www.netlib.org/lapack/explore-html/dd/dc3/group__trsv_ga7a7dcbb8745b4776ce13063ab031141f.html#ga7a7dcbb8745b4776ce13063ab031141f
; Example .......: No
; ===============================================================================================================================
Func _getSelectExplorerFiles($bFullpath = True)
	Local $oShell = ObjCreate("Shell.Application"), _
	      $oWin, $oSelectedFiles, $iC, $mReturn[]

	If Not IsObj($oShell) Then Return SetError(1, 0, Null)

	For $oWin in $oShell.Windows
		$oSelectedFiles = $oWin.Document.SelectedItems()
		If (Not IsObj($oSelectedFiles)) Then ContinueLoop

		Local $aSelected[$oSelectedFiles.Count]
		$iC = 0

		For $oFile In $oSelectedFiles
			$aSelected[$iC] = $bFullpath ? $oFile.Path : $oFile.Name
			
			$iC += 1
		Next

		$mReturn[_WinAPI_PathCreateFromUrl($oWin.LocationURL)] = $aSelected
	Next

	Return SetExtended(UBound($mReturn), $mReturn)
EndFunc

Alles anzeigen

Das kann man natürlich noch erweitern indem man die Windows-Handles zurückgibt um Herauszufinden, welches Explorerfenster ganz oben steht (also das letzte geöffnete) usw.

o0Julia0o

Zitat von SOLVE-SMART

Drücke Tastenkombi. STRG+ALT+G.
Schaue dir den Ordner C:\tmp\target-folder\#Im genau an. Es sollten statt "3 Dateien, 2 Ordner" nun "9 Dateien, 2 Ordner" in den Ordnereigenschaften zu sehen sein.
Schaue dir die bearbeitete Datei an, diese hat deinen neuen Text und wurde nicht überschrieben.

Danke! Ich habe die ganzen Schritte so ausgeführt. Also Strg + G sollte ja reichen. Nein, es bleibt bei 3 Dateien, 2 Ordner. Der Text wurde nicht überschrieben.

Aber es liegt daran, dass nichts geschrieben wurde, sehe ich ja an dem Ordnerdatum.

Den Ordner, wo der #Im-Ordner hineinkopiert werden soll, dort habe ich mit der linken Maustaste einmal hineingeklickt oder bin dort hineingetabbt. Also nicht auf die URL oder den Ordnernamen an sich(habe ich auch mal testweise gemacht, tat ber auch nicht).

Wenn kein #Im-Ordner vorhanden ist, soll dieser halt erstellt werden bzw. ja vom Quellordner genommen werden. Im #Im-Ornder soll nichts überschrieben werden. Nur ergäntzt, was im Quell-#Im-Ordner vorhanden ist und im Ziel-#Im-Ornder nicht.

**SOLVE-SMART**

o0Julia0o bitte schaue dir dies kurz an. Ich hoffe es ist verständlich und du kannst mich danach aufklären ob ich dich einfach falsch verstanden habe, wir aneinander vorbei reden/schreiben oder ob du es dir anders vorgestellt hast?

🎬 Erklärungs-Video

Danke und viele Grüße
Sven

o0Julia0o

wow, danke Dir! Also ja, genau so soll es stattfinden. Habe ich auch so probiert. Hat nicht funktioniert. Wobei ich grundsätzlich lieber in den Ornder klicke mit der Maus, und nicht auf den Ordnernamen. Habe es nochmal getestet, jetzt funktioniert es bei Klick auf den Ordnernamen. Aber ich möchte ja in das Fenster klicken, das ist im Alltag deutlich schneller und einfacher:

o0Julia0o

was nutzt du da für ein Tool überhaupt, wo man unten sehen kann, Output, debugging, terminal?

Ich kann nicht unter Bildern Text schreiben, daher neuer Post. Jetzt funktioniert das auch, wenn ich einfach in den Zielordner geklickt habe. Supi! freu!

Vermutlich hatte ich das Script nicht aktiv? Sobald man auf das icon rechts- oder linksklickt kommt das rote Symbol blinkend, dass das Scritp nicht aktiv ist. Das Häkchen davor spielt aber keine Rolle. Von daher komme ich damit immer durcheinander, ob ein Script gerade aktiv ist oder nicht.

**SOLVE-SMART**

Morgen oder am Montag gern mehr Details (zum Tooling usw.) - ich bin gleich offline.

Auf deine Frage mit "im Ordner sein" und dann den HotKey auslösen:
Schau dir bitte die Antworten von Moombas und AspirinJunkie an und versuche zu verstehen was getan wird. Ansonsten einfach weiter so - immer fragen 😅 .

Viele Grüße
Sven

o0Julia0o

Danke! Vielleicht kannste das auch noch am Montag beantworten:

Code

 If @error Or Not IsArray($aFolderMatch)

bedeutet, wenn er den Quellordner nicht findet. Aber die Then-Sache wird gar nicht ausgeführt, wenn ich eine Messagebox so ergänze:

Code

Local Const $aFolderMatch = StringRegExp($sSourceFolder, "([^\\]+)$", 1)
   If @error Or Not IsArray($aFolderMatch) Then
       ConsoleWrite('Oops! Handle this unexpected behavior.' & @CRLF)
    MsgBox(0, "Fehler", "Der Quellordner existiert nicht: " & $sourceFolder)
       Return

Das mit dem Ordner auswählen klappt nicht wirklich zuverässig. Ich muss oft den Ordnernamen angklicken, damit es klappt. Also den targed-folder. Wenn ich IN den targed-folder klicke, klappt das script nur selten. Wobei ich genau das eigentlich nur so nutze. Habe es gerade >20x hintereinander probiert. Klappt nicht.

**SOLVE-SMART**

Nein, so wie im Erklärvideo gezeigt und gesagt: meine Variante funktioniert nur, wenn du einen Ordner angeklickt hast und dann die Tastenkombi. drückst. Es wird dann der Ordner Pfad in die Zwischenablage kopiert und dann läuft alles super.

Das es bei dir gestern einmal geklappt hat, als du einfach im Ordner auf eine Freifläche geklickt hast liegt mit Sicherheit daran, dass der Ordnerpfad noch in der Zwischenablage war und es daher zufällig geklappt hat.

Daher schrieb ich auch schaue dir bitte die beiden anderen Vorschläge an, denn da wird der Ordnerpfad anders ermitteln.

Viele Grüße
Sven

**SOLVE-SMART**

Tritt dem AutoIt Community Projects-Discord-Server bei!

Your space to collaborate (in english or german) with other AutoIt enthusiast regarding shared projects and more. | 20 Mitglieder

discord.gg

Komme gern auf den Discord Server, denn da könnte ich per Audio-Call oder sogar per Video-Call einfacher erklären was du tun müsstest damit es so klappt wie du es dir erhoffst.

Es ist zwar alles bereits da (hier geschrieben/vorgeschlagen worden), doch du stehst mit AutoIt noch recht am Anfang, habe ich das Gefühl o0Julia0o .

**SOLVE-SMART**

Mit diesem Skript o0Julia0o (Abwandlung von Moombas Vorschlag), kannst du deine Tastenkombi. (STRG+ALT+G im Moment) direkt im Ordner anwählen und es funktioniert. Du musst nicht wie in der anderen Variante von mir, den Zielordner anklicken sondern einfach darin sein und los geht's.

AutoIt

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
#AutoIt3Wrapper_Outfile_x64=my-robocopy-action.exe

HotKeySet('^!g', '_Copy')
HotKeySet('{ESC}', '_Exit')

While True
    Sleep(100)
WEnd

Func _Exit()
    Exit
EndFunc

Func _Copy()
    Local Const $iErrorIcon      = 16
    Local Const $iInfoIcon       = 64
    Local Const $iArrayMatchFlag = 1

    Local Const $sSourceFolder = 'C:\tmp\source-folder\Info\#Im'
    Local Const $aFolderMatch  = StringRegExp($sSourceFolder, '([^\\]+)$', $iArrayMatchFlag)
    If @error Or Not IsArray($aFolderMatch) Then
        MsgBox($iErrorIcon, 'Error', 'Oops! Check source folder path and RegEx pattern.')
        _Exit()
    EndIf

    Local Const $sFolder = $aFolderMatch[0]

    ; Assumption: You have opened your target folder
    ; via Windows Explorer.
    Local $sTargetFolder = _GetWindowsExplorerFolderPath()
    If @error Then
        MsgBox($iErrorIcon, 'Error', 'Error code: ' & @error)
        _Exit()
    EndIf
    If $sTargetFolder == '' Or StringRegExp($sTargetFolder, '[a-z|A-Z]:\\') == 0 Then
        MsgBox($iErrorIcon, 'Error', 'Oops! Unexpected target folder path structure.')
        _Exit()
    EndIf

    ; Robocopy copies without overwriting
    Run(StringFormat('robocopy "%s" "%s" /E /XO', $sSourceFolder, $sTargetFolder & '\' & $sFolder), '', @SW_HIDE)
    If @error Then
        MsgBox($iErrorIcon, 'Error', 'Oops! Robocopy Run() was not okay.')
        _Exit()
    EndIf

    Local Const $iTimeout = 30
    MsgBox($iInfoIcon, 'Done', 'Copy action completed.', $iTimeout)
EndFunc

Func _GetWindowsExplorerFolderPath()
    Local Const $oShell = ObjCreate('Shell.Application')
    If @error Then
        Return SetError(1)
    EndIf

    Local Const $hActiveWindows = WinGetHandle('[ACTIVE]')
    If @error Then
        Return SetError(2)
    EndIf

    For $oWindow In $oShell.Windows
        If $oWindow.HWND <> $hActiveWindows Then
            ContinueLoop
        EndIf

        Return $oWindow.document.Folder.Self.Path
    Next

    Return SetError(3)
EndFunc

Alles anzeigen

💡 Ich habe nun auch die ConsoleWrite() Aufrufe durch MsgBox() Aufrufe ersetzt, weil du schriebst du wirst das kleine Tool (Skript/Programm) als *.exe kompilieren.

----------------------------

Nichts destotrotz könnte ich mir vorstellen, dass du weitere Fragen haben wirst, daher meine Empfehlung: Discord Server und somit Live Hilfe (wenn man eine Zeit entsprechend ausmacht).

Viele Grüße
Sven

o0Julia0o

Wow, genauso hatte ich mir das vorgestellt. Jetzt läuft es perfekt. Und ja genau, die Consolenauskunft hilft mir nicht so viel als Exe. Nochmals vielen Dank SOLVE-SMART!

**Moombas**

Dann brauch ich meins ja nicht weiter prüfen
Wo da nun bei mir der #Fehler lag schaue ich mir ggf. später nochmal an, denn zumindest bei mir hatte zumindest es geklappt, den Pfad des aktiven Ordners zu bekommen, das kopieren hatte ich dann nicht mehr geprüft. Aber SOLVE-SMART :

"Des Weiteren berücksichtigst du (glaube ich) nicht, dass die vorhandenen Dateien im Zielordner nicht überschrieben werden sollen."

Da habe ich seine Vorlage genommen: FileCopy($sourceFolder, $targetImFolder, 1) ; 1 = Überschreibe, wenn der Ordner bereits existiert
Daher bin ich auch wegen dem Kommentar davon ausgegangen das es Überschreiben soll.

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)