Prüfung einer Datei

**Alina**

Zitat von nwmbd

Hat das etwas mit dem Sleep 30 zutun?

Also das glaube ich mal so nicht.

Ich habe als erstes die Möglichkeit des EXIT (Gui schließen / Programm beenden) eingebau und danach abgefragt ob die Datei da ist. Auf das Ergebnis habe ich dann reagiert in dem ich den Button der sichtbar sein soll, auch sichtbar gebacht und den anderen dann unsichtbar. Mehr war das nicht.

Aber ich glaube Du hast Dir das Script zusammengestellt, was gar nicht schlimm ist und dabei ist wohl das eine oder ander nicht ganz so gut gelaufen. Und / Oder Du hast zuviel gelöscht.

So, nun ist aber die Lösung ja da. Mich würde interessieren, wie Du das umgesetzt hast mit "das Auslesen des Änderungsdatums". Reine Neugierde einer Frau halt.

**autoBert**

Zitat von Bitnugger

PS: Ich habe vorhin erst richtig mitbekommen, was @Kanashius in Post #15 da Feines geschrieben hat... ==> "_WinAPI_ShellChangeNotifyRegister". Die Funktion ist wirklich echt super und sie erledigt mit viel weniger Aufwand dieselbe Arbeit, wie mein Script!

Knapp daneben ist auch vorbei, deshalb zur Veranschaulichung verlinkt.

nwmbd

Hallo,

nochmal zum Ursprung

Wie kann Ich das Änderungsdatum und den neuen Eintrag überprüfen?

Ich würde gern eine MSGBOX auslösen wenn sich das Datum ändert und in der letzten Zeile *Öffnung Tor 3* steht, wie kann ich das realisieren, es kommt sonst bei jedem Eintrag das Fenster.

Vielen Dank vorab.

C

include <File.au3>
#include <WinAPI.au3>
While 1
$Original = FileGetTime("C:\Test\Test.txt", 0, 1)
$Ueberwachung = FileGetTime("C:\Test\Ueberwachung.txt", 0, 1)
$Text = 'Achtung neuer Eintrag' & @CRLF & _
	  'Unbedingt beheben!'
If $Original > $Ueberwachung Then
	MsgBox(48,"Achtung neuer Eintrag!", $Text)
	FileWrite("C:\Test\Ueberwachung.txt", "N")
 EndIf
    Sleep(30)
WEnd

Alles anzeigen

**Oscar**

Wir doktern hier wieder an "Lösungen" rum, ohne das eigentliche Problem zu kennen.
Wer legt denn die Datei an und schreibt den Eintrag "Öffnung Tor 3" dort hinein?

Wozu überhaupt so eine Datei auf die Festplatte schreiben?
Wenn auf dem Rechner sowieso das AutoIt-Script läuft, warum dann nicht einfach per TCP direkt eine Nachricht an das Script schicken?

nwmbd

Hallo,

die Datei legt niemand an, die ist schon da.
Sobald ein Ereignis stattfindet schreibt das Überwachungsprogramm (müsste ich nachsehen wie dies heisst) in die TXT die Einträge.
Da das Programm aber keine Möglichkeit hat irgendwas anzuzeigen möchte ich dies gern übernehmen.

Vielleicht noch einmal zum Verständnis:
PC A hat das Programm wo alles aufgezeichnet wird
PC A hat auch die Datei
PC A soll das Fenster angezeigt bekommen

Das ich dies bei mir "Überwachen" will ist nur Zusatz, für die Sache aber vollkommen unwichtig.

**Oscar**

Ok, Du hast also keinen Zugriff auf das Überwachungsprogramm.
Dann bleibt nur die Datei-Methode. Man sollte aber trotzdem nicht ständig auf die Datei zugreifen, sondern auf die Benachrichtigung durch Windows warten.
Hier mal ein Beispiel:

AutoIt

#include <APIShellExConstants.au3>
#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WinAPI.au3>
#include <WinAPIShellEx.au3>




Opt('GUIOnEventMode', 1)


Global $sNotifyFile = 'C:\Test\ueberwachung.txt' ; <- ggf. anpassen


Global $sNotifyPath = StringRegExpReplace($sNotifyFile, '(.+\\).+', '$1')


OnAutoItExitRegister('OnAutoItExit')


Global $hGui = GUICreate('Überwachung', 480, 160)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
Global $idLabel = GUICtrlCreateLabel('', 10, 10, 460, 100)
GUICtrlSetFont(-1, 16, 400, 0, 'Tahoma', 5)
Global $iMsg = _WinAPI_RegisterWindowMessage('SHELLCHANGENOTIFY')
GUIRegisterMsg($iMsg, 'WM_SHELLCHANGENOTIFY')
Global $g_iID = _WinAPI_ShellChangeNotifyRegister($hGui, $iMsg, $SHCNE_ALLEVENTS, BitOR($SHCNRF_INTERRUPTLEVEL, $SHCNRF_SHELLLEVEL, $SHCNRF_RECURSIVEINTERRUPT), $sNotifyPath, 1)
If @error Then Exit MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Error', 'Window does not registered.')
GUISetState()


WinWaitClose($hGui)
Exit


Func _CloseGui()
	GUIDelete($hGui)
EndFunc   ;==>_CloseGui


Func WM_SHELLCHANGENOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg


	Local $sPath = _WinAPI_ShellGetPathFromIDList(DllStructGetData(DllStructCreate('dword Item1; dword Item2', $wParam), 'Item1'))
	If $sPath = $sNotifyFile Then
		Local $sLastLine = FileReadLine($sNotifyFile, -1)
		Local $sMsg = 'Achtung! Neuer Eintrag:\n' & _Now() & ' -> ' & $sLastLine
		GUICtrlSetData($idLabel, StringFormat($sMsg))
		WinActivate($hGui)
	EndIf
EndFunc   ;==>WM_SHELLCHANGENOTIFY


Func OnAutoItExit()
	If $g_iID Then _WinAPI_ShellChangeNotifyDeregister($g_iID)
EndFunc   ;==>OnAutoItExit

Alles anzeigen

nwmbd

Danke Oscar,

das sieht doch mal richtig professionell aus.

Leider habe Ich weiterhin dasselbe Problem, es wird ja nun auch alles angezeigt.

Ich will quasi nur wenn dort Tor 3 in der Datei steht ein bestimmten Text, zB. "TOR UNBEDINGT WIEDER SCHLIESSEN!" stehen haben.

Dasselbe auch bei Tor 2, bei allem anderen soll er gar nichts machen.

Vielen Dank vorab.

**BugFix**

Na dann werte doch einfach die Texteinträge aus.
- neuer Eintrag (bekommst du ja über WM_SHELLCHANGENOTIFY) - enthält er die gesuchte Begriffe? - JA: Meldung

nwmbd

Hallo BugFix,

habe mir das mal angesehen aber irgendwie bin ich entweder zu doof oder verstehe das System nicht.

ich gehe mal davon aus das ich in diesem Teil etwas ändern muss.

If $sPath = $sNotifyFile Then
Local $sLastLine = FileReadLine($sNotifyFile, -1)
Local $sMsg = 'Achtung! Neuer Eintrag:\n' & _Now() & ' -> ' & $sLastLine
GUICtrlSetData($idLabel, StringFormat($sMsg))
WinActivate($hGui)
EndIf

Aber wo zum Geier pack ich die Zeilen die ich haben will hin?
Cool wäre ja auch wenn er, wie oben, auf einen Text den er ausliest einen benutzerdefinierten Text ausgibt.

Danke vorab

**Oscar**

Man kann auch auf den Text in der Datei reagieren:

AutoIt

#include <APIShellExConstants.au3>
#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WinAPI.au3>
#include <WinAPIShellEx.au3>




Opt('GUIOnEventMode', 1)


Global $sNotifyFile = 'C:\Test\ueberwachung.txt' ; <- ggf. anpassen


Global $sNotifyPath = StringRegExpReplace($sNotifyFile, '(.+\\).+', '$1')


OnAutoItExitRegister('OnAutoItExit')


Global $hGui = GUICreate('Überwachung', 480, 160)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
Global $idLabel = GUICtrlCreateLabel('', 10, 10, 460, 100)
GUICtrlSetFont(-1, 16, 400, 0, 'Tahoma', 5)
Global $iMsg = _WinAPI_RegisterWindowMessage('SHELLCHANGENOTIFY')
GUIRegisterMsg($iMsg, 'WM_SHELLCHANGENOTIFY')
Global $g_iID = _WinAPI_ShellChangeNotifyRegister($hGui, $iMsg, $SHCNE_ALLEVENTS, BitOR($SHCNRF_INTERRUPTLEVEL, $SHCNRF_SHELLLEVEL, $SHCNRF_RECURSIVEINTERRUPT), $sNotifyPath, 1)
If @error Then Exit MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Error', 'Window does not registered.')
GUISetState()


WinWaitClose($hGui)
Exit


Func _CloseGui()
	GUIDelete($hGui)
EndFunc   ;==>_CloseGui


Func WM_SHELLCHANGENOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg
	Local $sPath = _WinAPI_ShellGetPathFromIDList(DllStructGetData(DllStructCreate('dword Item1; dword Item2', $wParam), 'Item1'))
	If $sPath = $sNotifyFile Then
		Local $sLastLine = FileReadLine($sNotifyFile, -1)
		Switch $sLastLine
			Case 'Öffnung Tor 2'
				Local $sMsg = 'TOR 2 UNBEDINGT WIEDER SCHLIESSEN!'
			Case 'Öffnung Tor 3'
				Local $sMsg = 'TOR 3 UNBEDINGT WIEDER SCHLIESSEN!'
		EndSwitch
		GUICtrlSetData($idLabel, $sMsg)
		WinActivate($hGui)
	EndIf
EndFunc   ;==>WM_SHELLCHANGENOTIFY


Func OnAutoItExit()
	If $g_iID Then _WinAPI_ShellChangeNotifyDeregister($g_iID)
EndFunc   ;==>OnAutoItExit

Alles anzeigen

nwmbd

Hallo Oscar,

vielen Dank, klingt logisch.

Er bringt aber sobald die Datei andere Einträge hat folgenden Fehler.

45) : ==> Variable used without being declared.:
GUICtrlSetData($idLabel, $sMsg)
GUICtrlSetData($idLabel, ^ ERROR
->20:25:51 AutoIt3.exe ended.rc:1
+>20:25:51 AutoIt3Wrapper Finished.

EDIT:
Kann man den ausgelesen Text auch mit irgendwas auffüllen?! ( mit * ging bei meinem Test nicht ) vor den Einträgen steht immer Datum und Uhrzeit, die kenne ich ja nicht vorher

**Oscar**

Stimmt! $sMsg muss natürlich vor Switch deklariert werden (Flüchtigkeitsfehler).

Zu dem anderen Problem musst Du schon mal schreiben, wie genau so ein Eintrag aussieht.

nwmbd

Hallo Oscar,

Daten sehen wie folgt aus:

~~16.09.2016 07:14:53~~ Hauptgebäude ~~Anlagennummer Online/Alarm~~ Öffnung Tor 3. Es müsste quasi das Datum, die Anlagennummer sowie das Online/Alarm gekillt werden.

EDIT:

Habe den Code nun so verändert, funktioniert 1a. Ist das auch richtig so?

Code

Func WM_SHELLCHANGENOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg
	Local $sPath = _WinAPI_ShellGetPathFromIDList(DllStructGetData(DllStructCreate('dword Item1; dword Item2', $wParam), 'Item1'))
	If $sPath = $sNotifyFile Then
		Local $sLastLine = FileReadLine($sNotifyFile, -1)
		Local $sMsg = ""
		Switch $sLastLine
			Case 'Öffnung Tor 2'
				$sMsg = 'TOR 2 UNBEDINGT WIEDER SCHLIESSEN!'
				ShellExecute("C:\Test\Test.pdf")
			Case 'Öffnung Tor 3'
				$sMsg = 'TOR 3 UNBEDINGT WIEDER SCHLIESSEN!'
				ShellExecute("C:\Test\Test.pdf")
		EndSwitch
		GUICtrlSetData($idLabel, $sMsg)
		WinActivate($hGui)
	EndIf
EndFunc   ;==>WM_SHELLCHANGENOTIFY

Alles anzeigen

**Oscar**

Zitat von nwmbd

Habe den Code nun so verändert, funktioniert 1a. Ist das auch richtig so?

Schön, dass er funktioniert! Woher sollen wir wissen, ob das so richtig ist?
Wie hast Du denn nun das Problem mit dem Datum/Anlagenummer gelöst?

Zitat von nwmbd

Habe das mit dem WINwait so teilweise hinbekommen, er öffnet das aber egal was ich mit x1 x2 y1 y2 mache immer auf dem 1. Bildschirm

Dannn ist der Titel falsch!
Was sagt denn "Au3Info"?
Eventuell musst Du WinTitleMatchMode ändern.

nwmbd

Hallo Oscar,

Daten sehen wie folgt aus:

~~16.09.2016 07:14:53~~ Hauptgebäude ~~Anlagennummer Online/Alarm~~ Öffnung Tor 3. Es müsste quasi das Datum, die Anlagennummer sowie das Online/Alarm gekillt werden.

Wie bekomme ich das hin?

**Oscar**

Das heißt, Du hast das Problem noch nicht gelöst?!

Gut! Um dabei helfen zu können, muss ich wissen, was in dieser Zeile alles stehen wird oder stehen kann.
Das heißt:
- ist das Datum/Uhrzeit immer gleich lang (führende Nullen)?
- Steht dort immer Hauptgebäude?
- Wie viele Stellen hat die Anlagennummer? (Variabel oder mit führenden Nullen)
- Oder anders, auf welche (immer gleiche) Textstelle kann man testen? (immer "Öffnung Tor X"?)

nwmbd

Hallo Oscar,

Das Datum ist immer gleich, es sind zwischen dein Einträgen aber verschieden Lange Leerzellen. (Sofern das von Bedeutung ist)
Dort steht auch Nebengebäude, da gibt es dann andere Handlungen oder auch Lager.
Die Anlagennummer besteht aus 2Buchstaben und 6 Zahlen. zB ZZ123456

Es würde vollkommen reichen wenn er die Anlage und den Text ganz hinten filtert, der Rest ist vollkommen uninteressant.

Danke vorab.

**Oscar**

Wenn vorne immer unterschiedlicher Text mit unterschiedlicher Länge steht, dann kann man nicht so einfach den Text abschneiden.
Man muss also mit StringInStr auf einen String innerhalb der ganzen Zeile testen.
Vielleicht so:

AutoIt

Func WM_SHELLCHANGENOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg
	Local $sPath = _WinAPI_ShellGetPathFromIDList(DllStructGetData(DllStructCreate('dword Item1; dword Item2', $wParam), 'Item1'))
	If $sPath = $sNotifyFile Then
		Local $sLastLine = FileReadLine($sNotifyFile, -1)
		Local $sMsg = ''
		If StringInStr($sLastLine, 'Öffnung Tor 2') Then
			$sMsg = 'TOR 2 UNBEDINGT WIEDER SCHLIESSEN!'
		EndIf
		If StringInStr($sLastLine, 'Öffnung Tor 3') Then
			$sMsg = 'TOR 3 UNBEDINGT WIEDER SCHLIESSEN!'
		EndIf
		GUICtrlSetData($idLabel, $sMsg)
		WinActivate($hGui)
	EndIf
EndFunc   ;==>WM_SHELLCHANGENOTIFY

Alles anzeigen

nwmbd

Hallo Oscar,

vielen vielen Dank, hier wird einem gut geholfen.

Besteht nicht die Möglichkeit das man den ersten Teil sucht, ist dieser da dann den zweiten Teil sucht ist der da dann dann das Ereignis ausführen.

So in der Art:

If StringInStr($sLastLine, 'Hauptgebaeude') and If StringInStr($sLastLine, 'Öffnung Tor 3') Then

das er quasi in der ganzen Zeile sucht, theoretisch ist es ja egal, findet er die Texte, egal wo, soll er das Ereignis auslösen.

Es gibt ja nur 2 Faktoren die entscheidend sind, wo (Hauptgebäude Nebengebäude...) und was (Tor 1-X)

Danke vorab.

EDIT:
ES GEHT !!!!!!!!!!!!!

Danke Oscar, dein Ansatz hat mich zum Ziel gebracht.
Nachfolgend noch der Code falls dies jemand interessiert.

Einwas hätte ich dann doch noch, könnte ich das Überwachungsfenster auf dem 2. Monitor unten links anzeigen?

Code

Func WM_SHELLCHANGENOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg
	Local $sPath = _WinAPI_ShellGetPathFromIDList(DllStructGetData(DllStructCreate('dword Item1; dword Item2', $wParam), 'Item1'))
	If $sPath = $sNotifyFile Then
		Local $sLastLine = FileReadLine($sNotifyFile, -1)
		Local $sMsg = ""
		If StringInStr($sLastLine, 'Haupt') And StringInStr($sLastLine, 'Tor2') Then
			$sMsg = 'TOR 2 UNBEDINGT WIEDER SCHLIESSEN!'
				ShellExecute("C:\Test\Test.pdf")
				EndIf
		If StringInStr($sLastLine, 'Haupt') And StringInStr($sLastLine, 'Tor3') Then
			$sMsg = 'TOR 3 UNBEDINGT WIEDER SCHLIESSEN!'
			ShellExecute("C:\Test\Test.pdf")
		EndIf
		GUICtrlSetData($idLabel, $sMsg)
		WinActivate($hGui)
	EndIf
EndFunc   ;==>WM_SHELLCHANGENOTIFY

Alles anzeigen

bazii

Zitat von Bitnugger

PS: Ich habe vorhin erst richtig mitbekommen, was @Kanashius in Post #15 da Feines geschrieben hat... ==> "_WinAPI_ShellChangeNotifyRegister". Die Funktion ist wirklich echt super und sie erledigt mit viel weniger Aufwand dieselbe Arbeit, wie mein Script! Ich spiele noch damit rum... wenn ich eine kleine Demo fertig habe, schiebe ich sie bei Bedarf gerne hoch.

Bedarf angemeldet

Gibt es im Netzverwerk die Möglichkeit, den Verursacher einer Dateiaktion anstatt @UserName zu schreiben? Also bei @UserName wird im Netzwerk in der Ausgabe lediglichh meine Usernummer als Programmstarter übernommen, nicht die des Verursachers der Dateiaktion.