zahlenfolge in einer Datei korrigieren

MojoeB

Hallo zusammen,

Kann mir jemand helfen, irgendwas ist da falsch, eigentlich möchte ich nur die Zahlen in der Datei neu.txt

Code

<aktenid Akte=" ZAHL ">

in Rheinfolge einordnen also 0 1 2 3 unsw.

Wenn aber mal eine Nummer 2 mal vorkommt dann ersetze mit der Zahl in der Rheinfolge.

C

#include <String.au3>
#include <File.au3>
;~ #include <array.au3>
    $data1='neu.txt'
_korrigiere_zahlen($data1)
func _korrigiere_zahlen($datei); Korrigiert die rheinfolge bei Löschen eines Eintrages.

Local $iWerte[0]

    $rFile =FileRead($datei)
    $iWerte=_StringBetween($rFile, '<aktenid Akte="', '">')
    For $i = 0 To UBound($iWerte)-1 step 1
        ConsoleWrite($iWerte[$i]&'   -   '&$i&@CRLF)
        _ReplaceStringInFile($datei, '<aktenid Akte="' & $iWerte[$i] & '">', '<aktenid Akte="' & $i & '">', '', 1)
    Next
EndFunc

Alles anzeigen

**Moombas**

Ich würde das direkt mit arrays machen:

AutoIt

Opt('MustDeclareVars', 1)
#include <String.au3>
#include <File.au3>
#include <array.au3>
Global Const $data1='neu.txt'
_korrigiere_zahlen($data1)

func _korrigiere_zahlen($datei); Korrigiert die rheinfolge bei Löschen eines Eintrages.
Local Const $rFile = FileRead($datei)
Local $iWerte =_StringBetween($rFile, '<aktenid Akte="', '">')

    For $i = 0 to UBound($iWerte)-1 Step 1 ;Strings in Zahlen umwandeln
        $iWerte[$i] = Number($iWerte[$i])
    Next
    _ArraySort($iWerte, Default, Default, Default, Default, 1) ; Array sortieren

    For $i = UBound($iWerte)-1 To 1 step -1 ;Array um doppelte Werte erleichtern
        if $iWerte[$i] = $iWerte[$i - 1] Then _ArrayDelete($iWerte, $i)
    Next

EndFunc

Alles anzeigen

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi MojoeB ,

für den Fall das deine XML-Datei konstant aufgebaut ist und du wirklich nur die XML-Knoten Werte von "aktenid" ersetzen willst und nicht die Kind-Knoten darunter ebenfalls neu sortieren willst/musst, ist die Sache recht einfach 😁 :

AutoIt

; includes ---------------------------------------------------------------------
#include-once
#include <Array.au3>



; opt --------------------------------------------------------------------------
Opt('MustDeclareVars', 1)



; declaration ------------------------------------------------------------------
Global $sXmlFilePath   = 'neu.txt'
Global $sSearchPattern = '<aktenid Akte="\d+">'



; processing -------------------------------------------------------------------
Global $sFileContent                    = _getFileContent($sXmlFilePath)
Global $sDelimiter                      = @CRLF
Global $aFileContent                    = _fileContentToArray($sFileContent)
Global $aFileContentWithReplacedNumbers = _replaceNumberInArray($aFileContent)
Global $sNewFileContent                 = _reformatArrayToExpectedString($aFileContentWithReplacedNumbers)

_writeFile($sXmlFilePath, $sNewFileContent)



; functions --------------------------------------------------------------------
Func _getFileContent($sFile)
    Local Const $iUtf8WithoutBomMode = 256

    Local $hFile        = FileOpen($sFile, $iUtf8WithoutBomMode)
    Local $sFileContent = FileRead($hFile)
    FileClose($hFile)

    Return $sFileContent
EndFunc

Func _fileContentToArray($sContent)
    Local Const $iEntireDelimiter = 1

    Return StringSplit($sContent, $sDelimiter, $iEntireDelimiter)
EndFunc

Func _replaceNumberInArray($aList)
    Local $iNumber = 0
    Local $iCount  = $aList[0]

    For $i = 1 To $iCount Step 1
        If StringRegExp($aList[$i], $sSearchPattern) Then
            $aList[$i] = StringRegExpReplace($aList[$i], '(\d+)', $iNumber)
            $iNumber += 1
        EndIf
    Next

    Return $aList
EndFunc

Func _writeFile($sFile, $sText)
    Local Const $iUtf8WithoutBomAndOverwriteCreationMode = 256 + 2 + 8

    Local $hFile = FileOpen($sFile, $iUtf8WithoutBomAndOverwriteCreationMode)
    FileWrite($hFile, $sText)
    FileClose($hFile)
EndFunc

Func _reformatArrayToExpectedString($aList)
    _ArrayDelete($aList, 0)

    Return _ArrayToString($aList, $sDelimiter)
EndFunc

Alles anzeigen

Ich bin gespannt ob ich dich richtig verstanden habe.
Wenn dir die Benamung der Funktionen und Variablen als Erklärung nicht ausreicht, dann sage bitte Bescheid 😉 .

Viele Grüße
Sven

Velted

Mahlzeit!

Und hier noch die eher 'klassische' Methode aus den 'guten alten Zeiten':

AutoIt

#include <Array.au3>
#include <FileConstants.au3>
#include <MsgBoxConstants.au3>

Opt("MustDeclareVars", 1)

Dim $sDatEin = @ScriptDir & "\Neu.xml"
Dim $sDatTmp = @ScriptDir & "\__Temp__.xml"
Dim $hEingabe = FileOpen($sDatEin, $FO_READ)
If $hEingabe = -1 Then
    MsgBox(16, "Fehler!", "Kann die Datei " & $sDatEin & " nicht öffnen!")
    Exit
EndIf
Dim $hAusgabe = FileOpen($sDatTmp, $FO_OVERWRITE)
If $hAusgabe = -1 Then
    MsgBox(16, "Fehler!", "Kann die Datei " & $sDatTmp & " nicht öffnen!")
    Exit
EndIf
Dim $n = 0
Dim $sLine
While True
    $sLine = FileReadLine($hEingabe)
    If (@error = -1) Then ExitLoop
    If StringInStr($sLine, '<aktenid Akte="') Then
        $n += 1
        $sLine = StringRegExpReplace($sLine, "\d+", $n)
    EndIf
    FileWriteLine($hAusgabe, $sLine)
WEnd
FileClose($hEingabe)
FileClose($hAusgabe)
Dim $aFile = FileReadToArray($sDatTmp)
_ArrayDisplay($aFile)
Dim $iRval = MsgBox(36, "Überschreiben", "Soll die Datei " & $sDatEin & " überschrieben werden?")
If $iRval = $IDYES Then
    MsgBox(0, "", "FileMove($sDatTmp, $sDatEin, $FC_OVERWRITE)") ; FileMove($sDatTmp, $sDatEin, $FC_OVERWRITE)
EndIf

Alles anzeigen

Meine Annahmen darüber, was das Skript tun soll, decken sich mit denen von SOLVE-SMART.

**Musashi**

Hier ein weiterer 'rustikaler' Lösungsansatz :

AutoIt

#include <File.au3>
Local $sData1='neu.txt'
_korrigiere_zahlen($sData1)
func _korrigiere_zahlen($sDatei); Reihenfolge korrigieren
    Local $aRetArray, $iCounter = 0
    _FileReadToArray($sDatei, $aRetArray, $FRTA_NOCOUNT)
    For $i = 0 To UBound($aRetArray) - 1 step 1
        If StringRegExp($aRetArray[$i], '<aktenid Akte=') Then
            $aRetArray[$i] = @TAB & '<aktenid Akte="' & $iCounter & '">'
            $iCounter += 1
        EndIf
    Next
     _FileWriteFromArray($sDatei, $aRetArray)
EndFunc

Alles anzeigen

MojoeB

@Moombas : leider funktioniert deine Methode in meinem Beispiel nicht so wie ich mir das Vorstelle dennoch danke für deine Mühe.

@SOLVE-SMART & Velted :

Beide eure, Methoden funktionieren, super auch mit meiner Beispieldatei zusammen. Danke euch

@SOLVE-SMART :

Deine Skript sieht so schön Clean aus, ich werde es in mein Skript mit einbauen. Und wenn alles gebaut ist schauen ob es dann auch noch so super funkitoniert :).

Danke für die zu Arbeit.

MojoeB

@Musashi : ich war zu langsam

Deins funktioniert auch sehr gut '! Dankesehr.

**Moombas**

MojoeB Was hat denn nicht funktioniert? Er sortiert korrekt und entfernt doppelte Werte.

Da du das abspeichern nicht im Beispiel hattest, habe ich das weg gelassen (Endwert kann über _ArrayDisplay() geprüft werden).

Geprüft habe ich das auch mit deiner Datei, daher würde mich das interessieren.

**SOLVE-SMART** · Poweruser seit 21.01.2023

Hi MojoeB ,

freut mich, ich drück die Daumen das du gut mit deinem Projekt vorankommst.

Zitat von MojoeB

SOLVE-SMART :
Deine Skript sieht so schön Clean aus, ich werde es in mein Skript mit einbauen.

Made my day 👍 😊 , "Clean" => love it 😅 .

Auch wenn ich die "[...] eher 'klassische' Methode aus den 'guten alten Zeiten' [...]" ( Velted) und den "[...] 'rustikaler' Lösungsansatz [...]" ( Musashi) zum Schießen witzig finde 😂 .
Ist positiv gemeint ihr beiden, kurz, old school und rustikal 👍 .

Viele Grüße
Sven

MojoeB

Moombas, Ja dein Ergebnis ist ja auch nicht falsch, nur nicht so wie ich es erwartet hatte.

Ich habe mich bestimmt auch nicht ganz gut ausgedrückt.

im Grunde soll es bei 0 anfangen und dann nummeriert werden. <aktenid Akte="ZAHL">

bsp . als ist zustand der Datei sieht das Konstrukt so aus (kann natürlich auch anders aussehen :

...

</aktenid>

...

</aktenid>

...

</aktenid>

...

</aktenid>

Und so ist der SOLL zustand :

...

</aktenid>

...

</aktenid>

...

</aktenid>

...

</aktenid>

="ZAHL">

Nur ZAHL soll in der reinfolge ersetzt bzw. geändert werden in Fortlaufende Nummern.

Dein Beispiel löscht die doppelten Nummern und ersetzt diese nicht in Fortlaufende Nummern, allerdings ist das Array richtig geordnet.

Deswegen Moombas dein Lösungsvorschlag war nicht falsch aber nicht das was ich erreichen wollte, ich hab mich auch mal wieder doof ausgedrückt

**Moombas**

Okay, verständnis bzw. Verständigungsproblem

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)

🌍	Au3Forums
🎲	AutoIt (de) Cheat Sheet / en
💎	Code Katas: Eins, Zwei, Drei
🔮	GitHub
🥳	Poweruser seit 21.01.2023
🎭	Sammlung von GitHub Benutzern mit AutoIt Projekten
🔭	Umgang mit Powershell-Output
🔭	Umgang mit SQLite
✂	VSCode-AutoItSnippets
🎬	WebDriver Crashkurs
📑	WebDriver FAQs
👨‍💻	WebDriver Beispiel (Login, Klicks, Daten eingeben, robustes Warteverhalten)
👨‍💻	WebDriver Beispiel (Texte von Website lesen, in CSV überführen)