Ausgabe von ConsoleWrite anschauen

Spangenberg

Ich habe mein Skript zur Fehleranalyse mit Trace Lines versehen, z.B.:

ConsoleWrite('>Error code: ' & @error & @CRLF & @CRLF & '@@ Trace(1113) : $StartPositionenIndex = $Konten[9][$Konto]' & @CRLF) ;### Trace Console

Wie kann ich den STDOUT Stream mir anschauen bzw. in eine Datei oder in einen geöffneten Editor umleiten?

Ich starte das Skript eigenstädig, also nicht in SciTE.

**alpines**

Du kannst es über die CMD starten, so wird der StdOut in die CMD geleitet.
Wenn du es in einer Datei haben willst dann so cmd: script.au3 >> debug.txt.

Spangenberg

Danke, gibt es auch die Möglichkeit innerhalb des Skriptes die Umleitung in eine Datei einzurichten?

Micha_he

Ich mach das immer über eine globale Variable (z.B. Global $bDebug = False) im Script.
Diese stelle ich dann auf True zum debuggen... und anschließend wieder zurück auf False, wenn das Debuggen erledigt ist.

Ich Script dann:

If $bDebug = True Then FileWrite(...)

Es gibt auch noch ein _FileWriteLog() in der UDF 'File.au3', die Du dann noch includen musst.

Spangenberg

Ich wollte die Tracer Lines (s.o.) benutzen, da ich diese bereits automatisch formuliert sind und das Skript nicht über eine batch Datei starten.

Wie kann ich die STDOUT innerhalb des Skriptes umleiten?

**alpines**

Du kannst den Standardoutput nicht umleiten, er heißt ja eben Standardoutput.
Im Skript kannst du In den StdOut oder ErrOut schreiben aber nicht entscheiden was damit angefangen werden soll.
Das ist ja schließlich nicht der Sinn vom Programm. Das Programm teilt nur mit das was passiert ist und das Parentprogramm soll sich um das Auslesen / Speichern davon kümmern.

**Bitnugger**

Meinst du das in etwa so?

Redirect

AutoIt

;-- TIME_STAMP   2017-04-02 18:39:32   v 0.1


#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>


Global $g_iPID, $g_sOutput, $g_sCMD = 'Dir /B /AD ' & @UserProfileDir


_Read_CMD_Output()
_Redirect_CMD_OutputToFile()
_Redirect_CMD_OutputToEditor()


Func _Read_CMD_Output()
	$g_iPID = Run(@ComSpec & " /c " & $g_sCMD, '', @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)


	$g_sOutput = "StdoutRead_____________" & @CRLF
	While 1
		$g_sOutput &= StdoutRead($g_iPID)
		If @error Then ExitLoop ; Exit the loop if the process closes or StdoutRead returns an error.
	WEnd


	$g_sOutput &= @CRLF & @CRLF & "StderrRead_____________" & @CRLF
	While 1
		$g_sOutput &= StderrRead($g_iPID)
		If @error Then ExitLoop ; Exit the loop if the process closes or StderrRead returns an error.
	WEnd
	MsgBox($MB_SYSTEMMODAL, "Stdout Read / Stderr Read:", $g_sOutput)
EndFunc


Func _Redirect_CMD_OutputToFile()
	; Redirect StdoutRead & StderrRead --> 2>&1>
	; https://technet.microsoft.com/en-us/library/bb490982.aspx
	RunWait(@ComSpec & " /c " & $g_sCMD & ' 2>&1> ' & @TempDir & '\CMDOUT.txt', '', @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)


	$g_sOutput = "'FileRead(@TempDir & '\CMDOUT.txt')" & @CRLF & @CRLF
	$g_sOutput &= FileRead(@TempDir & '\CMDOUT.txt')
	MsgBox($MB_SYSTEMMODAL, "Stdout Read / Stderr Read:", $g_sOutput)


	; delete the file
	FileDelete(@TempDir & '\CMDOUT.txt')
EndFunc


Func _Redirect_CMD_OutputToEditor()
	RunWait(@ComSpec & " /c " & $g_sCMD & ' 2>&1> ' & @TempDir & '\CMDOUT.txt', '', @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)


	; Open the file in our default editor
	ShellExecute(@TempDir & '\CMDOUT.txt')
	Sleep(3000)


	; delete the file
	FileDelete(@TempDir & '\CMDOUT.txt')
EndFunc

Alles anzeigen