Run() geht nicht mehr o.o

xSunLighTx3

Hey,

seit gestern geht der Befehl Run() einfach nicht mehr. Ich habe nicht einmal was verändert am Script
und zuvor ging auch alles. Soweit ich mich erinnern kann, gab es auch kein Windows Update o.Ä.

Ich habe daraufhin ein Beispiel Script gemacht, weil das ursprüngliche Script etwas zu lang wäre
und nicht gerade zu schnellen Testzwecken geeignet ist.

Im Pfad kommen 2x Leerzeichen vor. Einmal im Usernamen und einmal im Ordner, wo sich w.txt und
die Autoit Datei befindet. "C:\Users\dev acc\Desktop\run test"

Als Error bekomme ich 1 heraus. Die Pid, wenn ich sie abfrage, ist immer 0.

Zitat

Paths with spaces need to be enclosed in quotation marks.

Das habe ich auch schon gemacht (wie im Script zu sehen). Ohne oder mit Anführungszeichen, nichts geht.
Habt ihr vielleicht auch solche Probleme oder wisst ihr, wie man das behebt?

Wenn ich Run("notepad.exe") ausführe, funktioniert jedoch alles.

AutoIt

#RequireAdmin


If Not FileExists(@ScriptDir & "\w.txt") Then
	MsgBox(0, "", "file not exists")
	Exit
EndIf


Local $pid = Run('"' & @ScriptDir & '\w.txt"')


If @error Then
	MsgBox(0, $pid, "error: " & @error)
	Exit
EndIf
ProcessClose($pid)

Alles anzeigen

**Xorianator**

Zitat von xSunLighTx3

seit gestern geht der Befehl Run() einfach nicht mehr

Verrückt!

Probier mal den Befehl "ShellExecute()"

xSunLighTx3

Hey Xorianator,

ShellExecute() geht zwar, aber wenn ich eine Datei mit unbekannter Endung starte,
z.B datei.xyz, dann will Windows, dass man ein Progrmam auswählt, mit der
man Dateien mit dieser Endung starten soll. Und im Hauptscript starte ich quasi
so eine Datei.

**Xorianator**

Starten?
Was genau tust du bitte?

xSunLighTx3

Eine Datei mit unbekannter Endung starten.

Bei Shellexecute("Datei") oder einer anderen unbekannten Endung
funktioniert das ja leider nicht.

Bei Run("Datei") ging das aber immer bis jetzt.

Lottich

Funktioniert es denn, wenn du den Ausführungsort änderst?
zB wenn @ScriptDir = "C:\Testordner" (also ohne Leerzeichen)

Aber wenn nicht bekannt ist, WOMIT die Datei geöffnet werden soll... wie soll das gehen??

xSunLighTx3

Heii Lottich,

ich habe es unter "C:\Testordner" probiert, aber das ging auch nicht. :o
Das mit der Datei meine ich so, die Datei hat keine bekannte Endung,
wie .exe. Und wenn ich die Dateiendung nicht in der registry drin habe,
fragt Windows bei Nutzung von ShellExecute(), womit die Datei geöffnet
werden soll. Ist bei Run() sonst nicht so gewesen, weswegen ich es genutzt habe.

Hier ein kleines Beispiel was ich meine: https://www.youtube.com/watch?v=HmN-knZmC3s

Edit: Ein Kollege hat den Code auch mal auf seinem PC getestet und da ging es ebenfalls nicht.

**autoBert**

Zitat von xSunLighTx3

Eine Datei mit unbekannter Endung starten.

Bei Shellexecute("Datei") oder einer anderen unbekannten Endung
funktioniert das ja leider nicht.

Bei Run("Datei") ging das aber immer bis jetzt.D

Die in Win ehemals integrierte Glaskugel ist seit kurzem in Rente!

Daher must du das Programm selbst bennenen mit dem die Datei geöffnet werden soll.

CentuCore

Wenn du die Datei mit ShellExecute öffnen kannst mach's so:
ShellExecute("PfadZumProgramm", "PfadZurDatei")

**Bitnugger**

Die Umgebungsvariable %PATHEXT% gibt Auskunft darüber, ob eine Datei ausgeführt werden kann. Wird die Dateiendung ".xyz" hier nicht aufgeführt, kann die Datei nicht ausgeführt werden - was bei unbekannten Dateiendungen ja immer der Fall ist!

Bash

:~# echo %PATHEXT%
.COM;.EXE;.BAT;.CMD;.VBS;.VBE;.JS;.JSE;.WSF;.WSH;.MSC;.PY;.PYW

Zitat von xSunLighTx3

Local $pid = Run('"' & @ScriptDir & '\w.txt"')

Schickst du diesen "Befehl" direkt in der Eingabeaufforderung ab, wird die Datei "w.txt" im Texteditor geöffnet.

Gleiches Verhalten kannst du in AutoIt so reproduzieren...

AutoIt

Local $pid = Run(@ComSpec & ' /c "' & @ScriptDir & '\w.txt"')

Die Run() Funktion in AutoIt liefert uns jedoch lediglich einen Fehlercode, was vermuten lässt, dass vorab überprüft wird, ob die Dateiendung ".txt" in der Variable %PATHEXT% enthalten ist - sprich: welche(s|r) Programm/Interpreter damit gefüttert werden soll.

Allerdings ist es für meine Begriffe nicht sonderlich klug, Dateien mit unbekannten Dateiendungen ausführen zu wollen... denn das kann u.U. sehr böse enden!

Ich habe dir aber dennoch ein kleines Script gebastelt, mit dem dies möglich ist...

Run_Unknown_Ext.au3

AutoIt

;-- TIME_STAMP   2016-08-05 15:45:00


#RequireAdmin


#Region    ;************ Includes ************
#include <WinAPIReg.au3>
#include <File.au3>
#EndRegion ;************ Includes ************


; Hier den Pfad anpassen...
Local $sPath = "C:\Users\dev acc\Desktop\run test"


If FileExists($sPath) = 0 Then DirCreate($sPath)
If FileExists($sPath & '\x.cmd') = 0 Then FileWrite($sPath & '\x.cmd', 'mspaint.exe')
If FileExists($sPath & '\x.txt') = 0 Then FileWrite($sPath & '\x.txt', 'notepad.exe')
If FileExists($sPath & '\x.xyz') = 0 Then FileWrite($sPath & '\x.xyz', 'C:\Windows\System32\win32calc.exe')


_ShowAssoc('.xyz')
_ShowAssoc('.cmd')
_ShowAssoc('.txt')
;_ShowAssoc('.au3')
;_ShowAssoc('.exe')


_Run_xyz($sPath & '\x.cmd')
_Run_xyz($sPath & '\x.txt')
_Run_xyz($sPath & '\x.xyz')


Func _ShowAssoc($sExt)
	ConsoleWrite('------------------------------------------------------------' & @CRLF)
	ConsoleWrite('Extension....: ' & $sExt & @CRLF)
	ConsoleWrite('Type.........: ' & _WinAPI_AssocQueryString($sExt, $ASSOCSTR_FRIENDLYDOCNAME) & @CRLF)
	ConsoleWrite('Command......: ' & _WinAPI_AssocQueryString($sExt, $ASSOCSTR_COMMAND) & @CRLF)
	ConsoleWrite('Executable...: ' & _WinAPI_AssocQueryString($sExt, $ASSOCSTR_EXECUTABLE) & @CRLF)
	ConsoleWrite('Icon.........: ' & _WinAPI_AssocQueryString($sExt, $ASSOCSTR_DEFAULTICON) & @CRLF)
	ConsoleWrite('+-----------------------------------------------------------' & @CRLF & @CRLF)
EndFunc


Func _Run_xyz($sCommand)
	ConsoleWrite('------------------------------------------------------------' & @CRLF)
	Local $sTempFile = ''
	Local $sDrive = "", $sDir = "", $sFileName = "", $sExtension = ""
	Local $aPathSplit = _PathSplit($sCommand, $sDrive, $sDir, $sFileName, $sExtension)
	Local $sPath = $sDrive & $sDir


	Local $sPATHEXT = EnvGet('PATHEXT')
	If StringInStr($sPATHEXT, $sExtension) = 0 Then


		If StringInStr(_WinAPI_AssocQueryString($sExtension, $ASSOCSTR_COMMAND), 'OpenWith.exe') Then
			$iError = 1
			$sMessage = '! Achtung - "' & $sFileName & $sExtension & '" ist eine Datei mit einer unbekannten Extension!' & @CRLF
			ConsoleWrite($sMessage)
		Else
			$iError = 2
			$sMessage = '! Achtung - "' & $sFileName & $sExtension & '" ist keine ausführbare Datei!' & @CRLF
			ConsoleWrite($sMessage)
		EndIf


		Local $iMsgBoxAnswer = MsgBox(262196, 'Achtung!', $sMessage & @CRLF & @CRLF & "Willst du versuchen die Datei als BatchFile auszuführen?")
		Select
			Case $iMsgBoxAnswer = 6 ;Yes
				ConsoleWrite('- Ok, dann versuchen wir die Datei als BatchFile auszuführen...' & @CRLF)
			Case $iMsgBoxAnswer = 7 ;No
				ConsoleWrite('+ No, das ist eine intelligente Entscheidung! ;-)' & @CRLF)
				Return SetError($iError, 0, $sMessage)
		EndSelect


		; Generate a unique filename in @TempDir
		$sTempFile = StringReplace(_TempFile(), '.tmp', '.cmd')
		FileCopy($sCommand, $sTempFile)
		$aPathSplit = _PathSplit($sTempFile, $sDrive, $sDir, $sFileName, $sExtension)
		$sCommand = $sTempFile
		$sPath = $sDrive & $sDir
	EndIf
	Local $sCMD = @ComSpec & ' /c "' & $sCommand & '"'
	ConsoleWrite('$sPath = ' & $sDrive & $sDir & @CRLF)
	ConsoleWrite('$sCMD  = ' & $sCMD & @CRLF)
	ConsoleWrite('+-----------------------------------------------------------' & @CRLF & @CRLF)
	Local $iPID = Run($sCMD, $sPath, @SW_HIDE)
	Local $iError = @error
	While ProcessExists($iPID)
		Sleep(100)
	WEnd
	If $sTempFile <> '' Then FileDelete($sTempFile)
	If $iError <> 0 Then Exit MsgBox(0, '#Error', "Run() lieferte den Fehlercode: " & $iError) +2
EndFunc

Alles anzeigen

xSunLighTx3

Hey Bitnugger,

awesome script, viel Dank dafür und die verbundene Mühe.
Wenn ich eine .exe in .xyz umbenenne und mit Run() starte,
wird sie trotzdem ausgeführt. Bei Shelleexecute() ging das nur nicht,
deshalb habe ich Run() benutzt. Leider muss man dann auf Parameter
verzichten. Ich benutze gerne eigene Dateiendungen für Cores o.Ä.
Autoit ist ja kein multithreading system, da muss man andere Maßnahmen
treffen.

Lottich

Hallo Sunlight

Nur weil ShellExecute() die Möglichkeit bietet Parameter explizit anzugeben heisst das noch lange nicht, dass du bei Run() keine Parameter benutzen kannst. Parameter werden unter Windows ans Ende der .exe angehängt. Also würde ein Aufruf via Run so aussehen:

AutoIt

Local $Programm = "C:\Programme\Programm.exe"
Local $Parameter = "-Param1 -Param2"
Local $pid = Run($Programm & " " & $Parameter)
;oder alternativ gehts auch so
Local $pid = Run("C:\Programme\Programm.exe -Param1 -Param2")

Damit wird das Programm mit den beiden Parametern gestartet.

Ausserdem ändert sich die Datei nicht, nur weil du die Endung änderst

Zitat von xSunLighTx3

Ich benutze gerne eigene Dateiendungen für Cores o.Ä.

Wenn du auf diese Weise aus einem Textfile "Text.txt" eine "Test.exe" machst und diese mit einem Editor öffnest, wirst du auch weiterhin den Text lesen können.
Darum hast du auch unter Run() kein Problem damit solch eine Datei zu starten. ShellExecute hingegen arbeitet da anders, denn es prüft vorher, ob die Dateiendung im System "anständig" registriert ist und meckert dann mit dem "öffne mit..." Dialog.
Hättest du das gleich von Beginn an gesagt, hätte man dir das auch gleich gesagt.

**Bitnugger**

Wenn du gene eigene Extensionen benutzt, dann registriere sie doch einfach...

Alienware

AGA.png