Prüfung einer Datei

; #FUNCTION# ;===============================================================================
;
; Name...........: _MD5ForFile
; Description ...: Calculates MD5 value for the specific file.
; Syntax.........: _MD5ForFile ($sFile)
; Parameters ....: $sFile - Full path to the file to process.
; Return values .: Success - Returns MD5 value in form of binary data
;                          - Sets @error to 0
;                  Failure - Returns empty string and sets @error:
;                  |1 - CreateFile function or call to it failed.
;                  |2 - MD5Init function or call to it failed.
;                  |4 - ReadFile function or call to it failed.
;                  |5 - MD5Update function or call to it failed.
;                  |6 - MD5Final function or call to it failed.
; Author ........: trancexx
;
;==========================================================================================
Func _MD5ForFile($sFile)


    Local $a_hCall = DllCall("kernel32.dll", "hwnd", "CreateFileW", _
            "wstr", $sFile, _
            "dword", 0x80000000, _ ; GENERIC_READ
            "dword", 1, _ ; FILE_SHARE_READ
            "ptr", 0, _
            "dword", 3, _ ; OPEN_EXISTING
            "dword", 0, _ ; SECURITY_ANONYMOUS
            "ptr", 0)


    If @error Or $a_hCall[0] = -1 Then
        Return SetError(1, 0, "")
    EndIf


    Local $hFile = $a_hCall[0]


    Local $tMD5_CTX = DllStructCreate("dword i[2];" & _
            "dword buf[4];" & _
            "ubyte in[64];" & _
            "ubyte digest[16]")


    DllCall("advapi32.dll", "none", "MD5Init", "ptr", DllStructGetPtr($tMD5_CTX))


    If @error Then
        _WinAPI_CloseHandle($hFile)
        Return SetError(2, 0, "")
    EndIf


	Local $tBuffer = DllStructCreate("byte[524288]")
	Local $pBuffer = DllStructGetPtr($tBuffer), $iSize


	Local $iReadErr = True
	While _WinAPI_ReadFile($hFile, $pBuffer, 524288, $iSize) And $iSize
		$iReadErr = False


		DllCall("advapi32.dll", "none", "MD5Update", _
            "ptr", DllStructGetPtr($tMD5_CTX), _
            "ptr", $pBuffer, _
            "dword", $iSize)


		If @error Then
			_WinAPI_CloseHandle($hFile)
			Return SetError(5, 0, "")
		EndIf


	WEnd
	If $iReadErr Then
		_WinAPI_CloseHandle($hFile)
        Return SetError(4, 0, "")
    EndIf


    DllCall("advapi32.dll", "none", "MD5Final", "ptr", DllStructGetPtr($tMD5_CTX))


    If @error Then
		_WinAPI_CloseHandle($hFile)
        Return SetError(6, 0, "")
    EndIf


    _WinAPI_CloseHandle($hFile)


    Local $sMD5 = DllStructGetData($tMD5_CTX, "digest")


    Return SetError(0, 0, $sMD5)


EndFunc   ;==>_MD5ForFile

;-- TIME_STAMP   2016-09-14 14:49:59


#Region ;************ Includes ************
#include <WindowsConstants.au3>
#include <Array.au3>
;~ #include <GUIConstants.au3>;~~~
#include <GUIConstantsEx.au3>
#include <MonitorDirectory.au3>
;~ #include <WindowsConstants.au3>;~~~
#EndRegion ;************ Includes ************


Global $g_aDirs = ['f:\_Scripts\AutoIt\AutoIt3_MyInclude\', 'f:\Eigene Dateien\Pictures\']
;_ArrayDisplay($g_aDirs, '$g_aDirs')
;~ =========================== FUNCTION _MonitorDirectory() ==============================
#cs
	Description:     Monitors the user defined directories for file activity.
	Original:        http://www.autoitscript.com/forum/index.php?showtopic=69044&hl=folderspy&st=0
	Modified:        Jack Chen
	Syntax:         _MonitorDirectory($Dirs = "", $Subtree = True, $TimerMs = 250, $Function = "_ReportChanges")
	Parameters:
	$Dirs          - Optional: Zero-based array of valid directories to be monitored.
	$Subtree       - Optional: Subtrees will be monitored if $Subtree = True.
	$TimerMs       - Optional: Timer to register changes in milliseconds.
	$Function      - Optional: Function to launch when changes are registered. e.g. _ReportChanges
	Syntax of your function must be e.g._ReportChanges($Action, $FilePath)
	Possible actions: Created, Deleted, Modified, Rename-, Rename+, Unknown
	Remarks:        Call _MonitorDirectory() without parameters to stop monitoring all directories.
	THIS SHOULD BE DONE BEFORE EXITING SCRIPT AT LEAST.
#ce


#Region - GUI Create
Global $g_hGUI = GUICreate('_MonitorDirectory-Demo', 600, 430, -800)


Global $g_idButton_Start = GUICtrlCreateButton('Start', 2, 402, 296)
Global $g_idButton_Exit = GUICtrlCreateButton('Exit', 302, 402, 296)


Global $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")


GUISetState()
#EndRegion - GUI Create


#Region - GUI SelectLoop
While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE, $g_idButton_Exit
			_MonitorDirectory()
			Exit
		Case $g_idButton_Start
			_MonitorDirectory($g_aDirs, True, 250, '__ReportChanges')
			If @error Then Exit 99
			MemoWrite('##################### Folgene Verzeichnisse werden überwacht ####################')
			MemoWrite(_ArrayToString($g_aDirs, @CRLF))
			MemoWrite('#################################################################################')
			;Case $msg =
	EndSwitch
WEnd
#EndRegion - GUI SelectLoop


Func __ReportChanges($Action, $FilePath)
	Local Static $sAktFilePath = ""
	Local $sColor = "", $aPos
;~ Your own script here ...
;~ ...
	If $sAktFilePath = "" Then
		$sAktFilePath = $FilePath
	Else
		If $sAktFilePath <> $FilePath Then
			$sAktFilePath = $FilePath
			ConsoleWrite(@LF)
		EndIf
	EndIf
	$aPos = MouseGetPos()
	Switch $Action
		Case "Created"
			$sColor = "+"
		Case "Deleted"
			$sColor = "!"
		Case "Modified"
			$sColor = "-"
		Case "Rename-"
			$sColor = ">"
		Case "Rename+"
			$sColor = ">"
		Case "Unknown"
			$sColor = ""
	EndSwitch
	; ConsoleWrite($sColor & StringFormat("%-9s%-5s%-256s", $Action, "-->", $FilePath) & @CRLF)
	MemoWrite(StringFormat('%s %s: %s %s %s', "MonitorDirectory", $Action, $FilePath, $aPos[0] + 10, $aPos[1] + 10))
EndFunc   ;==>__ReportChanges


; Write a line to the memo control
Func MemoWrite($sMessage = '')
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite