PowerShell srcipt von Autoscript

quasimodoz

Ich möchte ein winziges PowerShell script von Autoit aus aufrufen. Das klappt auch ganz gut, leider bekomme ich keine Returnwerte von PowerShell Script. Kann mir da jemand einen Tipp geben.

So sieht mein Autoscript aus:

Local $X = Runwait("powershell.exe d:\Wilfried\Desktop\mod.ps1", "", @SW_Maximize)

Msgbox(0,"Test",$X)

und so mein PowerShell sript:

$Sessions = Get-smbsession

if ($sessions) {

write-host "Sessions found"

return (1)

}

else {

write-host "No sessions found"

return (0)

}

Leider wird immer 0 zurückgegeben, egal ob eine Verbindung gefunden wurde oder nicht.

**BugFix**

Funktioniert denn dein PS Skript in der PS-Shell?

Hier ein Bsp. aus einem anderen Thread, wie man PS in AutoIt ausführen kann.

AutoIt

Global $sProcess = 'chrome.exe'
Global $sPathOutFile = 'C:\Code\chrome_processlist.txt'


Global $sCmdPS = _
'Get-WmiObject Win32_Process -Filter "name = ''' & $sProcess & '''" | Select-Object CommandLine | ' & _
'Format-Table -Property * -AutoSize | Out-String -Width 4096 | Out-File -FilePath ' & $sPathOutFile


_PowerShell_Run($sCmdPS)


Func _PowerShell_Run($_sCmd, $_iOutput=0)
    Local Const $sKey32 = "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\PowerShell\1\ShellIds\Microsoft.PowerShell"
    Local Const $sKey64 = "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\PowerShell\1\ShellIds\Microsoft.PowerShell"
    Local Static $sKey = @CPUArch = 'X64' ? $sKey64 : $sKey32
    Local Static $sPSexe = RegRead($sKey, 'Path')
    Local $sPathTMP = StringFormat('%s\__%s%s%s%s%s%s%s.ps1', @TempDir, @YEAR, @MON, @MDAY, @HOUR, @MIN, @SEC, @MSEC)
    Local $fH = FileOpen($sPathTMP, 2+8+128)
    FileWrite($fH, $_sCmd)
    FileClose($fH)
    Local $sRun = StringFormat('%s -ExecutionPolicy UnRestricted -File %s', $sPSexe, $sPathTMP)
    Local $sOut = '', $iPID = Run($sRun, @ScriptDir, @SW_HIDE, 0x2)
    If $_iOutput = 1 Then
        Do
            $sOut &= StdoutRead($iPID)
        Until @error
        StdioClose($iPID)
    Else
        While ProcessExists($iPID)
            Sleep(350)
        WEnd
    EndIf
    FileDelete($sPathTMP)
    Return ($_iOutput = 1 ? $sOut : 1)
EndFunc

Alles anzeigen

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi quasimodoz ,

BugFix hat dir bereits eine Variante aufgezeigt, wie du Powershell in AutoIt nutzen kannst bzw. wie du mit dem Output umgehen kannst.

Hier mal noch eine weitere, über die Zwischenablage:

AutoIt

Global $sPowershellFilePath = @ScriptDir & '\PowershellScript.ps1'
Global $sPowershellCode     = 'Get-Process | Select-Object -Property Id, ProcessName | Set-Clipboard'
Global $sPowershellResult   = _ExecutePowershellCode($sPowershellCode)

ConsoleWrite($sPowershellResult & @CRLF)

Func _ExecutePowershellCode($sCode)
    _DeleteTempFile()
    _WriteFile($sPowershellFilePath, $sCode)
    _ExecutePowershell()
    _DeleteTempFile()

    Return ClipGet()
EndFunc

Func _DeleteTempFile()
    FileDelete($sPowershellFilePath)
EndFunc

Func _WriteFile($sFile, $sText)
    Local Const $iUtf8WithoutBomAndOverwriteCreationMode = 256 + 2 + 8

    Local $hFile = FileOpen($sFile, $iUtf8WithoutBomAndOverwriteCreationMode)
    FileWrite($hFile, $sText)
    FileClose($hFile)
EndFunc

Func _ExecutePowershell()
    Local $sPowershellCall = 'powershell -executionpolicy bypass -File'
    ShellExecuteWait(@ComSpec, '/C ' & $sPowershellCall  & ' "' & $sPowershellFilePath & '"', '', '', @SW_HIDE)
EndFunc

Alles anzeigen

Ich gehe hier davon aus, dass powershell in den Umgebungsvariablen zu finden ist.
Desweiteren wird auf Abschluss des Powershell Aufrufs gewartet => ShellExecuteWait.
Danach ist das Ergebnis in der Zwischenablage und von dort kannst du ja machen was du willst 😅 .

Oftmals transformiere ich das Ergebnis in ein Array und von dort geht es dann weiter, je nach Bedarf.
Hilfreich kann auch sein, wenn du noch vor | Set-Clipboard ein Konvertierungs-Commandlet setzt wie bspw. ConvertTo-Json oder ConvertTo-Csv (Html, Xml) etc.

Get-Process | Select-Object -Property Id, ProcessName | ConvertTo-Json | Set-Clipboard

Update

So oder so ähnlich (musst du anpassen), könnte dann dein PS-Code aus post #1 aussehen.

AutoIt

Global $sPowershellCode     = _
    '$Test = "This is a test"' & @CRLF & _
    @CRLF & _
    'if ($Test -eq "This is my test") {' & @CRLF & _
    '    1  | Set-Clipboard' & @CRLF & _
    '} else {' & @CRLF & _
    '    2 | Set-Clipboard' & @CRLF & _
    '}'

Viele Grüße
Sven

quasimodoz

Vielen Dank für eure Anworten.

Ja, mein kleines script fuktioniert wunderbar, wenn ich es mit Adminrechten starte.

Ich hatte nun erwartet, dass der Aufruf direkt ein Resultat (true| false) zurückliefert. Da ist wohl nicht so und deshalb habt Ihr so schöne scripte geschrieben und damit von hinten durch die Brust ins Auge getroffen. 😀

Dann muss ich wohl in den sauren Apfel beißen. Aber noch einmal: Besten Dank.

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi quasimodoz ,

was genau meinst du damit?

Zitat von quasimodoz

Dann muss ich wohl in den sauren Apfel beißen.

Dein Skript funktioniert und du kannst es mit AutoIt nutzen aber du magst nicht den Weg wie du die Rückgabewerte des PS-Skript bekommst?
Oder was genau meinst du?

Also kurz gesagt, brauchst du noch weitere Hilfe/Tipps/Unterstützung oder ist das Thema für dich abgeschlossen?
Falls ja, dann kannst du es gern als solches, "erledigt", markieren 😀 .

Viele Grüße
Sven

**Schnuffel**

Hallo,

ich denke dein Aufruf ist nicht ganz korrekt.

AutoIt

Local $X = Runwait("powershell.exe d:\Wilfried\Desktop\mod.ps1", "", @SW_Maximize)

bitte ersetze das mal durch:

AutoIt

$iPID = Run("powershell.exe" & ' -ExecutionPolicy ByPass -File "d:\Wilfried\Desktop\mod.ps1"', "", @SW_Maximize, 0x2)
ProcessWaitClose($iPID)
ConsoleWrite(StdoutRead($iPID) & @CRLF)

ich denke die "0" die du immer zurückbekommst sagt lediglich aus, dass dein Powershell Skript an sich ohne Fehler beendet wurde.

Durch den Stream "0x2" = Stdout wird das Return des Skriptes selbst weitergeleitet.

Dieses kann durch StdoutRead ausgelesen werden. (in der autoit Hilfe kannst du das unter "StdOutRead" nachlesen)

Wenn Du nur mit 0 / 1 arbeitest, kann autoit dass auch als False / True verarbeiten.

Achtung, autoit macht es genau andersrum wie alle anderen^^

0 = nicht erfolgreich

1 = erfolgreich

Einzig: zwischen dem Aufruf deines PS-Skript's und dem auslesen des Stdout darf kein anderer Befehl dazwischen laufen.

Ansonsten ist der Stream verworfen und leer.

vergleiche:

AutoIt

$iPID = Run("powershell.exe" & ' -ExecutionPolicy ByPass -File "C:\Users\Oliver\Desktop\PS.ps1"', "", @SW_HIDE, 0x2)
ProcessWaitClose($iPID)

ConsoleWrite(StdoutRead($iPID) & @CRLF)
If StdoutRead($iPID) = True Then MsgBox(0, "", "juhu")

und

AutoIt

$iPID = Run("powershell.exe" & ' -ExecutionPolicy ByPass -File "C:\Users\Oliver\Desktop\PS.ps1"', "", @SW_HIDE, 0x2)
ProcessWaitClose($iPID)
If StdoutRead($iPID) = True Then MsgBox(0, "", "juhu")
ConsoleWrite(StdoutRead($iPID) & @CRLF)

quasimodoz

Vielen Dank für Eure Hilfe. Der Weg über die Zwischenablage scheint mir am einfachsten gangbar, obwohl es mich nach wie vor wurmt, dass nicht eine einfachere Lösung möglich ist. Ansonsten möchte ich diesen thread schließen.

Nun bin ich kein Autoit Experte und habe nur wenige scripts geschrieben. Bei der Durchsicht der Hilfefunktion ist mir aufgefallen, dass es die _Net_Share UDFs gibt. Das scheint mir ein Ansatzpunkt zu sein, auf den Umweg über die PS verzichten zu können.

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)