Checkboxen in "SysListView32" auslesen und steuern

FelixBro

Guten Tag,
ich bin Felix ich habe gestern mit AutoIT angefangen eine automatisierte Installation von mehreren Programmen ablaufen zu lassen. Das ganze soll dann auf mehreren (baugleichen) Rechner ausgeführt werden.
Ein einfacher Bot halt...
Denkt man, denn eines der Installationsprogramme enthält eine "SysListView32" und hat mehrere Checkboxen (rot markiert):
[Blockierte Grafik: http://www.bilder-upload.eu/thumb/7c0299-1484736548.jpg]
Mit dem Window Info habe ich herausgefunden das die Liste die ID: 1022 hat (blau markiert).

Per "ControlListView" kann ich auch die einzelnen Zeilen selektieren, oder ein "GetItemCount" ausführen.
Was ich nur gerne machen würde ist jede der Checkboxen zu aktivieren, da auf unterschiedlichen Rechnern, unterschiedliche Softwareteile (Trapcode Tao, - Starglow, - SoundKeys, etc.) vorinstalliert sind.

Ich habe schon mit "ControlCommand" probiert, mir den Zustand der Checkbox ausgeben zu lassen, bin aber nicht weiter gekommen, da der ausgegebene Wert immer 0 ist:

Code

#RequireAdmin
AutoItSetOption('MouseCoordMode', 0)
WinWait('Red Giant Software Registration')
WinActivate('Red Giant Software Registration')
$chk = ControlCommand ("Red Giant Software Registration", "", "SysListView321", "isChecked" )
MsgBox (0, "Gechecked?", $chk)

Ist "ControlCommand" hier überhaupt der richtige Befehl?
Was für alternativen könnte ich versuchen?

Irgendwie muss es ja klappen, da die Info in der Checkbox dem Programm sagt, welcher Teil installiert werden soll...

Hier noch die Window Info:
[Blockierte Grafik: http://www.bilder-upload.eu/thumb/5a674e-1484735910.jpg]

Besten Dank schon einmal für eure Ideen!

**Bitnugger**

Auszug aus der AutoIt-Hilfe: ControlCommand ( "title", "text", controlID, "command" [, "option"] )

Zitat von FelixBro

$chk = ControlCommand ("Red Giant Software Registration", "", "SysListView321", "isChecked" )

Hier hast du den Parameter controlID nicht richtig angegeben...

Richtig wäre:
$chk = ControlCommand("Red Giant Software Registration", "", 1, "isChecked")

Besser ist:
Global $hListView = ControlGetHandle(WinGetHandle("[TITLE:Red Giant Software Registration]"), "", 1)
$chk = _GUICtrlListView_GetItemChecked($hListView)

**alpines**

Du brauchst _GUICtrlListView_SetItemChecked dafür. Hier hast du ein Beispielscript wie du das ganze auf fremden GUIs machen kannst. (Ist aber ziemlich schlampig geschrieben!)

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>


#include <GUIListView.au3>


$Form1 = GUICreate("Form1", 427, 182, 192, 124)
$ListView1 = GUICtrlCreateListView("||", 16, 16, 250, 150, -1, BitOR($WS_EX_CLIENTEDGE,$LVS_EX_CHECKBOXES))
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 50)
$ListView1_0 = GUICtrlCreateListViewItem("1", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("22", $ListView1)
$ListView1_2 = GUICtrlCreateListViewItem("333", $ListView1)
$ListView1_3 = GUICtrlCreateListViewItem("444", $ListView1)
$Button1 = GUICtrlCreateButton("Button1", 296, 56, 97, 49)
GUISetState(@SW_SHOW)


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit


		Case $Button1
			$hListView = ControlGetHandle("Form1", "", "[CLASS:SysListView32; INSTANCE:1]")
			_GUICtrlListView_SetItemChecked($hListView, 0)
			_GUICtrlListView_SetItemChecked($hListView, 2)




	EndSwitch
WEnd

Alles anzeigen

Zitat von Bitnugger

Richtig wäre:
$chk = ControlCommand("Red Giant Software Registration", "", 1, "isChecked")

Richtig wäre eher wenn die bei der Control ID keine 1 steht, sondern das hier [CLASS:SysListView32; INSTANCE:1].

**Bitnugger**

Zitat von alpines

Richtig wäre eher wenn die bei der Control ID keine 1 steht, sondern das hier [CLASS:SysListView32; INSTANCE:1].

Ja ok, das ist noch etwas sicherer...

_GetItemChecked()

AutoIt

;-- TIME_STAMP   2017-01-18 15:43:14


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WinAPISys.au3>


Example()


Func Example()
    Local $hGUI = GUICreate("Listview Items", 220, 250, 100, 200)
    GUISetBkColor(0x00E0FFFF) ; will change background color


    Local $idButton = GUICtrlCreateButton("Check It!", 75, 170, 70, 20)


	Local $idListview = GUICtrlCreateListView("ItemList", 10, 10, 200, 150) ;,$LVS_SORTDESCENDING)
	_GUICtrlListView_SetExtendedListViewStyle($idListview, $LVS_EX_CHECKBOXES)
	_GUICtrlListView_SetColumnWidth($idListview, 0, 192)
    Local $idItem1 = GUICtrlCreateListViewItem("ListviewItem1", $idListview)
    Local $idItem2 = GUICtrlCreateListViewItem("ListviewItem2", $idListview)
    Local $idItem3 = GUICtrlCreateListViewItem("ListviewItem3", $idListview)
    GUISetState(@SW_SHOW)


	; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop


            Case $idButton
				; Handle des 'fremden' ListViews holen
				$hListview = ControlGetHandle('[TITLE:Listview Items]', '', '[CLASS:SysListView32; INSTANCE:1]')
				$iCount = _GUICtrlListView_GetItemCount($hListview)
				ConsoleWrite('---------------------------' & @CRLF)
				For $i = 0 To $iCount -1 Step 1
					Switch _GUICtrlListView_GetItemChecked($hListview, $i)
						Case True
							ConsoleWrite('+ Item ' & $i & ' ist checked!' & @CRLF)
						Case Else
							ConsoleWrite('! Item ' & $i & ' ist not checked!' & @CRLF)
					EndSwitch
				Next
				ConsoleWrite('---------------------------' & @CRLF)
        EndSwitch
    WEnd
EndFunc   ;==>Example

Alles anzeigen

FelixBro

So, da steht ja noch eine Antwort aus:

Es hat geklappt! Vielen Dank für die nützlichen Tipps!

Kurz zusammengefasst war es diese Lösung:

Code

$hListView = ControlGetHandle("Red Giant Software Registration", "", "[CLASS:SysListView32; INSTANCE:1]")
$isChecked = _GUICtrlListView_SetItemChecked($hListView, -1) ; -1 markiert alle Checkboxen in der Liste

Mit vorheriger Einbindung der "GUIListView".

**alpines**

Schön das es geklappt hat, ich hab mal den grünen Haken für gelöst/erledigt gesetzt damit andere Nutzer direkt die Lösung finden.
Das kannst du auch machen indem du den 1. Beitrag des Threads bearbeitest.