Teilstring einer Variable ab letztem Zeichen

Decide

Hallo zusammen,

bisher konnte ich alles was ich hilfsmäßig benötigt habe, immer im Forum finden. Nun komme ich aber an einer Stelle nicht weiter und vielleicht weiß einer hier Rat.

Ich habe einen Text, in dem Fall eine URL von einer Subdomain, der in eine Variable übergeht und benötge jetzt dafür die Teilstrings bis zum ersten und vom letzten Punkt.
Beispiel:
domainurl.test.com

Davon brauche ich quasi
domainurl und com

Zum Testen bring ich das in eine MsgBox und habe das schon mit SplitStringTeilstring gemacht. Der erste Teil domainurl ist damit kein Problem, allerdings bekomme ich das com nicht raus.
Wenn ich SplitStringTeilstring nutze bekomme ich domainurl und test.

Daher die Frage ob es die Möglichkeit gibt, den String ab dem letzten Punkt zu bekommen? Da dieser nicht immer 3-stellig ist, kann man ja schlecht mir StringRight arbeiten, oder?

Danke vorab und Gruß Björn

Hier mal der aktuelle Code:

C

; Begin AutoIt Includes
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>
#include <Misc.au3>
#include <File.au3>


; End AutoIt Includes


; Variables
	$Input_URL_Beispiel = "URL hier eingeben"
	$URLFront = "Teil1"
	$URLMiddle = "Teil2"
	$URLEnd = "Teil3"




; Begin Menue
$Form1 = GUICreate("Hauptmenue", 331, 153, 783, 463)
$Button_Create = GUICtrlCreateButton("Create", 224, 112, 97, 25)
$Button_Beenden = GUICtrlCreateButton("Beenden", 8, 112, 99, 25)
$Input_URL = GUICtrlCreateInput($Input_URL_Beispiel, 16, 72, 297, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_CENTER, $WS_BORDER))
GUICtrlSetFont (-1,9, 800); bold
GUISetState(@SW_SHOW)




While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit


		Case $Button_Beenden
			Exit


		Case $GUI_EVENT_PRIMARYDOWN
			$Input_URL_Leer = GUIGetCursorInfo()
					If IsArray($Input_URL_Leer) Then
						If $Input_URL_Leer[4] = $Input_URL Then
							GUICtrlSetData($Input_URL, "")
						Else
					EndIf
				EndIf


		Case $Button_Create
				$URL = GUICtrlRead($Input_URL)
				_Single()


	EndSwitch
WEnd
; End Menue


Func _Single()






		MsgBox(64, "Information", $URLFront & StringSplitTeilstring ($URL, ".", 1) & $URLMiddle & StringSplitTeilstring ($URL, ".",2) & $URLEnd, $BS_Left)


EndFunc




Func StringSplitTeilstring ($sString, $sDelimiters, $iNummer)
    Local $aTEMP


    $aTEMP = StringSplit ($sString, $sDelimiters, 0)
    Return($aTEMP[$iNummer])
EndFunc

Alles anzeigen

**alpines**

Wo genau liegt denn das Problem? Nimm doch dafür entweder die Zahl die in $aTEMP[0] steht (Anzahl der Funde) oder nimm UBound um die Größe des Arrays zu ermitteln.

Kleines Beispiel:

AutoIt

#include <Array.au3>


Local $sString = "domain.blablubb.com"
Local $aSplit_1 = StringSplit($sString, ".")
Local $aSplit_2 = StringSplit($sString, ".", 3)


_ArrayDisplay($aSplit_1, "Split")
_ArrayDisplay($aSplit_2, "Split mit Flag 3")


MsgBox(64, "Letzter Eintrag", "Letzter Eintrag: " & $aSplit_1[$aSplit_1[0]])
MsgBox(64, "Letzter Eintrag", "Letzter Eintrag: " & $aSplit_1[UBound($aSplit_1) - 1])

Alles anzeigen

**BugFix**

Oder mit StringRegExpReplace

AutoIt

$url = 'domainurl.test.com'


$sFirst = StringRegExpReplace($url, '([^.]+).+', '$1')
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $sFirst --> " & $sFirst & @LF)


$sLast = StringRegExpReplace($url, '.+\.([^.]+)$', '$1')
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $sLast --> " & $sLast & @LF)

Candyland

Da gibt es unmengen an möglichkeiten.

AutoIt

Local $sString, $Domain, $DotWhat
$sString = "sahnigedomain.kloete.security"


$Domain = StringLeft($sString, StringInStr($sString, '.', 0) - 1)
$DotWhat = StringTrimLeft($sString, StringInStr($sString, '.', 0, -1))


ConsoleWrite($Domain & @CRLF & $DotWhat & @CRLF)

Decide

Danke für die Unterstützung an Euch drei.

**alpines**

Zitat von Decide

Danke für die Unterstützung an Euch drei.

Und wie schauts nun aus?

horphi

Hallo,

ich hätte dazu ein Frage:

Kann man den Suchausdruck auch so anpassen, das er erst am dem 3. Punkt anfängt zu suchen und alles bis zum nächsten Punkt ausgibt?

Grüße,

horphi

**alpines**

Zitat von horphi

Kann man den Suchausdruck auch so anpassen, das er erst am dem 3. Punkt anfängt zu suchen und alles bis zum nächsten Punkt ausgibt?

Natürlich geht das, du splittest das ganze und lässt den Index [3] ausgeben. Solltest vorher natürlich prüfen, ob er existiert.

horphi

Hallo Alpines,

ich würde das gerne im StringRegExpReplace ausführen, da ich aus einem Textfile lese und nicht vorher einen Array erstellen möchte.

AutoIt

StringRegExpReplace($url, '([^;]*;){4}[^;]*?')

--> ich möchte hier erst den Wert NACH dem 4. Semikolon ausgegeben bekommen. Er zählt mir aber alles inkl des 4. Semikolons...

Ich weiß nicht, wie ich das ändern kann.

VG

horphi

**BugFix**

@horphi

AutoIt

$s = "eins;zwei;drei;vier;fünf;sechs"
$aMatch = StringRegExp($s, "(?:[^;]+;){4}([^;]+)", 1)
If Not @error Then
	ConsoleWrite('Eintrag nach 4. Semikolon: ' & $aMatch[0] & @CRLF)
EndIf

horphi

@BugFix

Mensch...was ein paar kleine Zeichen so schon ausmachen können.

VIELEN DANK!

horphi

Hi

ich muss noch mal nachfragen.

Beim StringRegExp funktioniert der Ausdruck.

Wenn ich aber StringRegExpReplace benutze, wird mir der gänderte Wert und der Rest der Zeile ausgegeben.

Wie kann ich das ändern, dass der ganze geänderten outputstring = dem inputstring entsprichtg?

AutoIt

$url = 'CN_OP;71507;false;"0620";"SD";0;8;;0.0;1091;1;39.0;23.4;"IM";false;1;8099;0;true;"";0.0;;;"";;"Dz";"V5";"6W";"O45";"A002";100.0;"00038.999";"P";"0";0.0;false;false;false;0.0;false;"ASSY";false;"V5";"B";279;false;"";"Type1";"";"V5";;;"";0.0;false;false;"";"";"";true'
$icol = 10
$sFirst = StringRegExp ($url, '(?:[^;]*;){45}([^;]+)', 1)
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $sFirst --> " & $sFirst[0] & @LF)


$sLast = StringRegExpReplace($url, '(?:[^;]*;){45}([^;]*[^;])', 'true',1)
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $sLast --> " & $sLast & @LF)

Gruß,

horphi

**Kanashius**

Garnicht, da das nicht der Rückgabe von StringRegExpReplace entspricht.
Normal will man nicht wissen, was ersetzt wurde, da genau das ja schon angegeben wurde und auch ersetzt wurde. Du musst also erst stringregexp machen und dann das stringregexpreplace drüberlaufen lassen.