[GDI+] Asteroiden Generator

**Mars**

Moin,

Im Prinzip wollte ich einen Thread im Hilfebereich aufmachen, da ich hier etwas Hilfe (oder eine "zündende" Idee) brauche, aber es gibt schon ein funktionierendes Skript, also sind wir im Skriptbereich.

Das Tool soll folgendes tun: Einen Asteroiden (in 2D, GDI+) generieren.

Anforderungen (ein Teil davon ist zum Teil erfüllt, das meiste aber nicht)
- Der Asteroid soll möglichst nicht "schlecht" aussehen. (z.B. eine einfarbige Fläche wäre nicht sonderlich gut).
- Die Laufzeit sollte unter 100ms betragen um einen Asteroiden zu generieren (da später mal eine ganze Menge gebraucht werden und niemand 5 Min Ladezeit haben will).
- Der Asteroid braucht eine Art "Rohstoff" (in diesem Fall Grün, jede andere Farbe geht aber auch) der ohne Formveränderung des Asteroiden bei gleichem Seed Einstellbar sein sollte.
- ggf eine Beleuchung mit 1-2 Lichtquellen. (Hier habe ich keine Idee, wie soetwas in annehmbarer Zeit via GDI+ machbar ist. Ich glaube aber, dass es hier mal eine kleine GDI+ Demonstration mit Leuchteffekten gab.)

Natürlich könnte ich jetzt noch stundenlang weiterbasteln bis alles eingebaut ist was ich gerne hätte und anschließend herumoptimieren bis die Zeit (halbwegs) stimmt. Ich möchte aber ggf vorher ein paar Ideen von einigen GDI+ Leuten einholen
Für alle anderen Gilt: Habt Spaß und generiert euch Asteroiden (Und falls ihr interessante Farbkombinationen findet könnt ihr sie gerne posten)

AutoIt: Asteroiden Generator

#include-once
#include <GDIPlus.au3>
#include <Array.au3>


_GDIPlus_Startup()


Global $hAsteroid, $bRefresh = True
Global $bPaint = False
Global $iW = 400, $iH = 200
Global $hGUI = GUICreate('Asteroid Generator', $iW, $iH)
Global $hGfx = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Global $hBmp = _GDIPlus_BitmapCreateFromScan0($iH, $iH)
Global $hBuf = _GDIPlus_ImageGetGraphicsContext($hBmp)
GUICtrlCreateEdit('Größe', $iH + 5, 5, 50, 20, 2049)
Global $hSli1 = GUICtrlCreateSlider($iH + 60, 5, $iW - $iH - 65 - 50, 20)
Global $hLab1 = GUICtrlCreateEdit('76', $iW - 50, 5, 45, 20, 2049)
GUICtrlSetData($hSli1, Round(GUICtrlRead($hLab1)/1.5 - 4, 0))


GUICtrlCreateEdit('Col3%', $iH + 5, 30, 50, 20, 2049)
Global $hSli2 = GUICtrlCreateSlider($iH + 60, 30, $iW - $iH - 65 - 50, 20)
Global $hLab2 = GUICtrlCreateEdit('50', $iW - 50, 30, 45, 20, 2049)
GUICtrlSetData($hSli2, GUICtrlRead($hLab2))


GUICtrlCreateEdit('Seed', $iH + 5, 55, 50, 20, 2049)
Global $hBtn3 = GUICtrlCreateButton('Random', $iH + 60, 55, $iW - $iH - 65 - 50, 20)
Global $hLab3 = GUICtrlCreateEdit(Random(0, 999999, 1), $iW - 50, 55, 45, 20, 1)


GUICtrlCreateEdit('Col 1', $iH + 5, 80, 62, 18, 2049)
GUICtrlCreateEdit('Col 2', $iH + 69, 80, 62, 18, 2049)
GUICtrlCreateEdit('Col 3', $iH + 133, 80, 62, 18, 2049)


Global $hCol1 = GUICtrlCreateEdit('FF602000', $iH + 5, 100, 62, 18, 1)
GUICtrlSetFont(-1, 7, 400, 0, 'Arial', 5)
Global $hCol2 = GUICtrlCreateEdit('FF909090', $iH + 69, 100, 62, 18, 1)
GUICtrlSetFont(-1, 7, 400, 0, 'Arial', 5)
Global $hCol3 = GUICtrlCreateEdit('FF00FF00', $iH + 133, 100, 62, 18, 1)
GUICtrlSetFont(-1, 7, 400, 0, 'Arial', 5)


Global $hNew = GUICtrlCreateButton('Redraw', $iH + Round(($iW - $iH)/2, 0) - 50, 125, 100, 25)
Global $hSave = GUICtrlCreateButton('Save', $iH + Round(($iW - $iH)/2, 0) - 50, 155, 100, 25)


GUISetState()
GUIRegisterMsg(0xF, 'WM_PAINT')


WM_PAINT()


While True
	Switch GUIGetMsg()
		Case -3
			ExitLoop
		Case $hSli1, $hSli2
			$xTmp = Round(1.5 * GUICtrlRead($hSli1) + 8, 0)
			GUICtrlSetData($hLab1, $xTmp)
			GUICtrlSetData($hLab2, GUICtrlRead($hSli2))
			$bRefresh = True
		Case $hBtn3
			GUICtrlSetData($hLab3, Random(0, 999999, 1))
			$bRefresh = True
		Case $hNew
			$bRefresh = True
		Case $hSave
			$xTmp = FileSaveDialog('Zieldatei eingeben', @ScriptDir, '(*.png)')
			_GDIPlus_ImageSaveToFile($hAsteroid, $xTmp)
	EndSwitch


	If $bRefresh Then
		$bRefresh = False
		$bPaint = False
		$xTmp = Round(1.5 * GUICtrlRead($hSli1) + 8, 0)
		_GDIPlus_BitmapDispose($hAsteroid)
		$hAsteroid = _AsteroidCreateBitmap($xTmp, GUICtrlRead($hSli2), GUICtrlRead($hLab3), '0x' & GUICtrlRead($hCol1), '0x' & GUICtrlRead($hCol2), '0x' & GUICtrlRead($hCol3))
		_GDIPlus_GraphicsClearCheckboard($hBuf, 0xFF9F9F9F, 0xFFE2E2E2, 200, 200)
		_GDIPlus_GraphicsDrawImage($hBuf, $hAsteroid, Round($iH/2 - $xTmp/2, 0), Round($iH/2 - $xTmp/2, 0))
		$bPaint = True
		WM_PAINT()
	EndIf


WEnd


Func _GDIPlus_GraphicsClearCheckboard($hGFX, $iCol1, $iCol2, $iW, $iH)
	Local $hBRU1 = _GDIPlus_BrushCreateSolid($iCol1)
	Local $hBRU2 = _GDIPlus_BrushCreateSolid($iCol2)
	Local $iD = Round(($iW ^ 2 + $iH ^ 2) ^ 0.25 / 2, 0)
	For $x = 0 To Int($iW / $iD) - 1 Step 1
		For $y = 0 To Int($iH / $iD) - 1 Step 1
			_GDIPlus_GraphicsFillRect($hGfx, $x * $iD, $y * $iD, $iD, $iD, IsInt($x/2) ? (IsInt($y/2) ? $hBRU1 : $hBRU2) : (IsInt($y/2) ? $hBRU2 : $hBRU1))
		Next
	Next
	_GDIPlus_BrushDispose($hBRU1)
	_GDIPlus_BrushDispose($hBRU2)
EndFunc


_GDIPlus_BitmapDispose($hAsteroid)
_GDIPlus_GraphicsDispose($hBuf)
_GDIPlus_BitmapDispose($hBmp)
_GDIPlus_GraphicsDispose($hGfx)


Func WM_PAINT()
	If $bPaint Then _GDIPlus_GraphicsDrawImage($hGfx, $hBmp, 0, 0)
EndFunc








;~ SRandom(@MSEC + @SEC*1000 + @MIN*1000*60)
;~ Global $t = TimerInit()
;~ For $i = 1 To 4 Step 1
;~ 	_AsteroidCreateBitmap(48, 0, $i*2)
;~ Next
;~ ConsoleWrite(Round(TimerDiff($t)/($i-1),0) & ' ms' & @CRLF)


_GDIPlus_Shutdown()


Func _AsteroidCreateBitmap($iSizePx = 32, $iCrystalPercent = 25, $iSeed = Default, $iCol1 = 0xFF602000, $iCol2 = 0xFF909090, $iCol3 = 0xFF00FF00)
	Local $hBmp = _GDIPlus_BitmapCreateFromScan0($iSizePx, $iSizePx)
	Local $hPen = _GDIPlus_PenCreate(0x40000000, $iSizePx^0.25/1.5)
	Local $hBru = _GDIPlus_BrushCreateSolid()
	Local $hGfx = _GDIPlus_ImageGetGraphicsContext($hBmp)
	Local Const $fDegToRad = 3.141592653589793 / 180
	_GDIPlus_GraphicsSetSmoothingMode($hGfx, 2)
	_GDIPlus_GraphicsSetPixelOffsetMode($hGfx, 2)


	If $iSeed <> Default Then SRandom($iSeed)


	; Schritt 1: Umriss definieren
	Local $iPoints = Round($iSizePx^0.45*2.5, 0), $aPoints[$iPoints + 1][2] = [[$iPoints, 0]], $iRandomOffset
	For $i = 1 To $iPoints Step 1
		$iRandomOffset = Random(-90/$iPoints, 90/$iPoints) * $fDegToRad
		$aPoints[$i][0] = ($iSizePx * 0.4 * Cos($i/($iPoints)*$fDegToRad*360 + $iRandomOffset) + $iSizePx * 0.5) * Random(0.9^(1/($iPoints^0.25)), 1.1^(1/($iPoints^0.25)))
		$aPoints[$i][1] = ($iSizePx * 0.4 * Sin($i/($iPoints)*$fDegToRad*360 + $iRandomOffset) + $iSizePx * 0.5) * Random(0.9^(1/($iPoints^0.25)), 1.1^(1/($iPoints^0.25)))
	Next
	_PointsStauchen($aPoints, $iSizePx * 0.5, Random(0.75, 1))
	_PointsRotate($aPoints, $iSizePx * 0.5, $iSizePx * 0.5, Random(0, 360))


	; Schritt 2: Textur Erzeugen
	Local $hTex = _TextureCreate($iSizePx, $iSizePx, $iCol1, $iCol2, $iCol3, $iCrystalPercent / 100)


	; Schritt 3: Zeichnen
	_GDIPlus_GraphicsClear($hGfx, 0)
	_GDIPlus_GraphicsFillPolygon($hGfx, $aPoints, $hTex)
	_GDIPlus_PenSetAlignment($hPen, 1)
	_GDIPlus_GraphicsDrawPolygon($hGfx, $aPoints, $hPen)
	_GDIPlus_PenSetWidth($hPen, 0.75)
	_GDIPlus_PenSetColor($hPen, 0xEE000000)
	_GDIPlus_PenSetAlignment($hPen, 0)
	_GDIPlus_GraphicsDrawPolygon($hGfx, $aPoints, $hPen)


;~ 	_GDIPlus_ImageSaveToFile($hBmp, Random(100, 999, 1) & '.png')


	_GDIPlus_BrushDispose($hTex)
	_GDIPlus_GraphicsDispose($hGfx)
	_GDIPlus_BrushDispose($hBru)
	_GDIPlus_PenDispose($hPen)




;~ 	_GDIPlus_BitmapDispose($hBmp)
	Return $hBmp
EndFunc


Func _TextureCreate($iW, $iH, $iCol1, $iCol2, $iCol3, $iMenge = 0.5)
	; iCol1  : Erste Grundfarbe des Ateroiden
	; iCol2  : Zweite Grundfarbe des Asteroiden
	; iCol3  : Farbe von besonderem Gestein auf der Oberfläche
	; iMenge : Menge von 0 bis 1 des besonderen Gesteins
	Local $hBmp = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
	Local $hGfx = _GDIPlus_ImageGetGraphicsContext($hBmp)
	Local $hBRU = _GDIPlus_BrushCreateSolid()
	Local $aPoints = [[2, 0], [-$iW/10, -$iH/10], [$iW*1.1, $iH*1.1]]
	_PointsRotate($aPoints, $iW/2, $iH/2, Random(0, 360))
	Local $hLine = _GDIPlus_LineBrushCreate($aPoints[1][0], $aPoints[1][1], $aPoints[2][0], $aPoints[2][1], $iCol1, $iCol2)
	_GDIPlus_GraphicsSetSmoothingMode($hGfx, 2)


	; Grundfarbe
	_GDIPlus_GraphicsFillRect($hGfx, -$iW/10, -$iH/10, $iW * 1.1, $iH*1.1, $hLine)
	Local $iD, $aMulti = [4, 3, 2, 2]


	For $n = 0 To 3 Step 1
		For $i = 0 To Round(($iW ^ 2 + $iH ^ 2) ^ 0.5 * $aMulti[$n], 0) Step 1
			_GDIPlus_BrushSetSolidColor($hBRU, BitOR('0x' & Hex(Int(Round(Random(24 / $aMulti[$n], 56 / $aMulti[$n])*$iMenge, 0)), 2) & '000000', BitAND($iCol3, 0xFFFFFF)))
			$iD = Random($iW/18*$aMulti[$n], $iW/12*$aMulti[$n]) * ((Random(0, 4, 1) = 0) ? 4 : 1)
			$aPoints = _PointsFromRect(0, 0, $iD, $iD)
			_PointsRotate($aPoints, $iD/2, $iD/2, Random(0, 360))
			_PointsTranslate($aPoints, Random(-$iD, $iW + $iD), Random(-$iD, $iH + $iD))
			_GDIPlus_GraphicsFillPolygon($hGfx, $aPoints, $hBRU)
			_GDIPlus_BrushSetSolidColor($hBRU, BitOR('0x' & Hex(Int(Random(16 / $aMulti[$n], 48 / $aMulti[$n], 1)), 2) & '000000', BitAND($iCol1, 0xFFFFFF)))
			$iD = Random($iW/9*$aMulti[$n], $iW/4*$aMulti[$n])
			$aPoints = _PointsFromRect(0, 0, $iD, $iD)
			_PointsRotate($aPoints, $iD/2, $iD/2, Random(0, 360))
			_PointsTranslate($aPoints, Random(-$iD, $iW + $iD), Random(-$iD, $iH + $iD))
			_GDIPlus_GraphicsFillPolygon($hGfx, $aPoints, $hBRU)
			_GDIPlus_BrushSetSolidColor($hBRU, BitOR('0x' & Hex(Int(Random(16 / $aMulti[$n], 48 / $aMulti[$n], 1)), 2) & '000000', BitAND($iCol2, 0xFFFFFF)))
			$iD = Random($iW/12*$aMulti[$n], $iW/8*$aMulti[$n])
			$aPoints = _PointsFromRect(0, 0, $iD, $iD)
			_PointsRotate($aPoints, $iD/2, $iD/2, Random(0, 360))
			_PointsTranslate($aPoints, Random(-$iD, $iW + $iD), Random(-$iD, $iH + $iD))
			_GDIPlus_GraphicsFillPolygon($hGfx, $aPoints, $hBRU)
			_GDIPlus_BrushSetSolidColor($hBRU, '0x' & Hex(Int(Random(8, 16, 1)), 2) & '000000')
			$iD = Random($iW/12*$aMulti[$n], $iW/8*$aMulti[$n])
			$aPoints = _PointsFromRect(0, 0, $iD, $iD)
			_PointsRotate($aPoints, $iD/2, $iD/2, Random(0, 360))
			_PointsTranslate($aPoints, Random(-$iD, $iW + $iD), Random(-$iD, $iH + $iD))
			_GDIPlus_GraphicsFillPolygon($hGfx, $aPoints, $hBRU)
		Next
	Next


;~ 	_GDIPlus_ImageSaveToFile($hBmp, Random(100, 999, 1) & '.png')


	Local $hTex = _GDIPlus_TextureCreate($hBmp)


	_GDIPlus_BrushDispose($hLine)
	_GDIPlus_BrushDispose($hBru)
	_GDIPlus_GraphicsDispose($hGfx)
	_GDIPlus_BitmapDispose($hBmp)
	Return $hTex
EndFunc


Func _PointsTranslate(ByRef $aPoints, $iX, $iY)
	For $i = 1 To $aPoints[0][0] Step 1
		$aPoints[$i][0] += $iX
		$aPoints[$i][1] += $iY
	Next
EndFunc


Func _PointsStauchen(ByRef $aPoints, $mY, $nFaktor = 1)
	For $i = 1 To $aPoints[0][0] Step 1
		$aPoints[$i][1] = ($aPoints[$i][1] - $mY) * $nFaktor + $mY
	Next
EndFunc


Func _PointsRotate(ByRef $aPoints, $mX, $mY, $nDegAngle)
	Local $x, $fAngle = $nDegAngle / 180 * 3.141593
	For $i = 1 To $aPoints[0][0] Step 1
		$x = $mX + Cos($fAngle) * ($aPoints[$i][0] - $mX) - Sin($fAngle) * ($aPoints[$i][1] - $mY)
		$aPoints[$i][1] = $mY + Sin($fAngle) * ($aPoints[$i][0] - $mX) + Cos($fAngle) * ($aPoints[$i][1] - $mY)
		$aPoints[$i][0] = $x
	Next
EndFunc


Func _PointsFromRect($iX, $iY, $iW, $iH)
	Local $aPoints[5][2]
	$aPoints[0][0] = 4
	$aPoints[1][0] = $iX
	$aPoints[1][1] = $iY
	$aPoints[2][0] = $iX + $iW
	$aPoints[2][1] = $iY
	$aPoints[3][0] = $iX + $iW
	$aPoints[3][1] = $iY + $iH
	$aPoints[4][0] = $iX
	$aPoints[4][1] = $iY + $iH
	Return $aPoints
EndFunc

Alles anzeigen

PS: Ich weiß, dass das Skript sehr Spaghetticodeartig ist. Optimierungen sind erstmal nicht nötig, solange das Ergebnis noch nicht stimmt

lg
Mars

**UEZ**

Es wäre cool, wenn du noch ein Bump Mapping Effekt hinzufügen würdest -> Code Beispiel in C/C++

Dann sieht es gleich noch besser aus.

**Mars**

Darüber habe ich auch schon nachgedacht... allerdings ist das ohne eine Dll oder ASM nicht zu bewerkstelligen. Ich wollte erstmal rein in AutoIt bleiben. (und dort sollte die Rechnung in unter 100ms fertig sein).

Was ich vergessen habe zu erwähnen: Die normale Größe die benötigt wird liegt zwischen 12 und ca. 56 Pixeln. Deshalb ist es nicht soooo schlimm, dass die Asteroiden mit 100+ Pixeln etwas hässlich aussehen.

**Mars**

Doppelpostalarm, aber es gibt auch etwas neues

Ich habe mir überlegt lieber auf 3D umzusteigen und später aus den Koordinaten von Punkten auf einer Kugel durch transformation die Asteroidenoberfläche zu bekommen. Nach sehr vielen Ansätzen wie man die Punkte mit bestmöglicher Verteilung platziert habe ich keine mathematische Lösung gefunden und bin auf das Vielkörperproblem umgestiehen, das man ja numerisch mit sehr viel Rechenzeit lösen kann.

Genutzt wird also eine Einheitskugel mit einer gewissen Anzahl Punkte aus der Oberfläche. Diese stoßen sich gegenseitig ab, sodass sie nach einiger Zeit den größt möglichen Abstand zueinander haben. Die daraus entstehenden Koordinaten kann man für jede Anzahl Punkte abspeichern, sodass diese nur 1x berechnet werden müssen. (Später kann man die Koordinaten im eigentlichen Generator einfach laden und damit weiterarbeiten).

Anbei ist das Skript welches (mit schöner 3D Animation) die einzelnen Punkte während des Rechenvorgangs anzeigt. (Ein Dank geht hier an die wunderbare 3D GDI+ UDF von Starg aus dem englischen Forum: [Klick mich])

lg
M

**eukalyptus**

Vielleicht kannst du ja das brauchen.
Dieses Script erstellt eine Kugel mit einer zufälligen Gleichverteilung:

AutoIt

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include "Matrix.au3"


Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)




Global $iWidth = 600
Global $iHeight = 600






Global Const $cPI = ATan(1) * 4


_GDIPlus_Startup()
Global $hGui_Main = GUICreate("", $iWidth, $iHeight)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")


Global $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui_Main)
Global $hBmp_Buffer = _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight)
Global $hGfx_Buffer = _GDIPlus_ImageGetGraphicsContext($hBmp_Buffer)
_GDIPlus_GraphicsClear($hGfx_Buffer, 0xFF000000)
_GDIPlus_GraphicsSetSmoothingMode($hGfx_Buffer, 2)


GUIRegisterMsg($WM_PAINT, "WM_PAINT")
GUISetState()








Global $tOBJ = _Create()
Global $tMX = _MX3D_Create()




While Sleep(10)
	_Test()
WEnd






Func _Create()
	Local $iCnt = 500
	Local $tPnt = DllStructCreate("uint Cnt; float Pnt[" & $iCnt * 2 & "]; byte Vis[" & $iCnt & "]; float 3D[" & $iCnt * 3 & "];")
	DllStructSetData($tPnt, "Cnt", $iCnt)


	Local $fPhi, $fTheta, $fVX, $fVY, $fVZ, $fD, $fX, $fY


	Local $iIdx = 0
	For $i = 0 To $iCnt - 1
		$fPhi = ACos(Random(-1, 1))
		$fTheta = Random(0, $cPI * 2)


		$fVX = Sin($fPhi) * Cos($fTheta) * 160; * $fSpeed
		$fVZ = Sin($fPhi) * Sin($fTheta) * 160; * $fSpeed
		$fVY = Cos($fPhi) * 160; * $fSpeed




		DllStructSetData($tPnt, "3D", $fVX, $i * 3 + 1)
		DllStructSetData($tPnt, "3D", $fVY, $i * 3 + 2)
		DllStructSetData($tPnt, "3D", $fVZ, $i * 3 + 3)




	Next


	Return $tPnt
EndFunc   ;==>_Create








Func _Test()
	Local Static $iStep = 0
	$iStep += 1






	Local $fSpeed = $iStep


	Local $hPen = _GDIPlus_PenCreate(0xFF00FF00)


	_MX3D_RotateX($tMX, 0.7)
	_MX3D_RotateY($tMX, 0.5)
	_MX3D_RotateZ($tMX, 0.2)


	TransFormPoints($tOBJ, $tMX)
	_GDIPlus_GraphicsClear($hGfx_Buffer, 0xFF000000)


	For $i = 0 To $tOBJ.Cnt - 1
		_GDIPlus_GraphicsDrawEllipse($hGfx_Buffer, DllStructGetData($tOBJ, "Pnt", $i * 2 + 1), DllStructGetData($tOBJ, "Pnt", $i * 2 + 2), 4, 4, $hPen)
	Next


	_GDIPlus_PenDispose($hPen)


	_GDIPlus_GraphicsDrawImage($hGraphics, $hBmp_Buffer, 0, 0)
EndFunc   ;==>_Test












Func TransFormPoints($tPnt, $tMX)
	Local $iCnt = DllStructGetData($tPnt, "Cnt")
	Local $fX, $fY, $fZ, $fRX, $fRY, $fRZ, $fD
	Local $iIdx
	Local Const $LENS = 800


	Local $fCenterX = $iWidth * 0.5
	Local $fCenterY = $iHeight * 0.5


	For $i = 0 To $iCnt - 1
		$iIdx = $i * 3
		$fX = DllStructGetData($tPnt, "3D", $iIdx + 1)
		$fY = DllStructGetData($tPnt, "3D", $iIdx + 2)
		$fZ = DllStructGetData($tPnt, "3D", $iIdx + 3)


		_MX3D_MulVector($tMX, $fX, $fY, $fZ, $fRX, $fRY, $fRZ)


		$fD = ($LENS - $fRZ)
		If $fD > 0 Then
			$iIdx = $i * 2
			DllStructSetData($tPnt, "Pnt", $fCenterX + ($LENS * $fRX / $fD), $iIdx + 1)
			DllStructSetData($tPnt, "Pnt", $fCenterY - ($LENS * $fRY / $fD), $iIdx + 2)
			DllStructSetData($tPnt, "Vis", True, $i + 1)
		Else
			DllStructSetData($tPnt, "Vis", False, $i + 1)
		EndIf
	Next


EndFunc   ;==>TransFormPoints












Func WM_PAINT($hWnd, $iMsg, $wParam, $lParam)
	_GDIPlus_GraphicsDrawImage($hGraphics, $hBmp_Buffer, 0, 0)
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_PAINT






Func _Exit()


	_GDIPlus_GraphicsDispose($hGfx_Buffer)
	_GDIPlus_BitmapDispose($hBmp_Buffer)
	_GDIPlus_GraphicsDispose($hGraphics)
	GUIDelete($hGui_Main)


	_GDIPlus_Shutdown()
	Exit
EndFunc   ;==>_Exit

Alles anzeigen

Hier noch die "Matrix.au3"

AutoIt

#include-once


Global Const $bMX2D_Init = "0x000000000000F03F000000000000000000000000000000000000000000000000000000000000F03F000000000000000000000000000000000000000000000000000000000000F03F"
Global Const $bMX3D_Init = "0x000000000000F03F0000000000000000000000000000000000000000000000000000000000000000000000000000F03F0000000000000000000000000000000000000000000000000000000000000000000000000000F03F0000000000000000000000000000000000000000000000000000000000000000000000000000F03F"




; # Matrix 2D # =================================================================================================================


Func _MX2D_Create()
	;[ 1 0 0 ]
	;[ 0 1 0 ]
	;[ 0 0 1 ]
	Local $tMX = DllStructCreate("double[9];")


	DllStructSetData($tMX, 1, 1, 1)
	DllStructSetData($tMX, 1, 1, 5)
	DllStructSetData($tMX, 1, 1, 9)


	Return $tMX
EndFunc   ;==>_MX2D_Create




Func _MX2D_Clear(ByRef $tMX)
	$tMX = 0
	$tMX = DllStructCreate("double[9];")
EndFunc   ;==>_MX2D_Clear




Func _MX2D_Reset(ByRef $tMX)
	;[ 1 0 0 ]
	;[ 0 1 0 ]
	;[ 0 0 1 ]
	Local $tSet = DllStructCreate("byte[72];", DllStructGetPtr($tMX))
	DllStructSetData($tSet, 1, $bMX2D_Init)
EndFunc   ;==>_MX2D_Reset




Func _MX2D_GetValue($tMX, $iX, $iY)
	Local $fRet = DllStructGetData($tMX, 1, $iX * 3 + $iY + 1)
	If @error Then Return SetError(1, 1, False)
	Return $fRet
EndFunc   ;==>_MX2D_GetValue




Func _MX2D_Rotate(ByRef $tMX, $fD, $iO = False)
	;[ C  S  0 ]
	;[-S  C  0 ]
	;[ 0  0  1 ]


	If $fD = 0 Then Return True
	Local $fR = $fD * 0.0174532925199433


	Local $fC = Cos($fR)
	Local $fS = Sin($fR)


	Local $tMX1 = _MX2D_Create()
	DllStructSetData($tMX1, 1, $fC, 1)
	DllStructSetData($tMX1, 1, $fS, 2)
	DllStructSetData($tMX1, 1, -$fS, 4)
	DllStructSetData($tMX1, 1, $fC, 5)


	Switch $iO
		Case False
			$tMX = _MX2D_Mul($tMX1, $tMX)
		Case Else
			$tMX = _MX2D_Mul($tMX, $tMX1)
	EndSwitch


EndFunc   ;==>_MX2D_Rotate




Func _MX2D_Scale(ByRef $tMX, $fSX, $fSY, $iO = False)
	;[ X  0  0 ]
	;[ 0  Y  0 ]
	;[ 0  0  1 ]


	Local $tMX1 = _MX2D_Create()
	DllStructSetData($tMX1, 1, $fSX, 1)
	DllStructSetData($tMX1, 1, $fSY, 5)


	Switch $iO
		Case False
			$tMX = _MX2D_Mul($tMX1, $tMX)
		Case Else
			$tMX = _MX2D_Mul($tMX, $tMX1)
	EndSwitch


EndFunc   ;==>_MX2D_Scale




Func _MX2D_Translate(ByRef $tMX, $fX, $fY, $iO = False)
	;[ 1  0  0 ]
	;[ 0  1  0 ]
	;[ X  Y  1 ]


	Local $tMX1 = _MX2D_Create()
	DllStructSetData($tMX1, 1, $fX, 7)
	DllStructSetData($tMX1, 1, $fY, 8)


	Switch $iO
		Case False
			$tMX = _MX2D_Mul($tMX1, $tMX)
		Case Else
			$tMX = _MX2D_Mul($tMX, $tMX1)
	EndSwitch


EndFunc   ;==>_MX2D_Translate




Func _MX2D_Mul($tMX1, $tMX2)
	Local $tMX = DllStructCreate("double[9];")
	Local $fS


	For $x = 0 To 2
		For $y = 0 To 2
			$fS = 0
			For $z = 0 To 2
				$fS += DllStructGetData($tMX1, 1, $x * 3 + $z + 1) * DllStructGetData($tMX2, 1, $z * 3 + $y + 1)
			Next
			DllStructSetData($tMX, 1, $fS, $x * 3 + $y + 1)
		Next
	Next


	Return $tMX
EndFunc   ;==>_MX2D_Mul




Func _MX2D_MulVector($tMX, $fX, $fY, ByRef $fRX, ByRef $fRY)
	$fRX = ($fX * DllStructGetData($tMX, 1, 1)) + ($fY * DllStructGetData($tMX, 1, 2)) + DllStructGetData($tMX, 1, 3)
	$fRY = ($fX * DllStructGetData($tMX, 1, 4)) + ($fY * DllStructGetData($tMX, 1, 5)) + DllStructGetData($tMX, 1, 6)
	Return True
EndFunc   ;==>_MX2D_MulVector


























; # Matrix 3D # =================================================================================================================


Func _MX3D_Create()
	;[ 1  0  0  0 ]
	;[ 0  1  0  0 ]
	;[ 0  0  1  0 ]
	;[ 0  0  0  1 ]
	Local $tMX = DllStructCreate("double[16];")


	DllStructSetData($tMX, 1, 1, 1)
	DllStructSetData($tMX, 1, 1, 6)
	DllStructSetData($tMX, 1, 1, 11)
	DllStructSetData($tMX, 1, 1, 16)


	Return $tMX
EndFunc   ;==>_MX3D_Create




Func _MX3D_Clear(ByRef $tMX)
	$tMX = 0
	$tMX = DllStructCreate("double[16];")
EndFunc   ;==>_MX3D_Clear




Func _MX3D_Reset(ByRef $tMX)
	;[ 1  0  0  0 ]
	;[ 0  1  0  0 ]
	;[ 0  0  1  0 ]
	;[ 0  0  0  1 ]
	Local $tSet = DllStructCreate("byte[128];", DllStructGetPtr($tMX))
	DllStructSetData($tSet, 1, $bMX3D_Init)
EndFunc   ;==>_MX3D_Reset




Func _MX3D_GetValue($tMX, $iX, $iY)
	Local $fRet = DllStructGetData($tMX, 1, $iX * 4 + $iY + 1)
	If @error Then Return SetError(1, 1, False)
	Return $fRet
EndFunc   ;==>_MX3D_GetValue








Func _MX3D_Skew(ByRef $tMX, $fSkewX, $fSkewY, $iO = False)
	;[ 1 SY  0 ]
	;[SX  1  0 ]
	;[ 0  0  1 ]


	$fSkewX *= 0.0174532925199433
	$fSkewY *= 0.0174532925199433


	Local $tMX1 = _MX2D_Create()
	DllStructSetData($tMX1, 1, Tan($fSkewY), 2)
	DllStructSetData($tMX1, 1, Tan($fSkewX), 4)


	Switch $iO
		Case False
			$tMX = _MX2D_Mul($tMX1, $tMX)
		Case Else
			$tMX = _MX2D_Mul($tMX, $tMX1)
	EndSwitch


EndFunc








Func _MX3D_RotateX(ByRef $tMX, $fD, $iO = False)
	;[ 1  0  0  0 ]
	;[ 0  C -S  0 ]
	;[ 0  S  C  0 ]
	;[ 0  0  0  1 ]


	If $fD = 0 Then Return
	Local $fR = $fD * 0.0174532925199433


	Local $fC = Cos($fR)
	Local $fS = Sin($fR)


	Local $tMX1 = _MX3D_Create()
	DllStructSetData($tMX1, 1, $fC, 6)
	DllStructSetData($tMX1, 1, -$fS, 7)
	DllStructSetData($tMX1, 1, $fS, 10)
	DllStructSetData($tMX1, 1, $fC, 11)


	Switch $iO
		Case False
			$tMX = _MX3D_MulMatrix($tMX1, $tMX)
		Case Else
			$tMX = _MX3D_MulMatrix($tMX, $tMX1)
	EndSwitch


EndFunc   ;==>_MX3D_RotateX




Func _MX3D_RotateY(ByRef $tMX, $fD, $iO = False)
	;[ C  0  S  0 ]
	;[ 0  1  0  0 ]
	;[-S  0  C  0 ]
	;[ 0  0  0  1 ]


	If $fD = 0 Then Return
	Local $fR = $fD * 0.0174532925199433


	Local $fC = Cos($fR)
	Local $fS = Sin($fR)


	Local $tMX1 = _MX3D_Create()
	DllStructSetData($tMX1, 1, $fC, 1)
	DllStructSetData($tMX1, 1, $fS, 3)
	DllStructSetData($tMX1, 1, -$fS, 9)
	DllStructSetData($tMX1, 1, $fC, 11)


	Switch $iO
		Case False
			$tMX = _MX3D_MulMatrix($tMX1, $tMX)
		Case Else
			$tMX = _MX3D_MulMatrix($tMX, $tMX1)
	EndSwitch


EndFunc   ;==>_MX3D_RotateY




Func _MX3D_RotateZ(ByRef $tMX, $fD, $iO = False)
	;[ C -S  0  0 ]
	;[ S  C  0  0 ]
	;[ 0  0  1  0 ]
	;[ 0  0  0  1 ]


	If $fD = 0 Then Return
	Local $fR = $fD * 0.0174532925199433


	Local $fC = Cos($fR)
	Local $fS = Sin($fR)


	Local $tMX1 = _MX3D_Create()
	DllStructSetData($tMX1, 1, $fC, 1)
	DllStructSetData($tMX1, 1, -$fS, 2)
	DllStructSetData($tMX1, 1, $fS, 5)
	DllStructSetData($tMX1, 1, $fC, 6)


	Switch $iO
		Case False
			$tMX = _MX3D_MulMatrix($tMX1, $tMX)
		Case Else
			$tMX = _MX3D_MulMatrix($tMX, $tMX1)
	EndSwitch


EndFunc   ;==>_MX3D_RotateZ




Func _MX3D_Scale(ByRef $tMX, $fX, $fY, $fZ, $iO = False)
	;[ X  0  0  0 ]
	;[ 0  Y  0  0 ]
	;[ 0  0  Z  0 ]
	;[ 0  0  0  1 ]


	Local $tMX1 = _MX3D_Create()
	DllStructSetData($tMX1, 1, $fX, 1)
	DllStructSetData($tMX1, 1, $fY, 6)
	DllStructSetData($tMX1, 1, $fZ, 11)


	Switch $iO
		Case False
			$tMX = _MX3D_MulMatrix($tMX1, $tMX)
		Case Else
			$tMX = _MX3D_MulMatrix($tMX, $tMX1)
	EndSwitch


EndFunc   ;==>_MX3D_Scale




Func _MX3D_Translate(ByRef $tMX, $fX, $fY, $fZ, $iO = False)
	;[ 1  0  0  X ]
	;[ 0  1  0  Y ]
	;[ 0  0  1  Z ]
	;[ 0  0  0  1 ]
	Local $tMX1 = _MX3D_Create()
	DllStructSetData($tMX1, 1, $fX, 4)
	DllStructSetData($tMX1, 1, $fY, 8)
	DllStructSetData($tMX1, 1, $fZ, 12)


	Switch $iO
		Case False
			$tMX = _MX3D_MulMatrix($tMX1, $tMX)
		Case Else
			$tMX = _MX3D_MulMatrix($tMX, $tMX1)
	EndSwitch


EndFunc   ;==>_MX3D_Translate




Func _MX3D_MulMatrix($tMX1, $tMX2)
	Local $tMX = DllStructCreate("double[16];")


	Local $fS
	For $x = 0 To 2
		For $y = 0 To 3
			$fS = 0
			For $z = 0 To 3
				$fS += DllStructGetData($tMX2, 1, $x * 4 + $z + 1) * DllStructGetData($tMX1, 1, $z * 4 + $y + 1)
			Next
			DllStructSetData($tMX, 1, $fS, $x * 4 + $y + 1)
		Next
	Next


	DllStructSetData($tMX, 1, 1, 16)


	Return $tMX
EndFunc   ;==>_MX3D_MulMatrix




Func _MX3D_MulVector($tMX, $fX, $fY, $fZ, ByRef $fRX, ByRef $fRY, ByRef $fRZ)
	$fRX = ($fX * DllStructGetData($tMX, 1, 1)) + ($fY * DllStructGetData($tMX, 1, 2)) + ($fZ * DllStructGetData($tMX, 1, 3)) + DllStructGetData($tMX, 1, 4)
	$fRY = ($fX * DllStructGetData($tMX, 1, 5)) + ($fY * DllStructGetData($tMX, 1, 6)) + ($fZ * DllStructGetData($tMX, 1, 7)) + DllStructGetData($tMX, 1, 8)
	$fRZ = ($fX * DllStructGetData($tMX, 1, 9)) + ($fY * DllStructGetData($tMX, 1, 10)) + ($fZ * DllStructGetData($tMX, 1, 11)) + DllStructGetData($tMX, 1, 12)
	Return True
EndFunc   ;==>_MX3D_MulVector

Alles anzeigen

Da du ja nur die Vorderseite benötigst, reicht es, wenn du "$fTheta = Random(0, $cPI)" schreibst.

LgE

**Mars**

Die Zufallsverteilung bei meinem Skript ist nicht sehr gut (habe ich eben gesehen. Da läuft wohl irgendetwas nicht ganz rund...), das ist aber nicht weiter tragisch, da ja nicht die Zufallsverteilung interessant ist, sondern die "perfekte" Anordnung in der alle Punkte den gleichen minimalen Abstand zu ihrem nächsten Nachbarn haben.

Das skript aus Post 4 kann jetzt folgendes zusätzlich:
- Multiplikator: Beschleunigt die Berechnung und erhöht die Ungenauigkeit (vorallem zu Beginn). Später ist man mit einem Wert 1.000 < x < 100.000 gut bedient, höher ist nutzlos, da die Geschwindigkeit durch Rundungsfehler verringert wird. Im Allgemeinen sollte er so eingestellt werden, dass er für die gegebene Verteilung nicht zu ungenau und nicht zu langsam ist.
- Berechnung pausieren (sodass man wieder eine flüssige Rotation bei normaler Geschwindigkeit hat)
- Speichern: Speichert die Koordinaten aller Punkte in einer Datei ab. (Obacht, es wird NICHT überschrieben. Also immer eine neue Datei anlegen)
- Laden: Läd eine vorher abgespeicherte Datei und zeigt die Punkte an.

Jetzt können Vertielungen berechnet und gespeichert werden. Man kann sie später laden und das Skript etwas weiterrechnen lassen (dann wird die Verteilung nach beliebig langer Zeit beliebig gleichmäßig), oder die gewonnenen Daten für irgendetwas benutzen. (ich habe aber bisher keine Ahnung wozu man soetwas gebrauchen könnte^^).

Im Anhang sind ein paar Verteilungen für 60, 100, 200, 300, 400 vorberechnet, sodass man sich ein Bild machen kann was dieses Skript bezwecken soll.

lg
M

**UEZ**

Jetzt könnte man die Punkte mit der Warp Funktion von Eukalyptus mit Texturen versehen. Das hatte ich bereits nach dem Sphere Outro vor, ist aber in Vergessenheit geraten.

So könnte man z.B. eine rotierende Weltkugel darstellen.