Checkboxen /IF /Else

hunterla

Hey ich habe vor das wenn man bei der GUI auf den button klickt das eine msg box mit "geht nicht" und wenn man auf den button klickt mit angehackter checkbox klickt das eine msg mit "geht" kommt. Haber aber ein problem mit if wie es mir scheint könnt ihr mir helfen ?

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 615, 438, 192, 124)
$Button = GUICtrlCreateButton("adssada", 264, 136, 75, 25)
$Check = GUICtrlCreateCheckbox("Test", 344, 200, 97, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit


		Case $Button




If GUICtrlRead($Check) = 1 then MsgBox(1,"","Geht")


Else	 GUICtrlRead($Check) = 0 then MsgBox(1,"","GEHT NED")


EndIf
Case $Check


	EndSwitch
WEnd

Alles anzeigen

**alpines**

Du hast kein ElseIf sondern ein Else genommen. Lass zwischen Else und MsgBox alles weg und pack die MsgBox in die nächste Zeile oder schreib ein ElseIf statt dem Else.

**autoiter**

Hallo @hunterla,
es beginnt schon in Zeile 20. Mach hinter Then einen Zeilenumbruch und wie alpines schrieb auch hinter Else.

AutoIt

If GUICtrlRead($Check) = 1 then MsgBox(1,"","Geht")

Das so in eine Zeile zu schreiben geht nur, wenn du keine anderen Bedingungen hast. Ich mache das ganz gerne, bin mir aber nicht sicher, ob das nicht schlechter Stil ist..
(Schau dir am Besten das Bsp. in der Hilfe an.)

**Bitnugger**

Ich würde das so machen...

Loop

AutoIt

;-- TIME_STAMP   2016-12-05 01:53:33


#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


_Example1()
_Example2()


Func _Example1()
	#Region ### START Koda GUI section ### Form=
	Local $hForm1, $idButton, $idCheck, $iCheck, $nMsg, $sMsg
	$hForm1 = GUICreate("Form1", 615, 168, 192, 124)
	$idButton = GUICtrlCreateButton("adssada", 264, 56, 110, 25)
	$idCheck = GUICtrlCreateCheckbox("Test", 268, 92, 97, 17)
	GUISetState(@SW_SHOW)
	#EndRegion ### END Koda GUI section ###
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				GUIDelete()
				ExitLoop	; kein Exit, weil wir nun 2. Example starten
			Case $idButton
				$sMsg = (_IsChecked($idCheck) = $GUI_CHECKED) ? "Geht" : "GEHT NED"
				MsgBox(1, "_Example1()", $sMsg)
		EndSwitch
	WEnd
EndFunc  ;==>_Example1


Func _Example2()
	#Region ### START Koda GUI section ### Form=
	Local $hForm1, $idButton, $idCheck, $iCheck, $nMsg, $sMsg
	$hForm1 = GUICreate("Form1", 615, 168, 192, 124)
	$idButton = GUICtrlCreateButton("adssada", 264, 56, 110, 25)
	$idCheck = GUICtrlCreateCheckbox("Test", 268, 92, 97, 17)
	GUISetState(@SW_SHOW)
	#EndRegion ### END Koda GUI section ###
	While 1
		$nMsg = GUIGetMsg()
		Select
			Case $nMsg = $GUI_EVENT_CLOSE
				Exit
			Case $nMsg = $idButton
				$sMsg = (_IsChecked($idCheck) = $GUI_CHECKED) ? "Geht" : "GEHT NED"
				MsgBox(1, "_Example2()", $sMsg)
		EndSelect
	WEnd
EndFunc  ;==>_Example2


Func _IsChecked($idControlID)
	Return BitAND(GUICtrlRead($idControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc  ;==>_IsChecked

Alles anzeigen

hunterla

Vielen dank an alle habs geschaft

**alpines**

Super, dann änder doch bitte den Präfix des Beitrages auf [gelöst] (1. Beitrag bearbeiten.)