Zoom in _IECreateEmbedded

Joschy41

Moin.
Ich versuche vergebens einen Zoomfaktor festzulegen für _IECreateEmbedded.

Ich habe es mittels "$oIE.document.parentwindow.scroll(151, 230)" hinbekommen zur Position zu Scrollen, jedoch wäre es schön wenn man so ähnlich noch den Zoomfaktor festlegen könnte.

C

#include <GUIConstants.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiSlider.au3>
#include <IE.au3>

GUICreate("Google", @DesktopWidth/2, @DesktopHeight/2, 0, 0)

Local $oIE = _IECreateEmbedded(), $msg, $sHtml_File
GUICtrlCreateObj($oIE, 0, 0,@DesktopWidth/2, @DesktopHeight/2)

GUISetState(@SW_SHOW)


While 1
_IENavigate($oIE, "https://www.google.de", 0) ;Öffnet Google
Sleep (1000) ;Wartet 1 Sek.
$oIE.document.parentwindow.scroll(151, 230) ;Positioniert IE Fenster
Sleep (600000) ;Wartet 10 Min.
WEnd ;Aktualisiert Google

Alles anzeigen

Gruß

**alpines**

Wenn ich nach "ie com object set zoom" suche finde ich direkt im ersten Treffer die Lösung objExplorer.Document.Body.Style.setAttribute "zoom","112%".

C

#include <GUIConstants.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiSlider.au3>
#include <IE.au3>

GUICreate("Google", @DesktopWidth/2, @DesktopHeight/2, 0, 0)

Local $oIE = _IECreateEmbedded(), $msg, $sHtml_File
GUICtrlCreateObj($oIE, 0, 0,@DesktopWidth/2, @DesktopHeight/2)

GUISetState(@SW_SHOW)


While 1
_IENavigate($oIE, "https://www.google.de", 0) ;Öffnet Google
Sleep (1000) ;Wartet 1 Sek.
$oIE.Document.Body.Style.Zoom = "200%"
Sleep (600000) ;Wartet 10 Min.
WEnd ;Aktualisiert Google

Alles anzeigen

Joschy41

Ich habe so viel bei google gesucht. Aber nicht nach diesen Stichwörtern.
Wie in meinem Ersten Beitrag immer nach IECreateEmbedded Zoom oder so.

Aber funktioniert jetzt einwandfrei.
Dank dir!

**Musashi**

Hi Joschy41 !

Erst mal solltest Du in :

While 1

...

Sleep (600000) ;Wartet 10 Min.

ExitLoop

WEnd

ein ExitLoop einfügen, sonst läuft das ewig .

Statt $oIE.Document.Body.Style.Zoom = "100%" kannst Du es auch mal mit $oIE.ExecWB(...) versuchen, siehe :

C

#include <GUIConstants.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiSlider.au3>
#include <IE.au3>

Global Const $OLECMDEXECOPT_DODEFAULT  = 0
Global Const $OLECMDID_OPTICAL_ZOOM    = 0x3F
Global $hGUI, $iMsg, $iZoom = 100

$hGUI = GUICreate("Google", @DesktopWidth/2, @DesktopHeight/2, 0, 0)
Global $oIE = _IECreateEmbedded(), $iMsg, $sHtml_File
GUICtrlCreateObj($oIE, 0, 0, @DesktopWidth / 2, @DesktopHeight / 2)
_IENavigate($oIE, "https://www.google.de", 1) ; öffnet Google
$oIE.ExecWB($OLECMDID_OPTICAL_ZOOM, $OLECMDEXECOPT_DODEFAULT, $iZoom, 0)
GUISetState(@SW_SHOW, $hGUI)
While 1
    $iMsg = GUIGetMsg()
    If $iMsg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd ; aktualisiert Google
GUIDelete($hGUI)

Alles anzeigen

Bei mir ergibt es unterschiedliche Ergebnisse, siehe Grafiken (100% /120%).

Gruß Musashi

Joschy41

Hallo,

vielen Dank für deinen Beitrag.
Ich komme zur Zeit mit " $oIE.Document.Body.Style.Zoom = "100%"" ganz gut zurecht.

Zu dem Loop
Der soll auch ewig laufen, da die Seite immer wieder aktualisiert werden soll.

**Musashi**

Zitat von Joschy41

Zu dem Loop
Der soll auch ewig laufen, da die Seite immer wieder aktualisiert werden soll.

NEIN, ein solches Skript sollte auch eine vernünftige Abbruchmöglichkeit haben !

Jetzt muss man das Skript in SciTE mit ->Tools ->Stop Executing abwürgen.

Startet man die kompilierte .exe-Datei, dann muss der Prozess über den Taskmanager gekillt werden.

Beides keine seriösen Optionen, oder ?

Ersetzte folgenden Bereich :

Code

While 1
    _IENavigate($oIE, "https://www.google.de", 0) ;Öffnet Google
    Sleep (1000) ;Wartet 1 Sek.
    $oIE.Document.Body.Style.Zoom = "200%"
    Sleep (600000) ;Wartet 10 Min.
WEnd ;Aktualisiert Google

mal durch :

Code

Global $bInterrupt = False
While 1
    _IENavigate($oIE, "https://www.google.de", 0) ; öffnet Google
    Sleep (1000) ; wartet 1 Sek.
    $oIE.Document.Body.Style.Zoom = "200%"
    If _SleepWithInterrupt($bInterrupt, 600000, 100) Then ExitLoop
WEnd ; aktualisiert Google
GUIDelete()

Func _SleepWithInterrupt(ByRef $bInterrupt, Const $iTimeSleep, Const $iTimeInterrupt = 500)
    Local Const $iParts     = Ceiling($iTimeSleep / $iTimeInterrupt)
    Local Const $iRemainder = $iTimeSleep - ($iTimeInterrupt * Floor($iTimeSleep / $iTimeInterrupt))
    Local $iCurrent   = $iTimeInterrupt
    Local $iReturn    = 0
    For $i1 = 1 To $iParts
        $bInterrupt = (GUIGetMsg() == $GUI_EVENT_CLOSE)
        If $bInterrupt Then
            $iReturn = 1
            ExitLoop 1
        EndIf
        If $i1 = $iParts And $iRemainder Then $iCurrent = $iRemainder
        Sleep($iCurrent)
    Next
    Return $iReturn
EndFunc

Alles anzeigen

Das gesamte Skript sollte dann so aussehen :

C

#include <GUIConstants.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiSlider.au3>
#include <IE.au3>

GUICreate("Google", @DesktopWidth/2, @DesktopHeight/2, 0, 0)
Local $oIE = _IECreateEmbedded(), $msg, $sHtml_File
GUICtrlCreateObj($oIE, 0, 0,@DesktopWidth/2, @DesktopHeight/2)
GUISetState(@SW_SHOW)

Global $bInterrupt = False
While 1
    _IENavigate($oIE, "https://www.google.de", 0) ; öffnet Google
    Sleep (1000) ; wartet 1 Sek.
    $oIE.Document.Body.Style.Zoom = "200%"
    If _SleepWithInterrupt($bInterrupt, 600000, 100) Then ExitLoop
WEnd ; aktualisiert Google
GUIDelete()

Func _SleepWithInterrupt(ByRef $bInterrupt, Const $iTimeSleep, Const $iTimeInterrupt = 500)
    Local Const $iParts     = Ceiling($iTimeSleep / $iTimeInterrupt)
    Local Const $iRemainder = $iTimeSleep - ($iTimeInterrupt * Floor($iTimeSleep / $iTimeInterrupt))
    Local $iCurrent   = $iTimeInterrupt
    Local $iReturn    = 0
    For $i1 = 1 To $iParts
        $bInterrupt = (GUIGetMsg() == $GUI_EVENT_CLOSE)
        If $bInterrupt Then
            $iReturn = 1
            ExitLoop 1
        EndIf
        If $i1 = $iParts And $iRemainder Then $iCurrent = $iRemainder
        Sleep($iCurrent)
    Next
    Return $iReturn
EndFunc

Alles anzeigen

Jetzt kann man das Skript durch das Schließen des Fensters (X) beenden !

Gruß Musashi

**alpines**

Zitat von Musashi

Beides keine seriösen Optionen, oder ?

Na na, was ist denn hiermit?

**Musashi**

Zitat von alpines

Na na, was ist denn hiermit?

Ok, das geht natürlich auch - sofern der User das kennt bzw. findet.

Ändert aber nichts daran, dass das Beenden eines Programms über das (X) im Fenster eine sinnvolle Ergänzung darstellt (das kennen alle).

Gruß Musashi

Joschy41

Hatte ein gekürztes Script eingefügt.

Hier mal mit der Funktion, dass man das X oben rechts vom Fenster nutzen kann.

(mit ";<-----------------------" die entscheidenden Sachen markiert)

C

#include <GUIConstants.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiSlider.au3>
#include <IE.au3>

Opt("GUIOnEventMode", 1) ;<-----------------------
GUICreate("Google", @DesktopWidth/2, @DesktopHeight/2, 0, 0)
GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEButton") ;<-----------------------

Local $oIE = _IECreateEmbedded(), $msg, $sHtml_File
GUICtrlCreateObj($oIE, 0, 0,@DesktopWidth/2, @DesktopHeight/2)
GUISetState(@SW_SHOW)

While 1
_IENavigate($oIE, "https://www.google.de", 0) ;Öffnet Google
Sleep (1000) ;Wartet 1 Sek.
$oIE.Document.Body.Style.Zoom = "200%"
Sleep (600000) ;Wartet 10 Min.
WEnd ;Aktualisiert Google


Func CLOSEButton() ;<-----------------------
   Exit ;<-----------------------
EndFunc ;<-----------------------

Alles anzeigen

Joschy41

Mittlerweile aber auch statt Sleep (1000) in Zeile 17 "_IELoadWait($oIE)" verwendet.
Wartet somit bis die Seite fertig geladen ist.

C

#include <GUIConstants.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiSlider.au3>
#include <IE.au3>

Opt("GUIOnEventMode", 1) 
GUICreate("Google", @DesktopWidth/2, @DesktopHeight/2, 0, 0)
GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEButton") 

Local $oIE = _IECreateEmbedded(), $msg, $sHtml_File
GUICtrlCreateObj($oIE, 0, 0,@DesktopWidth/2, @DesktopHeight/2)
GUISetState(@SW_SHOW)

While 1
_IENavigate($oIE, "https://www.google.de", 0) ;Öffnet Google
_IELoadWait($oIE) ;<-----------------------
$oIE.Document.Body.Style.Zoom = "200%"
Sleep (600000) ;Wartet 10 Min.
WEnd ;Aktualisiert Google

Func CLOSEButton()
   Exit
EndFunc

Alles anzeigen

**alpines**

Zitat von Joschy41

Mittlerweile aber auch statt Sleep (1000) in Zeile 17 "_IELoadWait($oIE)" verwendet.
Wartet somit bis die Seite fertig geladen ist.

Was absoluter Quatsch ist, wenn du den dritten Parameter von _IENavigate nicht 0 setzen würdest. Du hast dadurch einfach nur mehr Code.

**Musashi**

Zitat von Joschy41

Hatte ein gekürztes Script eingefügt.

Grundsätzlich ist ja nichts falsch daran gekürzte Skripte zu posten, speziell wenn es um die Analyse eines Teilproblems geht. In diesem Fall hätten die 4 Zeilen mehr den Kohl aber auch nicht fett gemacht, und man hätte sich die Diskussion über das Schließen des Programms sparen können.

EDIT :

Zitat von alpines

-> Zitat Joschy41 : "Mittlerweile aber auch statt Sleep (1000) in Zeile 17 "_IELoadWait($oIE)" verwendet. Wartet somit bis die Seite fertig geladen ist."

Antwort von alpines :

Was absoluter Quatsch ist, wenn du den dritten Parameter von _IENavigate nicht 0 setzen würdest. Du hast dadurch einfach nur mehr Code.

Völlig richtig !

Joschy41 : Du kannst den dritten Parameter sogar weglassen, da 1=Wait der Default ist.

Gruß Musashi

Joschy41

Zitat von Musashi

Grundsätzlich ist ja nichts falsch daran gekürzte Skripte zu posten, speziell wenn es um die Analyse eines Teilproblems geht. In diesem Fall hätten die 4 Zeilen mehr den Kohl aber auch nicht fett gemacht, und man hätte sich die Diskussion über das Schließen des Programms sparen können.

EDIT :

Völlig richtig !

Joschy41 : Du kannst den dritten Parameter sogar weglassen, da 1=Wait der Default ist.

Gruß Musashi

1. Viele wege führen nach Rom

2. Man lernt nicht aus! Danke!

Joschy41

Hier mal ne Erklärung woran ich überhaupt arbeite.
Ein Cam Viewer mit Wetteranzeige (wenn man bei Google einfach: "Stadt" Wetter eintippt) und der Uhrzeit.

[Blockierte Grafik: https://www.bilder-upload.eu/upload/bd6d2d-1551387898.jpg]

**Bitnugger**

Zitat von Joschy41

einfach: "Stadt" Wetter eintippt) und der Uhrzeit.

es geht auch...

"Stadt" Wetter Freitag

oder...

"Stadt" Wetter übermorgen

Joschy41

Zitat von Bitnugger

es geht auch...

"Stadt" Wetter Freitag

oder...

"Stadt" Wetter übermorgen

Ginge auch

Noch schöner wäre es wenn man von der Google Seite dann wirklich NUR dieses Wetter Fenster in eine HTML packen könnte.
https://www.bilder-upload.eu/upload/2fdf3e-1551421986.jpg

Ich habe schon versucht die HTML ein wenig einzukürzen, aber da hab ich zu wenig Kenntnisse für HTML Scripts
Wenn einer Zeit und Lust hat, kann er mir gern eine HTML basteln, die dann nur dieses Wetter Fenster von google abgreift xD

oh-ha

Würde es nicht reichen wenn du es hiermit machst? daswetter.com/widget/

Kann man als Bild oder als Script einbauen.

Gibt da auch noch massig andere zB

https://www.findlocalweather.com/free_weather_o…ur_website.html

https://www.meine-erste-homepage.com/wetter.php

https://hotel-mix.de/widgets/weather

usw

Joschy41

Ich glaub das mit dem Google Wetter ist schon nicht schlecht, da kann man dann in der Gui selbst auf Niederschlag und so klicken.