Text im Label dynamisch darstellen

hipfzwirgel

Hallole an alle,

Mit GUICtrlSetResizing(-1, $GUI_DOCKAUTO) ist das mit -1 angesprochene Control dynamisch die Größenänderung betreffend. So weit so Gut.

Wende ich das auf ein Label an, geht das zwar auch, jedoch der Text bleibt immer in der gleichen Größe.

Kann man den Text eines Labels auch i-wie dynamisieren das er seine Größe auch ändert, wenn sich das Fenster in der Größe ändert?

ein Beispiel-Label aus meinem Proggi:

Code

$Label7 = GUICtrlCreateLabel("Erase", 32, 399, 190, 25)
GUICtrlSetFont(-1, 12, 800, 0, "Bosch Sans Bold")
GUICtrlSetColor(-1, 0x000000)
GUICtrlSetResizing(-1, $GUI_DOCKAUTO)

Ja, ich habe den Text "formatiert" aber auch Standardtext wird nicht angepasst....

Bisher wird der Text eben abgeschnitten wenn das Fenster verkleinert wird anstatt angepasst...

**Moombas**

Noch nie genutzt aber müsste das nicht mit https://www.autoitscript.com/autoit3/docs/f…SetResizing.htm dem Label mitgeteilt werden können?

**BugFix**

Zitat von hipfzwirgel

Bisher wird der Text eben abgeschnitten wenn das Fenster verkleinert wird anstatt angepasst..

Das Resizing hat nur Einfluss auf die Abmessung des Labels, die Fontgröße hat damit nichts zu tun. Wenn du das zusätzlich anpassen möchtest, musst du WM_SIZING auswerten und im Verhältnis zur Größenänderung die Schriftgröße anpassen.

Aber den Zahn kann ich dir gleich ziehen - denn das funktioniert einfach nicht!

Ursache: Durch das Ermitteln des Verhältnisses musst du zwangsläufig runden. Die Rundungsdifferenzen führen dazu, dass bei mehrfacher Größenänderung du niemals zurück zur Anfangsgröße gelangst. Irgendwann wird die Schrift dann überproportional groß oder klein. Habe ich schon mal probiert.

**Bitnugger**

Zitat von BugFix

Die Rundungsdifferenzen führen dazu, dass bei mehrfacher Größenänderung du niemals zurück zur Anfangsgröße gelangst.

Ja, genau das ist das Problem... aber nur mal so als Idee... wir können Windows ja die Größe des Labels bestimmen lassen. Dazu wird dann ein Label in einer separaten GUI erstellt, ohne dabei die Größe anzugeben. Vor Erstellen des Labels setzen wir die Schriftgröße für die GUI entsprechend der Auswertung von WM_SIZING, also größer oder kleiner, die dann auch für das Label verwendet wird. Das Erstellen des Labels wiederholen wir dann mit größerer oder kleinerer Schriftgröße so oft, bis die passende Größe gefunden wurde.

**Oscar**

Mit GDI+ und dem Befehl _GDIPlus_GraphicsMeasureString kann man die Fontgröße experimentell ermitteln.

Das funktioniert zwar nicht ganz perfekt, weil teilweise angezeigte Zeilen auch mit gerechnet werden, aber zumindest sieht es schonmal ganz gut aus:

AutoIt

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WinAPISysInternals.au3>
#include <WindowsConstants.au3>

Global $sText = 'When a GUI window is resized the controls within react - how they react is determined by this function. To be able to resize a GUI window it needs to have been created with the $WS_SIZEBOX and $WS_SYSMENU styles. See GUICreate().'

Global $hGui = GUICreate('Test', 640, 110, -1, -1, $WS_SIZEBOX + $WS_SYSMENU)
Global $idLabel = GUICtrlCreateLabel($sText, 10, 10, 620, 60)
GUICtrlSetResizing(-1, $GUI_DOCKAUTO)
GUICtrlSetFont($idLabel, _GetFontSize($idLabel, $sText, 'Arial'))
GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_SIZING, '_WM_SIZING')
While 1
    Local $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WM_SIZING($hWnd, $iMsg, $wParam, $lParam)
    GUICtrlSetFont($idLabel, _GetFontSize($idLabel, $sText, 'Arial'))
    Return $GUI_RUNDEFMSG
EndFunc

Func _GetFontSize($idCtrl, $sText, $sFont)
    Local $hWnd, $hParent, $aPos, $hGraphic, $hFormat, $hFamily, $iFontSize, $hFont, $tLayout
    $hWnd = GUICtrlGetHandle($idCtrl)
    If Not IsHWnd($hWnd) Then Return SetError(1, 0, 0)
    $hParent = _WinAPI_GetParent($hWnd)
    $aPos = ControlGetPos($hParent, '', $hWnd)
    If @error Then Return SetError(2, 0, 0)
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hWnd)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate($sFont)
    $iFontSize = 100
    Do
        $iFontSize -= 1
        $hFont = _GDIPlus_FontCreate($hFamily, $iFontSize)
        $tLayout = _GDIPlus_RectFCreate(0, 0, $aPos[2], $aPos[3])
        $aInfo = _GDIPlus_GraphicsMeasureString($hGraphic, $sText, $hFont, $tLayout, $hFormat)
        _GDIPlus_FontDispose($hFont)
    Until $aInfo[1] >= StringLen($sText)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
    Return $iFontSize
EndFunc

Alles anzeigen

**Moombas**

Zitat von BugFix

Das Resizing hat nur Einfluss auf die Abmessung des Labels, die Fontgröße hat damit nichts zu tun. Wenn du das zusätzlich anpassen möchtest, musst du WM_SIZING auswerten und im Verhältnis zur Größenänderung die Schriftgröße anpassen.
Aber den Zahn kann ich dir gleich ziehen - denn das funktioniert einfach nicht!
Ursache: Durch das Ermitteln des Verhältnisses musst du zwangsläufig runden. Die Rundungsdifferenzen führen dazu, dass bei mehrfacher Größenänderung du niemals zurück zur Anfangsgröße gelangst. Irgendwann wird die Schrift dann überproportional groß oder klein. Habe ich schon mal probiert.

Jaein, wenn du die Standardfenstergröße als Default (Const) Wert nimmst wäre das doch egal.

Sprich Standardfenstergröße (z.B. 1000px = 100%) zu neuer Fenstergröße (z.B. 768px = X%) ins Verhältnis setzen und dementsprechend die Standardschriftgröße vergrößern/verkleinern (Dreisatz). Faktor = X% / 100

AutoIt

Global Const $DefaultWidth = 1000 ;px
Global Const $DefaultHeight = 1000 ;px
Global Const $DefaultFontSize = 16

Local Const $NewWidth  = 768 ;px ermittelt!
Local Const $NewHeight = 768 ;px ermittelt!
Local $NewFontSize, $NewFontSize2
$NewFontSize  = $DefaultFontSize * ((($NewWidth  * 100) / $DefaultWidth ) / 100)
$NewFontSize2 = $DefaultFontSize * ((($NewHeight * 100) / $DefaultHeight) / 100)
if $NewFontSize > $NewFontSize2 then $NewFontSize = $NewFontSize2
; dann wäre $NewFontSize immer der zu verwendende Wert.

Alles anzeigen

Ggf. musst du beides betrachten (Breite und Höhe) und dann den kleineren Wert wählen. Aber dadurch das du immer die Ausgangsgröße als Maßstab nimmst, müsste das Verhältnis immer passen (und auch immer wieder zum Startwert zurückkehren können).

**Oscar**

Zitat von Oscar

Mit GDI+ und dem Befehl _GDIPlus_GraphicsMeasureString kann man die Fontgröße experimentell ermitteln.
Das funktioniert zwar nicht ganz perfekt, weil teilweise angezeigte Zeilen auch mit gerechnet werden, aber zumindest sieht es schonmal ganz gut aus:

Ich zitiere mich mal.

Wenn man mein Script noch etwas abwandelt, funktioniert es perfekt.

Man muss nur zusätzlich die Zeilenhöhe einrechnen:

AutoIt

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WinAPISysInternals.au3>
#include <WindowsConstants.au3>

Global $sText = 'When a GUI window is resized the controls within react - how they react is determined by this function. To be able to resize a GUI window it needs to have been created with the $WS_SIZEBOX and $WS_SYSMENU styles. See GUICreate().'

Global $hGui = GUICreate('Test', 640, 110, -1, -1, $WS_SIZEBOX + $WS_SYSMENU)
Global $idLabel = GUICtrlCreateLabel($sText, 10, 10, 620, 60)
GUICtrlSetResizing(-1, $GUI_DOCKAUTO)
GUICtrlSetFont($idLabel, _GetFontSize($idLabel, $sText, 'Arial'))
GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_SIZING, '_WM_SIZING')
While 1
    Local $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WM_SIZING($hWnd, $iMsg, $wParam, $lParam)
    GUICtrlSetFont($idLabel, _GetFontSize($idLabel, $sText, 'Arial'))
    Return $GUI_RUNDEFMSG
EndFunc

Func _GetFontSize($idCtrl, $sText, $sFont)
    Local $hWnd, $tRect, $iW, $iH, $hGraphic, $hFormat, $hFamily, $iFontSize, $hFont, $tLayout
    $hWnd = GUICtrlGetHandle($idCtrl)
    If Not IsHWnd($hWnd) Then Return SetError(1, 0, 0)
    $tRect = _WinAPI_GetWindowRect($hWnd)
    $iW = $tRect.right - $tRect.left
    $iH = $tRect.bottom - $tRect.top
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hWnd)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate($sFont)
    $iFontSize = 200
    Do
        $iFontSize -= 1
        $hFont = _GDIPlus_FontCreate($hFamily, $iFontSize)
        $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
        $aInfo = _GDIPlus_GraphicsMeasureString($hGraphic, $sText, $hFont, $tLayout, $hFormat)
        _GDIPlus_FontDispose($hFont)
    Until ($aInfo[1] >= StringLen($sText)) and ($aInfo[2] * $iFontSize * 1.6 < $iH)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
    Return $iFontSize
EndFunc

Alles anzeigen