BitOperations64

Zitat von Oscar

Bitnugger hatte bemängelt, dass die UDF bei AND, OR und XOR nur zwei Parameter zulässt. Aber anstatt alle 64-Bit-Zahlen in den Funktionsaufruf zu packen, finde ich es praktischer ein Array mit den Werten zu übergeben.

Außerdem ist es nicht angebracht, die Assemblerfunktion x-mal aufzurufen (die DllCallAdress-Aufrufe kosten Zeit). Lieber alle Werte in eine Struktur packen, den Pointer übergeben (sowie die Anzahl) und den Rest von Assembler aus erledigen.

Sehr schön... doch ein paar mehr als zwei Parameter sollten es meiner Meinung nach doch schon sein, bevor ich "genötigt" bin, vor dem Funktionsaufruf ein Array zu definieren.

Hier als Bsp. bei _BitAND64 (mit max. 8 Parametern), wie ich mir das gedacht habe...

Func _BitAND64($iValue1, $iValue2 = 0, $iValue3 = 0, $iValue4 = 0, $iValue5 = 0, $iValue6 = 0, $iValue7 = 0, $iValue8 = 0)
    #forceref $iValue2, $iValue3, $iValue4, $iValue5, $iValue6, $iValue7, $iValue8
    Local $iCount, $tData, $pData
    If IsArray($iValue1) Then
        $iCount = UBound($iValue1)
        $tData = DllStructCreate('uint64 value[' & $iCount & '];')
        For $i = 1 To $iCount
            DllStructSetData($tData, 1, $iValue1[$i - 1], $i)
        Next
    Else
        $iCount = @NumParams
        $tData = DllStructCreate('uint64 value['&$iCount&'];')
        For $i = 1 To $iCount Step 1
            DllStructSetData($tData, 1, Eval('iValue' & $i), $i)
        Next
    EndIf
    $pData = DllStructGetPtr($tData)
    Local $aRet = DllCallAddress('uint64:cdecl', $__g_pBitOpASMCode[0], 'ptr', $pData, 'uint64', $iCount)
    If @error Or Not IsArray($aRet) Then Return SetError(1, 0, 0)
    Return $aRet[0]
EndFunc   ;==>_BitAND64

Sehr schön

Mir ist noch ein "Schönheitsfehler" aufgefallen, das OnAutoItExitRegister sollte erst nach _MemVirtualAlloc ausgeführt werden, da sonst (zumindest theoretisch) die Möglichkeit besteht, dass _MemVirtualFree aufgerufen wird bevor überhaupt Speicher reserviert wurde. Wird wahrscheinlich niemals auftreten, aber irgendwie verursacht diese Reihenfolge einen Knoten in meinem Hirn

lg

M

Zitat von Oscar

Ok, das macht Sinn!

Ich hab's aber noch etwas anders gelöst (ohne Eval).

Soso, du magst Eval also nicht... so sah auch meine erste Lösung aus... mir hatte es aber nicht gefallen, nur zum Befüllen der Struktur ein Array zu erzeugen. Deshalb tendiere ich eher zu Eval. Unterm Strich aber völlig egal, weil ja beides funktioniert. Oder?

Eine Sache solltest du dir aber unbedingt abgewöhnen... For...Next-Schleifen im globalen Kontext!

Denn dadurch machst du die Count-Variable $i zu einer globalen Variable, was nicht nur unschön ist, sondern später auch mächtig Ärger machen kann, weil man innerhalb von Funktionen davon ausgeht, dass solche Lauf-Variablen eben nicht global sind.

Hier ein Beispiel:

#AutoIt3Wrapper_UseX64=y ; AutoIt 64-Bit-Modus

#include 'BitOperations64.au3'

_Test()

Func _Test()
    If IsDeclared('i') Then ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $i --> " & $i & ' IsDeclared("i") = ' & IsDeclared('i') & ' (1 = Global)' & @CRLF)
    Local $aDirList[0]
    If UBound($aDirList) Then
        For $i = 0 To UBound($aDirList) -1 Step 1
            If DirGetSize($aDirList[$i]) > 100000 Then ExitLoop
        Next
    EndIf
    If $i Then ConsoleWrite('! Mindestens ein Verzeichnis ist groesser als 100000!' & @CRLF) ; <<< Dieser Fehler ist sehr schwer zu finden, denn diese Zeile gehört vor das EndIf, weil $i sonst nicht lokal deklariert ist und das Script mit einer Fehlermeldung beendet wird - was aber nicht passiert, da $i ja wegen der For...Next-Schleife in BitOperations64.au3 als globale Variable existiert!
EndFunc

Zitat von Mars

Mir ist noch ein "Schönheitsfehler" aufgefallen, das OnAutoItExitRegister sollte erst nach _MemVirtualAlloc ausgeführt werden, da sonst (zumindest theoretisch) die Möglichkeit besteht, dass _MemVirtualFree aufgerufen wird bevor überhaupt Speicher reserviert wurde.

Ja, ok, das ist aber in der Tat nur ein Schönheitsfehler, denn er überprüft doch die Werte in dem Array, bevor _MemVirtualFree aufgerufen wird...

If $__g_pBitOpASMCode[$i] > 0 Then _MemVirtualFree($__g_pBitOpASMCode[$i], $__g_iBitOpMemSize[$i], $MEM_DECOMMIT)

Zitat von Bitnugger

Eine Sache solltest du dir aber unbedingt abgewöhnen... For...Next-Schleifen im globalen Kontext!

Um diese Uhrzeit sollte ich vielleicht keine Fragen mehr stellen, aber was soll's :

Die Laufvariable in einer For...Next-Schleife ist ja nicht deklarationspflichtig bzw. gilt automatisch als deklariert, selbst bei Opt('MustDeclareVars', 1) .

(ich vermute mal, das war ursprünglich ein Bequemlichkeitsfeature, oder ? )

Man könnte die angesprochene Gefahr bannen, indem man eine passende Notation wählt, also z.B. :

Global $__g_Counter

Sollte man im globalen Teil eines Skriptes, welches als Include dienen soll, aber überhaupt Schleifen oder sonstigen Code schreiben ? Wenn ich die Standardincludes betrachte, sehe ich dort nur Deklarationen von globalen Variablen, Konstanten, Enums usw. und natürlich die Funktionen.

Hätte Oscar in seiner BitOperations64.au3 den Teil :

; Allocate memory for the Assembler-Code
For $i = 0 To UBound($__g_dBitOpASMBin) - 1
    $__g_iBitOpMemSize[$i] = StringLen($__g_dBitOpASMBin[$i]) / 2 - 1
    $__g_pBitOpASMCode[$i] = _MemVirtualAlloc(0, $__g_iBitOpMemSize[$i], $MEM_COMMIT, $PAGE_EXECUTE_READWRITE)
    If $__g_pBitOpASMCode[$i] = 0 Then Exit MsgBox(16, 'BitOpASM-Error!', "Can't allocate virtual memory!")
    $__g_tBitOpASMCode[$i] = DllStructCreate('byte[' & $__g_iBitOpMemSize[$i] & ']', $__g_pBitOpASMCode[$i])
    DllStructSetData($__g_tBitOpASMCode[$i], 1, $__g_dBitOpASMBin[$i])
Next

in eine Funktion gepackt, wäre doch alles ok, oder ?

Ich hoffe, Du verstehst was ich meine - ich bin mir da momentan nicht mehr sicher .

Gruß Musashi

Zitat von Musashi

(ich vermute mal, das war ursprünglich ein Bequemlichkeitsfeature, oder ? )

Ja, könnte man so nennen... und ist es immer noch...

Zitat von Musashi

in eine Funktion gepackt, wäre doch alles ok, oder ?

Ja, dann wäre alles klar!

Ich verwende dafür immer die Funktion _Main(), die es bei mir so gut wie immer gibt, damit solche Sachen nicht passieren.

Zitat von Oscar

Aber generell die Funktion "_Main" dafür zu verwenden, ist auch nicht gut.

Wenn Du das in mehreren UDFs machst, hast Du das Problem, dass es die Funktion doppelt gibt.

Selbstverständlich würde ich _Main() nicht in einer UDF verwenden, sondern nur in "normalen" Scripten und da ist das auch völlig ok.

Im Übrigen ist das OnAutoItExitRegister bzw. das If $__g_pBitOpASMCode[$i] > 0 Then wohl nicht zwingend nötig, da _MemVirtualFree($__g_pBitOpASMCode[$i], $__g_iBitOpMemSize[$i], $MEM_DECOMMIT) dann einfach ein False liefert, wenn $__g_pBitOpASMCode[$i] = "" ist. Konnte der Speicher freigegeben werden, liefert es True.... das allerdings traurigerweise auch, wenn man denselben Speicher mehrmals hintereinander freigibt.

In der Funktion _BitRotate64() hat sich ein Fehler eingeschlichen... denn wenn $iRotate = 0 ist, musst du $iValue1 und nicht $iRet zurückgeben!

Ich würde es so machen:

; A helper-function for "_BitROL64" and "_BitROR64"
; $iRotate = Number of bits to rotate to the right (negative numbers rotate left).
Func _BitRotate64($iValue1, $iRotate = 1)
    Return $iRotate = 0 ? $iValue1 : $iRotate > 0 ? _BitROR64($iValue1, $iRotate) : _BitROL64($iValue1, $iRotate)
EndFunc   ;==>_BitRotate64

In deinem aktuellen Example hast du für _BitAND64/_BitOR64/_BitXOR64 jetzt übrigens keine Beispiele mehr, die zeigen, wie es mit einem Array geht... die waren vorher drin und ich würde sie auch wieder hinzufügen.