Array crash dimension range exceeded

Kev

Nabend,

ich steh seit paar Stunden aufm Schlauch und weiß nicht wo es hängt, zum Ablauf:

1. Ich lese alle Services im "automatisch Startmode" welche "nicht Running" sind aus und speichere diese in $temp array
2. Ich stelle eine $excluded array bereit mit Services die excluded werden sollen.

Quasi möchte ich Alle Services die nicht Running sind mit denen aus $excluded Liste vergleichen und diese dann in $temp entfernen, damit ich nur Services habe, die im automatisch startmode stehen und nicht running sind und meine "blacklist" beachtet wurde.

Leider hauts beim Arraydelete immer hin. Das Script crashed einfach.

Wenn 4 Services nicht laufen, 3 in der Blacklist sind. Werden 3 abgezogen und er sagt mir "jap hier der Service läuft nicht , soll aber laufen".
Nehme ich aber an, dass alle Services laufen, die Laufen sollen. crashed das Ding.

Sprich 4 nicht running gefunden, 4 auf der blacklist. $temp = leer = crash.

Spoiler anzeigen

AutoIt

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=serviceadv.exe
#AutoIt3Wrapper_UseUpx=y
#AutoIt3Wrapper_Change2CUI=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <File.au3>




Global $excludes, $temp[0], $exit[0]


_FileReadToArray(@ScriptDir & "\dependencies\excluded_services.txt", $excludes, 1) ;array count first element




$objWMIService = ObjGet('winmgmts:\\.\root\cimv2')
$colItems = $objWMIService.ExecQuery("Select * From Win32_Service WHERE Startmode='auto'") ;alle Services im Automatisch Mode


If IsObj($colItems) Then
	For $objItem In $colItems
		If $objItem.State <> "Running" Then ;Wenn automatisch Mode und nicht Running
			_ArrayAdd($temp, $objItem.Displayname) ;safe in Array $temp
		Else
			_ArrayAdd($exit, $objItem.Displayname) ; alle anderen in $exit
		EndIf


	Next
EndIf




For $s = UBound($temp) - 1 To 0 Step -1
	For $x = UBound($excludes) -1 To 0 Step -1
		If $temp[$s] = $excludes[$x] Then ;wenn array $temp in $excluded liste dann 
			_ArrayDelete($temp, $s) ; lösche element ; hier crashed es wenn die excludes komplett in $temp enthalten sind. Also das array komplett geleert wird
		EndIf
	Next
Next


For $j = 0 To UBound($temp) - 1
	$code = "2"
	ConsoleWrite($code & "|" & $temp[$j] & " ist down !" & @LF)
	If $j == UBound($temp) - 1 Then
		Exit ($code)
	EndIf
Next


$allitems = UBound($exit)
		If $temp = @error Then
			$code = 0
			ConsoleWrite($code & "|Alle " & $allitems & " Services im automatisch Status laufen!" & @LF)
			Exit ($code)
		EndIf

Alles anzeigen

Vielen Dank

Lottich

meinst du so?

AutoIt

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=serviceadv.exe
#AutoIt3Wrapper_UseUpx=y
#AutoIt3Wrapper_Change2CUI=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <File.au3>




Global $excludes, $temp[0], $exit[0]


_FileReadToArray(@ScriptDir & "\dependencies\excluded_services.txt", $excludes, 1) ;array count first element




$objWMIService = ObjGet('winmgmts:\\.\root\cimv2')
$colItems = $objWMIService.ExecQuery("Select * From Win32_Service WHERE Startmode='auto'") ;alle Services im Automatisch Mode


If IsObj($colItems) Then
	For $objItem In $colItems
		If $objItem.State <> "Running" Then ;Wenn automatisch Mode und nicht Running
			_ArrayAdd($temp, $objItem.Displayname) ;safe in Array $temp
		Else
			_ArrayAdd($exit, $objItem.Displayname) ; alle anderen in $exit
		EndIf


	Next
EndIf


If IsArray($temp) Then
	For $s = UBound($temp) - 1 To 0 Step -1
		For $x = UBound($excludes) -1 To 0 Step -1
			If $temp[$s] = $excludes[$x] Then ;wenn array $temp in $excluded liste dann 
				_ArrayDelete($temp, $s) ; lösche element ; hier crashed es wenn die excludes komplett in $temp enthalten sind. Also das array komplett geleert wird
			EndIf
		Next
	Next


	For $j = 0 To UBound($temp) - 1
		$code = "2"
		ConsoleWrite($code & "|" & $temp[$j] & " ist down !" & @LF)
		If $j == UBound($temp) - 1 Then
			Exit ($code)
		EndIf
	Next
EndIf


$allitems = UBound($exit)
If $temp = @error Then
	$code = 0
	ConsoleWrite($code & "|Alle " & $allitems & " Services im automatisch Status laufen!" & @LF)
	Exit ($code)
EndIf

Alles anzeigen

Auf isObj prüfst du ja bereits, das kannst du auch beim Array machen. Alternativ kannst du auch prüfen ob Ubound($temp) grösser als null ist,
damit er auch das -1 machen kann. Ist vielleicht nicht das beste, was man machen kann, aber quick&dirty sollte erstmal klappen.

**Kanashius**

EDIT: Oder man geht einfach rückwärts durch das Array... Das vergess ich immer

AutoIt

For $s = UBound($temp) - 1 To 0 Step -1
	For $x = UBound($excludes) -1 To 0 Step -1
		If $temp[$s] = $excludes[$x] Then ;wenn array $temp in $excluded liste dann 
			_ArrayDelete($temp, $s) ; lösche element ; hier crashed es wenn die excludes komplett in $temp enthalten sind. Also das array komplett geleert wird

Das Problem findest du in dem _ArrayDelete. Was passiert, wenn alle gelöscht wurden und $temp keine Elemente mehr enthält? Die 2te Schleife kann da immernoch laufen.

AutoIt

For $s = UBound($temp) - 1 To 0 Step -1
	For $x = UBound($excludes) -1 To 0 Step -1
		If $temp[$s] = $excludes[$x] Then ;wenn array $temp in $excluded liste dann 
			_ArrayDelete($temp, $s) ; lösche element ; hier crashed es wenn die excludes komplett in $temp enthalten sind. Also das array komplett geleert wird
			$s-=1
			ExitLoop
		EndIf
	Next
Next

Durch das $s-=1 sorgst du dafür, dass keine Spalte ausgelassen wird und durch das ExitLoop wird der aktuelle Schleifendurchlauf beendet-> du kommst nicht in den Fall, dass das $ste Element gelöscht wurde, keine weiteren dahinter sind und das ArrayDelete später auf eine nicht existente Zeile zugreift.
_ArrayDelete in eine Schleife aufzurufen ist was performence angeht auch eine blöde Idee. Stattdessen einen sonst nicht vorhandenen Wert eintragen (z.b. -1) und später alle -1 löschen:

AutoIt

local $deleteCount=0
For $s = UBound($temp) - 1 To 0 Step -1
	For $x = UBound($excludes) -1 To 0 Step -1
		If $temp[$s] = $excludes[$x] Then
			$temp[$s]=-1
			$deleteCount+=1
			ExitLoop
		EndIf
	Next
Next
for $i=0 to UBound($temp)-1 step 1
	local $count
	while $i<UBound($temp)-1 and $temp[$i]=-1
		$i+=1
		$count+=1
	WEnd
	if NOT $i<UBound($temp)-1 then ExitLoop
	local $tmp=$temp[$i]
	$temp[$i]=-1
	$i-=$count
	$temp[$i]=$tmp
next
ReDim $temp[UBound($temp)-$deleteCount]

Alles anzeigen

Spielt aber bei der geringen Array-Größe keine Rolle, schätz ich. Aber das $s-1 wird nicht benötigt, da erst am Ende gelöscht wird.

Bsp. deines Problems (-> entspricht $s):
0: "Wert1" 0: "Wert1"
1: "Wert2" 1: "Wert2"
2: "Wert3" 2: "Wert3"
->3: "Wert4" ;Hier löschen ==>3: "Wert5" ;und du läuft das $excludes weiter durch, löscht wieder und wieder, bis dort kein Eintrag mehr ist.
4: "Wert5" 4: "Wert6"
5: "Wert6"
Außerdem Überspringst du dadurch, dass du kein $s-1 machst, Werte. Die nächste For-Schleife von $temp sähe so aus:

0: "Wert1"
1: "Wert2"
2: "Wert3"
3: "Wert5"
->4: "Wert6"
Auf "Wert5" wird nie die gesamte Schleife $excludes angewendet, da die for-Schleife nie dafür aufgerufen wird.

Also immer Vorsicht mit _arraydelete. Ich benutze es NIE bei mehr als 1 Value die gelöscht werden soll, weil es 1.Imperformant ist und man 2. Auf den Index achten muss.

Kev

Zitat von Kanashius

....

vielen Dank für die Mühe, leider funktioniert die $s-=1 nicht wirklich und ich counte ja schon rückwärts in beiden schleifen, scheitert leider genauso.

**autoBert**

Ich würde dafür ein 1 basiertes Array nehmen:

AutoIt

#include <Array.au3>
Global $aAll[1], $aBlack[1]


For $i=1 to 10
	_ArrayAdd($aAll,$i)
	_ArrayAdd($aBlack,$i)
Next


$aAll[0]=UBound($aAll)-1
$aBlack[0]=UBound($aBlack)-1


For $i=$aAll[0] to 1 Step -1
	ConsoleWrite('I: '&$i&$aAll[$i]&@TAB)
	If _ArraySearch($aBlack,$aAll[$i],1) Then
		_ArrayDelete($aAll,$i)
		$aAll[0]-=1
	EndIf
Next
_ArrayDisplay($aAll)


ConsoleWrite('Elements left: '&$aAll[0]&@CRLF)

Alles anzeigen

BuFF

Ich weiß nicht ob ich das richtig verstanden habe aber vielleicht geht das ja

AutoIt

Func ArrayDiff($src, $exclude, ByRef $resultArray)
	if UBound($exclude) == 0 Then
		$resultArray = $src
		return
	EndIf
	if UBound($src) > 0 Then
		$srcPart = _ArrayPop($src)
		$result = _ArraySearch($exclude, $srcPart)
		If $result == -1 Then
			_ArrayAdd($resultArray, $srcPart)
		EndIf
		ArrayDiff($src,$exclude,$resultArray)
	EndIf
EndFunc

Alles anzeigen

**Bitnugger**

Ich denke mal, der Fehler tritt auf, weil du in Zeile 11 angegeben hast, dass du in $excludes[0] einen Counter haben willst, den du übrigens an keiner Stelle nutzt.

Zitat von Kev

_FileReadToArray(@ScriptDir & "\dependencies\excluded_services.txt", $excludes, 1) ;array count first element

Wenn du dann noch Zeile 29 mit Zeile 30 vertauscht, dann funktioniert es.

Spoiler anzeigen

AutoIt

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=serviceadv.exe
#AutoIt3Wrapper_UseUpx=y
#AutoIt3Wrapper_Change2CUI=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****


#include <File.au3>


Global $excludes, $temp[0], $exit[0]


Global $iRet = _FileReadToArray(@ScriptDir & "\dependencies\excluded_services.txt", $excludes, 0) ;$FRTA_NOCOUNT (0) - array is 0-based use UBound() to get size


$objWMIService = ObjGet('winmgmts:\\.\root\cimv2')
$colItems = $objWMIService.ExecQuery("Select * From Win32_Service WHERE Startmode='auto'") ;alle Services im Automatisch Mode


If IsObj($colItems) Then
	For $objItem In $colItems
		If $objItem.State <> "Running" Then ; Wenn START_TYPE = 2 (AUTO_START) und nicht STATE = 4 (RUNNING)
			_ArrayAdd($temp, $objItem.Displayname) ;safe in Array $temp
		Else
			_ArrayAdd($exit, $objItem.Displayname) ; alle anderen in $exit
		EndIf


	Next
EndIf


For $x = UBound($excludes) - 1 To 0 Step -1
	For $s = UBound($temp) - 1 To 0 Step -1
		If $temp[$s] <> $excludes[$x] Then ContinueLoop
		_ArrayDelete($temp, $s)
	Next
Next


For $j = 0 To UBound($temp) - 1
	$code = "2"
	ConsoleWrite($code & "|" & $temp[$j] & " ist down !" & @LF)
	If $j == UBound($temp) - 1 Then
		Exit ($code)
	EndIf
Next


$allitems = UBound($exit)
If $temp = @error Then
	$code = 0
	ConsoleWrite($code & "|Alle " & $allitems & " Services im automatisch Status laufen!" & @LF)
	Exit ($code)
EndIf

Alles anzeigen