Datum umwandeln

Donsen64

Hallo,

ich habe ein Problem mit einem etwas seltsamen Datums Format.

Ich habe die folgende Liste:

Code

"source","End Time","Duration","Protocol"
xspw2,"Oct 22, 2018 04:00:59 PM",1539340540,tcp
xspw1,"Oct 22, 2018 04:04:34 PM",1539340540.05,tcp
xspw1,"Oct 22, 2018 04:22:37 PM",1539340147.9,tcp
.....

Um das Datum besser weiter zu verarbeiten, brauche ich aber die Liste im folgenden Format:

Code

source,"End Time",Duration,Protocol
xspw2,2018/10/22 16:00:59,1539340540,tcp
xspw1,2018/10/22 16:04:34,1539340540.05,tcp
xspw1,2018/10/22 16:22:37,1539340147.9,tcp
.....

Wie ich den Text finden habe ich schon. Aber wie ich das Format geändert bekommen dafür habe ich leider keine Lösung.

C

#include <Array.au3>
#include <String.au3>

Global $aTEMP
Global $aArray[5] = [4, '"source","End Time","Duration,Protocol"', _
                'xspw2,"Oct 22, 2018 04:00:59 PM",1539340540,tcp', _
                'xspw1,"Oct 22, 2018 04:04:34 PM",1539340540.05,tcp', _
                'xspw1,"Oct 22, 2018 04:22:37 PM",1539340147.9,tcp']
For $i = 1 To $aArray[0]
    $aTEMP = _StringBetween($aArray[$i], '"', '"')
    _ArrayDisplay($aTEMP, "$aTEMP")
Next

_ArrayDisplay($aArray, "$aArray")

Alles anzeigen

Hat jemand eine Idee wie ich das Datum Umformatieren kann.

Gruß

Donsen64

**alpines**

Ob die Date.au3 die Umwandlung unterstützt kann ich dir nicht sagen aber du kannst dich da ja mal umsehen.

Ansonsten scheint das keine komplizierte Umwandlung zu sein. Das Datum parst du mit RegEx raus und ersetzt den Monat durch die Zahl und formatierst das Datum.

Für die Uhrzeit musst du nur schauen ob da PM oder AM steht und jeweils +12 draufaddieren (aber Achtung, 12 PM = 12 Uhr Mittag, 12 AM = Mitternacht, 1 PM = 13 Uhr).

**BugFix**

Hiermit gehts:

AutoIt

Global $sDate = "Oct 22, 2018 12:00:59 AM"
ConsoleWrite(_Convert($sDate) & @CRLF)

Func _Convert($_sDate)
    Local Static $aM[12][2] = [['Jan','01'],['Feb','02'],['Mar','03'],['Apr','04'],['May','05'],['Jun','06'],['Jul','07'],['Aug','08'],['Sep','09'],['Oct','10'],['Nov','11'],['Dec','12']]
    Local $aDate = StringRegExp($_sDate, '(\w{3})\s(\d{2}),\s(\d{4})\s(\d{2}):(\d{2}):(\d{2})\s(AM|PM)', 1)
    Local $iMon
    For $i = 0 To 11
        If $aM[$i][0] = $aDate[0] Then
            $iMon = $aM[$i][1]
            ExitLoop
        EndIf
    Next
    Local $iDay = $aDate[1], $iYear = $aDate[2], $iHour = $aDate[3], $iMin = $aDate[4], $iSec = $aDate[5]
    If $aDate[6] = 'PM' Then
        If $iHour < 12 Then $iHour += 12
    ElseIf $aDate[6] = 'AM' Then
        If $iHour = 12 Then $iHour = 0
    EndIf
    Return StringFormat('%i/%02i/%02i %02i:%02i:%02i', $iYear, $iMon, $iDay, $iHour, $iMin, $iSec)
EndFunc

Alles anzeigen

Donsen64

Super!!! Vielen Dank ab BugFix und alpines!!!

**Bitnugger**

Habe dir mal eben eine kleine Funktion dafür geschrieben, weil ich gerade in der Warteschleife hänge und nichts Besseres zu tun habe...

AutoIt

;-- TIME_STAMP   2018-10-24 16:24:17   v 0.1

#include <Array.au3>

Global $sListe = _
'"source","End Time","Duration","Protocol"' & @CRLF & _
'xspw2,"Oct 22, 2018 04:00:59 PM",1539340540,tcp' & @CRLF & _
'xspw1,"Oct 22, 2018 04:04:34 PM",1539340540.05,tcp' & @CRLF & _
'xspw1,"Oct 22, 2018 04:22:37 PM",1539340147.9,tcp' & @CRLF

Global $aConvert = _ConvertList($sListe)

ConsoleWrite($sListe & @CRLF)
_ArrayDisplay($aConvert, '$aConvert')

Func _ConvertList(ByRef $sListe)
    Local Static $aMonate = ['Jan', 'Feb', 'Mar', 'Apr', 'Mai', 'Jun', 'Jul', 'Aug', 'Sep', 'Oct', 'Nov', 'Dec']
    Local $aTime, $aList = StringRegExp($sListe, '.+', 3)

    For $i = 0 To UBound($aList) -1 Step 1
        For $j = 0 To UBound($aMonate) -1 Step 1
            If StringRegExp($aList[$i], $aMonate[$j]) Then
                ; Datum konvertieren
                $aList[$i] = StringRegExpReplace($aList[$i], $aMonate[$j], StringFormat('%02i', $j + 1))
                $aList[$i] = StringRegExpReplace($aList[$i], '(\d{2}) (\d{2}), (\d{4})', '\3/\1/\2')
                ; Zeit konvertieren
                $aTime = StringRegExp($aList[$i], '(\d{2}):(\d{2}):(\d{2})', 1)
                Switch True
                    Case StringRegExp($sListe, 'PM')
                        $aTime[0] += $aTime[0] < 12 ? 12 : 0
                    Case StringRegExp($sListe, 'AM')
                        $aTime[0] += $aTime[0] = 12 ? 0 : $aTime[0]
                EndSwitch
                $aList[$i] = StringRegExpReplace($aList[$i], '(\d{2}):(\d{2}):(\d{2})', StringFormat('%02i:%02i:%02i', $aTime[0], $aTime[1], $aTime[2]))
                ; PM|AM entfernen
                $aList[$i] = StringRegExpReplace($aList[$i], ' PM| AM', '')
                ContinueLoop 2
            EndIf
        Next
    Next

    $sListe = _ArrayToString($aList, @CRLF)

    Return $aList
EndFunc

Alles anzeigen