OK-Button erkennen

Bernhard65

Leider gleich noch eine Frage:

Ich habe ein Programm wo ich viele Optionen (Checkbox) habe.

Die Optionen habe ich in verschiedene Fenster aufgeteilt um es für den Anwender etwas übersichtlicher zu machen.

Da die Optionen-Fenster aber immer gleich ausschauen habe ich mir gedacht dass ich eine Funktion für alle Fenster mache.

Meine Funktion funktioniert ja eigentlich, jetzt kommt wieder das aber:

Ich habe einen Close- und OK-Button.

Wie erkenne ich beim OK-Button welche Optionen angezeigt wurden?

Natürlich habe ich wieder ein Beispiel:

AutoIt: Beispiel

#include <GUIConstantsEx.au3>
#include <Array.au3>

; Beispiel-Optionen,
Global $aOpt1[][] = [[1,TRUE],[2,TRUE],[3,FALSE],[4,TRUE],[5,TRUE],[6,TRUE],[7,FALSE],[8,FALSE],[9,TRUE],[10,FALSE] ]
Global $aOpt2[][] = [[11,TRUE],[12,TRUE],[13,FALSE],[14,TRUE],[15,TRUE] ]
Global $aOpt3[][] = [[16,TRUE],[17,TRUE],[18,FALSE],[19,TRUE],[20,TRUE],[21,TRUE],[22,FALSE] ]


Opt("GUIOnEventMode", 1)

; HauptFenster anlegen
Local $hMainGUI = GUICreate("Beispiel", 400, 60)
GUISetOnEvent($GUI_EVENT_CLOSE, "CloseButton")

GUICtrlCreateButton("Optionen1 (1-10)", 30, 20,100)
GUICtrlSetOnEvent(-1, "Opt1")

GUICtrlCreateButton("Optionen2 (11-15)", 150, 20,100)
GUICtrlSetOnEvent(-1, "Opt2")

GUICtrlCreateButton("Optionen3 (16-22)", 270, 20,100)
GUICtrlSetOnEvent(-1, "Opt3")

GUISetState(@SW_SHOW, $hMainGUI)

While 1
Sleep(100) ; Sleep
WEnd

;-----------------------------------------------------

Func CloseButton()
Exit					;Programm verlassen
EndFunc


Func Opt1()
OptionsWindow("Optionen 1",$aOpt1)
EndFunc

Func Opt2()
OptionsWindow("Optionen 2",$aOpt2)
EndFunc

Func Opt3()
OptionsWindow("Optionen 3",$aOpt3)
EndFunc


; gemeinsames Optionen-Fenster, Fenstergrösse und Positionen werden nach Anzahl Optionen berechnet
Func OptionsWindow($sTitel,$aOptionen)
;_ArrayDisplay($aOptionen,"Optionen")
Local $iObj = UBound($aOptionen)

Local $hOptionsGUI = GUICreate($sTitel, 250,100+($iObj*20))
GUISetOnEvent($GUI_EVENT_CLOSE, "CloseOptionsButton")

GUICtrlCreateGroup($sTitel, 10, 10, 230, 30+($iObj*20))
For $x = 0 to $iObj-1
GUICtrlCreateCheckbox("Option " & $aOptionen[$x][0], 20, 30 + ($x*20))	; Optionstext aus Spalte 0
If $aOptionen[$x][1] Then GUICtrlSetState(-1,$GUI_CHECKED)					; ob Checked/Unckecked aus Spalte 1
Next

; einen gemeinsamen Button für OK
GUICtrlCreateButton("OK", 20, 60+($iObj*20), 80)
GUICtrlSetOnEvent(-1, "OKOptionsButton")
; und einen gemeinsamen Button für Close
GUICtrlCreateButton("Abbrechen", 150, 60+($iObj*20), 80)
GUICtrlSetOnEvent(-1, "CloseOptionsButton")

GUISetState(@SW_SHOW,$hOptionsGUI)
$iOptionsArrayIndex = 0
EndFunc


; Close ist kein Problem, es müssen keine Checkboxen abgefragt werden
Func CloseOptionsButton()		; gemeinsame CloseButton-Funktion für alle Options-Fenster
GUIDelete(@GUI_WinHandle)		; aktives Optionen-Fenster löschen
EndFunc


Func OKOptionsButton()
; wie erkenne ich hier welches Options-Fenster aktiv war um die Checkboses auszulesen und ins entsprechende Arry zu schreiben?
; kann man den Fenster-Titel abfragen (o.ä.) und die erzeugten Opjekte (Checkboses) abfragen
; event. geht das irgend wie über das @GUI_WinHandle

; hier würde ich gerne die Checkboxes abfragen
; Anzahl Checkboxes und dazugehörige ObjektID

;~ 	For $x = 0 to UBound( $ANZAHL )
;~ 		$aOptionen[$x][1] = _IsChecked(  $ObjectID  )
;~ 	Next

GUISetState(@SW_HIDE,@GUI_WinHandle)	; aktives Optionen-Fenster löschen
EndFunc

Alles anzeigen

Es geht mir da um die Funktion OKOptionsButton() ganz am Ende.

Gebt mir bitte mal einen Tip wie ich das lösen kann.

Vermutlich gibts da ja aber auch eine ganz andere (einfachere?) Lösung.

Danke, schon mal im vorraus.

**Oscar**

Das Problem ist, dass Du bei jedem Klick auf einen der Optionsbuttons ein neues Fenster erstellst, mit lokalen Variablen (der zweite Fehler).

Man könnte zwar rückwärts vom Ok-Button wieder das Parentfenster ermitteln und dort dann die Checkboxen, aber das ändert nichts daran, dass Du Dir ein Speicherleck schaffst, durch das ständige neu erstellen von den Fenstern.

Besser ist es die drei Optionenfenster am Anfang (global) zu erstellen und die IDs der Checkboxen in ein 2D-Array oder drei Einzelarrays speichern.

So lässt sich beim Klick auf "ok" leicht abfragen, welche Checkboxen gesetzt sind.

Bernhard65

Ist das Problem mit dem Speicherleck wirklich so gravierend?

Ich finde die Erstellung aller Fenster am Programmstart und dann mit SHOW und HIDE irgendwie nicht sehr elegand?

Ich habe nämlich jetzt für das gemeinsame Optionsfenter eine Lösung gefunden:

AutoIt

#include <GUIConstantsEx.au3>
#include <Array.au3>

; Beispiel-Optionen,
Global $aOpt1[][3] = [[1,TRUE],[2,TRUE],[3,FALSE],[4,TRUE],[5,TRUE],[6,TRUE],[7,FALSE],[8,FALSE],[9,TRUE],[10,FALSE] ]
Global $aOpt2[][3] = [[11,TRUE],[12,TRUE],[13,FALSE],[14,TRUE],[15,TRUE] ]
Global $aOpt3[][3] = [[16,TRUE],[17,TRUE],[18,FALSE],[19,TRUE],[20,TRUE],[21,TRUE],[22,FALSE] ]
;Array mit allen Option-Arrays und Index welche Opt 'aktiv', -1 = keins, sonst 1 bis 3
Global $aAll[] = [ -1, $aOpt1, $aOpt2, $aOpt3]


Opt("GUIOnEventMode", 1)

; HauptFenster anlegen
Local $hMainGUI = GUICreate("Beispiel", 400, 60)
GUISetOnEvent($GUI_EVENT_CLOSE, "CloseButton")

GUICtrlCreateButton("Optionen1 (1-10)", 30, 20,100)
GUICtrlSetOnEvent(-1, "Opt1")

GUICtrlCreateButton("Optionen2 (11-15)", 150, 20,100)
GUICtrlSetOnEvent(-1, "Opt2")

GUICtrlCreateButton("Optionen3 (16-22)", 270, 20,100)
GUICtrlSetOnEvent(-1, "Opt3")

GUISetState(@SW_SHOW, $hMainGUI)

While 1
Sleep(100) ; Sleep
WEnd

;-----------------------------------------------------

Func CloseButton()
Exit
EndFunc


Func Opt1()
OptionsWindow(1)
EndFunc

Func Opt2()
OptionsWindow(2)
EndFunc

Func Opt3()
OptionsWindow(3)
EndFunc


; gemeinsames Optionen-Fenster, Fenstergrösse und Positionen werden nach Anzahl Optionen berechnet
Func OptionsWindow($iIndex)

if $iIndex >= 1 AND $iIndex < UBound($aAll) Then
$aAll[0] = $iIndex
Local $aOptionen = $aAll[$iIndex]
Else
Return
EndIf

Local $iObj = UBound($aOptionen)

Local $hOptionsGUI = GUICreate("Optionen", 250,100+($iObj*20))
GUISetOnEvent($GUI_EVENT_CLOSE, "CloseOptionsButton")

GUICtrlCreateGroup("", 10, 10, 230, 30+($iObj*20))
For $x = 0 to $iObj-1
$aOptionen[$x][2] = GUICtrlCreateCheckbox("Option " & $aOptionen[$x][0], 20, 30 + ($x*20))	; Optionstext aus Spalte 0
If $aOptionen[$x][1] Then GUICtrlSetState(-1,$GUI_CHECKED)					; ob Checked/Unckecked aus Spalte 1
Next
$aAll[$iIndex] = $aOptionen

; einen gemeinsamen Button für OK
GUICtrlCreateButton("OK", 20, 60+($iObj*20), 80)
GUICtrlSetOnEvent(-1, "OKOptionsButton")
; und einen gemeinsamen Button für Close
GUICtrlCreateButton("Abbrechen", 150, 60+($iObj*20), 80)
GUICtrlSetOnEvent(-1, "CloseOptionsButton")

GUISetState(@SW_SHOW,$hOptionsGUI)
EndFunc


; Close ist kein Problem, es müssen keine Checkboxen abgefragt werden
Func CloseOptionsButton()		; gemeinsame CloseButton-Funktion für alle Options-Fenster
$aAll[0] = -1							; Index zurücksetzen
GUIDelete(@GUI_WinHandle)		; aktives Optionen-Fenster löschen
EndFunc


Func OKOptionsButton()
Local $iIndex = $aAll[0]				; aktuelles Optionsfenster 1-3
Local $aOptionen = $aAll[$iIndex]	; Array aus Array holen
For $x = 0 to UBound($aOptionen)-1	; alle gesicherden ObjIDs durchgehen
$aOptionen[$x][1] = _IsChecked($aOptionen[$x][2])	; und prüfen ob Checked/Unchecked
Next
$aAll[$iIndex] = $aOptionen			; Array in Array zurückschreiben

$aAll[0] = -1								; Index zurücksetzen

GUISetState(@SW_HIDE,@GUI_WinHandle)	; aktives Optionen-Fenster löschen
EndFunc

Func _IsChecked($idControlID)
Return BitAND(GUICtrlRead($idControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc

Alles anzeigen

Funktioniert sehr gut.

Alle Optionen werden bei OK ausgelesen und bei erneutem Aufruf sind die Optionen dementsprechend wieder gesetzt.

Aber wenn das mit dem Speicherleck so grosse Probleme bereitet muss ich das wohl doch anders machen.

**alpines**

Zitat von Bernhard65

Ist das Problem mit dem Speicherleck wirklich so gravierend?
Ich finde die Erstellung aller Fenster am Programmstart und dann mit SHOW und HIDE irgendwie nicht sehr elegand?

Nein, vom technischen Standpunkt her ist das heutzutage irrelevant aber es wird dir später das Genick brechen wenn plötzlich die Controls auf alte GUIs referenziert werden die nicht mehr existieren.

Wenn du trotzdem immer die Fenster neu erstellen willst solltest du auch die Fenster löschen wenn du sie neu erstellst, dann hast du das Problem nicht mehr.

Jedoch gehen dann sämtliche Eingaben verloren wenn du das Fenster wieder hervorholst und du musst sie erneut reinschreiben, deshalb werden grundsätzlich Fenster erzeugt und bei Bedarf versteckt oder angezeigt.

**BugFix**

Zitat von Bernhard65

Ich finde die Erstellung aller Fenster am Programmstart und dann mit SHOW und HIDE irgendwie nicht sehr elegand?

Glaub mir, es ist die eleganteste Variante überhaupt. Denn elegant hat auch was mit Effizienz zu tun. Abgesehen davon, dass du mit deiner Variante dein Skript früher oder später crashst, musst du alle anzuzeigenden Elemente ständig neu erstellen. Das frisst Zeit und Speicher - wie kann das elegant sein?

misterspeed

Je nach Fall kann man es sich auch sparen mehrere verschiedene aber sehr gleichartige Fenster zu erstellen.

Hab dein Script zwar nur überflogen, aber mein Eindruck war, dass deine Optionen Fenster sich kaum unterscheiden. Da wäre es auch eine möglichkeit nur mit unterschiedlichen Control-Gruppen zu arbeiten, welche je nach gewünschter "Otionsseite" ein- oder ausgebelendet werden.

Professor Bernd

@Bernhard65

Vielleicht denke ich zu einfach, aber wäre das hier nicht ein Fall für ein Tab-Control?

Bernd.

Bernhard65

Naja, das es für das Optionen-Anzeige-Fenster noch viele (bessere) Lösungen gibt (Control-Gruppen, Tab-Control...) möchte ich gar nicht bestreiten.

Mir ging es ja eigentlich eher darum, wie man aus dem @GUI_WinHandle die enthaltenen Objekte in dem Fenster ermitteln kann, um dann Status, Texte, usw. abzufragen.

Falls das jemand weiß, ich wäre sehr interessiert daran (ohne dass ich vorher die Obiekt-IDs alle speichern muss).

BTW: In meinem letztem Skript habe ich natürlich noch einen Fehler in Zeile 103

Statt

AutoIt

GUISetState(@SW_HIDE,@GUI_WinHandle)

muß es natürlich

AutoIt

GUIDelete(@GUI_WinHandle)

heißen.

Sonst entstehen wirklich Speicher-Leaks.

Habe inzwischen zu Multiple GUIs diese Seite gefunden

https://www.autoitscript.com/wiki/Managing_Multiple_GUIs

**Oscar**

Zitat von Bernhard65

Mir ging es ja eigentlich eher darum, wie man aus dem @GUI_WinHandle die enthaltenen Objekte in dem Fenster ermitteln kann, um dann Status, Texte, usw. abzufragen.
Falls das jemand weiß, ich wäre sehr interessiert daran (ohne dass ich vorher die Obiekt-IDs alle speichern muss).

Buttons oder generell alle Control-Elemente sind unter Windows einfach nur Child-Fenster.

Hat man das Handle vom Hauptfenster kann man sich alle "Kinder" auflisten lassen:

AutoIt

#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <WinAPISysWin.au3>

Opt('GUIOnEventMode', 1)

_CreateGui()

While Sleep(1000)
WEnd

Func _CreateGui()
    GUICreate('Test1234', 640, 480)
    GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
    GUICtrlCreateButton('B1', 10, 10, 60, 20)
    GUICtrlCreateButton('B2', 100, 10, 60, 20)
    GUICtrlCreateButton('B3', 200, 10, 60, 20)
    GUICtrlCreateButton('Show button infos', 80, 60, 120, 25)
    GUICtrlSetOnEvent(-1, '_ShowButtonInfo')
    GUISetState()
EndFunc

Func _CloseGui()
    GUIDelete(@GUI_WinHandle)
    Exit
EndFunc

Func _ShowButtonInfo()
    Local $ahChilds = _WinAPI_EnumChildWindows(@GUI_WinHandle)
    If @error Then Return
    Local $iCount = $ahChilds[0][0]
    Local $aOut[$iCount][3]
    For $i = 1 To $iCount
        $aOut[$i-1][0] = $ahChilds[$i][0] ; das Handle des Buttons
        $aOut[$i-1][1] = _WinAPI_GetDlgCtrlID($ahChilds[$i][0]) ; die ID des Buttons
        $aOut[$i-1][2] = WinGetTitle($ahChilds[$i][0]) ; der Titel des Buttons
    Next
    _ArrayDisplay($aOut, 'Output', '', 0, Default, 'Handle|ID|Title')
EndFunc

Alles anzeigen

Bernhard65

Super,

genau was ich gemeint hatte.

Danke