Datensicherung

thewanderer

Bin grade drüber, mir ein Script zur Datensicherung zu basteln...

Spoiler anzeigen

AutoIt

#include <GUIConstants.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Date.au3>
#include <GuiListBox.au3>
#include <APIConstants.au3>
#include <Array.au3>
#include <Debug.au3>
#include <GuiListView.au3>
#include <File.au3>


Global $ini = @ScriptDir & "\datensicherung.ini"
Global $sources = @ScriptDir & "\quellen.ini"
Global $dest_select, $file
$txtg1 = "Info"
$txtg2 = "Pfad-Einstellungen"


; GUI Erstellen
$Form1 = GuiCreate("Datensicherung by ...", 350, 700, -1, -1, "", $WS_EX_TOOLWINDOW )
GUISetFont(9, 1000, 0, "Arial")
$Group1 = GUICtrlCreateGroup($txtg1, 8, 4, 328, 90)


; ### Info ###
; Computernamen ausgeben
GUICtrlCreateLabel("Computername:", 20, 30)
GuiCtrlCreateLabel("" & @ComputerName & "" , 130, 30)


;Benutzernamen ausgeben
GUICtrlCreateLabel("Benutzername:", 20, 50)
GuiCtrlCreateLabel("" & @UserName & "" , 130, 50)
; ### END Info ###


; ### Pfade ###
$Group2 = GUICtrlCreateGroup($txtg2, 8, 100, 328, 600)
; Sicherungspfad
$dest_path = GUICtrlCreateLabel(IniRead($ini, "Einstellungen", "destination", ""), 20, 165, 300, 20) ;Label Destination-Pfad
GUICtrlSetData($dest_select, $dest_path)
$btn_dest= GUICtrlCreateButton("Sicherung Ziel", 20, 130, 150, 25)


; Quelle
$aSource_path = _GUICtrlListBox_Create($Form1, "", 20, 200, 310, 320)
$btn_addfolder = GUICtrlCreateButton("Verzeichnis hinzufügen", 20, 570, 150, 25)
$btn_delfolder = GUICtrlCreateButton("Verzeichnis entfernen", 175, 570, 150, 25)


$btn_sload = GUICtrlCreateButton("Pfade aus Ini laden", 20, 600, 150, 25)
$btn_start = GUICtrlCreateButton("Sicherung starten", 175, 600, 150, 25)


$but_end=GuiCtrlCreateButton("Beenden", 230, 640, 100, 25)


GUISetState ()


While 1
	$msg = GUIGetMsg()
	Switch  $msg
    	Case $GUI_EVENT_CLOSE
        	ExitLoop
    	Case $btn_dest
        	_destination()
		Case $btn_addfolder
			_folder_add()
		Case $btn_delfolder
			_folder_remove()
		Case $btn_sload
			_load_sources()
		Case $btn_start
			_filewrite()
			_saveini()
			_start_copy()
    	Case $but_end
			_quit()
        	Exit
	EndSwitch


Wend


Func _start_copy()
	$Countfile= _FileCountLines($sources)
	$ziel = IniRead($ini, "Einstellungen", "destination", "")


	GUICtrlSetState($btn_start,$GUI_DISABLE)
	GUICtrlSetState($btn_dest,$GUI_DISABLE)
	GUICtrlSetState($btn_addfolder,$GUI_DISABLE)
	GUICtrlSetState($btn_delfolder,$GUI_DISABLE)
	GUICtrlSetState($btn_sload,$GUI_DISABLE)
		For $i = 1 To $Countfile
			$file1 = FileReadLine($sources, $i)




  		$RoboCopy = RunWait(@ComSpec & " /c " & "robocopy " & $file1 & " " & $ziel & " /FP /S /E /COPY:DAT /ZB /R:0 /W:0", "")
		Next


	GUICtrlSetState($btn_start,$GUI_ENABLE)
	GUICtrlSetState($btn_dest,$GUI_ENABLE)
	GUICtrlSetState($btn_addfolder,$GUI_ENABLE)
	GUICtrlSetState($btn_delfolder,$GUI_ENABLE)
	GUICtrlSetState($btn_sload,$GUI_ENABLE)


EndFunc


Func _load_sources()
	$Countfile= _FileCountLines($sources)
	$file = $sources
		For $i = 1 To $CountFile
		$var1= FileReadLine($file, $i)
		_GUICtrlListBox_AddString($aSource_path, $var1)
	Next
EndFunc


Func _destination()
	$dest_select=FileSelectFolder("Ordner auswählen", @HomeDrive, 2, "", $Form1)
	GUICtrlSetData($dest_path, $dest_select)
EndFunc


Func _folder_add()
	Local $newFolder = FileSelectFolder("Verzeichnis auswählen", @HomeDrive, 2, "" , $Form1)
	If _GUICtrlListBox_GetCount($aSource_path) < 20 Then ;Max. 20 Einträge
		If $newFolder <> '' Then
			_GUICtrlListBox_AddString($aSource_path,$newFolder)


		EndIf
	EndIf
EndFunc


Func _folder_remove()
	Local $iIndex = _GUICtrlListBox_GetCurSel($aSource_path)
	Local $iIndex_text = _GUICtrlListBox_GetText($aSource_path, $iIndex)
	_GUICtrlListBox_DeleteString($aSource_path, $iIndex)
EndFunc


Func _filewrite()
	$file_s = FileOpen($sources,2)
	For $i = 0 To _GUICtrlListBox_GetCount($aSource_path) - 1
		FileWriteLine($file_s, _GUICtrlListBox_GetText($aSource_path, $i))
	Next
	FileClose($file_s)
EndFunc   ;==>_FileWrite




Func _saveini()
	IniWrite($ini, "Einstellungen", "destination", $dest_select)
EndFunc   ;==>saveini


Func _quit()
	_saveini()
	_filewrite()
	Exit
EndFunc   ;==>_Quit

Alles anzeigen

Allerdings scheint bei dem RoboCopy Befehl (Zeile 89) irgendwas nicht zu stimmen. Dos-Box geht zwar auf und er tut was, aber nicht kopieren
Kann da mal jemand drüber schauen und mir nen Tip geben?

Micha_he

ohne mir das Script näher angesehen zu haben würde ich die Zeile wie folgt ändern, um Leerzeichen verarbeiten zu können:

AutoIt

$RoboCopy = RunWait('robocopy "' & $file1 & '" "' & $ziel & '" /FP /S /E /COPY:DAT /ZB /R:0 /W:0', "")

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

High,
machst Du das Scribt aus Spass an der Freude - oder weil Du eine vernünftige Lösung suchst? Wenn letzteres versuch mal Back4shure
http://www.ukrebs-software.de/ .

Ist Freeware und zusammen mit einem kleinen Scribt autoit - macht das bei mir seit Jahren - extrem zuverlässig seinen Dienst.

Gruß

Peter

Ps.: Ich fand robocoby nie wirklich prikelnd

thewanderer

Danke für eure Antworten,
mach des nur um mich bissi in autoit reinzufummeln - austesten, was möglich ist. Sagen wir mal so, machbar ist viel, aber wesentlich umständlicher, wie mit nem shell-script. Da mach ich ne wöchentliche Datensicherung von zig verschiedenen Verzeichnissen, mit Rotation und zusätzlicher täglichen Synchronisierung mit nem Drittel an Code, was mein bisheriges Script hat

Zitat von Peter S. Taler

Ps.: Ich fand robocoby nie wirklich prikelnd

Musste ich auch grade herausfinden
Werd wohl doch bei meinem schönen rsync-script bleiben...

thewanderer

Hab grade eine portable Version von rsync gefunden, also kann man es doch mit Win machen. Meine meisten Kunden haben nunmal den Mist druff...
Problem ist nur, dass es mit cygwin arbeitet, demnach sehen die Pfadangaben so aus z.B. "/cygdrive/c/programme"

Hab es aber so in meinem Script gelöst:

AutoIt

Func _folder_add()
	Local $newFolder = FileSelectFolder("Verzeichnis auswählen", @HomeDrive, 2, "" , $Form1)
	If _GUICtrlListBox_GetCount($aSource_path) < 20 Then ;Max. 20 Einträge
		If $newFolder <> '' Then
			Local $aFirst = StringRegExp($newFolder, "\A[a-zA-Z]", 1)
			$aMod1 = StringRegExpReplace($newFolder, "(?i)[a-z]:\\", "/cygdrive/" & $aFirst[0] & "/", 0)
 			$aMod2 = StringRegExpReplace($aMod1, "(?i)\\", "/", 0)
  			_GUICtrlListBox_AddString($aSource_path,$aMod2)
		EndIf
	EndIf
EndFunc

Alles anzeigen

Nicht schön, aber funktioniert

Runa

Ich nehme schlicht die Freeware VEEAM EndpointBackup. Solltest du dir vielleicht mal angucken, auch wenn es ein Imageprogramm ist und somit nicht so restriktiv wie ein Backupprogramm.

Yaerox

SyncBack und Veeam in Kombination nutze ich für alle meine Anliegen.

Veeam bietet dir mehrere Möglichkeiten der Wiederherstellung, auf Volumen sowie Dateiebene.

thewanderer

Naja, ich hab mir schon zig Backup-Programme angeschaut, war aber noch nicht das Richtige dabei.
Ich mach momentan 1x im Monat eine Vollsicherung verschiedener Verzeichnisse auf verschiedenen Laufwerken von meinem Server und 3x im Monat ne inkrementelle Sicherung. Es sollen aber max. 6 Vollsicherungen auf dem Backup-NAS liegen

Yaerox

Bei der freien Version vom Veeam kannst du die Art des Backups nicht beeinflussen.* Ich nutze die Software nun seit gut 4 Monaten und mache ein Backup pro Woche von je allen Rechnern zu Hause. Das erste ist logischerweise immer ein Full, danach kamen bei mir Wochenlang nur Inkrementelle. (Zumindest habe ich anhand des Speicherplatzes kein Differenzielles Backup feststellen können).
Ich kann das jetzt nicht mit Sicherheit sagen und ob es zeitlich oder von der Häufigkeit abhängt, aber bei mir hat er nach 3 Monaten ein neues Fullbackup erzeugt.

Ich habe es in erster Linie aus Testgründen genutzt, nur finde ich es wirklich grandios, zumal wir mit den Business Produkten in der Firma arbeiten.
Zum Speicherplatz vll. mal ne grobe Aussage:
Ich sichere mein Notebook (240GB SSD Platte) und mein Rechner (240GB SSD + 1TB SSHD) wie gesagt 1x pro Woche. Bei der Komprimierung war mir aufgefallen, dass es wohl auch stark auf den Typ der Daten ankommt. Bekannter der nur Dokumente hat hat eine Komprimierung um Faktor 3, bei mir wo es auch viel Musik/Bild- und Videomaterial gibt ist es Faktor 2.

Da das Ziel bzw. der Grund die Software zu testen andere waren, habe ich mich bislang nicht mit weiteren Funktionalitäten beschäftigt, daher vll. auch einfach nochmal auf der Website schauen und lesen ob das wohl was für dich wäre. Ich habe früher viele verschiedene Arten von Datensicherungen genutzt, aber keine war wirklich komfortabel. Jetzt mit Veeam kann ich binnen 2 Stunden einen Rechner komplett recovern. Das ist sehr entspannend.

Update: * Ich hab es noch nicht ausprobiert, aber ein Test wäre vll. den Speicherort zu wechseln, oder die vorhandenen Backups aus dem Verzeichnis zu entfernen. Vll. beeinflusst es die Art des Backups. Ich könnte mir das vorstellen, wissen tu ich das jedoch nicht.

Update 2: Vergessen zu sagen, dass du jedoch noch verschiedene Modi hast die du nutzen kannst. Aber wie erwähnt, in jedem Modi wird die Art des Backups nicht wählbar gemacht: https://i.imgur.com/2J2jnHg.png

Runa

Was meinst du denn mit Backup-Art?

Du hast in der kostenlosen Variante die Wahl zwischen "Entire computer", "Volume Level Backup" sowie "File level backup". Und bei diesen wählst du aus, wo diese gespeichert werden soll, wie viele Versionen er behalten soll, was du gerne für nen Dateiformat hättest und so weiter.... meine Backups sind zum Beispiel täglich (!) Vollbackups im ISO-Format.

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

sorry wenn ich so hartnäckig bin - ich habe nichts davon - aber ich habe auch einige dutzend Programme versucht. Back4shure ist portable und macht alles was ich bis zum Einsatz nie hinbekommen habe. Die zwei oder drei sächelchen die nicht so waren wie ich es wollte macht das autoit scribt.

Freeware noch dazu --> schaut es Euch mal an.

Gruß

Peter

thewanderer

Ich bastel das Script ja auch, um mich in autoit reinzufummeln
Klappt ja soweit auch schon ganz gut, nur bei einer Sache häng ich grade fest.

Spoiler anzeigen

AutoIt

#include <GUIConstants.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Date.au3>
#include <GuiListBox.au3>
#include <APIConstants.au3>
#include <Array.au3>
#include <Debug.au3>
#include <GuiListView.au3>
#include <File.au3>


Global $ini = @ScriptDir & "\datensicherung.ini"
Global $sources = @ScriptDir & "\quellen.ini"
Global $dest_select, $file, $aMod2




$txtg1 = "Info"
$txtg2 = "Pfad-Einstellungen"


; GUI Erstellen
$Form1 = GuiCreate("Datensicherung", 350, 700, -1, -1, "")
GUISetFont(9, 1000, 0, "Arial")
$Group1 = GUICtrlCreateGroup($txtg1, 8, 4, 328, 60)


; ### Info ###
; Computernamen ausgeben
GUICtrlCreateLabel("Computername:", 20, 30)
GuiCtrlCreateLabel("" & @ComputerName & "" , 130, 30)


; ### Pfade ###
$Group2 = GUICtrlCreateGroup($txtg2, 8, 70, 328, 590)
; Sicherungspfad
; Win
$dest_path_win = GUICtrlCreateLabel(IniRead($ini, "Einstellungen", "dest1", ""), 20, 130, 300, 20) ;Label Destination-Pfad
GUICtrlSetData($dest_select, $dest_path_win)
; RSync
$dest_path_rs = GUICtrlCreateLabel(IniRead($ini, "Einstellungen", "dest2", ""), 20, 145, 300, 20) ;Label Destination-Pfad
GUICtrlSetData($dest_select, $dest_path_rs)
$btn_dest= GUICtrlCreateButton("Sicherung Ziel", 20, 95, 150, 25)


; Quelle
$aSource_path = _GUICtrlListBox_Create($Form1, "", 20, 170, 310, 320)




$btn_addfolder = GUICtrlCreateButton("Verzeichnis hinzufügen", 20, 560, 150, 25)
$btn_delfolder = GUICtrlCreateButton("Verzeichnis entfernen", 175, 560, 150, 25)


$btn_sload = GUICtrlCreateButton("Pfade aus Ini laden", 20, 590, 150, 25)
$btn_start = GUICtrlCreateButton("Sicherung starten", 175, 590, 150, 25)


$but_end=GuiCtrlCreateButton("Beenden", 225, 625, 100, 25)


GUISetState ()




While 1
	$msg = GUIGetMsg()
	Switch  $msg
    	Case $GUI_EVENT_CLOSE
        	ExitLoop
    	Case $btn_dest
        	_destination()
		Case $btn_addfolder
			_folder_add()
		Case $btn_delfolder
			_folder_remove()
		Case $btn_sload
			_load_sources()
		Case $btn_start
			_test_files()
    	Case $but_end
			Exit
	EndSwitch


Wend


func _test_files()
Local $s_path = (IniRead($ini, "Einstellungen", "dest1",""))
$aFiles = _FileListToArray($s_path, @ComputerName & "*", 2)
If @error = 4 Then
		_test_copy()
	Else
		local $aFilesExt[$aFiles[0]][2] ; 2D Array erstellen
		for $i= 1 to $aFiles[0]
			$aFilesExt[$i-1][0] = $aFiles[$i]
			$aFilesExt[$i-1][1] = FileGetTime($aFiles[$i], 0 , 1)
		next
		_ArraySort($aFilesExt, 0, 0, 0, 1) ; Array sortieren
		_ArrayDisplay($aFilesExt)
		If $aFilesExt[0][1] > 2 Then
			For $i = 1 To $aFilesExt[0][1] - 2
				DirRemove($s_path & "\" & $aFilesExt[$i][0], 1)
			Next
		EndIf
	_test_copy()
EndIf


EndFunc


Func _test_copy()
	Local $ziel_win = (IniRead($ini, "Einstellungen", "dest1","") & "\" & @ComputerName & "_" & @MDAY & "_" & @MON & "_" & @YEAR)
	If FileExists($ziel_win) Then
		$ask1 = MsgBox(1, "", "Sicherung vorhanden!" & @CRLF & "Trotzdem sichern?")
		Switch $ask1
			Case 1
				_start_copy()
			Case 2
				Exit
		EndSwitch
	Else
		DirCreate($ziel_win)
		_start_copy()
	EndIf
EndFunc


Func _start_copy()
Local $ziel_rs = (IniRead($ini, "Einstellungen", "dest2","") & "/" & @ComputerName & "_" & @MDAY & "_" & @MON & "_" & @YEAR)
Local $rsync = @ScriptDir & "\rsync\bin\rsync.exe"
Local $para = "-a -v -P --chmod=ugo=rwX --size-only "
$Countfile= _FileCountLines($sources)


	GUICtrlSetState($btn_start,$GUI_DISABLE)
	GUICtrlSetState($btn_dest,$GUI_DISABLE)
	GUICtrlSetState($btn_addfolder,$GUI_DISABLE)
	GUICtrlSetState($btn_delfolder,$GUI_DISABLE)
	GUICtrlSetState($btn_sload,$GUI_DISABLE)
		For $i = 1 To $Countfile
			$file1 = FileReadLine($sources, $i)
			$sync = RunWait( $rsync & " " & $para & " " & '"' & $file1 & '"' & " " & '"' & $ziel_rs & '"', "")
			$s_del = _GUICtrlListBox_FindString($aSource_path, $file1, True)
			_GUICtrlListBox_DeleteString($aSource_path, $s_del)
		Next
	GUICtrlSetState($btn_start,$GUI_ENABLE)
	GUICtrlSetState($btn_dest,$GUI_ENABLE)
	GUICtrlSetState($btn_addfolder,$GUI_ENABLE)
	GUICtrlSetState($btn_delfolder,$GUI_ENABLE)
	GUICtrlSetState($btn_sload,$GUI_ENABLE)
	MsgBox(0, "Abgeschlossen", "Kopieren abgeschlossen")
EndFunc


Func _load_sources()
	$Countfile= _FileCountLines($sources)
	$file = $sources
		For $i = 1 To $CountFile
		$var1= FileReadLine($file, $i)
		_GUICtrlListBox_AddString($aSource_path, $var1)
	Next
EndFunc


Func _destination()
	$dest_select=FileSelectFolder("Ordner auswählen", @HomeDrive, 2, "", $Form1)
				Local $aFirst = StringRegExp($dest_select, "\A[a-zA-Z]", 1)
			$aMod1 = StringRegExpReplace($dest_select, "(?i)[a-z]:\\", "/cygdrive/" & $aFirst[0] & "/", 0)
 			$aMod2 = StringRegExpReplace($aMod1, "(?i)\\", "/", 0)
	GUICtrlSetData($dest_path_win, $dest_select)
	GUICtrlSetData($dest_path_rs, $aMod2)
	_saveini()
EndFunc


Func _folder_add()
	Local $newFolder = FileSelectFolder("Verzeichnis auswählen", @HomeDrive, 2, "" , $Form1)
	If _GUICtrlListBox_GetCount($aSource_path) < 20 Then
		If $newFolder <> '' Then
			Local $aFirst = StringRegExp($newFolder, "\A[a-zA-Z]", 1)
			$aMod1 = StringRegExpReplace($newFolder, "(?i)[a-z]:\\", "/cygdrive/" & $aFirst[0] & "/", 0)
 			$aMod2 = StringRegExpReplace($aMod1, "(?i)\\", "/", 0)
  			_GUICtrlListBox_AddString($aSource_path,$aMod2)
		EndIf
	EndIf
_filewrite()
EndFunc


Func _folder_remove()
	Local $iIndex = _GUICtrlListBox_GetCurSel($aSource_path)
	Local $iIndex_text = _GUICtrlListBox_GetText($aSource_path, $iIndex)
	_GUICtrlListBox_DeleteString($aSource_path, $iIndex)
EndFunc


Func _filewrite()
	$file_s = FileOpen($sources,2)
	For $i = 0 To _GUICtrlListBox_GetCount($aSource_path) - 1
		FileWriteLine($file_s, _GUICtrlListBox_GetText($aSource_path, $i))
	Next
	FileClose($file_s)
EndFunc   ;==>_FileWrite




Func _saveini()
	IniWrite($ini, "Einstellungen", "dest1", $dest_select) ;Win-Pfad
	IniWrite($ini, "Einstellungen", "dest2", $aMod2) ; RSync-Pfad


EndFunc   ;==>saveini

Alles anzeigen

bei der Function ab Zeile 77 scheint etwas nicht zu stimmen. Ich les meine Verzeichnisse zwar in ein 2D Arrays ein, um auch das Datum der Verzeichnisse zu ermitteln, allerdings steht bei keinem Verzeichnis ein Datum im Array.

Wenn ich mit Explorer im Verzeichnis schau, steht alles bei. also Datum, Uhrzeit etc. Könnte da mal jemand drüber schauen und mir nen Tip geben? Mit Array's hab ich es NOCH nicht wirklich so;)

Ändere ich die Zeile 79 auf:
$aFiles = _FileListToArray(@ScriptDir, "*", 2) bzw. auf $aFiles = _FileListToArray(@HomeDrive & "/temp", "*", 2)
wird es komischerweise (teilweise) angezeigt. ok, ist anderes Verzeichnis, aber da steht was drin

thewanderer

Hab jetzt auch mal in Zeile 79 noch nen Backslash eingefügt, macht aber auch keinen Unterschied
$aFiles = _FileListToArray($s_path & "\", @ComputerName & "*", 2)

**autoBert**

In Zeile 79 ist definitv ein Fehler, denn der Filter ("*") ist der 2. Paramater, daß du

dem Path den du aus der Ini liest auch noch den Computernamen anhängst und
als Path den Zielpfad benutzt

irritiert mich noch mehr.

@Error=4 bedeutet übrigens keine Dateien gefunden.

thewanderer

in $s_path steht nur C:\temp (nur ein Beispiel, ist in Wirklichkeit auf dem NAS). Er erstellt dort bei jeder Sicherung ein Verzeichnis Computername_DD_MM_YYYY. Allerdings liegen da auch Sicherungen anderer Rechner mit anderen Namen, deshalb die Abfrage mit Computername, sonst würde er generell die ältesten Verzeichnisse löschen. Hab es aber auch schon mit $aFiles = _FileListToArray(@HomePath, "*", 2) mit dem gleichen Ergebnis. Bei einigen Verzeichnissen steht ein datum dabei, bei anderen nicht.

Das @Error = 4 hab ich drin, weil ja beim erstmaligen Aufruf der Sicherung noch keine Sicherung existiert und er deshalb abbrechen würde, bzw wenn man das Zielverzeichnis ändert und dort noch keine Sicherungen vorhanden sind

thewanderer

Hab meine Funktion jetzt abgeändert, sollte also jetzt stimmen. Hab bewußt auch mal anderes Verzeichnis genommen

AutoIt

func _test_files()
;~Local $s_path = ((IniRead($ini, "Einstellungen", "dest1","")) & "\")
Local $s_path = @HomeDrive & "\temp\"
$aFiles = _FileListToArray($s_path, "*", 2)
If @error = 4 Then
		_test_copy()
	Else
		local $aFilesExt[$aFiles[0]][2] ; 2D Array erstellen
		for $i= 1 to $aFiles[0]
			$aFilesExt[$i-1][0] = $aFiles[$i]
			$aFilesExt[$i-1][1] = FileGetTime($aFiles[$i], 0, 1)
		next
		_ArraySort($aFilesExt, 0, 0, 0, 1) ; Array sortieren
		_ArrayDisplay($aFilesExt)




		If $aFilesExt[0][1] > 2 Then
			For $i = 1 To $aFilesExt[0][1] - 2
				DirRemove($s_path & "\" & $aFilesExt[$i][0], 1)
			Next
		EndIf
	_test_copy()
EndIf
EndFunc

Alles anzeigen

Ergebnis ist folgendes:

thewanderer

FileGetTime scheint echt nur sporatisch zu funktionieren. Hab grade mal folgendes getestet

AutoIt

#include <Date.au3>
#include <Array.au3>
#include <File.au3>
#include <Debug.au3>
_test()
func _test()
Local $path = @HomeDrive & "\temp\rsync"
$aFiles = _FileListToArray($path, "*", 0)


	local $aFilesExt[$aFiles[0]][2] ; 2D Array erstellen
	for $i = 1 to $aFiles[0]
		$aFilesExt[$i - 1][0] = $aFiles[$i]
		$aFilesExt[$i - 1][1] = FileGetTime($aFiles[$i], 0, 1)
		next
		_ArrayDisplay($aFilesExt)
EndFunc

Alles anzeigen

In der ersten Spalte sollten ja die Dateinamen und in der 2. Spalte das Datum auftauchen.
Ergebnis:

Irgendwie ist der Wurm drin

**Kanashius**

Sieh dir mal Exiftool an, damit kann man das auch auslesen. Gibts auch ne art udf für, glaub ich,

**Andy**

Ich nutze viele Scripte, die per filegettime() Dateien bspw. älter als 6 Wochen verschieben/backuppen oder lösschen. Das funktioniert immer und auch zuverlässig auch innerhalb unseres Netzwerks.

Wenn man natürlich falsche Dateinamen (ohne Pfad !!) benutzt, dann ist man selber schuld wenn man kein Ergebnis bekommt....

$aFilesExt[$i - 1][1] = FileGetTime($path & "\" & $aFiles[$i], 0, 1)

Der "Fehler" wäre sofort aufgefallen, wenn @error und die Rückgabe des Befehls ausgewertet, bzw. das Beispiel aus der Hilfe konsultiert worden wäre.
Also ein klassischer "Handbook-not-read-Error"!