GDI+ Image als GUI nutzen

Die Bilddatei muss auf der Festplatte liegen, lade das Bild voher mit z.B Inetget runter.

Edit:
Wenn man die URL durch ein gültigen Datipfad austauscht, funktioniert es bei mir.

Hi,

Zitat

it folgendem Code habe ich es probiert klappt leider nicht.

Das wundert mich absolut garnicht, lass dir mal die Werte deiner Variablen ausgeben!
Und versuche mal die Zeilen so zu sortieren, dass nicht alles vollkommen durcheinander ist, sondern LOGISCH aufeinander folgt!

Falls du es soweit hinbekommen hast, dass eine GUI angezeigt wird, versuche mal zu verstehen was die Konstanten eigentlich aussagen....
Dann wird auch ein Bild angezeigt...jedenfalls bei mir^^

Und btw. lass dir das Geld wiedergeben von dem, der dieses Script verzapft hat!

• Bitte formuliere in Zukunft deine Problembeschreibungen etwas detailreicher. "klappt leider nicht" hilft uns nicht wirklich weiter.
• Lies dir am besten noch mal einige grundlegende Tutorials zu GDI+ durch.
• Du versuchst eine Grafik von einem Fenster zu erstellen, dass zu dem Zeitpunkt nicht existiert. $hGUI ist nur eine leere Variable, das Fensterhandle wird erst später durch GUICreate dort eingetragen.
• Du musst schon eine Datei für _GDIPlus_ImageLoadFromFile verwenden (wie es auch in der Hilfe beschrieben steht) und keine URL.
• Du verwendest direkt nach Erzeugung des, noch inaktiven, Fensters diese Zeile: GUISetState($GUI_DISABLE). Ich gehe davon aus, dass du das Fenster "disablen" willst, warum weiß ich nicht. Allerdings musst du dafür erstens das Makro @SW_DISABLE verwenden, nicht die Variable $GUI_DISABLE (ja, das steht auch in der Hilfe), zweitens würdest du keinen Unterschied feststellen, denn dein Fenster ist ja noch nicht einmal sichtbar (das macht man übrigens mit GUISetState(@SW_SHOW) oder auch GUISetState()).

Hier die Version, die du ursprünglich geplant hattest (benötigt die aktuelle Beta!

#AutoIt3Wrapper_Version=b
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <WinAPI.au3>
#include <GDIPlus.au3>

_GDIPlus_Startup()

Global $hImage, $hGUI, $hGrafics

$hImage = _GDIPlus_BitmapCreateFromMemory(InetRead("http://aut1.autoit-cdn.com/images/logo_autoit_210x72@2x.png"))
Global $iWidth = _GDIPlus_ImageGetWidth($hImage)
Global $iHeight = _GDIPlus_ImageGetHeight($hImage)

$hGUI = GUICreate("Mein Design", $iWidth, $iHeight, -1, -1)
GUISetBkColor(0x808090, $hGUI)
$iLabel = GUICtrlCreateLabel("", 0, 0, $iWidth, $iHeight)
GUISetState()
$hGrafics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
_GDIPlus_GraphicsDrawImageRect($hGrafics, $hImage, 0, 0, $iWidth, $iHeight)

GUIRegisterMsg($WM_PAINT, "MY_WM_PAINT")

While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GDIPlus_GraphicsDispose($hGrafics)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_Shutdown()
Exit
Case $iLabel
MsgBox(0, "Test", "Grafik wurde geklickt")
EndSwitch
WEnd

; Draw PNG image
Func MY_WM_PAINT($hWnd, $Msg, $wParam, $lParam)
_GDIPlus_GraphicsDrawImageRect($hGrafics, $hImage, 0, 0, $iWidth, $iHeight)
Return $GUI_RUNDEFMSG
EndFunc

Gruß,
UEZ