DirMove - Verzeichnis verschieben

AutoMit

Hallo,

wie verschiebe ich folgendes (ergibt derzeit Fehler 0, laut Hilfe: wenn das Verschieben des Ordners fehlschlug.):

Der Inhalt von "R:\0 - Kopie\02\02" soll nach "R:\0 - Kopie\02" verschoben werden.

$Start = "R:\0 - Kopie\02\02"
$Ziel = "R:\0 - Kopie\02"
DirMove ($Start, $Ziel, 1)

Hingegen funktioniert:

$Start = "R:\0 - Kopie\02\02"
$Ziel = "R:\0 - Kopie\04"
DirMove ($Start, $Ziel, 1)

Danke und ein erfreuliches Wochenende

PS:
Ziel des Ganzen: Mehrfach verschachtelte Verzeichnisse werden solange 1 Ebene nach oben verschoben, bis im Zielverzeichnis mehr als 1 Element (mehr als 1 Datei oder 1 Verzeichnis) ist.
Es kommt häufiger vor, dass bei mehrfach verschachtelten Verzeichnissen Unterverzeichnisse mit gleichem Namen vorhanden sind - wie z.B. in "R:\0 - Kopie\02\02".

**alpines**

Das liegt vermutlich daran, dass du auf der selben Ebene zwei Ordner hättest mit dem selben Namen.
Windows selbst verschiebt ja nicht direkt sondern fragt dich erst was du machen möchtest, also müsstest du die Dateien auflisten und rüberschieben.

misterspeed

Würd ich auch mal vermuten. Wenn man das manuell im Explorer macht erhält man diese Meldung

doppelter_ordner.png

Per commandline erscheint diese Rückfrage

Seltsamerweise erhalte ich per CMD ein "Zugriff verweigert" wenn ich dem Überschreiben zustimme oder dieses per Parameter /Y erzwinge.

Du könntest mal in der Hilfe nachsehen ob die dirmove Funktion ebenfalls einen Parameter für Überschreiben besitzt.

Als Workaround kann natürlich auch immer zuerst ein "02temp" als Ziel verwendet werden, danach das leere "02" löschen und dann "02temp" nach "02" umbenennen/verschieben.

**alpines**

Zitat von misterspeed

die dirmove Funktion ebenfalls einen Parameter für Überschreiben besitzt

Dafür ist doch hinten die ,1 gedacht. Das setzt den Flag für $FC_OVERWRITE. Trotz Adminrechte ersetzt er die Dateien dennoch nicht.

misterspeed

Ah okay... hatte keine Lust in der Hilfe nachzusehn wofür der Flag steht.

**Bitnugger**

Remarks
If the source and destination are on different volumes or UNC paths are used then a copy/delete operation will be performed rather than a move.

If the destination already exists and the overwrite flag is specified then the source directory will be moved inside the destination.

Da wird man dann wohl nicht um ein temporäres Verzeichnis herumkommen...

Ich habe das gerade mal so getestet:

MoveDir

AutoIt

;-- TIME_STAMP   2017-01-20 22:09:03


#include <File.au3>


Global $sHomeDir = 'R:\0 - Kopie\'
Global $sSubDir  = '02\'
Global $sTestDir = $sHomeDir & $sSubDir & $sSubDir & $sSubDir & $sSubDir
Global $aFileList, $sSourceDir = $sHomeDir, $sDestinationDir = $sHomeDir & $sSubDir, $sDestinationDirTemp, $iMove, $iRemove


$aFileList = _GetFileList($sDestinationDir)
If @extended = 0 And FileExists($sTestDir) = 0 Then
	ConsoleWrite('DirCreate: ' & $sTestDir & @CRLF)
	Global $iDirCreate = DirCreate($sTestDir)
	ConsoleWrite('$iDirCreate = ' & $iDirCreate & @CRLF)
	For $i = 1 To 3 Step 1
		FileWrite($sTestDir & '\Dummy_' & $i & '.txt', 'Dummytext = ' & $i)
	Next
EndIf


While 1
	$sSourceDir &= $sSubDir
	If FileExists($sSourceDir) = 0 Then Exit	; dann gibt es nichts zu tun...


	ConsoleWrite('$sSourceDir = ' & $sSourceDir & @CRLF)
	$aFileList = _GetFileList($sSourceDir)
	If @extended > 0 Then ExitLoop
WEnd


If $aFileList[0] > 0 Then
	If $sSourceDir = $sDestinationDir Then
		ConsoleWrite('$sSourceDir = $sDestinationDir' & @CRLF)
		Exit	; dann gibt es nichts zu tun...
	EndIf


	ConsoleWrite(@CRLF & 'FileList in Directory: ' & $sSourceDir & @CRLF & _ArrayToString($aFileList, @CRLF) & @CRLF)
	If StringRight($sDestinationDir, 1) = '\' Then	$sDestinationDir = StringTrimRight($sDestinationDir, 1)
	$sDestinationDirTemp = $sDestinationDir & '_Temp'
	ConsoleWrite(StringFormat('DirMove("%s", "%s")\n', $sSourceDir, $sDestinationDirTemp))
	$iMove = DirMove($sSourceDir, $sDestinationDirTemp, $FC_NOOVERWRITE)
	ConsoleWrite(@CRLF & '$iMove = ' & $iMove & @CRLF)


	If $iMove = 1 Then
		$iRemove = DirRemove($sDestinationDir, $DIR_REMOVE)	; remove files and subdirectories
		ConsoleWrite('$iRemove = ' & $iRemove & @CRLF)


		ConsoleWrite(StringFormat('DirMove("%s", "%s")\n', $sDestinationDirTemp, $sDestinationDir))
		$iMove = DirMove($sDestinationDirTemp, $sDestinationDir, $FC_NOOVERWRITE)
		ConsoleWrite(@CRLF & '$iMove = ' & $iMove & @CRLF)
	EndIf
EndIf


Func _GetFileList($sPath)
	$aFileList = _FileListToArray($sPath, "*", $FLTA_FILES, False)
	If @error Then Return SetError(@error, 0, 0)


	Return SetError(0, $aFileList[0], $aFileList)
EndFunc

Alles anzeigen

AutoMit

Danke Bitnugger für den Workaround

Zitat von alpines

Dafür ist doch hinten die ,1 gedacht. Das setzt den Flag für $FC_OVERWRITE. Trotz Adminrechte ersetzt er die Dateien dennoch nicht.

Ich hatte auch die Hoffnung, dass es überschrieben wird mit Flag = 1, daher in meinem ersten Post:
DirMove ($Start, $Ziel, 1)
Geht leider wirklich nicht.

Im Total Commander funktioniert das ohne Probleme - es kommt keine Überschreibwarnung - F6 und der Inhalt des gleichnamigen Verzeichnisses ist eine Ordnerebene höher.
So eine Funktion (API Aufruf?) suche ich für AutoIt, die einfach aufgerufen werden kann. Bis dahin versuche ich es mit dem Workaround und dem temp Verzeichnis.

DirMove
laut Hilfe
"Wenn der Zielort schon existiert, und bei "flag" angegeben wird, dass überschrieben werden soll, so wird das Quellverzeichnis in das Zielverzeichnis verschoben."

Das funktioniert scheinbar nicht, wie in der Hilfe beschrieben - oder verstehe ich die Beschreibung falsch?
Wie ist der Satz aus der Hilfe zu verstehen?

AutoMit

Zitat von Bitnugger

Remarks
If the source and destination are on different volumes or UNC paths are used then a copy/delete operation will be performed rather than a move.

If the destination already exists and the overwrite flag is specified then the source directory will be moved inside the destination.

Da wird man dann wohl nicht um ein temporäres Verzeichnis herumkommen...

Ich habe das gerade mal so getestet:

MoveDir

AutoIt

;-- TIME_STAMP   2017-01-20 22:09:03


#include <File.au3>


Global $sHomeDir = 'R:\0 - Kopie\'
Global $sSubDir  = '02\'
Global $sTestDir = $sHomeDir & $sSubDir & $sSubDir & $sSubDir & $sSubDir
Global $aFileList, $sSourceDir = $sHomeDir, $sDestinationDir = $sHomeDir & $sSubDir, $sDestinationDirTemp, $iMove, $iRemove


$aFileList = _GetFileList($sDestinationDir)
If @extended = 0 And FileExists($sTestDir) = 0 Then
	ConsoleWrite('DirCreate: ' & $sTestDir & @CRLF)
	Global $iDirCreate = DirCreate($sTestDir)
	ConsoleWrite('$iDirCreate = ' & $iDirCreate & @CRLF)
	For $i = 1 To 3 Step 1
		FileWrite($sTestDir & '\Dummy_' & $i & '.txt', 'Dummytext = ' & $i)
	Next
EndIf


While 1
	$sSourceDir &= $sSubDir
	If FileExists($sSourceDir) = 0 Then Exit	; dann gibt es nichts zu tun...


	ConsoleWrite('$sSourceDir = ' & $sSourceDir & @CRLF)
	$aFileList = _GetFileList($sSourceDir)
	If @extended > 0 Then ExitLoop
WEnd


If $aFileList[0] > 0 Then
	If $sSourceDir = $sDestinationDir Then
		ConsoleWrite('$sSourceDir = $sDestinationDir' & @CRLF)
		Exit	; dann gibt es nichts zu tun...
	EndIf


	ConsoleWrite(@CRLF & 'FileList in Directory: ' & $sSourceDir & @CRLF & _ArrayToString($aFileList, @CRLF) & @CRLF)
	If StringRight($sDestinationDir, 1) = '\' Then	$sDestinationDir = StringTrimRight($sDestinationDir, 1)
	$sDestinationDirTemp = $sDestinationDir & '_Temp'
	ConsoleWrite(StringFormat('DirMove("%s", "%s")\n', $sSourceDir, $sDestinationDirTemp))
	$iMove = DirMove($sSourceDir, $sDestinationDirTemp, $FC_NOOVERWRITE)
	ConsoleWrite(@CRLF & '$iMove = ' & $iMove & @CRLF)


	If $iMove = 1 Then
		$iRemove = DirRemove($sDestinationDir, $DIR_REMOVE)	; remove files and subdirectories
		ConsoleWrite('$iRemove = ' & $iRemove & @CRLF)


		ConsoleWrite(StringFormat('DirMove("%s", "%s")\n', $sDestinationDirTemp, $sDestinationDir))
		$iMove = DirMove($sDestinationDirTemp, $sDestinationDir, $FC_NOOVERWRITE)
		ConsoleWrite(@CRLF & '$iMove = ' & $iMove & @CRLF)
	EndIf
EndIf


Func _GetFileList($sPath)
	$aFileList = _FileListToArray($sPath, "*", $FLTA_FILES, False)
	If @error Then Return SetError(@error, 0, 0)


	Return SetError(0, $aFileList[0], $aFileList)
EndFunc

Alles anzeigen

Wie kann man das Script von Bitnugger erweitern, damit nur Verzeichnisse berücksichtigt werden?

If $aFileList[0] > 0 Then ... bedeutet wohl, nur Dateien werden verschoben.

Mein Ziel ist es, dass der Inhalt gleichnamiger Verzeichnisse verschoben wird.

Verschoben werden sollen nur Verzeichnisse inklusive der Dateien (nicht einzelne Dateien, daher habe ich es mit DirMove versucht)

So soll das Ergebnis aussehen

R:\0 - Kopie\02\02\Test -> R:\0 - Kopie\02\Test

Quelle:

R:\0 - Kopie\02\02\Test\Dummy_1.txt
R:\0 - Kopie\02\02\Test\Dummy_2.txt
R:\0 - Kopie\02\02\Test\Dummy_3.txt

Ergebnis:

R:\0 - Kopie\02\Test\Dummy_1.txt
R:\0 - Kopie\02\Test\Dummy_2.txt
R:\0 - Kopie\02\Test\Dummy_3.txt

Ein schönes Wochenende und Danke

**Bitnugger**

Zitat von AutoMit

Wie kann man das Script von Bitnugger erweitern, damit nur Verzeichnisse berücksichtigt werden?

MoveDir

AutoIt

;-- TIME_STAMP   2017-01-21 23:50:10


#include <File.au3>


Global $sHomeDir = 'R:\0 - Kopie\'
Global $sSubDir  = '02\'
Global $sTestDir = $sHomeDir & $sSubDir & $sSubDir & $sSubDir & $sSubDir
Global $aDirList, $aFileList, $sSourceDir = $sHomeDir, $sDestinationDir = $sHomeDir & $sSubDir, $sDestinationDirTemp, $iDirCreate, $iMove, $iRemove


_MakeTestDir()


While 1
	$sSourceDir &= $sSubDir


	ConsoleWrite('+ $sSourceDir = ' & $sSourceDir & @CRLF)
	$iMove = _GetFileList($sSourceDir & $sSubDir, $sSubDir)
	Select
		Case @error
			_MoveDir($sSourceDir, $sDestinationDir)
			ExitLoop
		Case $iMove = True
			_MoveDir($sSourceDir & $sSubDir, $sDestinationDir)
			ExitLoop
	EndSelect
WEnd


Func _MoveDir($sSourceDir, $sDestinationDir)
	If $sSourceDir = $sDestinationDir Then
		ConsoleWrite('! $sSourceDir = $sDestinationDir' & @CRLF)
		Exit	; dann gibt es nichts zu tun...
	EndIf


	; Trimm trailing backslashes
	If StringRight($sSourceDir, 1) = '\' Then $sSourceDir = StringTrimRight($sSourceDir, 1)
	If StringRight($sDestinationDir, 1) = '\' Then $sDestinationDir = StringTrimRight($sDestinationDir, 1)


	; move to TempDir as workaround, if ..\SubDir are identical for $sSourceDir and $sDestinationDir
	$sDestinationDirTemp = $sDestinationDir & '_Temp'
	ConsoleWrite(StringFormat('- DirMove("%s", "%s", $FC_NOOVERWRITE)\n', $sSourceDir, $sDestinationDirTemp))
	$iMove = DirMove($sSourceDir, $sDestinationDirTemp, $FC_NOOVERWRITE)
	If $iMove = 0 Then
		ConsoleWrite('! $sSourceDir "' & $sSourceDir & '" konnte nicht verschoben werden!' & @CRLF)
		Return SetError(1)
	EndIf


	; Remove this directory, inclusive all files and subdirectories
	ConsoleWrite(StringFormat('- DirRemove("%s", $DIR_REMOVE)\n', $sDestinationDir))
	$iRemove = DirRemove($sDestinationDir, $DIR_REMOVE)
	If $iRemove = 0 Then
		ConsoleWrite('! $sDestinationDir "' & $sDestinationDir & '" konnte nicht gelöscht werden!' & @CRLF)
		Return SetError(2)
	EndIf


	; Move TempDir to DestinationDir
	ConsoleWrite(StringFormat('- DirMove("%s", "%s", $FC_NOOVERWRITE)\n', $sDestinationDirTemp, $sDestinationDir))
	$iMove = DirMove($sDestinationDirTemp, $sDestinationDir, $FC_NOOVERWRITE)
	If $iMove = 0 Then
		ConsoleWrite('! $sDestinationDirTemp "' & $sDestinationDirTemp & '" konnte nicht verschoben werden!' & @CRLF)
		Return SetError(3)
	EndIf
EndFunc


Func _GetFileList($sPath, $sDirFilter)
	If FileExists($sPath) = 0 Then Return SetError(1, 0, False)	; dann gibt es nichts zu tun...


	$sDirFilter = StringReplace($sDirFilter, '\', '')


	Local $iError = 0, $iIndex = -1
	$aDirList  = _FileListToArray($sPath, "*", $FLTA_FOLDERS, False)
	If @error Then $iError = 1
	$aFileList = _FileListToArray($sPath, "*", $FLTA_FILES, False)
	If @error Then $iError += 2


	Switch $iError
		Case 0												; Verzeichnisse und Dateien gefunden - verschieben!
			Return True
		Case 1												; Nur Dateien gefunden - verschieben!
			Return True
		Case 2												; Nur Verzeichnisse gefunden...
			If _ArraySearch($aDirList, $sDirFilter) = 1 And $aDirList[0] = 1 Then
				Return False								; Nur das Verzeichnis $sDirFilter gefunden - NICHT verschieben!
			Else
				Return True									; Neben $sDirFilter noch weitere Verzeichnisse gefunden - verschieben!
			EndIf
		Case 3												; Verzeichnis ist leer - verschieben!
			Return True
	EndSwitch
EndFunc


Func _MakeTestDir()
	If FileExists($sTestDir) = 0 Then
		; Remove this directory, inclusive all files and subdirectories
		If FileExists($sHomeDir) = 1 Then DirRemove($sHomeDir, $DIR_REMOVE)


		ConsoleWrite(StringFormat('- DirCreate("%s")\n', $sTestDir & 'Test'))
		$iDirCreate = DirCreate($sTestDir & 'Test')
		If $iDirCreate = 0 Then
			ConsoleWrite('! "' & $sTestDir & 'Test\' & '" konnte nicht angelegt werden!' & @CRLF)
			Exit 1
		EndIf
		For $i = 1 To 3 Step 1
			ConsoleWrite('- MakeDummyFile(' & $sTestDir & '\Test\Dummy_' & $i & '.txt)' & @CRLF)
			FileWrite($sTestDir & '\Test\Dummy_' & $i & '.txt', 'Dummytext = ' & $i)
		Next
	EndIf
EndFunc

Alles anzeigen

AutoMit

Vielen Dank Bitnugger für die Ergänzung und Deine Hilfe

Ich lasse das Thema noch offen. Vielleicht kann jemand noch etwas zu den Fragen aus Post 7 schreiben.

Ein schönes Wochenende und Gute Nacht.

**Kanashius**

Der Ordnerinhalt wird nicht gelöscht, sondern die Dateien dann in den existierenden Ordner geschoben. Dateien werden weiterhin ersetzt.

AutoMit

Vielen Dank - habe das Thema grün gefärbt