Funktion in der While Schleife nur alle x mal Starten

sccssf

Hallo,

ich bräuchte einen Tip wie bekomme ich es hin das ich eine Funktion nicht bei jedem Schleifendurchlauf ausführe.

Hat jemand ein Beispiel oder einen Link zum Lesen. Habe nicht direkt was gefunden. (Vielleicht falsche Suchbegriffe)
Klar so in der Art. Mit If ist mir auch Klar nur lösche ich dann $i mal wieder auf Null oder macht man das anders ?

Frohes Fest

Steffen

AutoIt

global $i = 0
While Sleep( * 1000)
If $i> 10
_aelter_loeschen()
_verschieben_aelter()
$i = 0
Elsif< 10
_Datenbekommen()
_Verschieben()
_Umbennen()
_PDFMerge()
$i += 1
EndIf
WEnd

Alles anzeigen

BadBunny

Hey
Deine Idee sollte eigentlich fast funktionieren, ein Problem könnte aber auf jeden Fall sein, dass du im ElseIf die Bedingung < 10 genommen hast, in der If Bedingung aber > 10. Das würde bedeuten, dass du bis 10 hochaddierst, danach aber weder auf 0 resettest noch auf 11 kommst um die If Bedingung > 10 aus zu lösen. Versuche es einfach mal mit = 10 in deiner ersten If Bedingung.

Frohes Fest

Cape-City

Hi,

ist doch ein gangbarer Weg, allerdings hast Du Syntaxfehler in Deinem Script:

AutoIt

Global $i = 0
While Sleep(1000)
	If $i = 10 Then
		_aelter_loeschen()
		_verschieben_aelter()
		$i = 0
	ElseIf $i < 10 Then
;~	Else		
		_Datenbekommen()
		_Verschieben()
		_Umbennen()
		_PDFMerge()
		$i += 1
	EndIf


WEnd

Alles anzeigen

Allerdings wird der untere Teil dann nach 10 Durchläufen auch 1 mal nicht ausgeführt. Stattdessen nur der obere Teil. War das denn so geplant?
Ansonsten könnte man es auch so umstricken:

AutoIt

Global $i = 0
While Sleep(1000)
	If $i = 10 Then
		_aelter_loeschen()
		_verschieben_aelter()
		$i = 0
	EndIf		
	_Datenbekommen()
	_Verschieben()
	_Umbennen()
	_PDFMerge()
	$i += 1
WEnd

Alles anzeigen

Cape-City

Zitat von BadBunny

Hey
Deine Idee sollte eigentlich fast funktionieren, ein Problem könnte aber auf jeden Fall sein, dass du im ElseIf die Bedingung < 10 genommen hast, in der If Bedingung aber > 10. Das würde bedeuten, dass du bis 10 hochaddierst, danach aber weder auf 0 resettest noch auf 11 kommst um die If Bedingung > 10 aus zu lösen. Versuche es einfach mal mit = 10 in deiner ersten If Bedingung.

Frohes Fest

Ich denke damit kam er nie in den If-Bereich, denn sein Script hat nur bis 10 gezählt, das war aber noch zu klein für die If-Abfrag und schon zu groß für die ElseIf

sccssf

Danke,

Hatte das nur schnell hier zusammen geschrieben. Wollte mich nur nicht verrennen.

Steffen

sccssf

So habe mal etwas rum gespielt.

Will das bestimmte Funktionen alle 3 sek andere 1 x in der Stunde andere alle 5 Minuten.

oder kann man den Zähler durchlaufen lassen ? Gibt es dort Probleme bei 7/24 Betrieb?

AutoIt

While Sleep(3 * 1000)
	If Mod ($iwhile, 1200) = 0 Then
		_aelter_loeschen()
		_verschieben_aelter()
		$iwhile = 0
	ElseIf Mod ($iwhile,100) = 0 Then
		_PDFMerge()	
	EndIf
	_Datenbekommen()
	_Verschieben()
	_Umbennen()
	$iwhile +=1
WEnd

Alles anzeigen

**alpines**

Zitat von SCCSSF

So habe mal etwas rum gespielt.

Will das bestimmte Funktionen alle 3 sek andere 1 x in der Stunde andere alle 5 Minuten.

oder kann man den Zähler durchlaufen lassen ? Gibt es dort Probleme bei 7/24 Betrieb?

Warum kein AdlibRegister für die Funktionen? Dann sparst du auch dir die Zählervariable. Du brauchst dann nur eine Standard While-Sleep(100)-WEnd-Schleife.
Weiß jetzt nicht ob deine Funktionen blockierend sind oder parallel laufen dürfen.

sccssf

Zitat von alpines

Warum kein AdlibRegister für die Funktionen? Dann sparst du auch dir die Zählervariable. Du brauchst dann nur eine Standard While-Sleep(100)-WEnd-Schleife.Weiß jetzt nicht ob deine Funktionen blockierend sind oder parallel laufen dürfen.

Es gibt Funktionen die sollten vor anderen Funktionen laufen.

AdlibRegister war mir vorher noch nicht bekannt.

Hier mal mein ganzer Code ohne AdlibRegister.

AutoIt

#include <File.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <Misc.au3>
#include <Date.au3>
#include <_FileDeleteAfterXDays.au3> ;(autoit Forum)


If _Singleton("PDF-Name", 1) = 0 Then Exit


Opt('GUIOnEventMode', 1)
Opt('TrayOnEventMode', 1)
Opt('TrayMenuMode', 1)


Global Const $s_PATH_START = "D:\PDF-Aussteuerung\"
Global Const $s_PATH_ZWISCHEN = "D:\PDF-Aussteuerung\zwischen\"
Global Const $s_PATH_FERTIG = "D:\PDF-Aussteuerung\fertig\"
Global Const $s_PATH_WA = "D:\Daten\Archiv-WA\"
Global Const $s_PATH_WA_ARCHIV = "D:\Daten\Archiv-WA\Archiv\"
Global Const $s_KENNZEICEHN_WA_ARCHIV_AELTER_VERSCHIEBEN = "40"
Global Const $s_KENNZEICEHN_WA_ARCHIV_AELTER_LOESCHEN = "60"
Global Const $s_KENNZEICHEN_WA_ALT = "ab"
Global Const $s_KENNZEICHEN_WA_NEU = "wa"
Global Const $s_PATH_LS = "D:\PDF-Aussteuerung\fertig\LS\"
Global Const $s_KENNZEICHEN_LS = "LS"
Global Const $s_PATH_LS_ZWISCHEN = "D:\PDF-Aussteuerung\fertig\LS\zwischen\"
Global Const $s_PATH_MUELL = "D:\PDF-Aussteuerung\fertig\muell\"
Global Const $s_PDFTOTEXT = "D:\PDF-Aussteuerung\script\pdftotext.exe"
Global Const $s_PDFPDF = "D:\PDF-Aussteuerung\script\pdftk.exe"
Global Const $s_PDFBRIEFPAPIER = "D:\PDF-Aussteuerung\script\papier.pdf"
Global Const $s_MyFACTORY_DRUCK_ORDNER = "d:\Program Files (x86)\Serverprint\printed\"
Global Const $s_MyFACTORY_DRUCK_ORDNER_ABLAGE = "d:\Program Files (x86)\Serverprint\printed\ablage\"
Global Const $s_EXT = '.pdf'
Global Const $s_SEARCH = '@@WA-'
Global $a_REG
Global $iwhile = 1


$Form1 = GUICreate("Datei Umbennen", 294, 135, 192, 124)


$Setting_Menu = GUICtrlCreateMenu("Menü")
$Setting_exit = GUICtrlCreateMenuItem("Ende", $Setting_Menu)
GUICtrlSetOnEvent(-1, "_Exit")


$helpmenu = GUICtrlCreateMenu("?")
$Info = GUICtrlCreateMenuItem("Version", $helpmenu)
GUICtrlSetOnEvent(-1, "_showInfo")


GUICtrlCreateLabel("PDF Umbennungstool", 10, 10, 274, 104, $SS_CENTER, -1)
GUICtrlSetFont(-1, 22, 700, 0, "Tahoma")
GUICtrlSetBkColor(-1, "-2")


GUISetOnEvent($GUI_EVENT_CLOSE, '_Minimize')
GUISetOnEvent($GUI_EVENT_MINIMIZE, '_Minimize')


TraySetOnEvent(-7, '_Restore')


While Sleep(3 * 1000)
_Datenbekommen()
_Verschieben()
_Umbennen()


	If Mod ($iwhile, 1200) = 0 Then
		_aelter_loeschen()
		_verschieben_aelter()
		$iwhile = 0
	ElseIf Mod ($iwhile,100) = 0 Then
		_PDFMerge()	
	EndIf
	$iwhile +=1
WEnd


Func _Datenbekommen()
	_FileDeleteAfterXDays($s_MyFACTORY_DRUCK_ORDNER_ABLAGE, 2, True)


	FileDelete($s_PATH_START & "*.xml")


	FileCopy($s_MyFACTORY_DRUCK_ORDNER, $s_MyFACTORY_DRUCK_ORDNER_ABLAGE, 1)
	FileMove($s_MyFACTORY_DRUCK_ORDNER, $s_PATH_START, 1)
	FileMove($s_PATH_START & "*.pdf", $s_PATH_ZWISCHEN, 1)
EndFunc   ;==>_Datenbekommen




Func _PDFMerge()
	$s_SEARCHPDFMERGE = FileFindFirstFile($s_PATH_LS_ZWISCHEN & "*.pdf")
	If $s_SEARCHPDFMERGE <> -1 Then
		$a_LISTPDF = _FileListToArray($s_PATH_LS_ZWISCHEN, '*', 1)
		For $i = 1 To $a_LISTPDF[0]
			RunWait($s_PDFPDF & ' "' & $s_PATH_LS_ZWISCHEN & $a_LISTPDF[$i] & '"', "", @SW_HIDE)
			$s_Namein = $s_PATH_LS_ZWISCHEN & $a_LISTPDF[$i]
			$s_Nameout = $s_PATH_LS & $a_LISTPDF[$i]
			$s_Papier = ' background ' & $s_PDFBRIEFPAPIER & ' output '
			RunWait($s_PDFPDF & " " & $s_Namein & $s_Papier & $s_Nameout, "", @SW_HIDE)
			FileDelete($s_PATH_LS_ZWISCHEN & $a_LISTPDF[$i])
		Next
	EndIf
EndFunc   ;==>_PDFMerge


Func _Verschieben()
	FileMove($s_PATH_FERTIG & $s_KENNZEICHEN_WA_ALT & "*.pdf", $s_PATH_WA, 1)
	FileMove($s_PATH_FERTIG & $s_KENNZEICHEN_WA_NEU & "*.pdf", $s_PATH_WA, 1)
	FileMove($s_PATH_FERTIG & $s_KENNZEICHEN_LS & "*.pdf", $s_PATH_LS_ZWISCHEN, 1)
	FileMove($s_PATH_FERTIG & "*.pdf", $s_PATH_MUELL, 1)
EndFunc   ;==>_Verschieben


Func _Umbennen()
	$s_SEARCH_ZWISCHEN = FileFindFirstFile($s_PATH_ZWISCHEN & "*.pdf")
	If $s_SEARCH_ZWISCHEN <> -1 Then
		$a_LIST = _FileListToArray($s_PATH_ZWISCHEN, '*', 1)
		For $i = 1 To $a_LIST[0]
			If StringRight($s_PATH_ZWISCHEN & $a_LIST[$i], StringLen($s_EXT)) = $s_EXT Then
				RunWait($s_PDFTOTEXT & ' "' & $s_PATH_ZWISCHEN & $a_LIST[$i] & '"', "", @SW_HIDE)
				FileMove($s_PATH_ZWISCHEN & "*.txt", $s_PATH_FERTIG & "2.txt", 1)
				$a_REG = StringRegExp(FileRead($s_PATH_FERTIG & "2.txt"), $s_SEARCH & '(.*)', 1)
				FileDelete($s_PATH_FERTIG & "2.txt")
				If IsArray($a_REG) Then
					FileMove($s_PATH_ZWISCHEN & $a_LIST[$i], $s_PATH_FERTIG & $a_REG[0] & $s_EXT, 1)
				Else
					FileDelete($s_PATH_ZWISCHEN & $a_LIST[$i])
				EndIf
			EndIf
		Next
	EndIf
EndFunc   ;==>_Umbennen


Func _Showinfo()
	MsgBox(0, "Info", "Version 1.6 " & @CRLF & "24.12.2016")
EndFunc   ;==>_Showinfo


Func _Exit()
	Exit
EndFunc   ;==>_Exit


Func _Minimize()
	TraySetState(1)
	GUISetState(@SW_HIDE)
EndFunc   ;==>_Minimize


Func _Restore()
	TraySetState(2)
	GUISetState(@SW_SHOW)
EndFunc   ;==>_Restore


func _verschieben_aelter()
	local $s_SEARCH_VERSCHIEBN_AELTER = FileFindFirstFile($s_PATH_WA & "*")
	If $s_SEARCH_VERSCHIEBN_AELTER <> -1 Then


		local $a_WA_ARCHIV = _FileListToArray($s_PATH_WA, "*", 1)
		local $a_WA_ARCHIV_EXT [$a_WA_ARCHIV[0]][2] ; 2D Array erstellen


		for $i = 1 to $a_WA_ARCHIV[0]


		$a_WA_ARCHIV_EXT[$i - 1][0] = $a_WA_ARCHIV[$i]
		$a_WA_ARCHIV_EXT[$i - 1][1] = StringRegExpReplace(FileGetTime($s_PATH_WA  & $a_WA_ARCHIV[$i], 0, 1), '(\d{4})(\d{2})(\d{2})(.*)', '$1/$2/$3')


			If _DateDiff('D', $a_WA_ARCHIV_EXT[$i - 1][1], _NowCalc()) > $s_KENNZEICEHN_WA_ARCHIV_AELTER_VERSCHIEBEN Then
			Filemove ($s_PATH_WA & $a_WA_ARCHIV_Ext[$i - 1][0], $s_PATH_WA_ARCHIV ,1)


			EndIf
		next
	EndIf
EndFunc


func _aelter_loeschen()
	local $s_SEARCH_LOESCHEN = FileFindFirstFile($s_PATH_WA_ARCHIV & "*")
	If $s_SEARCH_LOESCHEN <> -1 Then


		local $a_WA_ARCHIV_ABLAGE = _FileListToArray($s_PATH_WA_ARCHIV, "*", 1)
		local $a_WA_ARCHIV_EXT_ABLAGE [$a_WA_ARCHIV_ABLAGE[0]][2] ; 2D Array erstellen


		for $i = 1 to $a_WA_ARCHIV_ABLAGE[0]


		$a_WA_ARCHIV_EXT_ABLAGE[$i - 1][0] = $a_WA_ARCHIV_ABLAGE[$i]
		$a_WA_ARCHIV_EXT_ABLAGE[$i - 1][1] = StringRegExpReplace(FileGetTime($s_PATH_WA_ARCHIV & $a_WA_ARCHIV_ABLAGE[$i], 0, 1), '(\d{4})(\d{2})(\d{2})(.*)', '$1/$2/$3')


			If _DateDiff('D', $a_WA_ARCHIV_EXT_ABLAGE[$i - 1][1], _NowCalc()) > $s_KENNZEICEHN_WA_ARCHIV_AELTER_LOESCHEN Then
			FileDelete ($s_PATH_WA_ARCHIV & $a_WA_ARCHIV_EXT_ABLAGE[$i - 1][0])


			EndIf	
		next
	EndIf
EndFunc

Alles anzeigen

**autoiter**

Hallo @SCCSSF,

Wenn etwas einmal die Stunde oder alle x Stunden ausgeführt werden soll, könntest du es auch etwas schräger machen.
Das folgende ist bestimmt Pfusch und irgendwer, der das liest, wird wohl seinen Kopf auf die Tischplatte hauen. Aber es ist ja Weihnachten

AutoIt

Global $iAusfuehrungszeitpunkt = @HOUR ; Am Anfang es Skripts bekommt die tolle Variable den Wert der aktuellen Stunde


If @HOUR = $iAusfuehrungszeitpunkt Then _aelter_loeschen() ; In der Schleife wo auch die anderen Funktionen aufgerufen werden, fügst du einfach die Bedingung ein, dass die Funktion ausgeführt wird, wenn $iAusfuehrungszeitpunkt die aktuelle Stunde ist.


Func _aelter_loeschen()
;~ ....
;~ ....
; In der Funktion, die du dann aufrufst, setzt du iAusfuehrungszeitpunkt eins hoch oder auf Null, wenn die Stunde 23 läuft.
$iAusfuehrungszeitpunkt = ($iAusfuehrungszeitpunkt = 23) ? 0 : ($iAusfuehrungszeitpunkt + 1)
EndFunc

Alles anzeigen

**alpines**

Zitat von autoiter

Wenn etwas einmal die Stunde oder alle x Stunden ausgeführt werden soll, könntest du es auch etwas schräger machen.
Das folgende ist bestimmt Pfusch und irgendwer, der das liest, wird wohl seinen Kopf auf die Tischplatte hauen. Aber es ist ja Weihnachten

Aber... aber warum?

Wenn du es noch schräger haben willst kannst du ja ein PHP-Script schreiben das auf einem Webserver läuft wo das Script auf dem Clienten alle 5 Sekunden die Infos runterlädt ob er die Funktionen ausführen soll oder nicht

**autoiter**

Der Ansatz gefällt mir @alpines

sccssf

Das mit der Stunde überlege ich mir maL

Vielleicht lasse ich es auch nur alle 24 h laufen.
Ich habe noch nicht unter Last getestet. Im Archiv werden ca. 2000-3000 Dateien liegen nach 40 Tagen. Das kommt dann nicht auf eine Stunde drauf an.

@autoiter @alpines Frohes Fest

**Kanashius**

Nur mal so als Idee in den Raum geworfen:
TimerInit()
TimerDiff()

Wofür gibt es die beiden Funktionen denn, wenn nicht dafür

Kann man einfach den Zeitabstandprüfen und den Timer einfach jedesmal neu initialisieren^^

**autoiter**

Obwohl sich das wie in meinem Beispiel anwenden lässt, benutze ich die Funktion nur bei kurzen Zeiträumen. Einfach weil ich die Ausgabe hässlich finde
Aber klar. So hat man definitiv eine leicht freiere, genauere Zeitraumfestlegung
Für die Funktionen die nur in x-Stunden oder Tagen laufen sollen, ist das so natürlich nicht notwendig. Aber es hat definitiv seinen Charme alles damit zu machen, weil man dann diese hässlichen und vllt. verwirrenden Schleifen in der Schleife umgeht und alles im selben Stil macht.

**alpines**

Zitat von Kanashius

Nur mal so als Idee in den Raum geworfen:
TimerInit()
TimerDiff()

Wofür gibt es die beiden Funktionen denn, wenn nicht dafür

Kann man einfach den Zeitabstandprüfen und den Timer einfach jedesmal neu initialisieren^^

Kommt bei SCCSSFs Implementation letzlich auf das Gleiche hinaus ob ich nun einen Timer resette oder die Zählervariable.

**autoiter**

Im Grunde ja, @alpines,
aber es würde imho besser aussehen als die aktuelle Umsetzung und es würde einen einheitlichen Stil für alle Funktionsaufrufe ermöglichen.

**alpines**

Zitat von autoiter

Im Grunde ja, @alpines,
aber es würde imho besser aussehen als die aktuelle Umsetzung und es würde einen einheitlichen Stil für alle Funktionsaufrufe ermöglichen.

Meiner Meinung nach ist das schon in Ordnung so, das Problem mit den Timern wäre der If-Zweig mit _PDFMerge() dort will man alle 100 Sekunden das ausführen.
Nun ich weiß nicht wie lange die Funktion dafür braucht aber wenn man das mit Timern macht dann muss man dafür automatisch einen Zähler dazunehmen, der Grund dafür ist folgender:

In diesem Fall resette ich den Timer nur wenn ich über die 1200 Sekunden drüber bin und nicht wenn ich alle 100 Sekunden _PDFMerge() ausführen möchte.
Das Problem ist nun, das _PDFMerge eine sehr schneller oder sehr kurze Funktion sein kann, und wenn ich die CPU-Last des Programms minimieren möchte und in die While-Schleife ein Sleep(10) reinpacke, dann laufe ich Gefahr das ich niemals Mod(TimerDiff($tmr), 1200 * 1000) = 0 zu erfüllen.

Also muss ich das so machen das er _PDFMerge() ausführt wenn die Mod-Bedingung = 0 oder kleiner als eine bestimmte Toleranz ist (siehst du gleich am Beispiel.)
Damit man sich nicht damit rumärgern muss, kann man nun eine Zählervariable einführen (in meinem Beispiel $iPassed).

Hier hast du mal das Beispiel das die Implementation als Timer zeigt (einmal mit Zählervariable und einmal mit der Toleranzbedingung)

AutoIt

$iPassed = 0
$tmr = TimerInit()


While Sleep(10)
	If TimerDiff($tmr) >= $iPassed * 2 * 1000 Then
		ConsoleWrite("Counter Passed! :)" & @CRLF)
		$iPassed += 1
	EndIf


	If Mod(TimerDiff($tmr), 2 * 1000) < 5 Then
		ConsoleWrite("Modulo Passed! :)" & @CRLF)
	EndIf
WEnd

Alles anzeigen

Wenn du das Script ausführst wirst du merken, das das Sleep(10) in der Schleife die Modulobedingung behindert.
Der String "Counter Passed!" wird alle zwei Sekunden in die Console geschrieben aber der String "Modulo Passed!" wird manchmal ausgelassen.

Du hast nun folgende Möglichkeiten um das Problem zu beseitigen, einmal kannst du das Sleep(10) weglassen, dann würde aber der Modulo Passed Zweig sehr häufig ausgeführt werden,
oder du passt die < 5 in der If-Abfrage an. Wenn du nun die 5 auf 10 oder höher setzt, dann läufst du ebenfalls Gefahr die Funktion mehrmals auszuführen.

Deshalb brauchst du hier noch die Extrazählervariable $iPassed, und wenn die Funktionen von @SCCSSF implementierst (einmal als $iWhile += 1 und einmal als Timer) dann wirst du merken, dass man sich die Timer auch ehrlich gesagt schenken kann, weil man auch noch den Zähler zurücksetzen muss. (meine Meinung).

AutoIt

;While-Implementation


While Sleep(3 * 1000)
	_Datenbekommen()
	_Verschieben()
	_Umbennen()


	If Mod ($iwhile, 1200) = 0 Then
		_aelter_loeschen()
		_verschieben_aelter()
		$iwhile = 0
	ElseIf Mod ($iwhile,100) = 0 Then
		_PDFMerge()
	EndIf


	$iwhile +=1
WEnd

Alles anzeigen

AutoIt

;Timer-Implementation mit Zählervariable


$tmr = TimerInit()
$iPassed = 1


While Sleep(10)
	_Datenbekommen()
	_Verschieben()
	_Umbennen()


	If TimerDiff($tmr) >= 1200 * 1000 Then
		_aelter_loeschen()
		_verschieben_aelter()
		$tmr = TimerInit()
		$iPassed = 1
	ElseIf TimerDiff($tmr) >= $iPassed * 100 * 1000 Then
		$iPassed += 1
		_PDFMerge()
	EndIf
WEnd

Alles anzeigen

Frohes Fest

**chip**

Für so etwas gibt es die Aufgabenplanung in Windows. Ist eigentlich komplett sinnfrei und auch ineffizient das nochmal separat nachzubauen.

**alpines**

Zitat von chip

Für so etwas gibt es die Aufgabenplanung in Windows. Ist eigentlich komplett sinnfrei und auch ineffizient das nochmal separat nachzubauen.

Naja, weiß nicht ob das jetzt wirklich sinnfrei ist sich in die Aufgabenplanung reinzufuchsen um alles richtig nachzubauen (Funktionen müssen ja blockierend sein etc).

sccssf

Hallo,

@chip @alpines

Natürlich ginge Aufgabenplanung. Aber ich möchte ebbend nicht mehr dran denken, wenn ich was ändern sollte auch dort was zu Überprüfen.

Ich habe meine ersten Sachen 2008 in Autoit geschrieben und dann läuft es Jahre und dann soll ich mal ebbend was ändern.

So finde ich es gleich wieder.

Ich habe mal den Ansatz von @autoiter angenommen.

Die Global Sachen stehen natürlich Außerhalb.
Klar könnte ich es noch in eine Funktion auslagern.
So läuft die Aufräum Aktion 1 x am Tag.

Ich kann bei meinen Variablen die Start-Stunde festlegen.

Wie gefällt Euch dies ?

AutoIt

Global $iAUFRAEUMEN_STUNDE = 19
Global $iWHILE = 1
While Sleep(3 * 1000)
	_Datenbekommen()
	_Verschieben()
	_Umbennen()
	Local $iZEIT_START = @HOUR
	Local $iZEIT_STOP = $iAUFRAEUMEN_STUNDE - 1
	If $iZEIT_STOP = $iZEIT_START Then
		$iAUFRAEUMEN_STUNDE += 1
	EndIf
	If $iZEIT_START = $iAUFRAEUMEN_STUNDE Then
		_aelter_loeschen()
		_verschieben_aelter()
		$iAUFRAEUMEN_STUNDE -= 1
	EndIf
	If Mod($iWHILE, 100) = 0 Then
        $iWHILE = 1
		_PDFMerge()
	EndIf
	$iWHILE += 1
WEnd

Alles anzeigen