if GuiCtrlRead(var) = 1 then setstate(lock/hide) else setstate(unlock/show)

Candyland

Hey Autoiter's!
ich versuche ein Gui herzustellen welche Autoit Scripte vervollständigt, denke das wird allgemein Builder gennant. Ich konzentriere mich jetzt ersteinmal auf die Probleme die mir begegnen während ich am schreiben davon bin.
Einerseits sind einige checkboxen ausgegraut die nach drücken eines Button/etc aufgeschlossen werden, so das der Benutzer diese jetzt benutzen kann. Allerdings fählt mir keine idee ein wie ich die Checkboxen wieder ausgrauen lassen kann wenn der button erneut gedrückt wird. Ich habe das hier noch überhaupt nicht gelöst ich wählte eine Checkbox die auf 1 gesetzt werden kann & damit die anderen Button aktiviert, sobald die Checkbox auf 0 wieder steht sollen die button wieder ausgegraut werden.
Andererseits beschäftigte ich mich mit der frage wie an eine bereits compilierte Autoit Exe noch code angehangen werden kann. Vielleicht weiß das ja einer der die Topic momentan liest. Ist nicht nötig dafür ein neuen Thread zu öffnen.

Ganz klein & simple hier ein Beispiel code.

AutoIt

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("This is a Form", 360, 85, 450, 414)
$Checkbox1 = GUICtrlCreateCheckbox("Funktion Aktivieren", 120, 8, 113, 17)
$Input1 = GUICtrlCreateInput("Irgendwas", 120, 40, 121, 21)
GUICtrlSetState(-1, $GUI_DISABLE)
$Input = GUICtrlCreateLabel("Input", 80, 40, 28, 17)
$Checkbox2 = GUICtrlCreateCheckbox("Extra", 256, 40, 97, 17)
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Checkbox1
			GUICtrlSetState($Input1, $GUI_ENABLE)
			GUICtrlSetState($Checkbox2, $GUI_ENABLE)
	EndSwitch
;~ 	if GUICtrlRead($Checkbox1) = 0 Then
;~ 		GUICtrlSetState($Input1, $GUI_DISABLE)
;~ 		GUICtrlSetState($Checkbox2, $GUI_DISABLE)
;~ 	EndIf
WEnd

Alles anzeigen

**alpines**

Erstell entweder eine boolean Variable die den aktuellen Status beinhaltet (True = Checked, False = Unchecked) oder schau ob BitAnd(GUICtrlRead($CheckBox), $GUI_CHECKED) true ist.
Je nach dem wie die Abfrage lautet kannst du dann die Checkboxen enablen / disablen.

Candyland

Gut ja hehe das wars, ich hab mich noch bissel dazu belesen & herausgefunden wies geht, aber auch erst mit der anmerkung von alpines mit BitAnd...

hier die lösung vollständigkeitshalber

AutoIt

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("This is a Form", 360, 85, 450, 414)
$Checkbox1 = GUICtrlCreateCheckbox("Funktion Aktivieren", 120, 8, 113, 17)
$Input1 = GUICtrlCreateInput("Irgendwas", 120, 40, 121, 21)
GUICtrlSetState(-1, $GUI_DISABLE)
$Input = GUICtrlCreateLabel("Input", 80, 40, 28, 17)
$Checkbox2 = GUICtrlCreateCheckbox("Extra", 256, 40, 97, 17)
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Checkbox1
			If BitAND(GUICtrlRead($Checkbox1), $GUI_CHECKED) AND BitAND(GUICtrlGetState($Checkbox1), $GUI_ENABLE) Then
			GUICtrlSetState($Input1, $GUI_ENABLE)
			GUICtrlSetState($Checkbox2, $GUI_ENABLE)
			Else
			GUICtrlSetState($Input1, $GUI_DISABLE)
			GUICtrlSetState($Checkbox2, $GUI_DISABLE)
			EndIf
	EndSwitch
WEnd

Alles anzeigen

**alpines**

Ich glaube die Enabled Abfrage kannst du dir sparen da wenn ein Control disabled ist es keine Message abwirft und du nicht in den Case reinspringst.

Candyland

Zitat von alpines

Ich glaube die Enabled Abfrage kannst du dir sparen da wenn ein Control disabled ist es keine Message abwirft und du nicht in den Case reinspringst.

ja so dachte ich auch, allerdings ging dies nicht & soweit ich mich hier belesen habe, scheint das problem genauso gelöst worden zu sein. & solange ich nicht auf unbekannte fehler stoße lasse ich das denke ich mal so

Friesel

Mahlzeit!

Als sehr großer Fan ternärer Operatoren kann ich dir nur folgendes nahe legen:

Spoiler anzeigen

AutoIt

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("This is a Form", 360, 85, 450, 414)
$Checkbox1 = GUICtrlCreateCheckbox("Funktion Aktivieren", 120, 8, 113, 17)
$Input1 = GUICtrlCreateInput("Irgendwas", 120, 40, 121, 21)
GUICtrlSetState(-1, $GUI_DISABLE)
$Input = GUICtrlCreateLabel("Input", 80, 40, 28, 17)
$Checkbox2 = GUICtrlCreateCheckbox("Extra", 256, 40, 97, 17)
GUICtrlSetState(-1, $GUI_DISABLE)
;==> zusätzliches Beispiel
$idHakenMenu = GUICtrlCreateMenu("&Haken Menü")
$idHakenItem = GUICtrlCreateMenuItem("Abgehakt?", $idHakenMenu)
;<== zusätzliches Beispiel
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Checkbox1
			GUICtrlSetState($Input1, (GUICtrlRead($Checkbox1) = $GUI_CHECKED) ? $GUI_ENABLE : $GUI_DISABLE)
			GUICtrlSetState($Checkbox2, (GUICtrlRead($Checkbox1) = $GUI_CHECKED) ? $GUI_ENABLE : $GUI_DISABLE)
		;==> zusätzliches Beispiel
		Case $idHakenItem
			GUICtrlSetState($idHakenItem, (GUICtrlRead($idHakenItem) = 68) ? 65 : 68) ; 68 = $GUI_UNCHECKED + $GUI_ENABLE // 65 = $GUI_CHECKED + $GUI_ENABLE
		;<== zusätzliches Beispiel
	EndSwitch
WEnd

Alles anzeigen

Besonders elegant lässt es sich damit zwischen zwei states eines Controls wechseln.
Siehe im Code mein Beispiel mit dem Menü-Haken.
Der Einfachheit halber habe ich die Konstanten direkt addiert, da Menu Items immer zwei Status haben, allerdings ist von solchen "Magic Numbers" grundsätzlich abzuraten

Beste Grüße, Friesel

Ps: Ternäre Operatoren sind eigendlich sehr einfach, wenn man das Prinzip mal verstanden hat. Ansonsten kannst gerne fragen...

Candyland

Zitat von Friesel

Ps: Ternäre Operatoren sind eigendlich sehr einfach, wenn man das Prinzip mal verstanden hat. Ansonsten kannst gerne fragen...

Ich denke ich werde das verwenden einfach weil ich soetwas noch nie zuvor gesehen habe! c:
ich werde Ternäre Operatoren wohl einige male verwenden müssen, bevor ich es wirklich verstehe c:

Friesel

Hi Candy!

Entschuldige, ich hätte vieleicht doch ein bisschen mehr erklären sollen

Also, "ternär" bedeutet, dass der gesamte Ausdruck aus 3 Teilen besteht:

links vom Fragezeichen steht ein (Boolescher) Ausdruck, der entweder TRUE oder FALSE ergibt (bzw. ergeben MUSS) *
der erste Wert rechts von Fragezeichen (und links vom Doppelpunkt) wird verwendet, wenn der Ausdruck TRUE ergibt
der zweite Wert rechts vom Doppelpunkt wird enspechend beim Ergebnis FALSE verwendet

*kurze Erläuterung zu Booleschen Ausdrücken:

z.B.: (3+4) = (10-3) ergibt TRUE (also 7=7 -> TRUE) / ensprechend ist 3=4 FALSE
hier muss aber nicht zwingend ein Vergleichsausdruck stehen.
Es geht zB auch eine einzelne Variable: Hat diese irgend einen Wert ausser 0 ist sie TRUE. Hat sie keinen Wert, wurde aber deklariert oder hat den Wert 0, ist sie FALSE...

Mein Beispiel mit dem Menü Haken sieht "übersetzt" in If/Then Schreibweise so aus:

AutoIt

If GUICtrlRead($idHakenItem) = $GUI_UNCHECKED + $GUI_ENABLE Then
	GUICtrlSetState($idHakenItem, $GUI_CHECKED + $GUI_ENABLE)
Else
	GUICtrlSetState($idHakenItem, $GUI_UNCHECKED + $GUI_ENABLE)
EndIf

Bitte beachte, dass ich extra die Konstanten und nicht wie vorher die addierten Werte verwendet habe.
Gerade als Anfäger können diese nichtssagenden Zahlen sehr verwirrend sein und so oder so machen Konstanten ein Script sehr viel besser lesbar...

Ich hoffe, das war einigermassen verständlich erklärt.

Beste Grüße, Friesel

**Oscar**

Zitat von Friesel

Bitte beachte, dass ich extra die Konstanten und nicht wie vorher die addierten Werte verwendet habe.
Gerade als Anfäger können diese nichtssagenden Zahlen sehr verwirrend sein und so oder so machen Konstanten ein Script sehr viel besser lesbar...

Es geht nicht nur darum, dass das Script besser lesbar ist, sondern auch darum, dass das Script in Zukunft lauffähig bleibt.
Wenn die AutoIt-Entwickler (warum auch immer) den Wert einer Konstanten ändern, dann funktioniert das Script nicht mehr, wenn man den Wert eingetragen hat.
Deshalb besser die Konstanten verwenden.

Ok, jetzt kommt wahrscheinlich der Einwand mit der GDI+ Konstanten, wo die Konstante geändert wurde.
Ich gebe zu, da haben sich die Entwickler wirklich nicht mit Ruhm bekleckert.

Und noch ein Hinweis zum checken, ob der Haken bei einer Checkbox gesetzt ist:
Verwende: BitAND(GuiCtrlRead($checkbox), $GUI_CHECKED)
Das ist eindeutig, auch wenn der 3State-Modus benutzt wird.

**alpines**

Zitat von Friesel

Als sehr großer Fan ternärer Operatoren kann ich dir nur folgendes nahe legen:

Ist um ehrlich zu sein keine gute Idee wenn Code danach noch kommt.
Wenn ich für die einzelnen If-Zweige noch weitere Sachen erledigen möchte, dann muss ich nach den Zeilen mit den ternären Operatoren nochmal eine If-Verzweigung einbauen weil ich die dort nicht unterkriege.

**BugFix**

Zitat von Friesel

$GUI_CHECKED + $GUI_ENABLE

Poooh - DAS kann tödlich sein. Nicht in diesem Fall, aber Konstanten enthalten oft Kombinationen von Werten. Wenn du dann addierst, wird unter Umständen eine völlig andere Kombination als gewollt entstehen.
Deshalb dafür ausschliesslich BitOr verwenden (so wie bei der Abfrage BitAnd).

AutoIt

$a = BitOR(1,2,4,8)
ConsoleWrite('Result: ' & $a & @CRLF)


$a = (1+2+4+8)
ConsoleWrite('Result like before: ' & $a & @CRLF)


$a = BitOR(1,2,4,8,4,8) ; 4 and 8 2-times ==> BUT NOT added!!
ConsoleWrite('Result: ' & $a & @CRLF)


$a = (1+2+4+8+4+8) ; 4 and 8 2-times ==> AND ALSO added!!
ConsoleWrite('Result is different: ' & $a & @CRLF)

Alles anzeigen

Friesel

Zitat von alpines

Ist um ehrlich zu sein keine gute Idee wenn Code danach noch kommt.Wenn ich für die einzelnen If-Zweige noch weitere Sachen erledigen möchte, dann muss ich nach den Zeilen mit den ternären Operatoren nochmal eine If-Verzweigung einbauen weil ich die dort nicht unterkriege.

Wenn man sich genug Mühe gibt, kann man alles schlecht reden

Ich sage ja nicht dass man ternäre Operatoren immer und überall benutzen sollte. Für den gegebenen Fall von Candyland halte ich sie aber für sehr geeignet.

Ich benutze zB sowas, wenn ich eine GUI initialisiere, bei der die Einstellungen in der Registry gespeichert sind.
Da hab ich sogar quasi 3 states: Ein, Aus und Default (wobei Default natürlich auch entweder Ein oder Aus ist).
So zum Beispiel:

AutoIt

GUICtrlSetState($idCheckBox, (RegRead("HKEY_CURRENT_USER\Software\Irgendwas", "Irgendwas anderes") = $GUI_UNCHECKED) ? $GUI_UNCHECKED : $GUI_CHECKED)

Wenn der Registry Wert nicht existiert (Default) wird $GUI_CHECKED übergeben.
Ansonsten wird der state aus dem vorhandenen Registry Schlüssel ausgelesen.

Zitat von BugFix

Poooh - DAS kann tödlich sein. Nicht in diesem Fall, aber Konstanten enthalten oft Kombinationen von Werten. Wenn du dann addierst, wird unter Umständen eine völlig andere Kombination als gewollt entstehen.Deshalb dafür ausschliesslich BitOr verwenden (so wie bei der Abfrage BitAnd).

Ich bin mir der Problematik durchaus bewußt. Habe mich auch immer dran gehalten BitOr zu verwenden, bis ich neulich nach 2-Jähriger AutoIt Abstinenz folgendes im Helpfile gelesen habe:

Zitat von GUICtrlSetState

State values can be summed up as for example $GUI_DISABLE (128) + $GUI_HIDE (32) sets the control in an disabled and hidden state.

Bei Styles und ähnlichem nutze ich aber weiterhin BitOr, keine Angst

Beste Grüße, Friesel

**alpines**

Zitat von Friesel

Ich benutze zB sowas, wenn ich eine GUI initialisiere, bei der die Einstellungen in der Registry gespeichert sind.

Ja keine Frage, ist sicherlich ziemlich praktisch, aber ich wills nur erwähnt haben damit @Candyland nicht auf die Idee kommt die zu nutzen und danach If-Verzweigungen mit den selben Bedingungen einzubauen.

Zitat von Friesel

bis ich neulich nach 2-Jähriger AutoIt Abstinenz folgendes im Helpfile gelesen habe

Das gilt aber leider nicht bei allen Konstanten und genau dort liegt das Problem begraben.

Candyland

Puuh da habe ich aber eine Diskusion angetreten. Also Friesel's Ternäre Operatoren habe ich eingebaut einfach auch weil ich nie einen sinn für '?' ':' gesehen habe. Ich habe mich lange gefragt wo diese Zeichen mal verwendet werden. Pro ist aufjedenfall das ich die hälfte an Code einsparen konnte durch den wechsel zu Ifthen, da freut sich der Imperator .. eehh Interpreter mein ich & ich mich auch weil das script übersichtlicher geworden ist. Danke auch für die Erklärung, diese habe ich mir schon von Google geben lassen, da ich mich gefragt habe wo Ternäre Operatoren zum Einsatz kommen, dennoch schön das mal auf der Muttersprache zu lesen.
Ich denke mehr kann ich hierzu nicht mehr schreiben, ich habe eine Lösung von euch angenommen & diese gefällt mir auch. Heute liegt mein Focus mal etwas auf verschlüsselungen :p