Status von Service abfragen

dieselwiesel

Hi @ll

Möchte von mehreren Servicen den Status abfragen und als ein Ergebnis zurückbekommen, sprich wenn alle (in dem Fall) 3 laufen ist es TRUE, wenn einer nicht läuft ERROR und wenn die Services nicht installiert sind ist es NULL. Habe es mit StdoutRead probiert, komme aber nur bis zur Auflistung des jeweiligen Status. Wer kann mir da evtl. weiterhelfen?

AutoIt

#include <AutoItConstants.au3>

Global $service[3]
$service[0] = 'Service1'
$service[1] = 'Service2'
$service[2] = 'Service3'

MsgBox(0, "", _check())


Func _check()

    Local $aService

    For $i = 0 To UBound($service) - 1
        $match = cmdread('sc.exe query ', $service[$i], ' | findstr /R /I /C:"\<state"')
        $aService &= $match ;& @CRLF
    Next

    Return $aService

EndFunc

Func cmdread($cmd1, $cmd2, $cmd3)

    Global $sOutput = ""
    Local $iPID = Run(@ComSpec & ' /c ' & $cmd1 & $cmd2 & $cmd3, @SystemDir, @SW_HIDE, $STDERR_MERGED)

        While 1
            $sOutput &= StdoutRead($iPID)
            If @error Then ExitLoop
        WEnd

    Return $sOutput

EndFunc

Alles anzeigen

**Bitnugger**

AutoIt

;-- TIME_STAMP   2018-07-13 11:57:41   v 0.1

#include <AutoItConstants.au3>

Global $aService = ['LanmanServer', 'Schedule', 'mysql', 'synergy', 'linux']

MsgBox(0, "", '_CheckService = ' & _CheckService($aService) & @CRLF & '@error = ' & @error & @CRLF & '@extended = ' & @extended)

Func _CheckService(ByRef $aService)
    Local $sCMD, $iPID, $iError = 0, $iExtended = 0

    For $i = 0 To UBound($aService) - 1
        $sCMD = StringFormat('%s /C sc.exe query %s | find "STATE"', @ComSpec, $aService[$i])
        ConsoleWrite('> $sCMD = ' & $sCMD & @CRLF)
        $iPID = Run($sCMD, @SystemDir, @SW_HIDE, $STDOUT_CHILD)
        If Not $iPID Then Return SetError(-1, $i, False)
        ProcessWaitClose($iPID)
        $sOutput = StdoutRead($iPID)
        ConsoleWrite($sOutput & @CRLF)
        Switch True
            Case StringRegExp($sOutput, 'RUNNING')
                ContinueLoop
            Case StringRegExp($sOutput, 'STOPPED')
                $iExtended += 1
            Case Else
                $iError += 1
        EndSwitch
    Next

    Return SetError($iError, $iExtended, ($iError Or $iExtended) ? False : True)
EndFunc

Alles anzeigen

Ich würde das aber etwa so machen...

AutoIt

;-- TIME_STAMP   2018-07-13 12:23:55   v 0.1

#Region    ;************ Includes ************
#Include <Array.au3>
#EndRegion ;************ Includes ************

Global $aService = ['LanmanServer', 'Schedule', 'mysql', 'synergy', 'linux']

Global $vRet = _CheckService($aService)
If @error Or @extended Then _ArrayDisplay($vRet, '$vRet', '', 0, Default, 'ID|NAME|STATE')

Func _CheckService(ByRef $aService)
    Local $aRet[0][3], $sCMD, $iPID, $iError = 0, $iExtended = 0

    For $i = 0 To UBound($aService) - 1
        $sCMD = StringFormat('%s /C sc.exe query %s | find "STATE"', @ComSpec, $aService[$i])
        ConsoleWrite('> $sCMD = ' & $sCMD & @CRLF)
        $iPID = Run($sCMD, @SystemDir, @SW_HIDE, $STDOUT_CHILD)
        If Not $iPID Then Return SetError(-1, $i, False)
        ProcessWaitClose($iPID)
        $sOutput = StdoutRead($iPID)
        ConsoleWrite($sOutput & @CRLF)
        Switch True
            Case StringRegExp($sOutput, 'RUNNING')
                ContinueLoop
            Case StringRegExp($sOutput, 'STOPPED')
                _ArrayAdd($aRet, $i & '|' & $aService[$i] & '|' & 'STOPPED')
                $iExtended += 1
            Case Else
                _ArrayAdd($aRet, $i & '|' & $aService[$i] & '|' & 'NOT INSTALLED')
                $iError += 1
        EndSwitch
    Next

    Return SetError($iError, $iExtended, ($iError Or $iExtended) ? $aRet : True)
EndFunc

Alles anzeigen

**Musashi**

Zitat von Bitnugger

Global $aService = ['LanmanServer', 'Schedule', 'mysql', 'synergy', 'Iinux']

Habe ich was an den Augen, oder steht hier 'Iinux' mit einem großem i ?

Gruß Musashi

**Bitnugger**

Zitat von Musashi

Habe ich was an den Augen, oder steht hier 'Iinux' mit einem großem i ?

Du hast was an den Augen...

So sähe es mit großem i aus: lInux

**alpines**

Zitat von Bitnugger

Du hast was an den Augen...

So sähe es mit großem i aus: lInux

Falsch, guck mal in den Sourcecode rein (da sieht man das I direkt) oder kopier das Wort aus Musashis Zitat hier rein http://string-functions.com/case.aspx.

Da steht iinux.

**Musashi**

Hmm, hier mal ein Screenshot aus dem Quelltext in Beitrag #2 !

Für mich sieht das nach einem großem i aus (siehe großes L bei LanmanServer).

Gruß Musashi

**Bitnugger**

Ja, tatsächlich... hm, ok, habe es korrigiert.

**Musashi**

Zitat von Bitnugger

Ja, tatsächlich... hm, ok, habe es korrigiert.

Ich möchte wirklich keine Erbsen zählen, aber in Listing 2 aus Beitrag #2 steht es noch falsch drin

dieselwiesel

Bitnugger

Thx for reply! Habe es getestet, läuft auch - aber noch nicht ganz was ich suche. Müsste den _CheckService dann nochmal mit dem @extended vergleichen (z.b. bei keiner läuft und keiner vorhanden bzw. alle laufen und keiner vorhanden). Beim Testen kamen folgende Konstellationen heraus...

alle laufen

_CheckService = True

@error = 0

@extended = 0

keiner vorhanden

_CheckService = False

@error = 3

@extended = 0

keiner läuft

_CheckService = False

@error = 0

@extended = 3

einer läuft

_CheckService = False

@error = 0

@extended = 2

zwei laufen

_CheckService = False

@error = 0

@extended = 1

**Bitnugger**

Musashi

Danke, habe jetzt beide "linux" korrigiert.

dieselwiesel

Deine Beschreibung zu dem was du willst ist sehr ungenau. Was soll z. B. passieren, wenn nur ein Service in der Liste nicht installiert ist?

So, hier noch ein Beispiel, dass deinen Wünschen evtl. besser entspricht... und mehr gibt es zu diesem Thema nicht von mir... grins

AutoIt

;-- TIME_STAMP   2018-07-13 18:10:57   v 0.1

#Region    ;************ Includes ************
#Include <Array.au3>
#EndRegion ;************ Includes ************

Global $aService = ['LanmanServer', 'Schedule', 'mysql', 'synergy', 'linux']

Global $vRet = _CheckService($aService)
If @error Then
    ConsoleWrite('! At least one Service ist not running: ' & $aService[@extended] & @CRLF)
ElseIf $vRet == 0 Then
    ConsoleWrite('! At least one Service ist not installed: ' & $aService[@extended] & @CRLF)
EndIf

; #FUNCTION# ====================================================================================================================
; Name ..........: _CheckService
; Description ...: Checks a list of services if they have been installed and started.
; Syntax ........: _CheckService(Byref $aService)
; Parameters ....: $aService            - [in/out] an array of service names.
; Return values .: Success:             - True                       - All service are running.
;                  Failure              - error by Run()             - False and set @error to -1
;                                         a service is not running   - False and set @error to index in list.
;                                         a service is not installed - return 0 and set @extended to index in list.
; Author ........: Bitnugger
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _CheckService(ByRef $aService)
    Local $sCMD, $iPID

    For $i = 0 To UBound($aService) - 1
        $sCMD = StringFormat('%s /C sc.exe query %s | find "STATE"', @ComSpec, $aService[$i])
        ConsoleWrite('> $sCMD = ' & $sCMD & @CRLF)
        $iPID = Run($sCMD, @SystemDir, @SW_HIDE, $STDOUT_CHILD)
        If Not $iPID Then Return SetError(-1, 0, False)
        ProcessWaitClose($iPID)
        $sOutput = StdoutRead($iPID)
        ConsoleWrite('- ' & $sOutput & @CRLF)
        Switch True
            Case StringRegExp($sOutput, 'RUNNING')
                ContinueLoop
            Case StringRegExp($sOutput, 'STOPPED')
                Return SetError(1, $i, False)
            Case Else
                Return SetExtended($i, 0)
        EndSwitch
    Next
EndFunc  ;==>_CheckService

Alles anzeigen

dieselwiesel

Zitat von Bitnugger

dieselwiesel

Deine Beschreibung zu dem was du willst ist sehr ungenau. Was soll z. B. passieren, wenn nur ein Service in der Liste nicht installiert ist?

Ich möchte ein Script schreiben, bei dem ein Treiber installiert wird, welcher mehrere Services startet.

Es soll beim Start prüfen, ob die Services alle laufen (zwecks Deinstallation), ein oder mehrere (egal welcher) gestoppt sind (auch wg. evtl. Deinstallation) oder problemlos installiert werden können.

Läuft einer nicht (völlig egal welcher) laufen die Anderen zu 99,9% auch nicht. Wenn das so ist muss deinstalliert werden, dann geht das aber nicht so sauber, wie wenn alle zu 100% laufen. Das lässt ich auch nicht so einfach drüber installieren, darum möchte ich wissen ob es sauber ist.

Am Ende der Prüfung würde es reichen, wenn z.B. ein CLEAN zurück kommt damit die Installtion beginnen kann, oder ein OKAY damit normal Deinstalliert werden kann bzw. ein ERROR damit es den anderen Weg der Deinstallation nimmt.

EDIT:

Habe dein erstes Bsp. ein bißchen "verunglimpft", da würde rauskommen was ich brauche - bin mir aber nicht sicher ob das so richtig ist, bzw. ob man es eleganter gestallten kann?!

AutoIt

Func _CheckService(ByRef $aService)
        Local $sCMD, $iPID, $iError = 0, $iExtended = 0
        For $i = 0 To UBound($aService) - 1
            $sCMD = StringFormat('%s /C sc.exe query %s | find "STATE"', @ComSpec, $aService[$i])
            ;ConsoleWrite('> $sCMD = ' & $sCMD & @CRLF)
            $iPID = Run($sCMD, @SystemDir, @SW_HIDE, $STDOUT_CHILD)
            If Not $iPID Then Return SetError(-1, $i, False)
            ProcessWaitClose($iPID)
            $sOutput = StdoutRead($iPID)
            ;ConsoleWrite($sOutput & @CRLF)
            Switch True
                Case StringRegExp($sOutput, 'RUNNING')
                    ContinueLoop
                Case StringRegExp($sOutput, 'STOPPED')
                    $iExtended += 1
                Case Else
                    $iError += 1
            EndSwitch
        Next

        ;Return SetError($iError, $iExtended, ($iError Or $iExtended) ? False : True)

        If $iError = Number("0") And $iExtended = Number("0") Then Return "CLEAN" ; läuft, kann normal deinstalliert werden
        If $iError = Number("0") And $iExtended <> Number("0") Then Return "ERROR" ; irgendwas läuft net sauber, muss auf anderem Weg deinstalliert werden, Reboot erforderlich
        If $iError <> Number("0") And $iExtended = Number("0") Then Return "READY" ; alles i.O., kann installiert werden

    EndFunc

Alles anzeigen

Racer

Wäre das nicht eleganter über WMI?

https://www.autoitscript.com/forum/topic/31…unning-service/

lg

Racer

**Bitnugger**

Zitat von Racer

Wäre das nicht eleganter über WMI?

Eleganz liegt im Auge des Betrachters... viel wichtiger ist, dass man selbst versteht, was in der Funktion passiert.

AutoIt

;-- TIME_STAMP   2018-07-16 12:39:00   v 0.1

Global $aService = ['LanmanServer', 'Schedule', 'mysql', 'synergy', 'linux']

Global $vRet = _CheckService($aService)
If @error > 0 Then
    ConsoleWrite('! At least one Service ist not running: ' & $aService[@extended] & @CRLF)
ElseIf $vRet == 0 Then
    ConsoleWrite('! At least one Service ist not installed: ' & $aService[@extended] & @CRLF)
Else
    ConsoleWrite('+ All Services are running!' & @CRLF)
EndIf

; #FUNCTION# ====================================================================================================================
; Name ..........: _CheckService
; Description ...: Checks a list of services if they have been installed and started.
; Syntax ........: _CheckService(Byref $_aServiceNames[, $_sMachine = '.'])
; Parameters ....: $_aServiceNames      - [in/out] an array of service names.
;                  $_sMachine           - [optional] an string value, the (Remote) Computer name. Default is '.'.
; Return values .: Success:             - True                       - All service are running.
;                  Failure:             - Error by ObjGet            - False and set @error to -1
;                                       - Error by ExecQuery         - False and set @error to -2
;                                       - a service is not running   - False and set @error to 1 and @extended to index in list.
;                                       - a service is not installed - 0 and set @extended to index in list.
; Author ........: Bitnugger
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _CheckService(ByRef $_aServiceNames, $_sMachine = '.')
    Local Const $wbemFlags = 0x10 ; ReturnImmediately
    Local $iItemCount, $colItems, $objItem, $objWMIService = ObjGet("winmgmts:\\" & $_sMachine & "\root\CIMV2")
    If @error Then Return SetError(-1, 0, False)
    For $i = 0 To UBound($_aServiceNames) -1 Step 1
        $colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_Service WHERE Name = '" & $_aServiceNames[$i] & "'", "WQL", $wbemFlags)
        If @error Or Not IsObj($colItems) Then Return SetError(-2, $i, False)
        $iItemCount = 0
        For $objItem In $colItems
            $iItemCount = $colItems.Count
            Switch True
                Case $objItem.State = 'Running'
                    ContinueLoop 2
                Case $objItem.State = 'Stopped'
                    Return SetError(1, $i, False)
            EndSwitch
        Next
        If $iItemCount = 0 Then Return SetExtended($i, 0) ; Service not found/installed
    Next
    Return True
EndFunc   ;==>_CheckService

Alles anzeigen

Racer