Rückrechnung

**Alina**

Es geht mal wieder um Kopfkino !!!

Ich hatte folgende Idee. Aus der Möglichkeit verschiedene Auswahlen zu treffen wollte ich einen "eindeutigen mathematischen Wert" (Zahl) ermitteln. Das klappt auch, wenn ich nicht irgendwo ein gedanklichen Querrschläger in den Beispielen haben.

Aber wie rechnet man das richtig zurück ???

AutoIt

$taeglich = 0
$mo = 1
$di = 2
$mi = 4
$do = 8
$fr = 16
$sa = 32
$so = 64


$woechentlich = 128
  $woechentlich_erste_Woche = 256
  $woechentlich_zweite_Woche = 512
  $woechentlich_dritte_Woche = 1024
  $woechentlich_vierte_Woche = 2048
  $woechentlich_fuenfte_Woche = 4096
  $woechentlich_gerade_Wochen = 8192
  $woechentlich_ungerade_Wochen = 16384


$monatlich = 32768
  $monatlich_gerade = 65536
  $monatlich_ungerade = 131072


$viertteljaehrlich = 524288


$jaehrlich = 1048576


; Min & Max Werte
$taeglich_min = 0
$taeglich_max = 127


$woechentlich_min = 128
$woechentlich_max = 32767


$monatlich_min = 32768
$monatlich_max = 524287




$viertteljaehrlich_min = 524288
$viertteljaehrlich_max = 1048575


$jaehrlich_min = 1048576 ; (eigentlich sinnlos, oder? Weil wenn der Wert größer ist als $viertteljaehrlich_max kann es nur $jaehrlich sein. Aber man weiß ja nicht. *blinzeln* )
$jaehrlich_max = 2097151 




; Ausgabe 1. Box = 33282 // 2. Box = 35330
MsgBox(0,"Terminnummer", "Jeden 2. Di im Monat hat die Nummer: " & ($monatlich + $woechentlich_zweite_Woche + $di) & ".")
MsgBox(0,"Terminnummer", "Jeden 2. und 4. Di im Monat hat die Nummer: " & ($monatlich + $woechentlich_zweite_Woche + $woechentlich_vierte_Woche + $di) & ".")


$Box_1 = 33282 ; bestehend aus: $monatlich + $woechentlich_zweite_Woche + $di
$Box_2 = 35330 ; Bestehend aus: $monatlich + $woechentlich_zweite_Woche + $woechentlich_vierte_Woche + $di

Alles anzeigen

Ja, jetzt sehe ich schon einige die ihre Hände über dem Kopf zusammen schlagen und denken: "Was geht das in Kopf ab?" Ich kann nur sagen: "Alles halb so schlimm!"

**Mars**

Du bist da schon auf dem richtigen Dampfer
Was du tust ist jedem Bit einen gewissen Sinn zu verleihen. z.B. ist Montag das erste bit, Dienstag das 2te usw. Im Endeffekt sind also alle Zahlen die du benutzt in Binärdarstellung soetwas wie ...00000100000.... Wenn man diese alle Addiert kommt soetwas heraus 001010110101100. Dabei steht jedes Bit für eine Variable. Um diese Bits aus der Zahl wieder zu extrahieren kann man sehr einfach BitAnd benutzen. z.B. um aus 00010010101100 die letzten 7 Stellen (für die 7 Tage) zu bekommen nimmt man einfach BitAnd und die Zahl 127 (1111111b).

AutoIt

$taeglich = 0
$mo = 1
$di = 2
$mi = 4
$do = 8
$fr = 16
$sa = 32
$so = 64
$woechentlich = 128
  $woechentlich_erste_Woche = 256
  $woechentlich_zweite_Woche = 512
  $woechentlich_dritte_Woche = 1024
  $woechentlich_vierte_Woche = 2048
  $woechentlich_fuenfte_Woche = 4096
  $woechentlich_gerade_Wochen = 8192
  $woechentlich_ungerade_Wochen = 16384
$monatlich = 32768
  $monatlich_gerade = 65536
  $monatlich_ungerade = 131072
$viertteljaehrlich = 524288
$jaehrlich = 1048576
; Min & Max Werte
$taeglich_min = 0
$taeglich_max = 127
$woechentlich_min = 128
$woechentlich_max = 32767
$monatlich_min = 32768
$monatlich_max = 524287
$viertteljaehrlich_min = 524288
$viertteljaehrlich_max = 1048575
$jaehrlich_min = 1048576 ; (eigentlich sinnlos, oder? Weil wenn der Wert größer ist als $viertteljaehrlich_max kann es nur $jaehrlich sein. Aber man weiß ja nicht. *blinzeln* )
$jaehrlich_max = 2097151
; Ausgabe 1. Box = 33282 // 2. Box = 35330
;~ MsgBox(0,"Terminnummer", "Jeden 2. Di im Monat hat die Nummer: " & ($monatlich + $woechentlich_zweite_Woche + $di) & ".")
;~ MsgBox(0,"Terminnummer", "Jeden 2. und 4. Di im Monat hat die Nummer: " & ($monatlich + $woechentlich_zweite_Woche + $woechentlich_vierte_Woche + $di) & ".")
$Box_1 = 33282 ; bestehend aus: $monatlich + $woechentlich_zweite_Woche + $di
$Box_2 = 35330 ; Bestehend aus: $monatlich + $woechentlich_zweite_Woche + $woechentlich_vierte_Woche + $di


$Box_1 = $viertteljaehrlich + $monatlich + $woechentlich_zweite_Woche + $so


; Um den Tag herauszufinden BitAnd mit 1111111b
ConsoleWrite('Tag: ' & BitAND($Box_1, 127) & @CRLF)


; Wöchentlich: BitAnd mit 111111110000000b
ConsoleWrite('Wöchentlich: ' & BitAND($Box_1, 32640) & @CRLF)


; Monatlich: BitAnd mit 111000000000000000b
ConsoleWrite('Monatlich: ' & BitAND($Box_1, 229376) & @CRLF)


; Jährlich: BitAnd mit 11000000000000000000b
ConsoleWrite('Jährlich: ' & BitAND($Box_1, 786432) & @CRLF)

Alles anzeigen

Edit: Das funktioniert natürlich nicht sooo einfach, wenn man z.B. Mehrere Werde aus einer Sparte gewählt hat. z.B. wenn man Di und So wählt erhält man bei Tag: 66. Diese Zahl muss man dann nach dem gleichen Prinzip wieder auseinandernehmen, wenn man es genau wissen will. 66 = 1000010b. (Da kann man direkt ablesen welche Tage gesetzt sind)

lg
M

**eukalyptus**

Evtl ist es besser verständlich, wenn du selber siehst, welche Bits gesetzt sind.
Dazu hätte ich eine Funktion im Angebot:

AutoIt

For $i = 0 To 16
	ConsoleWrite("> " & StringFormat("%032s", _TranslateBase(2 ^ $i)) & " = " & 2 ^ $i & @CRLF)
Next




Func _TranslateBase($sNumber, $iOldBase = 10, $iNewBase = 2)
	;by eukalyptus
	If $iOldBase < 2 Or $iOldBase > 128 Or $iNewBase < 2 Or $iNewBase > 128 Then Return SetError(1, 1, False)
	Local $iNum, $aRes, $tChr = DllStructCreate("char[65];")
	If $iOldBase <> 10 Then
		$aRes = DllCall("msvcrt.dll", "uint64:cdecl", "_strtoui64", "str", $sNumber, "ptr", 0, "int", $iOldBase)
		If @error Then Return SetError(1, 2, False)
		$iNum = $aRes[0]
	Else
		$iNum = Int($sNumber)
	EndIf
	$aRes = DllCall("msvcrt.dll", "ptr:cdecl", "_i64toa", "int64", $iNum, "ptr", DllStructGetPtr($tChr), "int", $iNewBase)
	If @error Then Return SetError(1, 3, False)
	Return DllStructGetData($tChr, 1)
EndFunc   ;==>_TranslateBase

Alles anzeigen

lgE

**Alina**

Das von Euch beiden ist ja echt lieb und ich verste was da passiert, nun ich weiß nicht, wie ich das nutzen kann, um im ersten Beitrag nun die Rückrechnung durchführe.

Die Zahl z. B. 35338 muss ungerechnet werden und dann wie zurück gerechnet werden? Monatlich in der 2. und 4. Woche an Dienstag und Donnerstag sähe theoretisch so aus:

35338 = 1000101000000010 ; 16 stellige Zahl
32768 = 1000000000000000 ; an 16. Stelle von re. ist eine "1", somit 32768 ---> Monatlich
2048 = 0000100000000000 ; an 12. Stelle von re. ist eine "1", somit 2048 ---> 4. Woche
512 = 0000001000000000 ; an 10. Stelle von re. ist eine "1", somit 512 ---> 2. Woche
8 = 0000000000001000; an 5. Stelle von re. ist eine "1", somit 8 ---> Donnerstag
2 = 0000000000000010 ; an 2. Stelle von re. ist eine "1", somit 2 ---> Dienstag

Theorie & Praxis

**eukalyptus**

Du könntest das so machen:

AutoIt

Global $aArray[22][2] = [[0, "täglich"], [0x1, "mo"], [0x2, "di"], [0x4, "mi"], [0x8, "do"], [0x10, "fr"], [0x20, "sa"], [0x40, "so"], [0x80, "wöchentlich"], [0x100, "1.WO"], [0x200, "2.WO"], [0x400, "3.WO"], [0x800, "4.WO"], [0x1000, "5.WO"], [0x2000, "gerade WO"], [0x4000, "ungerade WO"], [0x8000, "monatlich"], [0x10000, "monatlich gerade"], [0x20000, "monatlich ungerade"], [0x40000, "nix"], [0x80000, "viertteljaehrlich"], [0x100000, "jaehrlich"]]


$iX = 35338
For $i = 0 To UBound($aArray) - 1
	If BitAND($iX, $aArray[$i][0]) Then ConsoleWrite($aArray[$i][1] & @CRLF)
Next

**Alina**

Okay, sieht gut aus.

Erkläre mir doch mal, wie Du auf folgenden Wert kommst: [0x10, "fr"]
Wieso nicht [0x16, "fr"]?

Damit erklärt sich ja auch, wieso es später dann nicht mit 32,64,128,... weiter geht. Das möchte ich gerne verstehen.

**Mars**

Das liegt an der Hexadezimaldarstellung.

Hex	Dez	Bin
0x1	1	000001
0x2	2	000010
0x4	4	000100
0x8	8	001000
0x10	16	010000
0x20	32	100000
usw	...	...

Dann braucht man nicht so "krumme" große Zahlen

**Alina**

Okay, das habe ich dann mal verstanden. !?

Der Hex-Wert verdoppelt sich ab 0x10 dann jedes mal.

**Mars**

Jop. Die einzige Sache bei der man aufpassen muss ist 0x8. Denn 0x8 * 2 = 0x10 und 0x80 * 2 = 0x100, usw. Das geht unserem Kopf der im Dezimalsystem arbeitet manchmal etwas gegen den Strich

**Alina**

Meinst Du das hier?
0x80 =
0x100 =
0x800 =
0x1000 =
Noch nicht mal auf die DEZ bzw. BIN gekommen die dann genutzt werden kann.
Muss ich morgen mal schauen.

DANKE !!!

Edit: Dank Excel ging es schnell !!!

**Alina**

Das ist auch mal eine Berechnung, oder?

Mal gefragt: "Daraus könnte man doch sicherlich eine Funktion (dez2bin) erstellen, oder? Gobt es das schon? Wenn ja dann überflüssig!

AutoIt

Die Dezimalzahl 16112015 wird ins 2er-System umgewandelt


Gehe nach folgendem Verfahren vor:
 (1) Teile die Zahl mit Rest durch 2.
 (2) Der Divisionsrest ist die nächste Ziffer (von rechts nach links).
 (3) Falls der (ganzzahlige) Quotient = 0 ist, bist du fertig,
     andernfalls nimm den (ganzzahligen) Quotienten als neue Zahl 
     und wiederhole ab (1).


     16112015 : 2 =  8056007  Rest: 1
      8056007 : 2 =  4028003  Rest: 1
      4028003 : 2 =  2014001  Rest: 1
      2014001 : 2 =  1007000  Rest: 1
      1007000 : 2 =   503500  Rest: 0
       503500 : 2 =   251750  Rest: 0
       251750 : 2 =   125875  Rest: 0
       125875 : 2 =    62937  Rest: 1
        62937 : 2 =    31468  Rest: 1
        31468 : 2 =    15734  Rest: 0
        15734 : 2 =     7867  Rest: 0
         7867 : 2 =     3933  Rest: 1
         3933 : 2 =     1966  Rest: 1
         1966 : 2 =      983  Rest: 0
          983 : 2 =      491  Rest: 1
          491 : 2 =      245  Rest: 1
          245 : 2 =      122  Rest: 1
          122 : 2 =       61  Rest: 0
           61 : 2 =       30  Rest: 1
           30 : 2 =       15  Rest: 0
           15 : 2 =        7  Rest: 1
            7 : 2 =        3  Rest: 1
            3 : 2 =        1  Rest: 1
            1 : 2 =        0  Rest: 1


     Resultat: 111101011101100110001111

Alles anzeigen

**AspirinJunkie**

Zitat von Alina

Daraus könnte man doch sicherlich eine Funktion (dez2bin) erstellen, oder?

>>einmal<<
>>zweimal<<
>>dreimal<<
>>viermal<<

**eukalyptus**

Deine Excel-Tabelle ist falsch!

Code

> Hex:        0x1   Dec:          1   Bin:                                1
> Hex:        0x2   Dec:          2   Bin:                               10
> Hex:        0x4   Dec:          4   Bin:                              100
> Hex:        0x8   Dec:          8   Bin:                             1000
> Hex:       0x10   Dec:         16   Bin:                            10000
> Hex:       0x20   Dec:         32   Bin:                           100000
> Hex:       0x40   Dec:         64   Bin:                          1000000
> Hex:       0x80   Dec:        128   Bin:                         10000000
> Hex:      0x100   Dec:        256   Bin:                        100000000
> Hex:      0x200   Dec:        512   Bin:                       1000000000
> Hex:      0x400   Dec:       1024   Bin:                      10000000000
> Hex:      0x800   Dec:       2048   Bin:                     100000000000
> Hex:     0x1000   Dec:       4096   Bin:                    1000000000000
> Hex:     0x2000   Dec:       8192   Bin:                   10000000000000
> Hex:     0x4000   Dec:      16384   Bin:                  100000000000000
> Hex:     0x8000   Dec:      32768   Bin:                 1000000000000000
> Hex:    0x10000   Dec:      65536   Bin:                10000000000000000
> Hex:    0x20000   Dec:     131072   Bin:               100000000000000000
> Hex:    0x40000   Dec:     262144   Bin:              1000000000000000000
> Hex:    0x80000   Dec:     524288   Bin:             10000000000000000000
> Hex:   0x100000   Dec:    1048576   Bin:            100000000000000000000
> Hex:   0x200000   Dec:    2097152   Bin:           1000000000000000000000
> Hex:   0x400000   Dec:    4194304   Bin:          10000000000000000000000
> Hex:   0x800000   Dec:    8388608   Bin:         100000000000000000000000
> Hex:  0x1000000   Dec:   16777216   Bin:        1000000000000000000000000
> Hex:  0x2000000   Dec:   33554432   Bin:       10000000000000000000000000
> Hex:  0x4000000   Dec:   67108864   Bin:      100000000000000000000000000
> Hex:  0x8000000   Dec:  134217728   Bin:     1000000000000000000000000000
> Hex: 0x10000000   Dec:  268435456   Bin:    10000000000000000000000000000
> Hex: 0x20000000   Dec:  536870912   Bin:   100000000000000000000000000000
> Hex: 0x40000000   Dec: 1073741824   Bin:  1000000000000000000000000000000
> Hex: 0x80000000   Dec: 2147483648   Bin: 10000000000000000000000000000000

Alles anzeigen

AutoIt

MsgBox(0, "", "16112015 = " & _TranslateBase(16112015))






For $i = 0 To 31
	ConsoleWrite("> " & StringFormat("Hex: % 10s   Dec: % 10s   Bin: % 32s", "0x" & StringRegExpReplace(Hex(Int(2 ^ $i)), "^0+([^0]|0$)", "\1", 1), 2 ^ $i, _TranslateBase(2 ^ $i)) & @CRLF)
Next




Func _TranslateBase($sNumber, $iOldBase = 10, $iNewBase = 2)
	;by eukalyptus
	If $iOldBase < 2 Or $iOldBase > 128 Or $iNewBase < 2 Or $iNewBase > 128 Then Return SetError(1, 1, False)
	Local $iNum, $aRes, $tChr = DllStructCreate("char[65];")
	If $iOldBase <> 10 Then
		$aRes = DllCall("msvcrt.dll", "uint64:cdecl", "_strtoui64", "str", $sNumber, "ptr", 0, "int", $iOldBase)
		If @error Then Return SetError(1, 2, False)
		$iNum = $aRes[0]
	Else
		$iNum = Int($sNumber)
	EndIf
	$aRes = DllCall("msvcrt.dll", "ptr:cdecl", "_i64toa", "int64", $iNum, "ptr", DllStructGetPtr($tChr), "int", $iNewBase)
	If @error Then Return SetError(1, 3, False)
	Return DllStructGetData($tChr, 1)
EndFunc   ;==>_TranslateBase

Alles anzeigen

**Alina**

Danke Aspirinjungie & Eukalyptus