Navigation in Gui per TAB

subbafuchs

Hallo zusammen

ich möchte gerne die Navigation der Inputs in meiner GUI festlegen

wenn ich in ein input in der $gui_grundlagen anklicke und danach TAB drücke soll er in das nächste TAB in der gui wechseln.

Be mir wechselt er leider immer direkt zum button in der $gui_situng_basis

wie kann ich die "Navigation" festlegen damit er innerhalb der gui_grundlagen durch die inputs wechselt.

AutoIt: test1

global $GUI_Sitzung_Basis = GUICreate("Sitzung", 1050, 900, 120, 12, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_SYSMENU, $WS_CLIPCHILDREN))


$Sitzung_label = GUICtrlCreateLabel("Bearbeitung der Sitzung vom: ", 30, 25, 250, 30, $SS_Center)
 global $button_speichern = GUICtrlCreatebutton ( "Speichern", 30, 75, 80, 25)


global $gui_Grundlagen = GUICreate("Grundlagen", 1005, 780, 10, 60, $WS_CHILD, -1, $GUI_Sitzung_Basis)
        global $Input_Beginn = GUICtrlCreateInput ( "", 660, 175, 80, 25)
        global $Input_Ende = GUICtrlCreateInput ( "", 660, 220, 80, 25)
        global $Input_Raum = GUICtrlCreateInput ( "", 660, 265, 200, 25)
        GUISetState(@SW_SHOW, $GUI_Sitzung_Basis)
        GUISetState(@SW_SHOW, $gui_Grundlagen)

Alles anzeigen

**alpines**

Normalerweise definiert die Reihenfolge der Controls wie sie erstellt werden die Reihenfolge wie sie fokussiert werden.
Sollte das bei dir nicht klappen, kannst du Accelerators setzen, mitzählen und entsprechend ControlFocus verwenden.

subbafuchs

Wenn ich innerhalb der $GUI_Sitzung_Basis TAB benutze dann stimmt die Reihenfolge der Fokusierung. (von Button_speichern zu Button_abbrechen)

Das Problem tritt nur auf wenn ich in der $gui_Grundlagen ein Input auswähle und dann TAB drücke.
Dann springt die Fokussierung "raus" aus der Gui zum Button_speichern in der $GUI_Sitzung_Basis. Dort funktioniert die Fokusierung dann wieder allerdings wechselt die Fokusierung nie in die $gui_Grundlagen sondern bleibt immer in der $GUI_Sitzung_Basis.

**BugFix**

Leg die TAB-Funktionalität generell auf Accelerator-Keys, dann kannst du das unabhängig vom System definieren und egal in welcher Reihenfolge die Controls erstellt wurden.

Muster:

AutoIt

<#include <WinAPI.au3>


$hGui = GUICreate('Test')
$in3 = GUICtrlCreateInput('', 295, 10, 50, 20)
$in2 = GUICtrlCreateInput('', 180, 10, 50, 20)
$in1 = GUICtrlCreateInput('', 65, 10, 50, 20)


$lb3 = GUICtrlCreateLabel('Input 3', 240, 13, 50, 17)
$lb2 = GUICtrlCreateLabel('Input 2', 125, 13, 50, 17)
$lb1 = GUICtrlCreateLabel('Input 1', 10, 13, 50, 17)
$idDummy = GUICtrlCreateDummy()


Global $aAccKey[1][2] = [['{TAB}', $idDummy]]
GUISetAccelerators($aAccKey)




GUISetState()


While True
	Switch GUIGetMsg()
		Case -3
			Exit
		Case $idDummy
			_Dummy()
	EndSwitch
WEnd




Func _Dummy()
	Local Static $aTabFocus[3] = [$in1, $in2, $in3] ; Reihenfolge bei TAB
	Local $iFokus = _WinAPI_GetDlgCtrlID(ControlGetHandle($hGui, '', ControlGetFocus($hGui)))  ; aktueller Fokus - wenn nicht in TAB-Liste, wird erstes Element der Liste angesprungen
	Local $iIndex = UBound($aTabFocus)
	For $i = 0 To UBound($aTabFocus) -1
		If $aTabFocus[$i] = $iFokus Then
			$iIndex = $i
			ExitLoop
		EndIf
	Next
	$iIndex += 1   ; nächstes Element der Liste wählen
	If $iIndex = UBound($aTabFocus) Then $iIndex = 0
	ControlFocus($hGui, '', $aTabFocus[$iIndex])
EndFunc

Alles anzeigen

Edit: Include eingefügt

**Bitnugger**

AutoIt

<#include <WinAPI.au3>

Hier hat sich ein "<" an den Anfang der ersten Zeile geschmuggelt...