merkwürdige Zeichen - _ArraySearch

Banana_2_Day

Hallo,

mit

_FTP_ListToArray

lasse ich mir den Inhalt eines FTP-Servers ausgeben.

mit

_ArraySearch

durchsuche ich die Rückgabewerte des FTP-Servers, ob eine Datei vorhanden ist

Ich möchte herausfinden, ob die Datei "Testdatei - für AutoIt.au3" auf dem FTP-Server liegt.

_FTP_ListToArray gibt mir den Dateinamen als "Testdatei - fÃ¼r AutoIt.au3" zurück.

Wie kann ich mir mit _FTP_ListToArray die Dateinamen und Pfade mit deutschen Umlauten zurückgeben?

Falls das nicht geht - wie konvertiere ich "Testdatei - für AutoIt.au3" in Testdatei - fÃ¼r AutoIt.au3", um mit _ArraySearch prüfen zu können, ob die Datei bereits auf dem FTP-Server liegt?

Gibt es für obiges Ziel noch einen besseren Weg?

PS: am liebsten würde ich das komplette Array so konvertieren, dass es Umlaute enthält.

**Bitnugger**

Guck mal ob dir das weiter hilft:

ConsoleWrite(BinaryToString(StringToBinary('Testdatei - fÃ¼r AutoIt.au3'), 1) & @CRLF)

Ausgabe:

Testdatei - für AutoIt.au3

Banana_2_Day

Zitat von Bitnugger

Guck mal ob dir das weiter hilft:
ConsoleWrite(BinaryToString(StringToBinary('Testdatei - fÃ¼r AutoIt.au3'), 1) & @CRLF)
Ausgabe:
Testdatei - für AutoIt.au3

Was mache ich falsch?

Code

MsgBox ( 0 ,  "" , (BinaryToString(StringToBinary('Testdatei - fÃ¼r AutoIt.au3'), 1) ) )

Ausgabe

---------------------------

---------------------------
Testdatei - fÃ¼r AutoIt.au3
---------------------------
OK   
---------------------------

Alles anzeigen

Wenn es funktionieren würde, müsste ich mit der Befehlszeile jede Array-Zeile durchlaufen und das Ergebnis in ein neues Array schreiben? Oder gibt es einen besseren Weg, um ein Array zu konvertieren?

**alpines**

Das Flag am Ende kommt nicht hin, nimm UTF-8 (4) denn Umlaute gibt es im ANSI (1) nicht.

Du musst das Array durchlaufen und den Inhalt des Indexes einfach mit der Umwandlung ersetzen, du brauchst kein neues Array zu erzeugen.

**Bitnugger**

Zitat von alpines

Das Flag am Ende kommt nicht hin, nimm UTF-8 (4) denn Umlaute gibt es im ANSI (1) nicht.

Mein SciTE ist so eingestellt, dass Dateien als UTF-8 gespeichert und die Ausgaben als UTF-8 angezeigt werden. Deshalb hat mein Test-Script wohl auch mit 1 funktioniert.

Dass es im ANSI keine Umlaute gibt, wäre mir aber neu... du meinst wohl OEM (850)?!

Banana_2_Day

Zitat von alpines

Das Flag am Ende kommt nicht hin, nimm UTF-8 (4) denn Umlaute gibt es im ANSI (1) nicht.

Du musst das Array durchlaufen und den Inhalt des Indexes einfach mit der Umwandlung ersetzen, du brauchst kein neues Array zu erzeugen.

Flag 4 hat funktioniert. Danke!

Code

        For $i = 1 to $a_FTP[0]
            ToolTip ($a_FTP[$i])
            Sleep (1000)
            ToolTip ("")
        Next

Das Array durchlaufen bekomme ich hin. Bin auf der Suche nach einem "Ersetzen-Befehl". Mal schauen, ob was im Forum steht. Suche ...

**Musashi**

Zitat von Bitnugger

Dass es im ANSI keine Umlaute gibt, wäre mir aber neu...

Mir auch , siehe :

Gruß Musashi

**alpines**

Ich denk bei ANSI immer an ASCII.

Trotzdem sollte es nicht funktionieren, da ja der Umlaut mit zwei Bytes dargestellt wird, in ANSI ist aber nur ein Byte notwendig.

StringToBinary wandelt mit dem Standardflag ANSI (1) um, d.h. damit deine Variante funktioniert, hättest du den String mit UTF-8 (4) konvertieren müssen,

aber auch das klappt nicht, weil ja zwei separate Zeichen vorhanden sind und kein Umlaut.

Banana_2_Day

Gelöst Einfach die Zeile

BinaryToString(StringToBinary($a_FTP[$i]), 4)

in die For Next Schleife

Danke!

**Musashi**

Zitat von alpines

Ich denk bei ANSI immer an ASCII.

Habe ich mir gedacht ( Bitnugger sicher auch)

In der Sache hast Du aber natürlich recht.

ConsoleWrite(BinaryToString(StringToBinary('Testdatei - fÃ¼r AutoIt.au3'), 1) & @CRLF)

==> Konsole = Testdatei - fÃ¼r AutoIt.au3

ConsoleWrite(BinaryToString(StringToBinary('Testdatei - fÃ¼r AutoIt.au3'), 4) & @CRLF)

==> Konsole = Testdatei - für AutoIt.au3

Daher, wie üblich, lieber die Konstanten verwenden : $SB_ANSI statt 1 , $SB_UTF8 statt 4

Gruß Musashi

**Bitnugger**

Zitat von Musashi

In der Sache hast Du aber natürlich recht.

Soso... bei mir sieht es aber so aus:

So geht es aber auch:

ConsoleWrite(BinaryToString(StringToBinary('Testdatei - fÃ¼r AutoIt.au3', 4), 4) & @CRLF)

**autoiter**

Hallo Bitnugger
ich glaube, das liegt aber nur an deinen Einstellungen.
Das gibt dir denn folgendes aus?

Code

MsgBox(0,"", BinaryToString(StringToBinary('Testdatei - fÃ¼r AutoIt.au3'), 1) & @CRLF & _
BinaryToString(StringToBinary('Testdatei - fÃ¼r AutoIt.au3'), 4) & @CRLF & _
BinaryToString(StringToBinary('Testdatei - fÃ¼r AutoIt.au3', 4), 4))

**Musashi**

Zitat von Bitnugger

Soso... bei mir sieht es aber so aus:

Zitat von autoiter

Hallo Bitnugger - ich glaube, das liegt aber nur an deinen Einstellungen.

Das Verhalten hängt mit hoher Wahrscheinlichkeit von den jeweiligen Einstellungen ab !

In meiner SciTEGlobal.properties steht :

# Unicode

#code.page=65001

code.page=0

(keine Ahnung, ob ich das mal geändert habe oder ob es sich um den Default handelt)

In meiner SciTEUser.properties habe ich mal eingetragen (Settings sind akt. aber mit # deaktiviert) :

# code.page=65001

# output.code.page=65001

Sobald ich die Settings aktiviere und die Datei speichere, werden sofort alle Umlaute (z.B. in den Kommentaren) verändert -> ü wird zu Ã¼ usw.

Die Konsolenausgabe sieht dann aber auch so aus wie in Deinem Screenshot !

Ich verspüre allerdings wenig Begeisterung, hier groß herumzuwerkeln.

Das Thema Zeichenkonvertierung/-kodierung wird uns wahrscheinlich sowieso alle überleben .

Gruß Musashi

**Bitnugger**

code.page=0 ist Default, unter Windows ist das dann ANSI.

Zitat von Musashi

Ich verspüre allerdings wenig Begeisterung, hier groß herumzuwerkeln.

Na ja, so viel Aufwand ist das nun nicht. Ich habe mir dafür ein kleines Script geschrieben, um fremde/ältere Scripte (*.au3, *.lua) zu konvertieren, dass ich mit OHK aufrufe (Ctrl+Win, Ctrl+z).

Code: ownhotkeys.properties

#~ Ctrl+Win, Ctrl+Z
own.mode.cmd.90=OHK.ConvertFileToUTF8()
own.mode.descript.90=Ctrl+$(own.mode.indicator.descript), Ctrl+Z|Convert the current file to UTF-8 (*.au3 with BOM, *.lua without BOM)

Code: OHKfuncs.lua

--[[    OHK.ConvertFileToUTF8()
]]
-------------------------------------------------------------------------
OHK.ConvertFileToUTF8 = function()
    local UserTools   = props['user.tools.path']
    local FilePath    = props['FilePath']
--~     local FileDir     = props['FileDir']
--~     local FileName    = props['FileName']
--~     local FileExt     = props['FileExt']
--~     local FileNameExt = props['FileNameExt']

--~     print('UserTools   = '..UserTools)
--~     print('FilePath    = '..FilePath)
--~     print('FileDir     = '..FileDir)
--~     print('FileName    = '..FileName)
--~     print('FileExt     = '..FileExt)
--~     print('FileNameExt = '..FileNameExt)

    editor:BeginUndoAction()
    OHK.ExecuteAU3(UserTools..'\\_ConvertFileToUTF8.au3', FilePath)
    editor:EndUndoAction()
end
-------------------------------------------------------------------------

Alles anzeigen

Code: _ConvertFileToUTF8.au3

;-- TIME_STAMP   2018-06-23 07:32:01   v 0.1

#Region    ;************ Includes ************
#Include <File.au3>
;~ #Include <WinAPI.au3>
#EndRegion ;************ Includes ************

Switch $CMDLINE[0]
    Case 0
        Exit 1
    Case 1
        _ToUTF8($CMDLINE[1])
    Case 2
        _ToUTF8($CMDLINE[1], $CMDLINE[2])
    Case Else
        Exit 2
EndSwitch

Func _ToUTF8($sFilePath, $sSaveAs = '')
    If $sSaveAs = '' Then $sSaveAs = $sFilePath

;~     MsgBox(0, '_ToUTF8', '$sFilePath = ' & $sFilePath & @CRLF & '$sSaveAs = ' & $sSaveAs)
;~     Return

    Local $sFile, $hFile, $iSize, $iEncoding, $iWrite, $FO, $sExt

    $hFile = FileOpen($sFilePath, $FO_READ) ; $FO_READ (0), $FO_BINARY (16), $FO_UTF8 (128), $FO_UTF8_NOBOM (256), $FO_ANSI (512)
    $iEncoding = FileGetEncoding($hFile)
    $sFile = FileRead($hFile)
    $iSize = @extended
    FileClose($hFile)
    If $iSize = 0 Then
        ConsoleWrite('! Error $hFile = ' & $hFile & ' $iSize = ' & $iSize & ' FileRead('&$sFilePath&')' & @CRLF)
        Return 0
    EndIf

    $sExt = StringRegExpReplace($sFilePath, '.+(\..+)', '\1')

;~     Leere Datei.txt = $FO_UTF8_NOBOM
    Switch $iEncoding
        Case $FO_UTF8_NOBOM
            If $sExt = '.lua' Then
                Return SetExtended($iSize, $iEncoding) ; Lua mag kein BOM!!!
                ConsoleWrite(StringFormat('+ %s %s %s\r', $sFilePath, _StrRepeat('.', 92 - StringLen($sFilePath)), 'Codepage ist bereits $FO_UTF8_NOBOM'))
            Else
                ConsoleWrite(StringFormat('- %s %s %s\r', $sFilePath, _StrRepeat('.', 92 - StringLen($sFilePath)), 'Codepage $FO_UTF8_NOBOM wird zu $FO_UTF8 konvertiert'))
            EndIf
        Case $FO_UTF8
            ConsoleWrite(StringFormat('+ %s %s %s\r', $sFilePath, _StrRepeat('.', 92 - StringLen($sFilePath)), 'Codepage ist bereits $FO_UTF8'))
            Return SetExtended($iSize, $iEncoding)
        Case $FO_ANSI
            If $sExt = '.lua' Then
                ConsoleWrite(StringFormat('- %s %s %s\r', $sFilePath, _StrRepeat('.', 92 - StringLen($sFilePath)), 'Codepage $FO_ANSI wird zu $FO_UTF8_NOBOM konvertiert'))
            Else
                ConsoleWrite(StringFormat('- %s %s %s\r', $sFilePath, _StrRepeat('.', 92 - StringLen($sFilePath)), 'Codepage $FO_ANSI wird zu $FO_UTF8 konvertiert'))
            EndIf
        Case Else
            Return 0
    EndSwitch

    $hFile = FileOpen($sSaveAs, $FO_OVERWRITE + $FO_CREATEPATH + ($sExt = '.lua' ? $FO_UTF8_NOBOM : $FO_UTF8)) ; $FO_APPEND (1), $FO_OVERWRITE (2), $FO_CREATEPATH (8), $FO_BINARY (16), $FO_UTF8 (128), $FO_UTF8_NOBOM (256), $FO_ANSI (512)
    $iWrite = FileWrite($hFile, $sFile) + FileClose($hFile) ? FileGetSize($sSaveAs) : -1
    If $iWrite < 1 Then
        ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : Error $hFile = ' & $hFile & ' $iWrite = ' & $iWrite & ' FileWrite('&$sSaveAs&')' & @CRLF)
        Exit 999
    EndIf
    Send('^r')
    Return SetExtended($iSize, $iEncoding)
EndFunc

Func _StrRepeat($sStr, $iRepeat)
    Local $sString
    For $i = 1 To $iRepeat Step 1
        $sString &= $sStr
    Next
    Return $sString
EndFunc

Alles anzeigen

Code: SciTEUser.properties

# Pfad für eigene Tools
#~ user.tools.path=f:\AutoIt\AutoIt3_Tools
user.tools.path=f:\\AutoIt\\AutoIt3_Tools

# Pfad für eigene Lua-Scripte
#~ lua.user.scripts.path=f:\AutoIt\AutoIt3_LuaScripts
lua.user.scripts.path=f:\\AutoIt\\AutoIt3_LuaScripts

**Musashi**

Zitat von Bitnugger

-> Zitat Musashi : "Ich verspüre allerdings wenig Begeisterung, hier groß herumzuwerkeln.
-> Das Thema Zeichenkonvertierung/-kodierung wird uns wahrscheinlich alle überleben ."
Na ja, so viel Aufwand ist das nun nicht.

Stimmt, der Aufwand wäre nicht 'unmenschlich' , aber bei mir nicht zwingend erforderlich.

Quasi alle von mir verwendeten Community-UDF's sind i.d.R. in englisch und/oder ANSI.
Skripte aus dem Forum lese ich eh erst durch bevor ich sie einbinde. Finde ich dort falsch codierte Zeichen (selten), dann ändere ich sie manuell. Ich habe mal aus Interesse einige akt. Skripte von BugFix, water, Oscar usw. geprüft => alles ANSI.

Ich habe haufenweise (firmen-)eigene Skripte, die von mir extrem dokumentiert wurden (deutsch) - falls man mal gegen den berühmten Baum fährt usw. ). Ein Umstellen der code.page von 0 auf 65001 bzw. Umkodieren würde mir nichts Wesentliches bringen.Die Aussage "Das Thema [...] wird uns wahrscheinlich sowieso alle überleben

" bezog sich auch mehr auf Kodierung/Konvertierung/Maskierung i.a., denke z.B. mal an dieQuoted-Printable-Kodierung

Völlig unabhängig davon sind Deine o.a. Skripte im Bedarfsfall aber sehr hilfreich .

Gruß Musashi