Lautstärke einstellen Windows - SoundSetWaveVolume - Bass udf

;-- TIME_STAMP   2017-06-14 15:15:04   v 1.1


Global $g_sNIRCMD = (@OSArch = 'X64') ? 'F:\Progdir\NirSoft Utilities\x64\nircmd.exe' : 'F:\Progdir\NirSoft Utilities\nircmd.exe'


; #FUNCTION# ====================================================================================================================
; Name ..........: _ChangeSysVolume
; Description ...:
; Syntax ........: _ChangeSysVolume($vVolume)
; Parameters ....: $vVolume             - a variant value.
;                                         Volume in percent: min. = 0%, max. = 100%
;                                         Volume in integer: min. = 0, max. = 65535
; Return values .: Success: the exit code from nircmd.exe
;                  Failure: 0 and sets the @error flag to non-zero
; Author ........: Bitnugger
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: Yes
; _ChangeSysVolume('80%')
; _ChangeSysVolume(25600)
; ===============================================================================================================================
Func _ChangeSysVolume($vVolume)
	Switch True
		Case FileExists($g_sNIRCMD) = 0
			MsgBox(262160, 'Error', 'nircmd.exe not found...')
			Return SetError(1, 0, 0)
		Case StringInStr($vVolume, '%') > 0
			$vVolume = Int($vVolume)
			If StringIsDigit($vVolume) = 0 Or $vVolume < 0 Or $vVolume > 100 Then
				MsgBox(262160, 'Error', '$vVolume is out of range (0% - 100%) --> ' & $vVolume)
				Return SetError(2, 0, 0)
			EndIf
			$vVolume *= 65535 / 100
		Case StringIsDigit($vVolume) = 0 Or $vVolume < 0 Or $vVolume > 65535
			MsgBox(262160, 'Error', '$vVolume is out of range (0 - 65535) --> ' & $vVolume)
			Return SetError(3, 0, 0)
	EndSwitch


	Return RunWait(StringFormat('"%s" %s %i', $g_sNIRCMD, 'setsysvolume', $vVolume), '', @SW_HIDE, $STDOUT_CHILD)
EndFunc   ;==>_ChangeSysVolume


; #FUNCTION# ====================================================================================================================
; Name ..........: _MuteSysVolume
; Description ...:
; Syntax ........: _MuteSysVolume([$iState = 2])
; Parameters ....: $iState              - [optional] an integer value. Default is 2.
;                                         1 = Mute the system volume
;                                         0 = Unmute the system volume
;                                         2 = Switch the system volume between the mute and normal state
; Return values .: Success: the exit code from nircmd.exe
;                  Failure: 0 and sets the @error flag to non-zero
; Author ........: Bitnugger
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: Yes
; _MuteSysVolume()
; _MuteSysVolume(1)
; ===============================================================================================================================
Func _MuteSysVolume($iState = 2)
	Switch True
		Case FileExists($g_sNIRCMD) = 0
			MsgBox(262160, 'Error', 'nircmd.exe not found...')
			Return SetError(1, 0, 0)
		Case $iState = 0 Or $iState = 1 Or $iState = 2
			Return RunWait(StringFormat('"%s" %s %i', $g_sNIRCMD, 'mutesysvolume', $iState), '', @SW_HIDE, $STDOUT_CHILD)
		Case Else
			MsgBox(262160, 'Error', '$iState is out of range (0, 1 or 2)')
			Return SetError(2, 0, 0)
	EndSwitch
EndFunc   ;==>_MuteSysVolume