Code Kata - Galgenraten

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi Leute,

hier mal wieder, wie angekündigt, etwas für zwischendurch: Die "Galgenraten" Code Kata.

💡 Ziel: Ist es einen Algorithmus bestehend aus einer oder mehreren Funktionen zu schreiben, der dich "Galgenraten" in der Konsole spielen lässt.

Galgenraten
- Es wird ein Begriff (ein Wort) gesucht, welchen man versucht zu erraten. Dabei kann man entweder Buchstabe für Buchstabe eine Eingabe machen oder gleich versuchen das richtige Wort einzugeben und zu erraten.
- Man hat n Versuche, das Wort zu erraten. Falls der jeweilige eingegebene Buchstabe, nicht im gesuchten Wort vorkommt, wird die Anzahl der verbleibenden Versuche reduziert.
- Entweder man errät das Wort innerhalb seiner Versuche, dann gewinnt man, oder man verliert eben.

🥈 Teil 1: Entwickle die Funktion(en) unter Beachtung der folgenden Vorgaben. Nutze InputBox() als Eingabe¹ der Buchstaben/des Wortes und die Console als Output.

Vorgaben
- Verwende die Wörterliste word-list.au3 #include "word-list.au3" => _WordList() im Anhang, welche einfach nur ein Array mit Wörtern zurück gibt.
- Es soll möglich sein, einen Buchstabe einzugeben (InputBox()) oder auch gleich ein Wort.
- Jeder falsche Buchstabe der nicht im Wort vorkommt reduziert die Versuche.
- Die Anzahl der Versuche richtet sich nach dem zufällig ausgewähltem Wort.
  - Angenommen es wird das Wort Tauchen gesucht, welches 7 Buchstaben hat, dann soll die Versuchsanzahl 14 betragen (also doppelt so viele Versuche wie das jeweilige Wort Buchstaben hat).
- Der Begrüßungstext² des Spiels, in der Console, soll wie folgt aussehen (siehe Spoiler unten).
  - Wichtig hierbei ist die Darstellung der gesuchten Buchstaben als Unterstriche mit Leerzeichen dazwischen 😈 🤭 .
    Also aus tauchen wird _ _ _ _ _ _ _.
- Wenn ein falscher³ Buchstabe geraten wurde, sieht es so aus (siehe Spoiler unten).
- Wenn ein richtiger⁴ Buchstabe geraten wurde, sieht es so aus (siehe Spoiler unten).
- Wenn gewonnen⁵ wurde, sieht es so aus (siehe Spoiler unten).
- Wenn verloren⁶ wurde, sieht es so aus (siehe Spoiler unten).

1: Eingabe

2: Begrüßungstext

Code

+---------------+
|--GALGENRATEN--|
+---------------+

💡 Errate ein Wort mit 4 Buchstaben _ _ _ _ , aus der Kategorie Software Entwicklung.
Du hast 8 Versuche 🤹‍♂️ , jeder falsche Buchstabe reduziert deine Versuche.

3: falscher Buchstabe

Code

+---------------+
|--GALGENRATEN--|
+---------------+

💡 Errate ein Wort mit 4 Buchstaben _ _ _ _ , aus der Kategorie Software Entwicklung.
Du hast 8 Versuche 🤹‍♂️ , jeder falsche Buchstabe reduziert deine Versuche.

Wort: _ _ _ _ (7 Versuche noch)
Wort: _ _ _ _ (6 Versuche noch)

4: richtiger Buchstabe

Code

+---------------+
|--GALGENRATEN--|
+---------------+

💡 Errate ein Wort mit 4 Buchstaben _ _ _ _ , aus der Kategorie Software Entwicklung.
Du hast 8 Versuche 🤹‍♂️ , jeder falsche Buchstabe reduziert deine Versuche.

Wort: _ _ _ _ (7 Versuche noch)
Wort: _ _ _ _ (6 Versuche noch)
Wort: _ u _ _ (6 Versuche noch)

5: gewonnen

Code

+---------------+
|--GALGENRATEN--|
+---------------+

💡 Errate ein Wort mit 4 Buchstaben _ _ _ _ , aus der Kategorie Software Entwicklung.
Du hast 8 Versuche 🤹‍♂️ , jeder falsche Buchstabe reduziert deine Versuche.

Wort: _ _ _ _ (7 Versuche noch)
Wort: _ _ _ _ (6 Versuche noch)
Wort: _ u _ _ (6 Versuche noch)
Wort: r u _ _ (6 Versuche noch)
Wort: r u _ _ (5 Versuche noch)
Wort: r u _ _ (4 Versuche noch)
Wort: r u _ t (4 Versuche noch)
Wort: r u s t (4 Versuche noch)

😀 Gewonnen! 4 Versuche übrig, gut gemacht.

Alles anzeigen

6: verloren

Code

+---------------+
|--GALGENRATEN--|
+---------------+

💡 Errate ein Wort mit 4 Buchstaben _ _ _ _ , aus der Kategorie Software Entwicklung.
Du hast 8 Versuche 🤹‍♂️ , jeder falsche Buchstabe reduziert deine Versuche.

Wort: _ _ _ _ (7 Versuche noch)
Wort: _ _ s _ (7 Versuche noch)
Wort: _ _ s _ (6 Versuche noch)
Wort: _ _ s _ (5 Versuche noch)
Wort: _ _ s _ (4 Versuche noch)
Wort: _ _ s _ (3 Versuche noch)
Wort: _ _ s _ (2 Versuche noch)
Wort: _ _ s t (2 Versuche noch)
Wort: _ _ s t (1 Versuche noch)
Wort: _ _ s t (0 Versuche noch)

😥 Verloren! Das gesuchte Wort war "rust".

Alles anzeigen

🥇 Teil 2 (optional): Erweitere den Ansatz um die Möglichkeit, die Eingabe entweder direkt in der Console tätigen zu können (anstatt über InputBox() wie im Teil 1) oder überlege dir eine andere Möglichkeit (GUI, file system, what ever).

⚡ Rahmenbedingungen:

Versuche es möglichst komplett ohne Hilfsmittel und ohne Google Suche.
Zeitliche Vorstellung für diese Challenge ist um die 50 - 90 min (für Teil 1, Teil 2 muss nicht, kann jedoch gemacht werden 😄).
Wenn du eine Lösung hast und diese hier postest, dann bitte den Code in Spoiler einbinden, damit jeder selbst entscheiden kann ob er die Lösungsvariante der Anderen sehen möchte oder nicht 😉 .

Ich bin gespannt auf eure Lösungen und wünsche happy coding 👍 .

Viele Grüße
Sven

---------------------

Update: Hier noch ein Video um besser die Aufgabenstellung zu verstehen 😅 .

⚠ Disclaimer: Das folgende Video hat den Zweck (Bildungszweck), des aufbauens und teilen von Wissen. Es dient in keinster Weise dem Autor (mir) in Bezug auf Youtube, Wachstum des Kanals oder einer Monetarisierung. Falls dies als Nebenprodukt entstehen sollte, ist dies unabhängig von der Intension des Bildungszweckes hier.

---------------------

🎬 Code Kata Galgenraten (Aufgabenstellung)

Externer Inhalt www.youtube.com

Inhalte von externen Seiten werden ohne deine Zustimmung nicht automatisch geladen und angezeigt.

Durch die Aktivierung der externen Inhalte erklärst du dich damit einverstanden, dass personenbezogene Daten an Drittplattformen übermittelt werden. Mehr Informationen dazu haben wir in unserer Datenschutzerklärung zur Verfügung gestellt.

⌚ Kapitel:
00:00 Einleitung
00:31 Vorgaben beim Spiel gewinnen
02:26 Vorgaben beim Spiel verlieren
03:03 CUI (Consolen App)
04:20 Kontext für nicht Forum-Mitglieder
04:47 Frage nach Lösungsvorschlägen

📑 Inhalt:
Kurzvorstellung der Code Kata "Galgenraten" und meiner Aufgabenstellung (Vorgaben) an diese Coding Challange.

🎪 Zielgruppe:
Für die Teilnehmer der Code Kata "Galgenraten" im AutoIt Forum.
Mit der Fragestellung wie genau ist die Aufgabenstellung gemeint.

🔇 Out of scope:
Ich habe bewusst auf das Zeigen meines Codes, meiner Lösungsvariante verzichtet.
Ebenfalls wurde der Mechanismus wie man von "InputBox()" zur "Consolen App" kommt, nicht erläutert.

---------------------

💡 Eindrücke/Feedback ist natürlich erwünscht, Danke 🤝 .

**Kanashius**

Hi,

Ich dachte mir ich hab grad nen moment und könnte auch mal wieder programmieren

Nette Idee von dir.

Hier meine Lösung (Teil 1&2) ca. 80min.:

Spoiler anzeigen

AutoIt

#AutoIt3Wrapper_Change2CUI=y
#pragma compile(Console, true)

#include "word-list.au3"

Global $bConsole = false ; Change to True to enable console mode

While True
	_startGame()
	If @error Then ExitLoop
	$sRequest = _readInput($bConsole, "Möchtest du nocheinmal spielen? Ja (y) or Nein (n)?")
	If $sRequest<>"y" Then ExitLoop
WEnd

Func _startGame()
	ConsoleWrite("+---------------+"&@crlf)
	ConsoleWrite("|--GALGENRATEN--|"&@crlf)
	ConsoleWrite("+---------------+"&@crlf&@crlf)

	Local $mData[]
	$mData["word"] = _selectWord()
	$mData["letters"] = StringSplit(StringLower($mData.word), "", BitOR(1,2))
	Local $mTries[]
	$mData["tries"] = $mTries
	$mData["left"] = StringLen($mData.word)*2

	ConsoleWrite("Errate ein Wort mit "&StringLen($mData.word)&" Buchstaben "&_generateOutput($mData)&" , aus der Kategorie Software Entwicklung."&@crlf)
	ConsoleWrite("Du hast "&$mData.left&" Versuche, jeder falsche Buchstabe reduziert deine Versuche."&@crlf)

	Local $bSuccess = False
	While $mData.left>=0
		Local $sInput = _requestNextLetter($bConsole)
		If @error Then Return SetError(1, @error&":"&@extended, -1)
		$sInput = StringLower($sInput)
		If StringLen($sInput)>1 Then
			If StringLower($mData.word)=StringLower($sInput) Then
				$bSuccess = True
				ExitLoop
			EndIf
			$mData.left-=1
		Else
			If Not MapExists($mData.tries, $sInput) Then
				$mData["tries"][$sInput] = $sInput
				If Not StringInStr(StringLower($mData.word), StringLower($sInput)) Then $mData.left-=1
			EndIf
		EndIf
		If _isWordGuessed($mData) Then
			$bSuccess = True
			ExitLoop
		EndIf
		If $mData.left>=0 Then ConsoleWrite("Wort: "&_generateOutput($mData)&"("&$mData.left&" Versuche noch)"&@crlf)
	WEnd
	ConsoleWrite(@crlf)
	If $bSuccess Then
		ConsoleWrite("Gewonnen! "&$mData.left&" Versuche übrig, gut gemacht."&@crlf)
	Else
		ConsoleWrite("Verloren! Das gesuchte Wort war """&$mData.word&"""."&@crlf)
	EndIf
EndFunc

Func _isWordGuessed(ByRef $mData)
	For $i=0 To Ubound($mData.letters)-1 Step 1
		If Not MapExists($mData.tries, $mData.letters[$i]) Then return False
	Next
	return True
EndFunc

Func _generateOutput(ByRef $mData)
	Local $sResult = ""
	For $i=0 To Ubound($mData.letters)-1 Step 1
		If $i<>0 Then $sResult&=" "
		$sResult&=MapExists($mData.tries, $mData.letters[$i])?$mData.letters[$i]:"_"
	Next
	return $sResult
EndFunc

Func _selectWord()
	Local $arWords = _WordList()
	return $arWords[Random(0 ,UBound($arWords)-1 , 1)]
EndFunc

Func _requestNextLetter($bConsole=False)
	Local $sResult = _readInput($bConsole)
	If @error Then return SetError(1, @error, "")
	While $sResult = ""
		$sResult = _readInput($bConsole, "Es muss mindestens ein Zeichen eingegeben werden. Versuch es noch einmal: ")
		If @error Then return SetError(1, @error, "")
	WEnd
	return $sResult
EndFunc

Func _readInput($bConsole=False, $sText=Default, $sTitle=Default)
	If $sText = Default Then $sText = "Gib einen Buchstaben oder ein Wort ein: "
	If $sTitle = Default Then $sTitle = "Galgenraten"
	If $bConsole Then
		ConsoleWrite($sText)
		Local $sInput = ""
		While sleep(100)
			$sInput = ConsoleRead()
			If @error Then
				ConsoleWriteError("Error reading from console input. Maybe the console does not provide an STDIN."&@crlf)
				return SetError(1, 0, "")
			EndIf
			If @extended > 0 Then ExitLoop
		WEnd
		return StringReplace($sInput, @crlf, "")
	Else
		return InputBox($sTitle, $sText)
	EndIf
EndFunc

Alles anzeigen

Bin schon gespannt, was noch für Lösungen kommen.

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi Kanashius 👋 , vielen Dank fürs teilnehmen an dieser coding Challange.

Auf Grund meiner vielleicht doch nicht ausreichend eindeutigen Aufgabenstellung (Vorgaben), kam es im Ablauf deiner Lösungsvariante zu Logik-Fehlern. Also ich habe mir es angeschaut, sowohl Teil 1, als auch Teil 2 funktionieren an sich, auch wenn sich das Spiel nicht ganz so verhält, wie ich meinte.

Daher im Post#1 nun ein kurzes 🎬 Video dazu verlinkt, um den Interpretationsspielraum zu verkleinern 😅 .
Vielleicht passt du deine Variante nochmal ein wenig an, nachdem du das Video gesehen hast und deinen Ablauf mal testest bitte.

Ansonsten ist klar zu erkennen, das du weißt was du tust 😇 .
Danke und bis später. Mal schauen was da noch von den Anderen kommt 🤞 .

Viele Grüße
Sven

**AspirinJunkie**

Meine Lösung für Teil 1 (46 min.):

Spoiler anzeigen

AutoIt

#include <String.au3>
#include <GUIConstantsEx.au3>

; zufälliges (deutsches) Suchwort
Global $sWord = StringRegExp(BinaryToString(InetRead('https://random-word-api.herokuapp.com/word?lang=de')), "[[:alpha:]]+", 1)[0]

; Umlaute konvertieren
$sWord = StringReplace($sWord, 'ä', 'ae', 0, 2)
$sWord = StringReplace($sWord, 'ö', 'oe', 0, 2)
$sWord = StringReplace($sWord, 'ü', 'ue', 0, 2)
$sWord = StringReplace($sWord, 'ß', 'ss', 0, 2)

; Parameter des Suchwortes
Global Const $nWordLen = StringLen($sWord)
Global Const $aWord = StringSplit($sWord, '', 2)
Global Const $nVersuche = 8

#Region GUI
Opt("GUIOnEventMode", 1)
GUICreate("Galgenraten", 227, 119)
GUICtrlCreateLabel("Gib einen Buchstaben oder ein Wort ein.", 8, 16, 196, 17)
Global $idInput = GUICtrlCreateInput("", 8, 48, 201, 21)
Global $idStart = GUICtrlCreateButton("OK", 24, 72, 81, 33)
Global $idAbbrechen = GUICtrlCreateButton("Abbrechen", 120, 72, 73, 33)

GUISetOnEvent($GUI_EVENT_CLOSE, _raus)
GUICtrlSetOnEvent($idAbbrechen, _raus)
GUICtrlSetOnEvent($idStart, _nextChar)

; Tastenbelegung
Local $aAccelKeys[2][2] = [["{ESC}", $idAbbrechen], ["{Enter}", $idStart]]
GUISetAccelerators($aAccelKeys)

GUISetState(@SW_SHOW)

; Begrüßungstext
ConsoleWrite(StringFormat('+---------------+\n|--GALGENRATEN--|\n+---------------+\n\nErrate ein Wort mit %d Buchstaben %s.\nDu hast %d Versuche, jeder falsche Buchstabe reduziert deine Versuche.\n\n', $nWordLen, _StringRepeat("_ ", $nWordLen), $nVersuche))

Do
	Sleep(100)
Until 0

Func _raus()
	Exit
EndFunc

#EndRegion GUI

; Funktion welche bei einer Usereingabe ausgeführt wird
Func _nextChar()
	Local Static $mUsed[] ; bereits verwendete Buchstaben
	Local Static $nTries = 0, $nChars = 0
	Local Static $aLoesung[$nWordLen]

	; process input
	For $cChar In StringSplit(GUICtrlRead($idInput), '', 2)
		Local $bFound = False

		If MapExists($mUsed, $cChar) Then
			ConsoleWrite("Buchstabe " & $cChar & " bereits versucht du Trottel!" & @CRLF)
			ContinueLoop
		ElseIf Not StringRegExp($cChar, '^[a-zA-z]$') Then
			ConsoleWrite('Dein eingegebenes Zeichen "' & $cChar & '" ist kein Buchstabe' & @CRLF)
			ContinueLoop
		Else
			$mUsed[$cChar] = 1
		EndIf

		; die Eingabebuchstaben durchgehen:
		For $i = 0 To UBound($aWord) - 1

			; Buchstabe für Buchstabe mit Lösungswort vergleichen:
			If $aWord[$i] = $cChar Then
				$aLoesung[$i] = StringUpper($cChar)
				$nChars += 1
				$bFound = True
			EndIf
		Next

		; Versuchezähler hochzählen
		$nTries += $bFound ? 0 : 1

		; Lösung gefunden:
		If $nChars >= $nWordLen Then
			ConsoleWrite(StringFormat('\n:-) Gewonnen!\n%d Versuche übrig, gut gemacht!\nDas gesuchte Wort war "%s".\n\n' & @CRLF, $nVersuche - $nTries, $sWord))
			Exit
		; verloren
		ElseIf $nTries >= $nVersuche Then
			ConsoleWrite(StringFormat('\n;-( Verloren! Das gesuchte Wort war "%s".\n\n,', $sWord))
			Exit
		EndIf
	Next

	; Inputfeld löschen
	GUICtrlSetData($idInput, '')

	; Zwischenstand ausgeben:
	ConsoleWrite(StringFormat("Wort: %s (%d Versuche übrig)\n", _printLoesung($aLoesung), $nVersuche - $nTries))
EndFunc


Func _printLoesung($aWord)
	Local $sRet = ""
	For $i = 0 To UBound($aWord) - 1
		$sRet &= $aWord[$i] = "" ? "_ " : $aWord[$i] & " "
	Next
	Return StringTrimRight($sRet, 1)
EndFunc

Alles anzeigen

Und doch noch die Erweiterung auf Teil 2 (+ 20 Minuten) um optional auf der Konsole zu spielen:

Teil 2

AutoIt

#pragma compile(Console, true)

#include <String.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIProc.au3>

; cmdline-Version oder GUI-Version?
Global Const $bCMD =  StringInStr(_WinAPI_GetProcessName(_WinAPI_GetParentProcess(@AutoItPID)), 'cmd.exe') = 0 ? False : True

; zufälliges (deutsches) Suchwort
Global $sWord = StringRegExp(BinaryToString(InetRead('https://random-word-api.herokuapp.com/word?lang=de')), "[[:alpha:]]+", 1)[0]

; Umlaute konvertieren
$sWord = StringReplace($sWord, 'ä', 'ae', 0, 2)
$sWord = StringReplace($sWord, 'ö', 'oe', 0, 2)
$sWord = StringReplace($sWord, 'ü', 'ue', 0, 2)
$sWord = StringReplace($sWord, 'ß', 'ss', 0, 2)

; Parameter des Suchwortes
Global Const $nWordLen = StringLen($sWord)
Global Const $aWord = StringSplit($sWord, '', 2)
Global Const $nVersuche = 8

; Begrüßungstext
ConsoleWrite(StringFormat('+---------------+\n|--GALGENRATEN--|\n+---------------+\n\nErrate ein Wort mit %d Buchstaben %s.\nDu hast %d Versuche, jeder falsche Buchstabe reduziert deine Versuche.\n\n', $nWordLen, _StringRepeat("_ ", $nWordLen), $nVersuche))

If $bCMD = False Then ; gui-version
#Region GUI
	Opt("GUIOnEventMode", 1)
	GUICreate("Galgenraten", 227, 119)
	GUICtrlCreateLabel("Gib einen Buchstaben oder ein Wort ein.", 8, 16, 196, 17)
	Global $idInput = GUICtrlCreateInput("", 8, 48, 201, 21)
	Global $idStart = GUICtrlCreateButton("OK", 24, 72, 81, 33)
	Global $idAbbrechen = GUICtrlCreateButton("Abbrechen", 120, 72, 73, 33)

	GUISetOnEvent($GUI_EVENT_CLOSE, _raus)
	GUICtrlSetOnEvent($idAbbrechen, _raus)
	GUICtrlSetOnEvent($idStart, _guiInput)

	; Tastenbelegung
	Local $aAccelKeys[2][2] = [["{ESC}", $idAbbrechen], ["{Enter}", $idStart]]
	GUISetAccelerators($aAccelKeys)

	GUISetState(@SW_SHOW)

	; Endlosschleife um das GUI am Leben zu erhalten
	Do
		Sleep(100)
	Until 0
#EndRegion GUI

Else ; cmdline-Version
	Global $sInput
	ConsoleWrite("Eingabe: ")

	While sleep(100)
		$sInput = ConsoleRead()
		If @error Then
			ConsoleWrite("Fehler bei ConsoleRead()" & @CRLF)
			Exit
		ElseIf @extended > 0 Then
			$sInput = StringRegExpReplace($sInput, '\R', '')
			If StringLen($sInput) = 0 Then ContinueLoop

			_nextChar($sInput)
			ConsoleWrite(@CRLF & "Eingabe: ")
		EndIf
	WEnd
EndIf

Func _raus()
	Exit
EndFunc

; wrapper if gui is used
Func _guiInput()
	_nextChar(GUICtrlRead($idInput))

	; Inputfeld leeren
	GUICtrlSetData($idInput, '')
EndFunc


; Funktion welche bei einer Usereingabe ausgeführt wird
Func _nextChar($sInput)
	Local Static $mUsed[] ; bereits verwendete Buchstaben
	Local Static $nTries = 0, $nChars = 0
	Local Static $aLoesung[$nWordLen]

	; Console aufräumen
	RunWait(@ComSpec & " /C  CLS", "", @SW_HIDE)

	; process input
	For $cChar In StringSplit($sInput, '', 2)
		Local $bFound = False

		If MapExists($mUsed, $cChar) Then
			ConsoleWrite("Buchstabe " & $cChar & " bereits versucht du Trottel!" & @CRLF)
			ContinueLoop
		ElseIf Not StringRegExp($cChar, '^[a-zA-z]$') Then
			ConsoleWrite('Dein eingegebenes Zeichen "' & $cChar & '" ist kein Buchstabe' & @CRLF)
			ContinueLoop
		Else
			$mUsed[$cChar] = 1
		EndIf

		; die Eingabebuchstaben durchgehen:
		For $i = 0 To UBound($aWord) - 1

			; Buchstabe für Buchstabe mit Lösungswort vergleichen:
			If $aWord[$i] = $cChar Then
				$aLoesung[$i] = StringUpper($cChar)
				$nChars += 1
				$bFound = True
			EndIf
		Next

		; Versuchezähler hochzählen
		$nTries += $bFound ? 0 : 1

		; Lösung gefunden:
		If $nChars >= $nWordLen Then
			ConsoleWrite(StringFormat('\n:-) Gewonnen!\n%d Versuche übrig, gut gemacht!\nDas gesuchte Wort war "%s".\n\n' & @CRLF, $nVersuche - $nTries, $sWord))
			Exit
		; verloren
		ElseIf $nTries >= $nVersuche Then
			ConsoleWrite(StringFormat('\n;-( Verloren! Das gesuchte Wort war "%s".\n\n', $sWord))
			Exit
		EndIf
	Next

	; Zwischenstand ausgeben:
	ConsoleWrite(StringFormat("Wort: %s (%d Versuche übrig)\n", _printLoesung($aLoesung), $nVersuche - $nTries))
EndFunc


Func _printLoesung($aWord)
	Local $sRet = ""
	For $i = 0 To UBound($aWord) - 1
		$sRet &= $aWord[$i] = "" ? "_ " : $aWord[$i] & " "
	Next
	Return StringTrimRight($sRet, 1)
EndFunc

Alles anzeigen

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi AspirinJunkie 👋 ,

nur ganz kurz, bin auf dem Sprung: Ich glaube es wäre gut wenn du GUICreate("Galgenraten", 227, 119, 4115, -62) bspw. zu GUICreate("Galgenraten", 227, 119) änderst, damit User die nicht deine Monitoraufteilung haben, die GUI auch angezeigt bekommen 😅 oder ist dies Absicht?

Später mehr zum Code und Spielverhalten ... muss ab und an auch mal arbeiten 🤣 .
Viele Grüße
Sven

**AspirinJunkie**

Ups - stimmt.
Bin nicht so der GUI-Experte

**SOLVE-SMART** · Poweruser seit 21.01.2023

Das du im Backend ein absoluter Held 🦸‍♂️ bist (ist nicht ironisch), weiß man ja mittlerweile, doch das GUI Handling mit GuiOnEventMode ist doch nicht schlecht.
So 'ne Kleinigkeit ist nicht der Rede wert. Wie gesagt, später mehr (Bewertung der Lösung) 🤝 .

**Moombas**

Hier ist meine Variante für Teil 1 (ggf. etwas umständlich und 1-2 Sachen zusätzlich XD).

Ca. 52 Min.

Edit: Hatte die Version ohne die Konsolenausgabe für doppelte Buchstaben kopiert (die Prüfung darauf war bereits enthalten) XD hier mal nachgeliefert.

Spoiler anzeigen

AutoIt

Opt('MustDeclareVars', 1)

#include "word-list.au3"
#include <Array.au3>
#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>


Global Const $aWords   = _WordList()


_start($aWords)

Func _start(Const $Words, $tries = 8)
Local $input, $hit, $text, $used[0]
Local $search = StringLower($Words[Random(0, Ubound($Words, $UBOUND_ROWS) - 1)])
Local Const $Title  = 'Galgenraten'
Local Const $Lost = @CRLF & 'Verloren! Das gesuchte Wort war "' & $search & '".' & @CRLF
Local Const $searchComplete = $search
	$search = Stringsplit($search, '')
Local $Greeting = '+---------------+' & @CRLF & _
				  '|--' & StringUpper($Title) &'--|' & @CRLF & _
				  '+---------------+' & @CRLF & @CRLF & _
				  'Errate ein Wort mit ' & $search[0] & ' Buchstaben'
	For $Char = 1 to $search[0]
		$Greeting &= ' _'
	Next
	$Greeting &=  ' , aus der Kategorie Software Entwicklung.' & @CRLF & _
				  'Du hast ' & $tries & ' Versuche, jeder falsche Buchstabe reduziert deine Versuche.' & @CRLF &@CRLF
	Consolewrite($Greeting)

	_ArrayColInsert($search, 1)
	For $Row = 1 to $search[0][0]
		$search[$Row][1] = '_'
	Next
	While 1
		$input = StringSplit(StringLower(InputBox($Title, 'Gib einen Buchstabe oder Wort ein.')), '')
		If $input[0] = 0 Then Return False
		If ($input[0] > $search[0][0]) and _
			$input[0] <> 1 then
			Consolewrite('Du hast ein zu langes Wort eingegeben. Versuche es nochmal.' & @CRLF)
			$tries -= 1
			_Try($search, $tries)
		ElseIf $input[0] > 1 Then
			$text = ''
			For $Char = 1 to $input[0]
				$text &= $input[$Char]
			Next
			If $text = $searchComplete Then
				_Won($tries)
				Return True
			Else
				$tries -= 1
				_Try($search, $tries)
			EndIf
		ElseIf $input[0] = 1 Then
			$hit = false
			If _ArraySearch($used, $input[1]) = -1 Then
				_ArrayAdd($used, $input[1])
				For $Char = 1 to $search[0][0]
					If $input[1] = $search[$Char][0] then
						$search[$Char][1] = $search[$Char][0]
						$hit = true
					EndIf
				Next
			Else
				Consolewrite(@CRLF & 'Diesen Buchstaben hast du bereits ausprobiert!' & @CRLF)
			EndIf
			If not $hit Then $tries -= 1

			_Try($search, $tries)
		EndIf

		If $tries = 0 then
			ConsoleWrite($Lost)
			Return False
		Else
			If _ArraySearch($search, '_') = -1 Then
				_Won($tries)
				Return True
			EndIf
		EndIf
	WEnd
EndFunc

Func _Try(Const $aArray, Const $iTries)
Local $text = 'Wort:'
	For $Row = 1 to $aArray[0][0]
		$text &= ' ' & $aArray[$Row][1]
	Next
	$text &= ' (' & $iTries & ' Versuche noch)' & @CRLF
	ConsoleWrite($text)
EndFunc

Func _Won(Const $iTries)
	Consolewrite(@CRLF & 'Gewonnen! ' & $iTries & ' Versuche übrig, gut gemacht.' & @CRLF)
EndFunc

Alles anzeigen

**Schnuffel**

so hier mein kurzer Ansatz. Hab Online-Schulung und es immer nebenbei gemacht. Zeitansatz kann ich nicht sagen

Spoiler anzeigen

AutoIt

Global $InputBox, $Platzhalter, $nTreffer, $nCountFound, $aWortliste = _WordList()
Global $aWortVorgabe = StringSplit($aWortliste[Random(1, $aWortliste[0], 1)], '')
Global $aWortSuche = $aWortVorgabe
Global $sSuchwort
For $i = 1 To $aWortSuche[0]
	$aWortSuche[$i] = "_"
	$Platzhalter &= " _"
	$sSuchwort &= $aWortVorgabe[$i]
Next
$nCount = $aWortSuche[0]
ConsoleWrite('' & _
		"+---------------+" & @CRLF & _
		"|--GALGENRATEN--|" & @CRLF & _
		"+---------------+" & @CRLF & _
		"Errate ein Wort mit " & $aWortVorgabe[0] & " Buchstaben" & $Platzhalter & " , aus der Kategorie Software Entwicklung." & @CRLF & _
		"Du hast " & $aWortVorgabe[0] & " Versuche, jeder falsche Buchstabe reduziert deine Versuche" & @CRLF)

While 1
	$InputBox = InputBox('GALGENRATEN', 'Gib einen Buchstaben oder ein Wort ein.')
	If @error > 0 Then
		ConsoleWrite("Du hast das Spiel abgebrochen!" & @CRLF)
		Exit
	EndIf
	If StringLen($InputBox) = 1 Then
		$Platzhalter = ""
		$nTreffer = 0
		For $i = 1 To $aWortSuche[0]
			If $InputBox = $aWortVorgabe[$i] Then
				$nTreffer = 1
				$nCountFound += 1
				$aWortSuche[$i] = $InputBox
			EndIf
		Next
		If $nTreffer = 0 Then $nCount -= 1
		If $nCount = 0 Then
			ConsoleWrite('Verloren! Das gesuchte Wort war "' & $sSuchwort & '"' & @CRLF)
			Exit
		Else
			For $j = 1 To $aWortSuche[0]
				$Platzhalter &= " " & $aWortSuche[$j]
			Next
			ConsoleWrite("Wort:" & $Platzhalter & " (" & $nCount & " Versuche noch)" & @CRLF)
		EndIf
		If $aWortSuche[0] = $nCountFound Then
			ConsoleWrite("Gewonnen! " & $nCount & " Versuche übrig, gut gemacht." & @CRLF)
			Exit
		EndIf
	EndIf
WEnd
Exit

Func _WordList()
	Local $sList = _
			'autoit|' & _
			'c#|' & _
			'go|' & _
			'java|' & _
			'javascript|' & _
			'matlab|' & _
			'php|' & _
			'python|' & _
			'ruby|' & _
			'sql'
	Return StringSplit($sList, '|')
EndFunc

Alles anzeigen

**Moombas**

Schnuffel hab es mal in einen Spiler gepackt

**Schnuffel**

upps, ja danke hab ich nicht dran gedacht.

Danke

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi liebe Leute 👋 ,

Danke für eure Einsendungen 👍 . Allerdings darf ich auch bekannt geben, dass sich keines der Programme/Skripte bisher so verhält wie ich es "versucht habe" in den Vorgaben zu beschreiben/vorzugeben => mit anderen Worten: Macht die Glotzen oof beim lesen oder guggt mein Video dazu .

💡 Nein wirklich vielen Dank. Mir ist klar das ihr das mal zwischendurch gemacht habt und genau so war ja auch die Intension, etwas Abwechslung.
⚠ Ich versuche mal die Unterschiede etwas zu beleuchten/aufzulisten.

Bisher kann ich sagen das ihr alle die Coding Challenge (erfolgreich) absolviert habt 👌 .
Wenn es auch hier und da Unterschiede bei euren Lösungen gibt. Die programmatischen Hürden sind bisher keine für euch, eher die "hab' ich das nun wirklich richtig verstanden was der da von mir will 🤔" 🤭 .

Also ich melde mich mit 'ner kleinen Auflistung von Abweichungen usw.
Weiterhin einen angenehmen Tag euch allen noch.

Viele Grüße
Sven

**AspirinJunkie**

Zitat von SOLVE-SMART

Allerdings darf ich auch bekannt geben, dass sich keines der Programme/Skripte bisher so verhält wie ich es "versucht habe" in den Vorgaben zu beschreiben/vorzugeben

Das war an 2 Stellen bei mir auch bewusst so gemacht.

Die vorgebene Wortliste - gefiel mir einfach nicht, weswegen ich die Online-API genommen habe (damit ist aber auch die Kategorieangabe raus)
Die Anzahl der Versuche richtet sich nach dem zufällig ausgewähltem Wort:
Die Methodik der Verdopplung war für mich hierbei fachlich nicht nachvollziehbar.
Denn: Wenn ein Wort 9 verschiedene Buchstaben hat, dann ist die Anzahl der maximalen Fehlversuche 18.
Das bedeutet, dass man schlicht gar nicht mehr verlieren kann, da es mehr Fehlversuche gibt als mögliche Fehlbuchstaben.
Daher schlage ich einen Ansatz vor, welcher versucht die Wahrscheinlichkeit, dass man in der vorgegebenen Anzahl an Ziehungen das Lösungswort zufällig richtig zieht, über alle Buchstabenanzahlen hinweg halbwegs konstant zu halten.
Mein Vorschlag (mit nicht ganz trivialer Stochastik) zur Berechnung der Anzahl der Fehlversuche wäre daher hierzu folgender:

Spoiler anzeigen

AutoIt

$sWord = "blablablub"
$nDistinctChars = StringLen(StringRegExpReplace($sWord, '(?i)(.)(?!.*\1)', ''))
$nVersuche = _getSteps($nDistinctChars, 0.005)
$nVersuche = $nVersuche > (26 - $nDistinctChars) ? 26 - $nDistinctChars - 1 : $nVersuche

ConsoleWrite($nVersuche & @CRLF)

; berechnet die Anzahl an Fehlversuchen um eine Mindestwahrscheinlichkeit $nPMind zu erreichen
; diese gibt an wie wahrscheinlich es ist das Wort mit $n verschiedenen Buchstaben zufällig zu erraten
Func _getSteps($n, $nPMind = 0.005)
	Local $nP

	For $k = $n To 25
		; Wahrscheinlichkeit, dass man in $k zufällige Züge die $n richtigen Buchstaben erwischt:
		$nP = _calcProb($k, $n)
		If $nP > $nPMind Then Return $k
	Next
EndFunc

; berechnet die Wahrscheinlichkeit alle $k korrekten Elemente in $n Ziehungen zufällig zu ziehen
; Ansatz: Die Wahrscheinlichkeiten der Scheitervarianten aufaddieren
; $n = Anz. Ziehungen, $k = Anz. korrekte Elemente
Func _calcProb($n, $k, $nG = 26)
	Local $M = $nG - $k ; Anzahl Trefferelemente (hier Fehlversuche)
	Local $nP = 0

	For $i = $n - $k + 1 To ($n > $M ? $M : $n)
		$nP += _hypergeom($nG, $M, $n, $i)
	Next

	; Erfolgswahrscheinlichkeit zurückgeben
	Return 1 - ($nP > 1 ? 1 : $nP)
EndFunc

; berechnet die hypergeometrische Verteilung
Func _hypergeom($N, $M, $nC, $k)
	Return _binomialcoefficient($M, $k) * _binomialcoefficient($N - $M, $nC - $k) / _binomialcoefficient($N, $nC)
EndFunc


; berechnet den Binomialkoeffizienten
Func _binomialcoefficient($n, $k)
	Local $iR = 1

	If $k > ($n - $k) Then $k = $n - $k

	For $i = 0 To $k - 1
		$iR *= $n - $i
		$iR /= $i + 1
	Next

	Return $iR
EndFunc

Alles anzeigen

**Schnuffel**

da wir nicht an der Uni sind, würde ich meinen Versuch nochmal korrigiert abgeben wollen. Ich hatte das mit dem vollen Suchbegriff vergessen.

wenn diese Version nicht mehr in die Wertung geht alles gut.

Spoiler anzeigen

AutoIt

#include "Word-list.au3"
Global $InputBox, $Platzhalter, $nTreffer, $nCountFound, $sSuchwort, $aWortliste = _WordList()
Global $aWortVorgabe = StringSplit($aWortliste[Random(1, UBound($aWortliste)-1, 1)], '')
Global $aWortSuche = $aWortVorgabe
For $i = 1 To $aWortSuche[0]
	$aWortSuche[$i] = "_"
	$Platzhalter &= " _"
	$sSuchwort &= $aWortVorgabe[$i]
Next
$nCount = $aWortSuche[0]
ConsoleWrite('' & _
		"+---------------+" & @CRLF & _
		"|--GALGENRATEN--|" & @CRLF & _
		"+---------------+" & @CRLF & _
		"Errate ein Wort mit " & $aWortVorgabe[0] & " Buchstaben" & $Platzhalter &  " , aus der Kategorie Software Entwicklung." & @CRLF & _
		"Du hast " & $aWortVorgabe[0] & " Versuche, jeder falsche Buchstabe reduziert deine Versuche" & @CRLF)

While 1
	$InputBox = InputBox('GALGENRATEN', 'Gib einen Buchstaben oder ein Wort ein.')
	If @error > 0 Then
		ConsoleWrite("Du hast das Spiel abgebrochen!" & @CRLF)
		Exit
	EndIf
	$Platzhalter = ""
	If StringLen($InputBox) = 1 Then
		$nTreffer = 0
		For $i = 1 To $aWortSuche[0]
			If $InputBox = $aWortVorgabe[$i] Then
				$nTreffer = 1
				$nCountFound += 1
				$aWortSuche[$i] = $InputBox
			EndIf
		Next
		If $nTreffer = 0 Then 	$nCount -= 1
		If $nCount = 0 Then
			ConsoleWrite('Verloren! Das gesuchte Wort war "' & $sSuchwort & '"' & @CRLF)
			Exit
		Else
			For $j = 1 To $aWortSuche[0]
				$Platzhalter &= " " & $aWortSuche[$j]
			Next
			ConsoleWrite("Wort:" & $Platzhalter & " (" & $nCount & " Versuche noch)" & @CRLF)
		EndIf
		If $aWortSuche[0] = $nCountFound Then
			ConsoleWrite("Gewonnen! " & $nCount & " Versuche übrig, gut gemacht." & @CRLF)
			Exit
		EndIf
	EndIf
	If StringLen($InputBox) = $aWortSuche[0] Then
		If $InputBox = $sSuchwort Then
			For $j = 1 To $aWortVorgabe[0]
				$Platzhalter &= " " & $aWortVorgabe[$j]
			Next
			ConsoleWrite("Wort:" & $Platzhalter & " (" & $nCount & " Versuche noch)" & @CRLF)
			ConsoleWrite("Gewonnen! " & $nCount & " Versuche übrig, gut gemacht." & @CRLF)
			Exit
		EndIf
	EndIf
WEnd

Alles anzeigen

Ich stelle fest, dass ich eher fahrig bin. Jetzt hab ich umgestellt auf Sven seine 0-based Wortliste und den UBound vergessen.

peinlich, peinlich

**SOLVE-SMART** · Poweruser seit 21.01.2023

Oh wow, ihr macht mich fertig 😂 .

AspirinJunkie ich gehe davon aus (hoffe es), dass du meinen Kommentar mit einem Schmunzeln aufgenommen hast und dich nicht zur Rechtfertig gedrängt gefühlt hast jetzt?! Ist doch alles ein Spaß und ein wenig Übung für nebenbei. Deinen Ansatz bzw. deine Erläuterung verstehe ich. Ehrlich gesagt hatte ich bei der Konzeption der Aufgabe nicht so detailiert darüber nachgedacht, was "fachlich" korrekt(er) wäre. Es stimmt aber einfach was du sagst 🤝 .

Schnuffel alles gut auch auf meiner Seite. Gern nehme ich deinen neuen Code mit auf. Die Wertung ist auch keine Siegerehrung (leider 😅). Ist eher interessant zu sehen, wie verschiedene Leute an die Aufgabe herangehen usw. Da fällt mir ein, ich muss mein Code auch noch posten. Folgt noch.

Wenn ich die Zeit finde mir das genauer anzuschauen AspirinJunkie, gebe ich dir gern Feedback.

Viele Grüße
Sven

**Moombas**

Hmm, ich weiß nicht warum aber ich befürchte das auch meine Abweichungen bewusst gewählt wurden aber schauen wir mal auf deine Auflistung XD

Ich weiß schon warum ich früher mit div. Lehrern aneinander gerasselt bin

**SOLVE-SMART** · Poweruser seit 21.01.2023

Zitat von Moombas

Ich weiß schon warum ich früher mit div. Lehrern aneinander gerasselt bin

Ein wenig Reibung ist völlig okay 🤭🙃😏 . Bin trotzdem froh das du teilgenommen hast 😅 .

**SOLVE-SMART** · Poweruser seit 21.01.2023

So liebe Leute, hier nun mein "Wurf" für die Beschäftigungstherapie "Galgenraten" 😂 .

Galgenraten (Teil1 und Teil2 (wenn compiled))

AutoIt

#pragma compile(Console, true)
#pragma compile(FileVersion, 0.1.0)
#pragma compile(LegalCopyright, © Sven Seyfert (SOLVE-SMART))
#pragma compile(ProductVersion, 0.1.0 - 2024-02-04)

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
#AutoIt3Wrapper_Change2CUI=y
#AutoIt3Wrapper_Outfile_x64=main.exe
#AutoIt3Wrapper_Run_Au3Stripper=y
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_UseX64=y
#Au3Stripper_Parameters=/sf /sv /mo /rm /rsln

#include-once
#include <String.au3>
#include "word-list.au3"

_Main()

Func _Main()
    Local Const $sWord       = _GetRandomWord()
    Local Const $iWordLength = StringLen($sWord)
    Local $sUnderscores      = _GetUnderscoresByWord($sWord)

    Local $iAttempts  = $iWordLength * 2
    Local $bIsCorrect = False

    _Print(StringFormat( _
        '+---------------+\n' & _
        '|--GALGENRATEN--|\n' & _
        '+---------------+\n' & _
        '\n' & _
        '💡 Errate ein Wort mit %d Buchstaben %s , aus der Kategorie Software Entwicklung.\n' & _
        'Du hast %d Versuche 🤹‍♂️ , jeder falsche Buchstabe reduziert deine Versuche.\n', _
        $iWordLength, $sUnderscores, $iAttempts))

    While True
        Local $sInput = _GetInput()

        For $i = 1 To StringLen($sInput) Step 1
            $bIsCorrect = False

            For $j = 1 To $iWordLength Step 1
                Local $sInputCharacter = StringMid($sInput, $i, 1)
                Local $sWordCharacter  = StringMid($sWord, $j, 1)

                If $sInputCharacter == $sWordCharacter Then
                    $sUnderscores = _ReplaceUnderscores($j, $sUnderscores, $sWordCharacter)
                    $bIsCorrect   = True
                EndIf
            Next

            If Not $bIsCorrect Then
                $iAttempts -= 1
            EndIf
        Next

        _PrintAttempt($sUnderscores, $iAttempts)

        If _IsLost($iAttempts, $sWord) Then
            ExitLoop
        EndIf

        If _IsWon($sWord, $sUnderscores, $iAttempts) Then
            ExitLoop
        EndIf
    WEnd

    Local Const $iSecondsToWait = 5
    Sleep($iSecondsToWait * 1000)
EndFunc

Func _Print($sData)
    Local Const $iAnsiFlag = 1
    Local Const $iUtf8Flag = 4

    ; Teil 1: to show emojis
    If Not @Compiled Then
        ConsoleWrite(BinaryToString(StringToBinary($sData & @LF, $iUtf8Flag), $iAnsiFlag))
        Return
    EndIf

    ; Teil 2: to show at least ? instead of cryptic characters
    ConsoleWrite(BinaryToString(StringToBinary($sData & @LF, $iAnsiFlag), $iUtf8Flag))
EndFunc

Func _GetRandomWord()
    Local Const $aList    = _WordList()
    Local Const $iIntFlag = 1
    Local Const $iIndex   = Random(0, _GetCount($aList), $iIntFlag)

    Return StringLower($aList[$iIndex])
EndFunc

Func _GetCount($aList)
    Return UBound($aList) - 1
EndFunc

Func _GetUnderscoresByWord($sWord)
    Local Const $iTrailingWhitespaceFlag = 2
    Return StringStripWS(_StringRepeat('_ ', StringLen($sWord)), $iTrailingWhitespaceFlag)
EndFunc

Func _GetInput()
    ; Teil 1: by InputBox()
    If Not @Compiled Then
        Local $sInput = InputBox('GALGENRATEN', 'Gib einen Buchstabe oder ein Wort ein.')
        If @error Then
            Exit -1
        EndIf

        Return StringLower($sInput)
    EndIf

    ; Teil 2: by ConsoleRead()
    While True
        Local $sInput = ConsoleRead()
        If @error Then
            Exit -1
        EndIf

        If @extended > 0 Then
            ExitLoop
        EndIf

        Sleep(25)
    WEnd

    Return StringLower(StringReplace($sInput, @CRLF, ''))
EndFunc

Func _ReplaceUnderscores($j, $sUnderscores, $sWordCharacter)
    Local Const $iPosition = ($j * 2) - 1 ; HINT: This is because of the space after each underscore "_ ".
    Local Const $sBefore   = StringMid($sUnderscores, 1, $iPosition - 1)
    Local Const $sAfter    = StringMid($sUnderscores, $iPosition + 1)

    Return $sBefore & $sWordCharacter & $sAfter
EndFunc

Func _PrintAttempt($sUnderscores, $iAttempts)
    _Print(StringFormat( _
        'Wort: %s (%d Versuche noch)', _
        $sUnderscores, ($iAttempts >= 0) ? $iAttempts : 0 ))
EndFunc

Func _IsLost($iAttempts, $sWord)
    If $iAttempts > 0 Then
        Return False
    EndIf

    _Print(StringFormat( _
        '\n😥 Verloren! Das gesuchte Wort war "%s".', _
        $sWord))

    Return True
EndFunc

Func _IsWon($sWord, $sUnderscores, $iAttempts)
    Local Const $iStripAllWhitespacesFlag = 8
    If $sWord <> StringStripWS($sUnderscores, $iStripAllWhitespacesFlag) Then
        Return False
    EndIf

    _Print(StringFormat( _
        '\n😀 Gewonnen! %d Versuche übrig, gut gemacht.', _
        $iAttempts))

    Return True
EndFunc

Alles anzeigen

Wie so oft, mein Code ist länger als der jedes Anderen bisher hier. Auch 'ne Art von Erkennungsmerkmal oder so 😅 .

💡 Die Auswertung folgt. Mal sehen ob ich das heute noch schaffe oder erst morgen dann.

Viele Grüße und guten Abend
Sven

MojoeB

ich hab auch mal mein glück versucht mit dem Galgen

Leider bekomme ich bei der Lösung immer Fehler aber schaut selbst.

^^^ich habe mir grad eben erst dein video angesehen hoffe dich stört die gui nicht^^.

edit:

Galgen.zip nochmal die Anzahl an versuchen angepasst. bei mir bis zu 16max damit der galgen wachsen kann.

**Moombas**

Hier noch meine Variante mit GUI, wobei ich versucht habe so wenig wie möglich am ursprünglichen Code zu verändern (und ja, normalerweise würde ich start des Programms und GUI-Erstellung trennen, ka warum ich das diesmal anders gemacht habe^^):

Spoiler anzeigen

AutoIt

Opt('MustDeclareVars', 1)

#include "word-list.au3"
#include <Array.au3>
#include <AutoItConstants.au3>
#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>

;~ GUI
Global $Main, $LGreeting, $LWord, $EWord, $BEnter, $LInfo
;~ Script
Global Const $aWords = _WordList()

While 1
	_start($aWords)
	GUIDelete($Main)
WEnd

Func _GUICreate(Const $sTitle, Const $aLength, Const $iTries)
Local $Word
Local Const $Width  = 800
Local Const $Height = $Width /2
Local Const $LineHeight = 20
Local Const $InputWidth = 80
Local $Greeting = '+---------------+' & @CRLF & _
				  '|--' & StringUpper($sTitle) &'--|' & @CRLF & _
				  '+---------------+' & @CRLF & @CRLF & _
				  'Errate ein Wort mit ' & $aLength[0][0] & ' Buchstaben'
	For $Char = 1 to $aLength[0][0]
		$Greeting &= ' _'
		$Word &= ' _'
	Next
	$Greeting &=  ' , aus der Kategorie Software Entwicklung.' & @CRLF & _
				  'Du hast ' & $iTries & ' Versuche, jeder falsche Buchstabe reduziert deine Versuche.' & @CRLF &@CRLF

	$Main = GUICreate($sTitle, $Width, $Height)
	$LGreeting = GUICtrlCreateLabel($Greeting, 0, 0, $Width, 6*$LineHeight, $SS_CENTER)
	GUICtrlSetFont($LGreeting, Default, Default, Default, 'Courier New')

	$LWord = GUICtrlCreateLabel('', 0, 6*$LineHeight, $Width, $LineHeight, $SS_CENTER)
	GUICtrlSetFont($LWord, Default, Default, Default, 'Courier New')
	_Try($aLength, $iTries)

	$EWord = GUICtrlCreateEdit('', ($Width - (3*$InputWidth))/2, 8*$LineHeight, $InputWidth, $LineHeight, $SS_CENTER)
	GUICtrlSetFont($EWord, Default, Default, Default, 'Courier New')

	$BEnter = GUICtrlCreateButton('Versuchen', ($Width + $InputWidth)/2, 8*$LineHeight, $InputWidth, $LineHeight, BitOR($SS_CENTER, $BS_DEFPUSHBUTTON))
	GUICtrlSetFont($BEnter, Default, Default, Default, 'Courier New')

	$LInfo = GUICtrlCreateLabel('', 0, 10*$LineHeight, $Width, $LineHeight, $SS_CENTER)
	GUICtrlSetFont($LInfo, Default, Default, Default, 'Courier New')

	GUISetState(@SW_SHOW, $Main)
EndFunc

Func _start(Const $Words, $tries = 8)
Local $input, $hit, $text, $used[0]
Local $search = StringLower($Words[Random(0, Ubound($Words, $UBOUND_ROWS) - 1)])
Local Const $Title  = 'Galgenraten'
Local Const $Lost  = 'Verloren! Das gesuchte Wort war "' & $search & '".'
Local Const $tried = 'Diesen Buchstaben hast du bereits ausprobiert!'
Local Const $searchComplete = $search
	$search = Stringsplit($search, '')

		_ArrayColInsert($search, 1)
	For $Row = 1 to $search[0][0]
		$search[$Row][1] = '_'
	Next

	_GUICreate($Title, $search, $tries)
	While 1
		Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
				Exit
			Case $BEnter
				$input = StringSplit(GUICtrlRead($EWord), '')
				GUICtrlSetData($EWord, '')
				GUICtrlSetData($LInfo, '')
				If ($input[0] > $search[0][0]) and _
					$input[0] <> 1 then
					GUICtrlSetData($LInfo, 'Du hast ein zu langes Wort eingegeben. Versuche es nochmal.')
					$tries -= 1
					_Try($search, $tries)
				ElseIf $input[0] > 1 Then
					$text = ''
					For $Char = 1 to $input[0]
						$text &= $input[$Char]
					Next
					If $text = $searchComplete Then
						_Won($tries)
						Return True
					Else
						$tries -= 1
						_Try($search, $tries)
					EndIf
				ElseIf $input[0] = 1 Then
					$hit = false
					If _ArraySearch($used, $input[1]) = -1 Then
						_ArrayAdd($used, $input[1])
						For $Char = 1 to $search[0][0]
							If $input[1] = $search[$Char][0] then
								$search[$Char][1] = $search[$Char][0]
								$hit = true
							EndIf
						Next
					Else
						GUICtrlSetData($LInfo, $tried)
						Consolewrite($tried & @CRLF)
					EndIf
					If not $hit Then $tries -= 1

					_Try($search, $tries)
				EndIf

				If $tries = 0 then
					GUICtrlSetData($LInfo, $Lost)
					ConsoleWrite(@CRLF & $Lost & @CRLF)
					Return False
				Else
					If _ArraySearch($search, '_') = -1 Then
						_Won($tries)
						Return True
					EndIf
				EndIf
				ControlFocus($Main, '', $EWord)
        EndSwitch
	WEnd
EndFunc

Func _Try(Const $aArray, Const $iTries)
Local $text = 'Wort:'
	For $Row = 1 to $aArray[0][0]
		$text &= ' ' & $aArray[$Row][1]
	Next
	$text &= ' (' & $iTries & ' Versuche noch)' & @CRLF
	GUICtrlSetData($LWord, $text)
	ConsoleWrite($text)
EndFunc

Func _Won(Const $iTries)
Local Const $Message = 'Gewonnen! ' & $iTries & ' Versuche übrig, gut gemacht.'
	GUICtrlSetData($LInfo, $Message)
	Consolewrite(@CRLF & $Message & @CRLF)
EndFunc

Alles anzeigen

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)