Datensätze als Array of struct speichern

**Oscar**

Für mein aktuelles Projekt machte ich mir gerade darüber Gedanken, wie ich die Datensätze im Programm verwalten will und kam zu dem Schluß, dass ein "Array of struct" eigentlich ganz gut dafür geeignet ist.

Vor allem sieht man im Quelltext dann auch gleich welche Daten wo liegen, weil man sie über die Punktnotation ansprechen kann. Das ist gegenüber einem 2D-Array ein großer Vorteil.

Aber auch das Laden und Speichern der Daten ist so viel unkomplizierter. Vielleicht könnt ihr das ja auch gebrauchen...

Hier mal ein Beispiel dazu:

AutoIt

#include <WinAPIHObj.au3>
#include <WinAPIInternals.au3>

; Datenstruktur definieren
Global Const $tagWORKER = 'struct;uint ID;char Nachname[60];char Vorname[60];char Geburtstag[8];' & _
        'char Strasse[60];char HausNr[6];char PLZ[5];char Wohnort[60];char TelNr[20];endstruct'

; Das "Array of struct" erstellen
Global $g_aWorker[2]
For $i = 0 To UBound($g_aWorker) - 1
    $g_aWorker[$i] = DllStructCreate($tagWORKER)
Next

#Region "Array of struct" mit Testdaten fuellen
$g_aWorker[0].ID = 10000
$g_aWorker[0].Nachname = 'Meiselbach'
$g_aWorker[0].Vorname = 'Karl-Heinz'
$g_aWorker[0].Geburtstag = '19640428'
$g_aWorker[0].Strasse = 'Josef-Zinnbauer-Straße'
$g_aWorker[0].HausNr = '308D'
$g_aWorker[0].PLZ = '75633'
$g_aWorker[0].Wohnort = 'Hintertupfingen'
$g_aWorker[0].TelNr = '+49 7366 783411'

$g_aWorker[1].ID = 10001
$g_aWorker[1].Nachname = 'Rotfuss'
$g_aWorker[1].Vorname = 'Theodor'
$g_aWorker[1].Geburtstag = '19591030'
$g_aWorker[1].Strasse = 'Am alten Forsthaus'
$g_aWorker[1].HausNr = '33'
$g_aWorker[1].PLZ = '58721'
$g_aWorker[1].Wohnort = 'Kronsbach'
$g_aWorker[1].TelNr = '+49 4862 11598'
#EndRegion

ConsoleWrite('Vor dem speichern auf Festplatte:' & @CRLF)
ConsoleWrite('$g_aWorker[0].Nachname = ' & $g_aWorker[0].Nachname & @CRLF)
ConsoleWrite('$g_aWorker[0].Wohnort = ' & $g_aWorker[0].Wohnort & @CRLF)
ConsoleWrite('$g_aWorker[0].TelNr = ' & $g_aWorker[0].TelNr & @CRLF)
ConsoleWrite('$g_aWorker[1].Nachname = ' & $g_aWorker[1].Nachname & @CRLF)
ConsoleWrite('$g_aWorker[1].Wohnort = ' & $g_aWorker[1].Wohnort & @CRLF)
ConsoleWrite('$g_aWorker[1].TelNr = ' & $g_aWorker[1].TelNr & @CRLF & @CRLF)

Global Const $sDatafile = @ScriptDir & '\Data.bin'
_WriteData($sDatafile) ; alle Daten auf Festplatte speichern
$g_aWorker = 0 ; Array of struct loeschen
_ReadData($sDatafile) ; die Daten wieder von der Festplatte laden

ConsoleWrite('Nach dem laden von Festplatte:' & @CRLF)
ConsoleWrite('$g_aWorker[0].Nachname = ' & $g_aWorker[0].Nachname & @CRLF)
ConsoleWrite('$g_aWorker[0].Wohnort = ' & $g_aWorker[0].Wohnort & @CRLF)
ConsoleWrite('$g_aWorker[0].TelNr = ' & $g_aWorker[0].TelNr & @CRLF)
ConsoleWrite('$g_aWorker[1].Nachname = ' & $g_aWorker[1].Nachname & @CRLF)
ConsoleWrite('$g_aWorker[1].Wohnort = ' & $g_aWorker[1].Wohnort & @CRLF)
ConsoleWrite('$g_aWorker[1].TelNr = ' & $g_aWorker[1].TelNr & @CRLF)

Func _WriteData($sPath)
    Local $hFile, $nBytes, $tData
    $hFile = _WinAPI_CreateFile($sPath, 1, 4) ; 1 = create file if not exist, 4 = write access
    If Not $hFile Then Return
    $tData = DllStructCreate('uint Count;')
    $tData.Count = UBound($g_aWorker)
    _WinAPI_WriteFile($hFile, $tData, DllStructGetSize($tData), $nBytes)
    For $i = 0 To UBound($g_aWorker) - 1
        _WinAPI_WriteFile($hFile, $g_aWorker[$i], DllStructGetSize($g_aWorker[$i]), $nBytes)
    Next
    _WinAPI_CloseHandle($hFile)
EndFunc

Func _ReadData($sPath)
    Local $hFile, $nBytes, $tData
    $hFile = _WinAPI_CreateFile($sPath, 2, 2) ; 2 = open file, 2 = read access
    If Not $hFile Then Return
    $tData = DllStructCreate('uint Count;')
    _WinAPI_ReadFile($hFile, $tData, DllStructGetSize($tData), $nBytes)
    Global $g_aWorker[$tData.Count]
    For $i = 0 To $tData.Count - 1
        $g_aWorker[$i] = DllStructCreate($tagWORKER)
        _WinAPI_ReadFile($hFile, $g_aWorker[$i], DllStructGetSize($g_aWorker[$i]), $nBytes)
    Next
    _WinAPI_CloseHandle($hFile)
EndFunc

Alles anzeigen

**water**

Coole Sache 👍

**Musashi**

Danke ! Auch von mir den

**chesstiger**

Ja, das ist eine sehr schöne Idee. Auf Structs bin ich an der Stelle noch nicht gekommen. Ich nehme dafür - je nach Komplexitätsgrad - folgende Wege:

1. Index-Konstanten mit Enum

Code

Global Enum $ID, $LASTNAME, $FORENAME, $BIRTHDAY
Global $aData[2][$BIRTHDAY + 1]
$aData[0][$LASTNAME] = "Schwahfel"
$aData[0][$FORENAME] = "Heribert"
$aData[0][$BIRTHDAY] = "2022-11-09"

2. Array of Dictionary

Code

Global $aoData[2]
$aoData[0] = ObjCreate("Scripting.Dictionary")
$aoData[0]("LastName") = "Schwahfel"
$aoData[0]("ForeName") = "Heribert"
$aoData[0]("Birthday") = "2022-11-09"

Habe den Code jetzt gerade aus dem Kopf runtergetippt. Es ist gerade kein Windows mit Au3 greifbar.

Aber solche Methoden können die Lesbarkeit des Codes um einiges erhöhen.

**AspirinJunkie**

Die Variante mit den Structs / Enumeration unterscheided sich prinzipiell von der Variante mit dem Dictionary dahingehend, dass bei ersterem eine feste Datenstruktur vorgegeben ist - und zwar sowohl hinsichtlich der Attribute, deren Namen als auch deren Typ.
Bei der Dictionary-Variante ist man hingegen flexibel, welche Attribute gesetzt werden können und kann dann hinterher wild die Datentypen mischen.

Ersteres benötigt etwas mehr Schreibarbeit, da man ja die Struktur erst definieren muss, ermöglicht jedoch - wie oben gezeigt - eine platzsparende Speichermöglichkeit, da man gleich binär alles hintereinander schreiben kann.
Beim Datenaustausch muss man hier jedoch noch aufpassen, dass man keine Pointer-Typen in der Struct hat. Wenn man z.B. die Daten auf einem 64Bit-System geschrieben hat, dann würde das Einlesen auf einem 32Bit-System scheitern. Aber wie gesagt: sollte eigentlich nur passieren, wenn man Pointer-Typen hat.

Wenn es hingegen nur um die Dot-Notation geht, dann kann man dies auch mit Maps erreichen.
Man muss im Grunde nur folgenden Teil im Skript ändern (und die Struct-Definition kann man sich dann natürlich auch sparen):

AutoIt

For $i = 0 To UBound($g_aWorker) - 1
    Local $mTemp[]
    $g_aWorker[$i] =$mTemp
Next

Zum Speichern und Auslesen der Daten auf der Platte braucht es dann aber ein anderes Format.
Beispielsweise json, yaml und Konsorten.

Von der Performance her wäre, die Map-Variante die fixere von beiden nach meinen Tests (Erstellen ca. 2x und Auslesen ca. 4x)

**Oscar**

Zitat von chesstiger

Aber solche Methoden können die Lesbarkeit des Codes um einiges erhöhen.

Ja, an Enum hatte ich zuerst auch gedacht, aber ich finde die Structs doch noch besser, weil man da notfalls auch gleich einen Pointer auf die Daten hat (für evtl. Assembler-Routinen) und weil man beim Laden/Speichern nicht verschachtelte Schleifen und Trennzeichen braucht.

**Moombas**

Hmm, wusste noch nicht das das geht, muss ich mir für das nächste Mal merken.

Aber ein Frage, auch wenn es nur ein Beispiel ist, wäre bei PLZ nicht int anstatt char besser?

**BugFix**

Zitat von Moombas

wäre bei PLZ nicht int anstatt char besser?

Nein: Es gibt PLZ, die mit "0" beginnen.

**Moombas**

Stimmt, die wird dann weg gekürzt.

Manchmal sind die offensichtlichen Dinge unsichtbar XD.

Danke für den Hinweis BugFix

**Moombas**

Vielleicht eine Blöde Frage aber gibt es wie beim normalen Array hoerbei auch die Möglichkeit dies "einfach" (wie z.B. _Filewritefromarray()) in eine Datei zu speichern oder muss ich mir dann eine entsprechende Routine dafür selber bauen?

**Oscar**

Auf welche Methode bezieht sich Deine Frage?

**Moombas**

Wenn man ein ArrayofStruct hat, dieses "einfach" zu speichern.

Ich vermute das man dafür eine eigene Fumnktion bauen muss, richtig?

**Oscar**

Zitat von Moombas

Ich vermute das man dafür eine eigene Fumnktion bauen muss, richtig?

Das ist doch oben im Beispiel mit aufgeführt. Die Funktion ist doch recht "einfach". IMHO.

**BugFix**

Zitat von Moombas

Wenn man ein ArrayofStruct hat, dieses "einfach" zu speichern.
Ich vermute das man dafür eine eigene Fumnktion bauen muss, richtig?

Die ist doch enthalten im Bsp.: _WriteData

**Oscar**

Weil das normale "_ArraySort" kein "Array of struct" sortieren kann (ich aber eine Sortierung brauche), habe ich mal eine QuickSort-Funktion hinzugefügt:

AutoIt

#include <WinAPIHObj.au3>
#include <WinAPIInternals.au3>

; Datenstruktur definieren
Global Const $tagWORKER = 'struct;uint ID;char Nachname[60];char Vorname[60];char Geburtstag[8];' & _
        'char Strasse[60];char HausNr[6];char PLZ[5];char Wohnort[60];char TelNr[20];endstruct'

; "Array of struct" erstellen
Global $g_aWorker[2]
For $i = 0 To UBound($g_aWorker) - 1
    $g_aWorker[$i] = DllStructCreate($tagWORKER)
Next

#Region "Array of struct" mit Testdaten fuellen
$g_aWorker[0].ID = 10000
$g_aWorker[0].Nachname = 'Meiselbach'
$g_aWorker[0].Vorname = 'Karl-Heinz'
$g_aWorker[0].Geburtstag = '19640428'
$g_aWorker[0].Strasse = 'Josef-Zinnbauer-Straße'
$g_aWorker[0].HausNr = '308D'
$g_aWorker[0].PLZ = '75633'
$g_aWorker[0].Wohnort = 'Hintertupfingen'
$g_aWorker[0].TelNr = '+49 7366 783411'

$g_aWorker[1].ID = 10001
$g_aWorker[1].Nachname = 'Rotfuss'
$g_aWorker[1].Vorname = 'Theodor'
$g_aWorker[1].Geburtstag = '19591030'
$g_aWorker[1].Strasse = 'Am alten Forsthaus'
$g_aWorker[1].HausNr = '33'
$g_aWorker[1].PLZ = '58721'
$g_aWorker[1].Wohnort = 'Kronsbach'
$g_aWorker[1].TelNr = '+49 4862 11598'
#EndRegion "Array of struct" mit Testdaten fuellen

_QSSort($g_aWorker) ; "Array of struct" sortieren (Sortierung siehe unten "_QSStringCmp")

ConsoleWrite('Vor dem speichern auf Festplatte:' & @CRLF)
ConsoleWrite('$g_aWorker[0].Nachname = ' & $g_aWorker[0].Nachname & @CRLF)
ConsoleWrite('$g_aWorker[0].Wohnort = ' & $g_aWorker[0].Wohnort & @CRLF)
ConsoleWrite('$g_aWorker[0].TelNr = ' & $g_aWorker[0].TelNr & @CRLF)
ConsoleWrite('$g_aWorker[1].Nachname = ' & $g_aWorker[1].Nachname & @CRLF)
ConsoleWrite('$g_aWorker[1].Wohnort = ' & $g_aWorker[1].Wohnort & @CRLF)
ConsoleWrite('$g_aWorker[1].TelNr = ' & $g_aWorker[1].TelNr & @CRLF & @CRLF)

Global Const $sDatafile = @ScriptDir & '\Data.bin'
_WriteData($sDatafile) ; alle Daten auf Festplatte speichern
$g_aWorker = 0 ; Array of struct loeschen
_ReadData($sDatafile) ; die Daten wieder von der Festplatte laden

ConsoleWrite('Nach dem laden von Festplatte:' & @CRLF)
ConsoleWrite('$g_aWorker[0].Nachname = ' & $g_aWorker[0].Nachname & @CRLF)
ConsoleWrite('$g_aWorker[0].Wohnort = ' & $g_aWorker[0].Wohnort & @CRLF)
ConsoleWrite('$g_aWorker[0].TelNr = ' & $g_aWorker[0].TelNr & @CRLF)
ConsoleWrite('$g_aWorker[1].Nachname = ' & $g_aWorker[1].Nachname & @CRLF)
ConsoleWrite('$g_aWorker[1].Wohnort = ' & $g_aWorker[1].Wohnort & @CRLF)
ConsoleWrite('$g_aWorker[1].TelNr = ' & $g_aWorker[1].TelNr & @CRLF)

Func _WriteData($sPath)
    Local $hFile, $nBytes, $tData
    $hFile = _WinAPI_CreateFile($sPath, 1, 4) ; 1 = create file if not exist, 4 = write access
    If Not $hFile Then Return
    $tData = DllStructCreate('uint Count;')
    $tData.Count = UBound($g_aWorker)
    _WinAPI_WriteFile($hFile, $tData, DllStructGetSize($tData), $nBytes)
    For $i = 0 To UBound($g_aWorker) - 1
        _WinAPI_WriteFile($hFile, $g_aWorker[$i], DllStructGetSize($g_aWorker[$i]), $nBytes)
    Next
    _WinAPI_CloseHandle($hFile)
EndFunc   ;==>_WriteData

Func _ReadData($sPath)
    Local $hFile, $nBytes, $tData
    $hFile = _WinAPI_CreateFile($sPath, 2, 2) ; 2 = open file, 2 = read access
    If Not $hFile Then Return
    $tData = DllStructCreate('uint Count;')
    _WinAPI_ReadFile($hFile, $tData, DllStructGetSize($tData), $nBytes)
    Global $g_aWorker[$tData.Count]
    For $i = 0 To $tData.Count - 1
        $g_aWorker[$i] = DllStructCreate($tagWORKER)
        _WinAPI_ReadFile($hFile, $g_aWorker[$i], DllStructGetSize($g_aWorker[$i]), $nBytes)
    Next
    _WinAPI_CloseHandle($hFile)
EndFunc   ;==>_ReadData

#Region Quicksort fuer "Array of struct"
; Funktion fuer den Stringvergleich (Erst Nachnamen vergleichen. Wenn gleich, dann Vornamen)
; Wenn eine andere Sortierung gewuenscht wird, muss hier der Vergleich angepasst werden!
Func _QSStringCmp(Const $vD1, Const $vD2)
    Local $iCmp = StringCompare($vD1.Nachname, $vD2.Nachname, 1)
    If Not $iCmp Then $iCmp = StringCompare($vD1.Vorname, $vD2.Vorname, 1)
    Return $iCmp < 0
EndFunc   ;==>_QSStringCmp

; Rekursive Quicksort-Funktion
Func _QSSort(ByRef $aData, $left = 0, $right = UBound($aData) - 1)
    If $right - $left >= 20 Then ; bei 20 und mehr Elementen, Quicksort benutzen
        If $left < $right Then
            Local $pivot = _QSSplitSwap($aData, $left, $right)
            _QSSort($aData, $left, $pivot - 1)
            _QSSort($aData, $pivot + 1, $right)
        EndIf
    Else ; bei weniger als 20 (noch verbleibenden) Elementen, ist InsertionSort schneller
        _QSInsertionSort($aData, $left, $right)
    EndIf
EndFunc   ;==>_QSSort

Func _QSSplitSwap(ByRef $aData, $left, $right)
    Local $i = $left, $j = $right - 1, $pivot = $aData[$right], $h
    Do
        While _QSStringCmp($aData[$i], $pivot) And $i < $right
            $i += 1
        WEnd
        While _QSStringCmp($pivot, $aData[$j]) And $j > $left
            $j -= 1
        WEnd
        If $i < $j Then
            $h = $aData[$i]
            $aData[$i] = $aData[$j]
            $aData[$j] = $h
        EndIf
    Until $i >= $j
    $aData[$right] = $aData[$i]
    $aData[$i] = $pivot
    Return $i
EndFunc   ;==>_QSSplitSwap

; InsertionSort-Funktion
Func _QSInsertionSort(ByRef $aData, $iStart = 0, $iEnd = UBound($aData) - 1)
    Local $sVal, $j
    For $i = $iStart + 1 To $iEnd
        $sVal = $aData[$i]
        $j = $i
        While ($j > $iStart) And _QSStringCmp($sVal, $aData[$j - 1])
            $aData[$j] = $aData[$j - 1]
            $j -= 1
        WEnd
        $aData[$j] = $sVal
    Next
EndFunc   ;==>_QSInsertionSort
#EndRegion Quicksort fuer "Array of struct"

Alles anzeigen

**Moombas**

BugFix Bekloppterweise habe ich mir nur den Part mit dem erzeugen der Strucktur und dessen Zugriff angeschaut aber nicht weiter unten das Dateischreiben beachtet.

**Moombas**

Blöde (schnelle) Frage.

Weiß jemand ob ich auch direkt auf etwas zugreifen kann ohne das Array of Struct zu durchlaufen?

Evtl. ist etwas sample-Code besser um zu verstehen was ich meine:

AutoIt

Opt('MustDeclareVars', 1)
#include <Array.au3>

Global Const $tagVariables = 'struct;char id[36];char Name[999];endstruct'
Global $Networks[1], $Count = 5

ReDim $Networks[$Count + 1]
$Networks[0] = $Count
For $i = 1 To $Networks[0]
    $Networks[$i] = DllStructCreate($tagVariables)
Next

For $Row = 1 to $Count
    $Networks[$Row].id = $Row
    $Networks[$Row].name = $Row & '_name'
    ConsoleWrite($Networks[$Row].id & ': ')
    ConsoleWrite($Networks[$Row].name & @CRLF)
Next
$Networks[0] = UBound($Networks) - 1

For $Row = 1 to $Networks[0]
    If $Networks[$Row].id = 3 then ConsoleWrite($Networks[$Row].name & @CRLF) ;funktioniert
Next

Global $A = DllStructGetData($Networks, '3', 'id') ;funktioniert nicht (Struct not a valid struct returned by DllStructCreate())
ConsoleWrite(@error & @CRLF)
Consolewrite($A & @CRLF)

Alles anzeigen

**AspirinJunkie**

Naja du machst ja eine Bedingungsabfrage.
Willst also die Objekte haben, welche eine bestimmte Eigenschaft besitzen.
Das geht in einem einzelnen AutoIt-Aufruf nicht.

Du könntest eine Funktion schreiben in die deine Schleife verpackt wird und du so die Filterung erreichst.

Oder du nimmst statt einem Array eine Map und verwendest dort als Schlüssel die ID.
Auf die Art kannst du schnell per ID auf die einzelnen structs zugreifen:

AutoIt

Global Const $tagVariables = 'struct;char id[36];char Name[999];endstruct'
Global $Count = 5

Global $mNetworks[] ; leere Map

For $i = 0 To $Count
    Global $tVariable = DllStructCreate($tagVariables)
    With $tVariable
        .id = $i + 1
        .Name = $i +  1 & "_name"
    EndWith
    $mNetworks[$i + 1] = $tVariable
Next

For $Row = 1 to $Count
    With $mNetworks[$Row]
        .id = $Row
        .name = $Row & '_name'
        ConsoleWrite(.id & ': ')
        ConsoleWrite(.name & @CRLF)
    EndWith
Next

Global $A = DllStructGetData($mNetworks[3], "Name")
If @error Then ConsoleWrite("@error: " & @error & @CRLF)
Consolewrite($A & @CRLF)

Alles anzeigen

**Moombas**

Hi AspirinJunkie : Ich glaube ich war doch etwas ungenau. Ich wollte die '3' bei deiner Zeile 24 eben nicht, da ich diese "nicht weiß", sondern über die ID ermitteln und dann den zugehörigen tag .name ausgeben.

Ich habe/hatte die Hoffnung das es dafür etwas gibt, ohne das man eine Schleife durchlaufen muss und es relativ simpel abfragbar ist und ich es nur nicht weiß wie.

Habe es nun aber erst mal über eine Schleife gelöst.

**AspirinJunkie**

Zitat von Moombas

Ich wollte die '3' bei deiner Zeile 24 eben nicht, da ich diese "nicht weiß", sondern über die ID ermitteln und dann den zugehörigen tag .name ausgeben.

Ich weiß. Deshalb habe ich bei der Erstellung der Map die ID als Key verwendet.
Sprich: Wenn du auf das Element mit dem Key "3" zugreifst - erhälst du die Struktur mit der ID=3.