Ich mag erkennen in welcher Zeile "If" zuspricht

Peter Sativa

Ich will es in meinem Programm so machen, dass der Input als Textdatei gespeichert wird und der Benutzer alle Texte danach als Ouput bekommen kann. Das entscheidende liegt bei Zeile 52-64.

AutoIt

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <File.au3>
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
If Not DirGetSize("documents\p19data") Then
   DirCreate("documents\p19data")
   DirCreate("documents\p19data\input")
   DirCreate("documents\p19data")
   DirCreate("documents\p19data\output")
EndIf
If Not FileExists("documents\p19data\input\data.txt") Then
   _FileCreate("documents\p19data\input\data.txt")
   FileOpen("documents\p19data\input\data.txt")
   FileWriteLine("documents\p19data\input\data.txt","")
   FileClose("documents\p19data\input\data.txt")
EndIf
If Not FileExists("documents\p19data\output\data.txt") Then
   _FileCreate("documents\p19data\output\data.txt")
   FileOpen("documents\p19data\output\data.txt")
   FileWriteLine("documents\p19data\output\data.txt","")
   FileClose("documents\p19data\output\data.txt")
EndIf
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
HotKeySet("{F5}","antwort")
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
$formp19 = GUICreate("P19", 480, 270, 694, 228)
$input = GUICtrlCreateInput("", 30, 24, 425, 28)
GUICtrlSetBkColor(-1, 0xAEFFFF)
GUICtrlSetFont(-1, 11, 400, 0, "Segoe UI Semilight")
$output = GUICtrlCreateLabel("", 42, 75, 398, 148, $WS_BORDER)
GUICtrlSetFont(-1, 14, 400, 0, "Segoe UI Semilight")
GUICtrlSetBkColor(-1, 0xAEFFFF)
GUISetState(@SW_SHOW)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		 Case $GUI_EVENT_CLOSE
			ExitLoop
   EndSwitch
WEnd


Func antwort()
   $data = GUICtrlRead($input)
   $r2 = Random(1,2,1)
   $icount = _FileCountLines("documents\p19data\input\data.txt")
   $ocount = _FileCountLines("documents\p19data\output\data.txt")
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   $wait= If StringInStr($data,$idata[1<99]) Then
   EndIf
   For $icount = 1 To $wait [Step 1]
   next
	  GUICtrlSetData($output,$odata[])
   EndIf
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   If Not StringInStr($data,$idata[1<99999]) Then
	  FileOpen("documents\p19data\input\data.txt")
	  FileOpen("documents\p19data\input\data.txt")
	  FileWriteLine("documents\p19data\input\data.txt","")
	  FileClose("documents\p19data\input\data.txt")
	  Do
		 sleep(100)
	  Until _IsPressed("0D")
	  FileOpen("documents\p19data\output\data.txt")
	  FileWriteLine("documents\p19data\output\data.txt","")
	  FileClose("documents\p19data\output\data.txt")
	  GUICtrlSetData($output,"Okay, danke")
   EndIf

Alles anzeigen

**autoiter**

Hallo @Peter Sativa,
Ich kann mit deinem Code Zeile 52-64 nichts anfangen und habe nur Kommentare dazu, anhand derer du vielleicht noch mal prüfst, was du da tun möchtest und ob das so geht?

AutoIt

$icount = _FileCountLines("documents\p19data\input\data.txt") ; $icount hat also bspw. den Wert 50. Nur wozu? Siehe Zeile 58.
   $ocount = _FileCountLines("documents\p19data\output\data.txt")
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   $wait= If StringInStr($data,$idata[1<99]) Then ; Lass dir mal den Wert von $wait ausgeben (von 1 bis zum Wert von $wait soll ja die Schleife laufen..) ..Und?
   EndIf
   For $icount = 1 To $wait [Step 1] ; $icount ist hier nur die lokale Zähler-Variable, die in jedem Durchlauf einen neuen Wert bekommt. Warum Zeile 52? [Step 1] ist unnötig und die eckigen Klammern werfen keinen Fehler aus?
   next
	  GUICtrlSetData($output,$odata[]) ; Was ist $odata[]? Ist das korrekte Syntax?
   EndIf
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   If Not StringInStr($data,$idata[1<99999]) Then ; Was ist $idata[1<99999]? Geht das?

Alles anzeigen

**alpines**

Zitat von autoiter

; Was ist $odata[]? Ist das korrekte Syntax?

Nein.

Zitat von autoiter

; Was ist $idata[1<99999]? Geht das?

Nein.

Er möchte vermutlich schauen ob irgendein Index von $idata in $data vorkommt. Das kann man mit einer For-Schleife machen und nicht so.

**autoiter**

Ah, danke dir @alpines,

da habe ich wieder etwas gelernt.

**alpines**

Zitat von autoiter

da habe ich wieder etwas gelernt.

Streng genommen ist $aData[] möglich, aber nur bei der Deklarierung von Arrays wenn man die Größe nicht angeben will (wenn man die Werte direkt zuweist).
Local $aData[] = [1, 2, 3, 4, 5]

Peter Sativa

@alpines @autoiter Und wie macht mán das, dass ich alles von 1-99 auswähle ohne jede zahl einzeln zu schreiben und wie bekomme ich das hin, dass das Programm ausgibt in welcher zeile es das wort gefunden hat?

**autoiter**

Genau streng genommen, ist das was er da macht aber natürlich nicht möglich.Klar kann man schreiben.

AutoIt

Local $aData[]

Aber nicht:

AutoIt

; ...
$aData[]
; ...
; ...


; oder 


GUICtrlSetData($output,$odata[])

**alpines**

Das machst du mit einer For-Schleife. UBound gibt dir die Größe des Arrays zurück. Die For-Schleife läuft von Index 0 bis zum letzten Index und vergleicht die Strings.
Wenn es einen gefunden hast, so löst die If-Bedingung aus.

AutoIt

$sData ;Den String den du durchsuchen willst
$aData ;Das Array mit all den Suchstrings


For $i = 0 To UBound($aData) - 1
	If StringInStr($sData, $aData[$i]) Then
		;Gefunden
	EndIf
Next

Peter Sativa

@alpines Jetzt habe ich nur noch ein kleines Problem: Wie weiß das Programm in WELCHE ZEILE der Substring gefunden wurde?

**alpines**

Zitat von Peter Sativa

Jetzt habe ich nur noch ein kleines Problem: Wie weiß das Programm in WELCHE ZEILE der Substring gefunden wurde?

Du meinst welcher Index von $aData den Treffer erzielt hat? Wie wäre es denn mit $i?

Peter Sativa

@alpines Ich habe jetzt dashier daraus gemacht aber es funktioniert immernoch nicht

AutoIt

$data = GUICtrlRead($input)
   $aData = FileRead("documents\p19data\input\data.txt")
   For $i = 0 To UBound($aData) - 1
	  If StringInStr($data, $aData[$i]) Then
		   $zeile = FileReadLine("documents\p19data\input\data.txt",$i)
		   GUICtrlSetData($output,$zeile)
		 Else
		   FileOpen("documents\p19data\input\data.txt")
		 FileOpen("documents\p19data\input\data.txt")
		 FileWriteLine("documents\p19data\input\data.txt","")
		 FileClose("documents\p19data\input\data.txt")
		 Do
			sleep(100)
		 Until _IsPressed("0D")
		 FileOpen("documents\p19data\output\data.txt")
		 FileWriteLine("documents\p19data\output\data.txt","")
		 FileClose("documents\p19data\output\data.txt")
		 GUICtrlSetData($output,"Okay, danke")
	  EndIf
   Next

Alles anzeigen

**alpines**

Zitat von Peter Sativa

$aData = FileRead("documents\p19data\input\data.txt")

Was erwartest du soll denn von FileRead zurückkommen? Das liefert einen String und kein Array!
Du musst den Return davon mit @CRLF splitten wenn du es zeilenweise haben willst.

Peter Sativa

@alpines Ich verstehe nicht ganz wie ich den Return mit @CRLD splitten kann

**alpines**

Zitat von Peter Sativa

@alpines Ich verstehe nicht ganz wie ich den Return mit @CRLD splitten kann

Wenn du das nicht verstehst solltest du erstmal die Grundlagen von AutoIt lernen und nach entsprechenden Befehlen googlen sowie die Hilfe durchforsten.
Du wirst hier nicht alles häppchengerecht auf dem Silbertablett serviert bekommen.

Bei deinem Code sind sehr heftige Fehler enthalten die mittels grundlegenden Kentnissen nicht passieren würden.
Deshalb fasse es nicht als abwertigende Bemerkung oder Beleidigung auf aber du tust uns und dir selbst einen Gefallen wenn du die Grundlagen lernst und sie dann richtig anwendest.

Fragen stellen kannst du danach immer noch.

Zitat von Peter Sativa

FileOpen("documents\p19data\input\data.txt")
FileWriteLine("documents\p19data\input\data.txt","")
FileClose("documents\p19data\input\data.txt")

Schau dir mal bitte die Befehle in der Hilfe an. So wie du sie verwendest ist es falsch.

**Bitnugger**

Demo ;-)

AutoIt

;-- TIME_STAMP   2017-04-29 22:59:06   v 0.1


#Region ;************ Includes ************
#include <GUIConstantsEx.au3>
#include <ScrollBarsConstants.au3>


#include <Array.au3>
#include <GuiEdit.au3>
#EndRegion ;************ Includes ************


Global $g_sSpacer = '------------------------------------------------------------------------' & @CRLF


Global $g_idEdit_aData, $g_idButton_OK, $g_idButton_ArrayDisplay, $g_idButton_Demo1, $g_idButton_Demo2, $g_idButton_EXIT


Global $g_sData = 'Test' ; Der gesuchte String
Global $g_aData = ['Probe', 'Test', 'Demo', 'Versuch'] ; Das zu durchsuchende Array


_ShowData()


Func _ShowData()
	#Region - GUI Create
	Local $hGUI = GUICreate(@ScriptName, 800, 400)
	GUISetBkColor(0x2F2F2F, $hGUI)
	GUISetState()
	$g_idEdit_aData = GUICtrlCreateEdit('', 0, 0, 800, 350)
	GUICtrlSetColor($g_idEdit_aData, 0x00FF00)
	GUICtrlSetFont($g_idEdit_aData, 9, 800, 0, 'Courier New')
	GUICtrlSetState($g_idEdit_aData, $GUI_HIDE)
	$g_idButton_ArrayDisplay = GUICtrlCreateButton('_ArrayDisplay($g_aData, "$g_aData")', 0, 350, 400, 50)
	GUICtrlSetState($g_idButton_ArrayDisplay, $GUI_HIDE)
	$g_idButton_OK = GUICtrlCreateButton('OK', 400, 350, 400, 50)
	GUICtrlSetState($g_idButton_OK, $GUI_HIDE)
	$g_idButton_Demo1 = GUICtrlCreateButton('Demo 1 - Suche "Test"', 0, 0, 400, 350)
	$g_idButton_Demo2 = GUICtrlCreateButton('Demo 2 - Suche "Func"', 400, 0, 400, 350)
	$g_idButton_EXIT = GUICtrlCreateButton('EXIT', 0, 350, 800, 50)
	#EndRegion - GUI Create


	#Region - GUI SelectLoop
	While 1
		$msg = GUIGetMsg()
		Select
			Case $msg = $GUI_EVENT_CLOSE Or $msg = $g_idButton_EXIT
				GUIDelete()
				ExitLoop
			Case $msg = $g_idButton_Demo1
				GUICtrlSetState($g_idButton_Demo1, $GUI_HIDE)
				GUICtrlSetState($g_idButton_Demo2, $GUI_HIDE)
				GUICtrlSetState($g_idButton_EXIT, $GUI_HIDE)
				GUICtrlSetState($g_idEdit_aData, $GUI_SHOW)
				_Demo1()
			Case $msg = $g_idButton_Demo2
				GUICtrlSetState($g_idButton_Demo1, $GUI_HIDE)
				GUICtrlSetState($g_idButton_Demo2, $GUI_HIDE)
				GUICtrlSetState($g_idButton_EXIT, $GUI_HIDE)
				GUICtrlSetState($g_idEdit_aData, $GUI_SHOW)
				Local $sData = $g_sData, $aData = $g_aData
				_Demo2()
				$g_sData = $sData
				$g_aData = $aData
			Case $msg = $g_idButton_ArrayDisplay
				_ArrayDisplay($g_aData, '$g_aData')
			Case $msg = $g_idButton_OK
				GUICtrlSetData($g_idEdit_aData, '')
				GUICtrlSetState($g_idButton_Demo1, $GUI_SHOW)
				GUICtrlSetState($g_idButton_Demo2, $GUI_SHOW)
				GUICtrlSetState($g_idButton_EXIT, $GUI_SHOW)
				GUICtrlSetState($g_idButton_ArrayDisplay, $GUI_HIDE)
				GUICtrlSetState($g_idButton_OK, $GUI_HIDE)
				GUICtrlSetState($g_idEdit_aData, $GUI_HIDE)
		EndSelect
	WEnd
	#EndRegion - GUI SelectLoop
EndFunc   ;==>_ShowData


Func _Demo1()
	Local $iBINGO = 1
	For $i = 0 To UBound($g_aData) - 1
		If StringInStr($g_aData[$i], $g_sData) Then
			GUICtrlSetData($g_idEdit_aData, 'Bingo (' & $iBINGO & ') - der String "' & $g_sData & '" wurde in $aData[$i] gefunden! ;-)' & @CRLF & @CRLF & _
					' $i         = ' & $i & @CRLF & @CRLF & _
					' $aData[$i] = "' & $g_aData[$i] & '"' & @CRLF & @CRLF & _
					' $aData[ 0] = "' & $g_aData[0] & '"' & @CRLF & _
					' $aData[ 1] = "' & $g_aData[1] & '"' & @CRLF & _
					' $aData[ 2] = "' & $g_aData[2] & '"' & @CRLF & _
					' $aData[ n] = "..."' & @CRLF & $g_sSpacer, 1)
			$iBINGO += 1
		EndIf
	Next
	_GUICtrlEdit_ScrollToTop($g_idEdit_aData)
	GUICtrlSetState($g_idButton_ArrayDisplay, $GUI_SHOW)
	GUICtrlSetState($g_idButton_OK, $GUI_SHOW)
EndFunc   ;==>_Demo1


Func _Demo2()
	Local $iBINGO = 1, $a, $z
	$g_sData = 'Func'
	$g_aData = FileRead(@ScriptFullPath)


;~ 	ConsoleWrite($g_sSpacer & $g_aData & @CRLF & $g_sSpacer)


	$g_aData = StringSplit($g_aData, @CRLF, 3) ; 1 = entire delimiter string is needed to mark the split, 2 = disable the return count


	For $i = 0 To UBound($g_aData) - 1
		If StringInStr($g_aData[$i], $g_sData) Then
			$a = ($i > 0) ? $i - 1 : 0
			$z = ($i + 3 < UBound($g_aData) - 1) ? $i + 3 : $i
			GUICtrlSetData($g_idEdit_aData, 'Bingo (' & $iBINGO & ') - der String "' & $g_sData & '" wurde in $aData[$i] gefunden! ;-)' & @CRLF & @CRLF & _
					' $i           = ' & $i & @CRLF & @CRLF & _
					' $aData[ $i]  = "' & $g_aData[$i] & '"' & @CRLF & @CRLF, 1)
			For $n = $a To $z
				GUICtrlSetData($g_idEdit_aData, ' $aData[' & _FO($n) & ']  = "' & $g_aData[$n] & '"' & @CRLF, 1)
			Next
			GUICtrlSetData($g_idEdit_aData, $g_sSpacer, 1)
			$iBINGO += 1
		EndIf
	Next
	_GUICtrlEdit_ScrollToTop($g_idEdit_aData)
	GUICtrlSetState($g_idButton_ArrayDisplay, $GUI_SHOW)
	GUICtrlSetState($g_idButton_OK, $GUI_SHOW)
EndFunc   ;==>_Demo2


Func _FO($vNum)
	Return StringRight('  ' & $vNum, 3)
EndFunc   ;==>_FO


Func _GUICtrlEdit_ScrollToTop($idEdit)
	_GUICtrlEdit_LineScroll($idEdit, 0, - _GUICtrlEdit_GetLineCount($idEdit))
EndFunc   ;==>_ScrollToTop

Alles anzeigen