Deutsche Hilfe - Funktionen ohne Beispiel

#include <ScreenCapture.au3>
#include <Color.au3>

_GDIPlus_Startup()

$hBmp = _ScreenCapture_Capture("") ; erstelle Screenshot
$hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBmp) ; erstelle ein Bitmap aus Screenshot zur Verwendung mit GDI+
_WinAPI_DeleteObject($hBmp) ; lösche Screenshot aus Speicher

_GreyScale($hBitmap, 50, 50, 300, 200) ; Bereich wird in Graustufen umberechnet

$hGraphics = _GDIPlus_ImageGetGraphicsContext($hBitmap) ; erstelle Grafikhandle um auf dem Bitmap zu zeichnen
_GDIPlus_GraphicsDrawRect($hGraphics, 50, 50, 300, 200) ; zeichne Umrandung des ergrauten Bereiches
_GDIPlus_GraphicsDispose($hGraphics) ; gibt Grafikhandle wieder frei

_GDIPlus_ImageSaveToFile($hBitmap, @MyDocumentsDir & "\_GDIPlus_BitmapLockBits.jpg") ; speichere fertiges Bild

_GDIPlus_BitmapDispose($hBitmap) ; lösche Bild aus dem Speicher
_GDIPlus_Shutdown()

Func _GreyScale($hBitmap, $iX, $iY, $iW, $iH)
Local $BitmapData = _GDIPlus_BitmapLockBits($hBitmap, $iX, $iY, $iW, $iH, BitOR($GDIP_ILMREAD, $GDIP_ILMWRITE), $GDIP_PXF32RGB)
Local $Stride = DllStructGetData($BitmapData, "Stride") ; Stride ist der Offset von einer Reihe zur nächsten
Local $Width = DllStructGetData($BitmapData, "Width") ; Anzahl der Spalten
Local $Height = DllStructGetData($BitmapData, "Height") ; Anzahl der Reihen
Local $Scan0 = DllStructGetData($BitmapData, "Scan0") ; Die Bilddaten im Speicher
Local $PixelData, $Color, $Luma
For $row = 0 To $Height - 1 ; Reihe für Reihe
For $col = 0 To $Width - 1 ; Spalte für Spalte
; lese Farbinformation des aktuellen Pixels(Spalte,Reihe) aus
$PixelData = DllStructCreate("dword", $Scan0 + ($row * $Stride) + ($col * 4))
$Color = DllStructGetData($PixelData, 1)
; berechne Grauwert
$Luma = _ColorGetRed($Color) * 0.3 + _ColorGetGreen($Color) * 0.59 + _ColorGetBlue($Color) * 0.11
; Rot Grün und Blau wert werden jeweils auf den berechneten Grauwert gesetzt
DllStructSetData($PixelData, 1, BitOR($Luma, BitShift($Luma, -8), BitShift($Luma, -16)))
Next
Next
_GDIPlus_BitmapUnlockBits($hBitmap, $BitmapData)
EndFunc ;==>_GreyScale

#include <WinAPI.au3>
#include <WindowsConstants.au3>

$hGui = GUICreate("_WinAPI_BitBlt", 640, 480)
GUISetState()
$hWnd = _WinAPI_GetDesktopWindow()

$hDC_Gui = _WinAPI_GetDC($hGui)
$hDC_Desk = _WinAPI_GetDC($hWnd)

_WinAPI_BitBlt($hDC_Gui, 0, 0, 640, 480, $hDC_Desk, 0, 0, $SRCINVERT)
_WinAPI_BitBlt($hDC_Gui, 100, 100, 320, 240, $hDC_Desk, 0, 0, $SRCCOPY)

While GUIGetMsg() <> -3
Sleep(10)
WEnd

_WinAPI_ReleaseDC($hGui, $hDC_Gui)
_WinAPI_ReleaseDC($hWnd, $hDC_Desk)

#include <Constants.au3>
#include <WinAPI.au3>

$hGui = GUICreate("_WinAPI_Icon", 450, 120)
GUISetState()
$hDC = _WinAPI_GetDC($hGui)

$hInstance = _WinAPI_GetModuleHandle("shell32.dll")
$hIcon1 = _WinAPI_LoadImage($hInstance, 1, $IMAGE_ICON, 0, 0, $LR_DEFAULTSIZE)
$hIcon2 = _WinAPI_LoadImage($hInstance, 2, $IMAGE_ICON, 0, 0, $LR_DEFAULTSIZE)
$hIcon3 = _WinAPI_CopyIcon($hIcon2)
;$hIcon4 = _WinAPI_PrivateExtractIcon("shell32.dll", 4, 96, 96) ; ab der nächsten Beta
$hIcon5 = _WinAPI_LoadShell32Icon(5)

_WinAPI_DrawIcon($hDC, 10, 10, $hIcon1)
_WinAPI_DrawIconEx($hDC, 70, 10, $hIcon2, 100, 50)
_WinAPI_DrawIcon($hDC, 200, 10, $hIcon3)
;_WinAPI_DrawIconEx($hDC, 300, 10, $hIcon4, 96, 96)
_WinAPI_DrawIcon($hDC, 400, 10, $hIcon5)

While GUIGetMsg() <> -3
Sleep(10)
WEnd

_WinAPI_DestroyIcon($hIcon1)
_WinAPI_DestroyIcon($hIcon2)
_WinAPI_DestroyIcon($hIcon3)
;_WinAPI_DestroyIcon($hIcon4)
_WinAPI_DestroyIcon($hIcon5)
_WinAPI_ReleaseDC($hGui, $hDC)

#include <WindowsConstants.au3>
#include <Constants.au3>
#include <WinAPI.au3>

$hGui = GUICreate("_WinAPI_SetParent", 320, 240, Default, Default, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_CLIPCHILDREN))
GUISetState(@SW_SHOW, $hGui)

$hPid = Run(@SystemDir & '\notepad.exe', "", @SW_HIDE)
WinWait("[CLASS:Notepad]")
$hChild = WinGetHandle("[CLASS:Notepad]")

_WinAPI_SetParent($hChild, $hGui)
_WinAPI_SetWindowLong($hChild, $GWL_STYLE, BitOR($WS_CAPTION, $WS_POPUP))

WinSetState($hChild, "", @SW_SHOW)

While GUIGetMsg() <> -3
Sleep(1)
WEnd

#include <FTPEx.au3>

$server = 'ftp.csx.cam.ac.uk'
$username = ''
$pass = ''

$Open = _FTP_Open('Mein FTP-Control')
$Conn = _FTP_Connect($Open, $server, $username, $pass)

$aFile = _FTP_FileGet($conn, "README", @DesktopDir & "\Readme.txt")

_FTP_Close($Open)

#include <FTPEx.au3>
#include <Misc.au3>

$server = 'ftp.csx.cam.ac.uk'
$username = ''
$pass = ''

$Open = _FTP_Open('Mein FTP-Control')
$Conn = _FTP_Connect($Open, $server, $username, $pass)
ProgressOn("Download", "Status:")

$aFile = _FTP_ProgressDownload($Conn, @ScriptDir & "\tmp.tmp", "README", "_UpdateProgress")
If @error Then MsgBox(64,"Fehler: ", @error)
FileDelete(@TempDir & "\tmp.tmp")

_FTP_Close($Open)
ProgressOff()

Func _UpdateProgress($Prozent)
ProgressSet($Prozent, $Prozent & "%")
If _IsPressed("77") Then Return 0 ; Abbruch bei F8
Return 1 ; bei 1 Fortsetzten
EndFunc ;==>_UpdateProgress

Bei _FTP_ProgressDownload hab ich ein Problem: Der Error-Wert ist immer -3 (=Quelldatei konnte nicht geöffnet werden), aber das passiert mit allen Dateien. WIeso funktioniert dann aber FileGet?
Naja, ich hab zumindest die Vorlage gemacht, Debug ist noch enthalten. Wär schön, wenn das noch jemand ans Laufen bekommt^^

#include <FTPEx.au3>
#include <Misc.au3>

$server = 'ftp.csx.cam.ac.uk'
$username = ''
$pass = ''

$Open = _FTP_Open('Mein FTP-Control')
$Conn = _FTP_Connect($Open, $server, $username, $pass)
ProgressOn("Download", "Status:")

$aFile = _FTP_ProgressDownload($Conn, @ScriptDir & "\tmp.tmp", "README", "_UpdateProgress") ; pub/software/programming/pcre/pcre-7.9.zip
if @error Then MsgBox(64,"Fehler: ", @error)
;ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $aFile = ' & $aFile & @CRLF & '>Error code: ' & @error & 'Extended code: ' & @extended & 'SystemTime: ' & @HOUR & ':' & @MIN & ':' & @SEC & @CRLF) ;### Debug Console
;FileDelete(@TempDir & "\tmp.tmp")

_FTP_Close($Open)
ProgressOff()

Func _UpdateProgress($Prozent)
ProgressSet($Prozent, $Prozent & "%")
If _IsPressed("77") Then Return 0 ; Abbruch bei F8
Return 1 ; bei 1 Fortsetzten
EndFunc ;==>_UpdateProgress

#include <WinAPI.au3>
;=========================================================
; Create the struct (Rectangle)
; unsigned int Left;
; unsigned int Top;
; unsigned int Right;
; unsigned int Bottom;
;=========================================================
$tRect = DllStructCreate("uint Left;uint Top;uint Right;uint Bottom")
If @error Then
MsgBox(0, "", "Error in DllStructCreate " & @error);
Exit
EndIf
;=========================================================
; Set data in the struct (Rect)
;=========================================================
DllStructSetData($tRect, "Left", 100)
DllStructSetData($tRect, "Top", 100)
DllStructSetData($tRect, "Right", 200)
DllStructSetData($tRect, "Bottom", 200)

;=========================================================
; Create the struct (Point)
; int X;
; int Y;
;=========================================================
$tPoint = DllStructCreate("int x;int y")
If @error Then
MsgBox(0, "", "Error in DllStructCreate " & @error);
Exit
EndIf
;=========================================================
; Set data in the struct (Point)
;=========================================================
DllStructSetData($tPoint, "x", 150)
DllStructSetData($tPoint, "y", 150)

;=========================================================
; Call _WinAPI_PtInRect()
;=========================================================
If _WinAPI_PtInRect($tRect, $tPoint) Then
MsgBox(0,"","Point is in Rect")
Else
MsgBox(0,"","Point is not in Rect")
EndIf

#include <WinAPI.au3>
Run("Notepad") ; Notepad starten
$hWnd = WinWait("[CLASS:Notepad]") ; Auf Fenster warten.

$tRect = _WinAPI_GetWindowRect($hWnd) ; Struct mit Koordinaten auslesen
; Siehe $tagRECT in der Keyword Reference.

MsgBox(0, "Example", _
WinGetTitle($hWnd) & ":" & @CRLF & _
DllStructGetData($tRect, "Left") & @CRLF & _ ; Daten ausgeben
DllStructGetData($tRect, "Top") & @CRLF & _
DllStructGetData($tRect, "Right") & @CRLF & _
DllStructGetData($tRect, "Bottom") & @CRLF _
)