Herausfinden, welcher Button die Funktion mit GUICtrlSetOnEvent aufgerufen hat

aSeCa

Hey,

ich kann es zu schlecht in kurzen Worten beschreiben, um via Google etwas dazu zu finden. Ich hoffe, jemand kann mir helfen, ich glaube, ich habe das schon mal irgendwo gesehen.

Ausgangslage: Eine GUI, die für verschiedene Objekte immer die gleiche Auswahlmöglichkeiten bietet, so auch einen "Bearbeiten"-Button.

Ziel: Ich möchte natürlich nur eine "Bearbeiten-Funktion" haben, also würde ich mit GUICtrlSetOnEvent immer diese aufrufen. Jetzt soll aber das Bearbeiten natürlich nur genau auf das Objekt wirken, das ich bearbeiten möchte und dafür müsste ich "nachträglich" wissen, welcher Button diese Funktion aufgerufen hat. Das sollte natürlich dynamisch sein, ohne "Helper-Funktionen", ala "Config_1 ruft "Config(1)" auf und Config_2 ruft "Config(2)" auf" oder so.

Minimal-Beispiel:

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>

Opt("GUIOnEventMode", 1)

Local $hGUI = GUICreate("Example", 300, 200)
Local $idButton1 = GUICtrlCreateButton("Config_1", 120, 170, 85, 25)
GUICtrlSetOnEvent($idButton1, "_test")
Local $idButton2 = GUICtrlCreateButton("Config_2", 210, 170, 85, 25)
GUICtrlSetOnEvent($idButton2, "_test")

GUISetState(@SW_SHOW, $hGUI)

While Sleep(50)
WEnd

Func _test()
    ConsoleWrite("Button Nr. " & "?" & @CRLF)

    Sleep(1000)

    GUIDelete($hGUI)
    Exit
EndFunc

Alles anzeigen

=> ich möchte, dass das "?" ersetzt wird, durch die "1" (oder "2).

Danke für die Unterstützung!

**alpines**

@GUI_CtrlHandle

@GUI_CtrlId

aSeCa

Danke dir! Damit habe ich es mit dem Testscript auf jeden Fall hinbekommen.

Im Beispielscript erstelle ich sie ja nicht dynamisch, da wäre das dann so:

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>

Opt("GUIOnEventMode", 1)

Local $hGUI = GUICreate("Example", 300, 200)
Local $idButton1 = GUICtrlCreateButton("Config_1", 120, 170, 85, 25)
GUICtrlSetOnEvent($idButton1, "_test")
Local $idButton2 = GUICtrlCreateButton("Config_2", 210, 170, 85, 25)
GUICtrlSetOnEvent($idButton2, "_test")

GUISetState(@SW_SHOW, $hGUI)

While Sleep(50)
WEnd

Func _test()
;~     ConsoleWrite("Button 1 ID " & $idButton1 & @CRLF)
;~     ConsoleWrite("Button 2 ID " & $idButton2 & @CRLF)
;~     ConsoleWrite("---" & @CRLF)

    ConsoleWrite("Button Handle " & @GUI_CtrlHandle & @CRLF)
    ConsoleWrite("Button ID " & @GUI_CtrlId & @CRLF)

    If @GUI_CtrlId == $idButton1 Then
        ConsoleWrite("Button Nr. 1" & @CRLF)
    ElseIf @GUI_CtrlId == $idButton2 Then
        ConsoleWrite("Button Nr. 2" & @CRLF)
    Else
        ConsoleWrite("??? O.o" & @CRLF)
    EndIf

    Sleep(1000)

    GUIDelete($hGUI)
    Exit
EndFunc

Alles anzeigen

Das hat die Frage dann auch direkt geklärt, super!

**Oscar**

Bei dynamisch erstellten Buttons kommst Du um Arrays nicht herum.

Hier mal ein Beispiel:

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>

Opt("GUIOnEventMode", 1)

Global $aidButton[6]

Global $hGUI = GUICreate("Example", 300, 200)
For $i = 0 To UBound($aidButton) - 1
    $aidButton[$i] = GUICtrlCreateButton("Config_" & $i + 1, 20, 10 + $i * 30, 85, 25)
    GUICtrlSetOnEvent(-1, "_test")
Next

GUISetState(@SW_SHOW, $hGUI)

While Sleep(50)
WEnd

Func _test()
    Local $iIndex = @GUI_CtrlId - $aidButton[0]
    ConsoleWrite('Config: ' & $iIndex + 1 & @CR)
    Sleep(1000)
    GUIDelete($hGUI)
    Exit
EndFunc

Alles anzeigen

aSeCa

Danke auch an dich!

Ich benutze ISN AutoIt Studio, da ist das Erstellen der Forms echt bequem. Leider ist das für so dynamische Fälle etwas uncool, da ich dann den Überblick verliere, wo noch überall Controls sind (/sein werden).

Daher schiebe ich das erstmal vor mir her und mache es per späterem Refactoring "schön" (/dynamisch).

Dann wird mir der Array-Impuls auf jeden Fall helfen.

Professor Bernd

Zitat von aSeCa

If @GUI_CtrlId == $idButton1 Then

aSeCa Pssst! Geheimtipp. Das "==" nutzt dir nur was bei Strings.

Bernd.

**alpines**

Zitat von Professor Bernd

aSeCa Pssst! Geheimtipp. Das "==" nutzt dir nur was bei Strings.

Code

Local $b1 = False = 0
Local $b2 = False == 0

MsgBox(0, 0, _
    "b1 = " & $b1 & @CRLF & _
    "b2 = " & $b2 _
)