Arduino - Problem

const int relayPins[] = {2, 3, 4}; // Relais Pins
const int buttonPin = 5 ;              // Taster Pin
const int relayCount = 3;             // Anzahl der Relais
const unsigned long onTime = 60000;    // Einschaltdauer in Millisekunden (1 Minute)

int currentRelay = 0;
unsigned long lastDebounceTime = 0;
int lastButtonState = LOW;
bool relayActive = false;
unsigned long relayStartTime = 0;

void setup() {
  for (int i = 0; i < relayCount; i++) {
    pinMode(relayPins[i], OUTPUT);
    digitalWrite(relayPins[i], LOW); // Relais zu Beginn ausschalten
  }
  pinMode(buttonPin, INPUT_PULLUP); // Taster mit internem Pull-Up Widerstand
}

void loop() {
  int reading = digitalRead(buttonPin);

  // Entprellung des Tasters
  if (reading != lastButtonState) {
    lastDebounceTime = millis();
  }

  if ((millis() - lastDebounceTime) > 50) {
    if (reading == LOW && lastButtonState == HIGH) { // Nur bei steigender Flanke
      // Taster wurde gedrückt
      toggleRelay();
    }
  }
  lastButtonState = reading;

  // Überprüfen, ob ein Relais aktiv ist und die Einschaltdauer abgelaufen ist
  if (relayActive && (millis() - relayStartTime) >= onTime) {
    deactivateRelay(currentRelay);
    relayActive = false;
  }
}

void toggleRelay() {
  // Aktuelles Relais deaktivieren
  if (relayActive) {
      deactivateRelay(currentRelay);
      relayActive = false;
  }

  // Nächstes Relais aktivieren
  currentRelay = (currentRelay + 1) % relayCount;
  activateRelay(currentRelay);
  relayActive = true;
  relayStartTime = millis();
}


void activateRelay(int relayIndex) {
  digitalWrite(relayPins[relayIndex], HIGH);
  // zusätzliche Aktionen ausführen, wenn ein Relais aktiviert wird
}

void deactivateRelay(int relayIndex) {
  digitalWrite(relayPins[relayIndex], LOW);
  // zusätzliche Aktionen ausführen, wenn ein Relais deaktiviert wird
}

const int relayPins[] = {2, 3, 4};    // Pin-Nummern für die Relais
const int buttonPin = 5 ;             // Taster zum Durchschalten der Relais
const int relayCount = 3;             // Anzahl der Relais
const unsigned long onTime = 5000;    // Einschaltdauer in Millisekunden, 5 Sekunden im Test
bool relayActive = false;             // Irgendein Relais aktiv
int curRelayIndex = -1;               // Array-Index des aktiven Relais (0 - 2; -1 wenn keins aktiv)
int prevRelayIndex = -1;              // Array-Index des zuletzt aktiven Relais (0 - 2; -1 wenn zuletzt keins aktiv)
unsigned long lastButtonTime = 0;     // Zeitpunkt des letzten Buttondrucks


void setup() {
 for (int i = 0; i < relayCount; i++) {
   pinMode(relayPins[i], OUTPUT);    // Pins für Relaisansteuerung definieren
   digitalWrite(relayPins[i], HIGH); // Relaispins HIGH setzen = Relais OFF 
 }
 pinMode(buttonPin, INPUT_PULLUP);   // Taster mit internem Pull-Up Widerstand
}


void loop() {
 if (lastButtonTime != 0) {
    if (millis() - lastButtonTime >= onTime) {           // Es ist ein Relais aktiv und die Zeit ist abgelaufen
     digitalWrite(relayPins[prevRelayIndex], HIGH);      // letztes aktives Relais OFF
     resetVars();                                        // alles auf Anfang
   }
 }
 int reading = digitalRead(buttonPin);                 // Abfrage, ob Button gedrückt
 if (reading == 0) {                                   // Taster wurde betätigt
   // das erste/nächste Relais wird aktiviert (wenn das aktive das letzte: alle OFF)
   setNextRelay();                                     // Index des nächsten Relais setzen (curRelayIndex)
   if (relayActive) {                                  // ist ein Relais aktiv?
     digitalWrite(relayPins[prevRelayIndex], HIGH);    // aktives Relais OFF
     if (curRelayIndex == -1) {
       resetVars();                                    // alles auf Anfang        
     } else {
       activateCurRelay();                             // nächstes Relais ON, lastButtonTime u. prevRelayIndex setzen
     }
   } else {                                            // kein Relais aktiv
     activateCurRelay();                               // nächstes (erstes) Relais ON, lastButtonTime u. prevRelayIndex setzen
   }
 }
 delay(100);
}


void activateCurRelay() {
 /* 
  *  hier zusätzlicher Code während Relaisaktivität, z.B. externe LED
  */
 digitalWrite(relayPins[curRelayIndex], LOW);
 prevRelayIndex = curRelayIndex;
 lastButtonTime = millis();
 relayActive = true;
}


void setNextRelay() {
 if (!relayActive) {                     // wenn kein Relais aktiv, nächstes ist Index 0
   curRelayIndex = 0;
 } else {                                // wenn ein Relais aktiv
   curRelayIndex += 1;
   if (curRelayIndex == relayCount) {    // wenn letztes Relais bereits aktiv
     curRelayIndex = -1;
   }
 }
}


void resetVars() {
 curRelayIndex = -1; 
 prevRelayIndex = -1;
 lastButtonTime = 0; 
 relayActive = false;
}