Kollegen zum Geburtstag gratulieren

Kloppstock

Hallo,

ich möchte gerne ein Script schreiben, dass 00:01 Uhr im Intranet einen Geburtstagsgruß hinterlässt.

Code

While True
    If @MON = 7 And @MDAY = 13 And @HOUR = 0 And @MIN = 1 Then
        MsgBox(64, "", "It's your birthday !")
        ExitLoop
    EndIf
    Sleep(60000) ;jede Minute
WEnd

So wie hier ungefähr.
Habe aber eine Liste mit den Daten. Wie kann ich autoit sagen, dass er in der Liste jeden Tag suchen soll und ggf auch 2 verschiedene Grüße schickt? Außerdem muss er auch den richtigen Namen in der Zeile mit dem entsprechenden Datum sehen.

Vielen dank für die Hilfe

**alpines**

Willst du die Grüße über Mail verschicken oder die Datei auf dem PC ausführen und es als MsgBox anzeigen lassen?

Bei der MsgBox legst du am besten ein Array an mit den Daten an und iterierst es einfach jede Minute/jeden Tag.
Ich hab mal ein kleines Beispiel programmiert, kannst es dir ja mal ansehen.

AutoIt

Local $aGeburtstage[2][2] = [["Andreas", "28.12 09:26"], ["Kloppstock", "31.12 00:16"]]


While Sleep(50 * 1000)
	For $i = 0 To UBound($aGeburtstage) - 1
		$aDate = StringSplit($aGeburtstage[$i][1], " ", 3)


		$aTime = $aDate[1]
		$aDate = StringSplit($aDate[0], ".", 3)


		$aTime = StringSplit($aTime, ":", 3)


		If @MDAY = $aDate[0] and @MON = $aDate[1] and @HOUR = $aTime[0] and @MIN = $aTime[1] Then
			MsgBox(48, "Alles Gute!", "Herzlichen Glückwunsch zum Geburtstag " & $aGeburtstage[$i][0] & "!")
		EndIf
	Next
WEnd

Alles anzeigen

Kloppstock

Es soll dann mehrere Mausbegwungen (navigieren im Intranet) und halt die Texteingabe machen.
in dem bsp oben muss ich ja alle nutzer definieren, geht das auch, dass er es als iniread macht?

**alpines**

Du kannst das auch per IniRead machen, wenn du dazu die richtigen Ini-Funktionen nimmst, musst du die Exe nie neustarten sondern nur die Ini anpassen.
Hier mal ein Beispiel wie du das machen kannst.

AutoIt

While Sleep(50 * 1000)
	$aGeburtstage = IniReadSection("Geburtstage.ini", "Geburtstage")


	For $i = 1 To $aGeburtstage[0][0]
		$aDate = StringSplit($aGeburtstage[$i][1], " ", 3)


		$aTime = $aDate[1]
		$aDate = StringSplit($aDate[0], ".", 3)


		$aTime = StringSplit($aTime, ":", 3)


		If @MDAY = $aDate[0] and @MON = $aDate[1] and @HOUR = $aTime[0] and @MIN = $aTime[1] Then
			MsgBox(48, "Alles Gute!", "Herzlichen Glückwunsch zum Geburtstag " & $aGeburtstage[$i][0] & "!")
		EndIf
	Next
WEnd

Alles anzeigen

Code

[Geburtstage]
Andreas=25.12 12:53
Kloppstock=28.12 10:40

**autoiter**

Zitat von alpines

Du kannst das auch per IniRead machen, wenn du dazu die richtigen Ini-Funktionen nimmst, musst du die Exe nie neustarten sondern nur die Ini anpassen.
Hier mal ein Beispiel wie du das machen kannst.

Damit die Exe nie neu gestartet werden muss, sollte aber das IniReadSection auch in die Schleife, nicht wahr?
(Ich weiß, war ja nur ein Bsp. )

**alpines**

Zitat von autoiter

Damit die Exe nie neu gestartet werden muss, sollte aber das IniReadSection auch in die Schleife, nicht wahr?(Ich weiß, war ja nur ein Bsp. )

So früh am Morgen habe ich keinen klaren Kopf, natürlich muss das in die Schleife.
Habs mal fix editiert. Das #include <Array.au3> kann man sich auch sparen.

**Oscar**

Ich würde das noch etwas abwandeln, so dass man auch das Alter des Geburtstagskindes anzeigen lassen kann.

AutoIt

#include <Date.au3>
Local $aGeburtstage[2][3] = [["Andreas", "28.12.1989 10:43", False], ["Kloppstock", "31.12.1996 00:16", False]]


While Sleep(1000)
	For $i = 0 To UBound($aGeburtstage) - 1
		$aDate = StringSplit($aGeburtstage[$i][1], " ", 3)


		$aTime = $aDate[1]
		$aDate = StringSplit($aDate[0], ".", 3)


		$aTime = StringSplit($aTime, ":", 3)


		$iDiff = _DateDiff("n", StringFormat("%04i/%02i/%02i %02i:%02i:00", @YEAR, $aDate[1], $aDate[0], $aTime[0], $aTime[1]), _NowCalc()) ; die Differenz in Minuten berechnen (wenn Datum/Zeit noch nicht erreicht, dann ist die Differenz negativ)


		If $iDiff >= 0 And Not $aGeburtstage[$i][2] Then ; wenn das Geburtsdatum/-Zeit erreicht wurde und die MsgBox noch nicht angezeigt wurde, dann...
			$iCount = _DateDiff("Y", StringFormat("%04i/%02i/%02i 00:00:00", $aDate[2], $aDate[1], $aDate[0]), _NowCalc()) ; das Alter berechnen
			MsgBox(48, "Alles Gute!", StringFormat("Hallo %s!\nHerzlichen Glückwunsch zum %i. Geburtstag!", $aGeburtstage[$i][0], $iCount))
			$aGeburtstage[$i][2] = True ; MsgBox wurde bereits angezeigt
		EndIf
		$iDiff = _DateDiff("s", @YEAR & "/12/31 23:59:59", _NowCalc())
		If $iDiff >= 0 Then $aGeburtstage[$i][2] = False ; Neujahr alle Geburtstage zurücksetzen
	Next
WEnd

Alles anzeigen

**BugFix**

[OT]

Zitat von Oscar

so dass man auch das Alter des Geburtstagskindes anzeigen lassen kann

Bei Frauen aber bitte als festes Alter die 29 hinterlegen....
[/OT]

**alpines**

Zitat von BugFix

Bei Frauen aber bitte als festes Alter die 29 hinterlegen....

Oder das Alter einfach ausblenden wenn sie über 29 sind

Kloppstock

Funktioniert schonmal super.
Vielen Dank für eure Über-Schnelle-Hilfe

**alpines**

Wenn alles geklärt ist dann setz ich mal den grünen Haken für [gelöst] (1. Beitrag bearbeiten).
Solltest du Probleme haben die Grüße abzuschicken (über die Maus und Tastatursteuerung) kannst du ja trotzdem hier fragen oder einen neuen Thread aufmachen.

Kloppstock

Wie schaffe ich es, dass autoit dann auf den link klickt? (siehe roter Kasten im Anhang)
Scheint für mich als noob ieframe zu sein.

Das hat doch was mit "_IEFormElementGetObjByName" zu tun, wobei hier Name "name" ist wie es mir der Quelltext anzeigt oder?

**alpines**

Zitat von Kloppstock

Wie schaffe ich es, dass autoit dann auf den link klickt? (siehe roter Kasten im Anhang)
Scheint für mich als noob ieframe zu sein.

Das hat doch was mit "_IEFormElementGetObjByName" zu tun, wobei hier Name "name" ist wie es mir der Quelltext anzeigt oder?

Die Id des Buttons lautet "edit-submit", also holst du mit _IEGetObjById() das Objekt und mit _IEAction() klickst du drauf.

Kloppstock

Irgendwas mache ich falsch:

Code

#include <IE.au3>


$Address = "http://intranet.com/user/login"


Local $oIE = _IECreate ($Address,1,1,1,1)
_IELoadWait($oIE)
Local $oSubmit = _IEGetObjById($oIE, "edit-submit")
_IEAction($oSubmit, "click")
_IELoadWait($oIE)

Alles anzeigen

Fehlermeldung:

Spoiler anzeigen

--> IE.au3 T3.0-2 Warning from function _IEAttach, $_IESTATUS_NoMatch
--> IE.au3 T3.0-2 Error from function _IELoadWait, $_IESTATUS_ClientDisconnected (-2147417848, Browser has been deleted prior to operation.)
--> IE.au3 T3.0-2 Error from function _IELoadWait, $_IESTATUS_InvalidObjectType ()
--> IE.au3 T3.0-2 Error from function _IEGetObById, $_IESTATUS_InvalidObjectType
--> IE.au3 T3.0-2 Error from function _IEAction(click), $_IESTATUS_InvalidDataType
--> IE.au3 T3.0-2 Error from function _IELoadWait, $_IESTATUS_InvalidObjectType ()
>Exit code: 0 Time: 0.9109

Wenn ich schon eine Instanz vom IE offen habe, kommt die Fehlermendung nicht.

**alpines**

Das ist das Problem mit der IE-UDF, der spinnt teilweise rum und startet einfach nicht - aber da gibt es einen kleinen Workaround für.

AutoIt

#include <IE.au3>


Global Const $S_USERNAME = "test"
Global Const $S_PASSWORD = "12345"


_IEErrorNotify(False)


Do
	Global $oIE = _IECreate("intranet.com/user/login")
Until IsObj($oIE)


$oUsername = _IEGetObjById($oIE, "edit-name")
$oPassword = _IEGetObjById($oIE, "edit-password") ;<- Nicht sicher ob die ID stimmt
$oSubmit = _IEGetObjById($oIE, "edit-submit")


_IEFormElementSetValue($oUsername, $S_USERNAME)
_IEFormElementSetValue($oPassword, $S_PASSWORD)
_IEAction($oSubmit, "click")


Sleep(500)
_IELoadWait($oIE)

Alles anzeigen

Außerdem brauchst du die ganzen optionalen Parameter für _IECreate nicht auszufüllen.
Das _IELoadWait() danach kannst du dir auch schenken, weil das im _IECreate schon enthalten ist.

Kloppstock

Sieht gut aus, aber noch nicht ganz.
"
(10) : ==> Error in expression.:
Until

Until^ ERROR
"

**alpines**

Oh mein Gott, es ist viel zu früh am Morgen... Habs gefixt.

Kloppstock

Hm kommt immer noch "$_IESTATUS_InvalidObjectType"

Kloppstock

Also es geht so:

Code

#include <IE.au3>
$Address = "http://intranet.com/user/login"
$pwd="mypassword"
Do
Local $oIE = _IECreate ($Address,1,1,1,1)
Until IsObj($oIE)
Local $oSubmit = _IEGetObjById($oIE, "edit-submit")
_IEAction($oSubmit, "click")
_IELoadWait($oIE)

Es funktioniert aber auhc nur, wenn ich das Script zum zweiten mal starte (also das IE Fenster schon geöffnet wurde). Workaround hat net so funktioniert.

Kloppstock

Nicht schön, aber funktioniert:

AutoIt

#include <IE.au3>


$Address = "http://intranet.com/user/login"
Global Const $S_USERNAME = "Kloppstcok"
Global Const $S_PASSWORD = "123456"
Do
Local $oIE = _IECreate ($Address,1,1,1,1)
Until IsObj($oIE)
sleep(2000)
Do
Local $oIE = _IECreate ($Address,1,1,1,1)
Until IsObj($oIE)
$oUsername = _IEGetObjById($oIE, "edit-name")
$oPassword = _IEGetObjById($oIE, "edit-pass") ;<- Nicht sicher ob die ID stimmt
$oSubmit = _IEGetObjById($oIE, "edit-submit")
_IEFormElementSetValue($oUsername, $S_USERNAME)
_IEFormElementSetValue($oPassword, $S_PASSWORD)
_IEAction($oSubmit, "click")
_IELoadWait($oIE)

Alles anzeigen