Toolbar - Icon-Namen

mumpel

Hallo!

Ich habe erfolgreich eine Toolbar integriert (https://www.autoitscript.com/autoit3/docs/l…lbar_Create.htm). Funktioniert auch wie es soll. Aber wo stehen die Iconnamen (z.B. $STD_FILEOPEN). Ich bräuchte z.B. "Schließen". In der GuiToolbar.au3 finde ich nichts. Danke!

Gruß, René

**eukalyptus**

Die Konstanten findest du in WinAPIConstants.au3, es gibt aber nicht viel Auswahl.

Du kannst eigene Icons hinzufügen:

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>
#include <GuiImageList.au3>


Global $g_hToolbar, $g_idMemo
Global $g_iItem ; Command identifier of the button associated with the notification.
Global Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp, $e_idMein

Example()

Func Example()
    Local $hGUI, $aSize

    ; Create GUI
    $hGUI = GUICreate("Toolbar", 600, 400)
    $g_hToolbar = _GUICtrlToolbar_Create($hGUI)
    $aSize = _GUICtrlToolbar_GetMaxSize($g_hToolbar)

    $g_idMemo = GUICtrlCreateEdit("", 2, $aSize[1] + 20, 596, 396 - ($aSize[1] + 20), $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)
    GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

    ; Add standard system bitmaps
    _GUICtrlToolbar_AddBitmap($g_hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    Local $hImageList = _GUICtrlToolbar_GetImageList($g_hToolbar)
    _GUIImageList_AddIcon($hImageList, "MeinIcon.ico")
    _GUICtrlToolbar_SetImageList($g_hToolbar, $hImageList)

    ; Add buttons
    _GUICtrlToolbar_AddButton($g_hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($g_hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($g_hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($g_hToolbar)
    _GUICtrlToolbar_AddButton($g_hToolbar, $e_idHelp, $STD_HELP)
    _GUICtrlToolbar_AddButtonSep($g_hToolbar)
    _GUICtrlToolbar_AddButton($g_hToolbar, $e_idMein, 15)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; WM_NOTIFY event handler
Func _WM_NOTIFY($hWndGUI, $iMsgID, $wParam, $lParam)
    #forceref $hWndGUI, $iMsgID, $wParam
    Local $tNMHDR, $hWndFrom, $iCode, $iNew, $iFlags, $iOld
    Local $tNMTBHOTITEM
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $g_hToolbar
            Switch $iCode
                Case $NM_LDOWN
                    ;----------------------------------------------------------------------------------------------
                    MemoWrite("$NM_LDOWN: Clicked Item: " & $g_iItem & " at index: " & _GUICtrlToolbar_CommandToIndex($g_hToolbar, $g_iItem))
                    ;----------------------------------------------------------------------------------------------
                Case $TBN_HOTITEMCHANGE
                    $tNMTBHOTITEM = DllStructCreate($tagNMTBHOTITEM, $lParam)
                    $iOld = DllStructGetData($tNMTBHOTITEM, "idOld")
                    $iNew = DllStructGetData($tNMTBHOTITEM, "idNew")
                    $g_iItem = $iNew
                    $iFlags = DllStructGetData($tNMTBHOTITEM, "dwFlags")
                    If BitAND($iFlags, $HICF_LEAVING) = $HICF_LEAVING Then
                        MemoWrite("$HICF_LEAVING: " & $iOld)
                    Else
                        Switch $iNew
                            Case $e_idNew
                                ;----------------------------------------------------------------------------------------------
                                MemoWrite("$TBN_HOTITEMCHANGE: $e_idNew")
                                ;----------------------------------------------------------------------------------------------
                            Case $e_idOpen
                                ;----------------------------------------------------------------------------------------------
                                MemoWrite("$TBN_HOTITEMCHANGE: $e_idOpen")
                                ;----------------------------------------------------------------------------------------------
                            Case $e_idSave
                                ;----------------------------------------------------------------------------------------------
                                MemoWrite("$TBN_HOTITEMCHANGE: $e_idSave")
                                ;----------------------------------------------------------------------------------------------
                            Case $e_idHelp
                                ;----------------------------------------------------------------------------------------------
                                MemoWrite("$TBN_HOTITEMCHANGE: $idHelp")
                                ;----------------------------------------------------------------------------------------------
                        EndSwitch
                    EndIf
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_NOTIFY

Alles anzeigen

Oder schau dir das Beispiel zu _GUICtrlToolbar_LoadBitmap an

lgE

mumpel

Zitat von eukalyptus

Oder schau dir das Beispiel zu _GUICtrlToolbar_LoadBitmap an

Kenne ich schon. Ich finde aber keine passenden Icons. Früher gab es sowas mal im Internet. )

mumpel

BTW:

Seit ich das gestern eingebaut habe, zeigt mir der Defender wieder eine Trojanermeldung (Trojan:Win32/Bearfoos.B!ml). Mal wieder etwas unerklärliches?

Velted

Toolbar Standard Button Image Index Values

Und dazu noch die Definitionen in CommCtrl.h:

Code

#define HINST_COMMCTRL          ((HINSTANCE)-1)
#define IDB_STD_SMALL_COLOR     0
#define IDB_STD_LARGE_COLOR     1
#define IDB_VIEW_SMALL_COLOR    4
#define IDB_VIEW_LARGE_COLOR    5
#define IDB_HIST_SMALL_COLOR    8
#define IDB_HIST_LARGE_COLOR    9
#if (NTDDI_VERSION >= NTDDI_VISTA)
#define IDB_HIST_NORMAL         12
#define IDB_HIST_HOT            13
#define IDB_HIST_DISABLED       14
#define IDB_HIST_PRESSED        15
#endif // (NTDDI_VERSION >= NTDDI_VISTA)

// icon indexes for standard bitmap

#define STD_CUT                 0
#define STD_COPY                1
#define STD_PASTE               2
#define STD_UNDO                3
#define STD_REDOW               4
#define STD_DELETE              5
#define STD_FILENEW             6
#define STD_FILEOPEN            7
#define STD_FILESAVE            8
#define STD_PRINTPRE            9
#define STD_PROPERTIES          10
#define STD_HELP                11
#define STD_FIND                12
#define STD_REPLACE             13
#define STD_PRINT               14

// icon indexes for standard view bitmap

#define VIEW_LARGEICONS         0
#define VIEW_SMALLICONS         1
#define VIEW_LIST               2
#define VIEW_DETAILS            3
#define VIEW_SORTNAME           4
#define VIEW_SORTSIZE           5
#define VIEW_SORTDATE           6
#define VIEW_SORTTYPE           7
#define VIEW_PARENTFOLDER       8
#define VIEW_NETCONNECT         9
#define VIEW_NETDISCONNECT      10
#define VIEW_NEWFOLDER          11
#define VIEW_VIEWMENU           12

#define HIST_BACK               0
#define HIST_FORWARD            1
#define HIST_FAVORITES          2
#define HIST_ADDTOFAVORITES     3
#define HIST_VIEWTREE           4

#endif

Alles anzeigen

Viele der zugehörigen AutoIt-Konstanten habe ich auf die Schnelle im Wirrwar der #Includes nicht gefunden.

mumpel

Und wo/wie binde ich das in AutoIt ein?

Velted

Die von Dir verlinkte Beschreibung zu _GUICtrlToolbar_Create() enthält doch ein Beispiel. Wenn Du die Definition der AutoIt-Konstanten nicht findest, kannst Du stattdessen die numerischen Werte verwenden.

Aus

Code

_GUICtrlToolbar_AddBitmap($g_hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

wird dann

Code

_GUICtrlToolbar_AddBitmap($g_hToolbar, 1, -1, 1) ; #define IDB_STD_LARGE_COLOR     1

und aus

Code

_GUICtrlToolbar_AddButton($g_hToolbar, $e_idNew, $STD_FILENEW)

wird

Code

_GUICtrlToolbar_AddButton($g_hToolbar, $e_idNew, 6) ; #define STD_FILENEW             6

Die Bilder aus den anderen Listen kannst Du mit zusätzlichen Aufrufen von _GUICtrlToolbar_AddBitmap() laden, z.B.

Code

$iView = _GUICtrlToolbar_AddBitmap($g_hToolbar, 1, -1, 5) ; #define IDB_VIEW_LARGE_COLOR    5

für die View-Icons. Du musst dann aber den Rückhabewert der Funktion speichern, weil er als Offset für die View-Indices gebraucht wird, z.B.

Code

_GUICtrlToolbar_AddButton($g_hToolbar, $e_idNew, $iView + 3) ; #define VIEW_DETAILS            3

für VIEW_DETAILS.

mumpel

Code

_GUICtrlToolbar_AddButton($g_hToolbar, $e_idNew, $iView + 3) ; #define VIEW_DETAILS            3

Wie kommt man auf $iView + 3?

Velted

Gegenfrage: Wir kommt man darauf, dass man ein ToolBar-Control braucht?

mumpel

Weil eine Symbolleiste schöner aussieht als Schaltflächen (Derzeit habe ich 8 Schaltflächen. Es könnten noch mehr werden). Das sieht in einer Symbolleiste optisch schöner aus). Und man kann dann dem Treeview und dem WebBrowser-Control die selbe Höhe geben. Ich habe jetzt schon einiges ausprobiert. Aber ich finde kein passendes Icon. Und die Icons aus Dlls (z.B. imageres.dll und shell32.dll) erzeugen einen schwarzen Hintergrund.

**Oscar**

Zitat von mumpel

Und die Icons aus Dlls (z.B. imageres.dll und shell32.dll) erzeugen einen schwarzen Hintergrund.

Dann machst Du etwas falsch! Das sind 32Bit-Icons.

Zeig mal Dein Script!

mumpel

Zitat von Oscar

Dann machst Du etwas falsch!

Der Code stammt aus dem Internet.

Code

Global $aSize, $g_hToolbar, $g_idMemo, $g_iItem
Global Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp, $e_idClose, $e_idBack, $e_idForward, $e_idStop, $e_idZu, $e_idAuf, $e_IdRefresh, $e_idBlank
Global $i, $hImage, $count
Global Const $sSearchDir = @ScriptDir
Global Const $sFileExtensions = '*.pdf;*.docx;*.xlsm'
Global Const $bLargeIcons = False
Global $hlibary = @ScriptDir &"\icons\imageres.dll" ;der Pfad zu deiner .dll

Global $mPathMap[]
_WinAPI_FileIconInit()
Global $hSystemImgList = _WinAPI_ShellGetImageList(Not $bLargeIcons)
Global $hBusyCur = _WinAPI_LoadCursorFromFile(@WindowsDir & '\Cursors\aero_busy_xl.ani')

Global $hMainGui = GUICreate('Konzernregelwerke', 1700, 1000, -1, -1)
Global $g_hToolbar = _GUICtrlToolbar_Create($hMainGui)
Global $aSize = _GUICtrlToolbar_GetMaxSize($g_hToolbar)


#Region ; **** Tooolbar füllen ****
$hImage = _GUIImageList_Create()
$count = _WinAPI_ExtractIconEx($hlibary, -1, 0, 0, 0)

for $i = 0 to $count -1
_GUIImageList_AddIcon($hImage, $hlibary, $i)
next
_GUICtrlToolbar_SetImageList($g_hToolbar, $hImage)

_GUICtrlToolbar_AddBitmap($g_hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

        Local $aStrings[9]
        $aStrings[0] = _GUICtrlToolbar_AddString($g_hToolbar, "Datei öffnen")
        $aStrings[1] = _GUICtrlToolbar_AddString($g_hToolbar, "Zuklappen")
        $aStrings[2] = _GUICtrlToolbar_AddString($g_hToolbar, "Aufklappen")
        $aStrings[3] = _GUICtrlToolbar_AddString($g_hToolbar, "Zurück")
        $aStrings[4] = _GUICtrlToolbar_AddString($g_hToolbar, "Vorwärts")
        $aStrings[5] = _GUICtrlToolbar_AddString($g_hToolbar, "Stop")
        $aStrings[6] = _GUICtrlToolbar_AddString($g_hToolbar, "Beenden")
        $aStrings[7] = _GUICtrlToolbar_AddString($g_hToolbar, "Neu laden")
        $aStrings[8] = _GUICtrlToolbar_AddString($g_hToolbar, "Datei schließen")

Local $iView = _GUICtrlToolbar_AddBitmap($g_hToolbar, 1, -1, 5)
_GUICtrlToolbar_AddButton($g_hToolbar, $e_idOpen, $STD_FILEOPEN, $aStrings[0])
_GUICtrlToolbar_AddButtonSep($g_hToolbar)
_GUICtrlToolbar_AddButton($g_hToolbar, $e_idZu, 11, $aStrings[1])
_GUICtrlToolbar_AddButton($g_hToolbar, $e_idAuf, 12, $aStrings[2])
_GUICtrlToolbar_AddButtonSep($g_hToolbar)
_GUICtrlToolbar_AddButton($g_hToolbar, $e_idBack, 8, $aStrings[3])
_GUICtrlToolbar_AddButton($g_hToolbar, $e_idForward, 9, $aStrings[4])
_GUICtrlToolbar_AddButton($g_hToolbar, $e_idRefresh, 8, $aStrings[7])
_GUICtrlToolbar_AddButton($g_hToolbar, $e_idStop, 10, $aStrings[5])
_GUICtrlToolbar_AddButton($g_hToolbar, $e_idBlank, 13, $aStrings[8])
_GUICtrlToolbar_AddButtonSep($g_hToolbar)
_GUICtrlToolbar_AddButton($g_hToolbar, $e_idNew, 5, $aStrings[6])

#EndRegion ; **** Toolbar Ende ****

Alles anzeigen

**Oscar**

Zitat von mumpel

Der Code stammt aus dem Internet.

Ein voll funktionsfähiges Beispiel wäre sinnvoller gewesen!

Aber das Problem liegt mit Sicherheit an "_GUIImageList_Create". Das musst Du mit "5" als dritten Parameter starten (die ersten beiden musst Du dann auch angeben).

Die "5" besagt: "Use a 32 bit DIB section". 32 Bit ist mit Alphawert (transparenz). 24Bit ist ohne Alpha.

mumpel

Danke! Ich schau mal in die Hilfe.

Edit:

Und schon funktioniert es. Danke!

mumpel

Etwas Interessantes zum Thema: Menüband (Ribbon) in AutoIt => https://www.autoitscript.com/forum/topic/128242-ribbon/ => Das werde ich versuchen bei mir einzubauen

**BugFix**

Zitat von mumpel

Ich finde aber keine passenden Icons. Früher gab es sowas mal im Internet.

Etwas Suchen muss man. "Free Icon Windows" als Suchbegriff bringt Einiges. Aber Beachten: "Free Download" heißt nicht zwingend, dass die Icons selbst "Free" sind. Da musst du drauf achten.

Ich nehme gerne Icons aus diesem Pack: Aeon Icon Pack

Vorschau

mumpel

Ich habe lange gesucht, aber trotzdem nichts passendes gefunden. Was ist das Aeon-Icon-Pack für ein Dateityp?

**Moombas**

zip sollte gehen

mumpel

Die haben bei mir keine Dateiendung. Aber wie immer hat 7zip geholfen. Mir fehlen noch schöne Icons für "Ordner aufklappen" und "Ordner zuklappen. Ich suche auch schon ein Programm zum Erstellen eigener Icon-Librarys.

**BugFix**

Zitat von mumpel

Ich suche auch schon ein Programm zum Erstellen eigener Icon-Librarys.

Eigene Icons erstelle ich mit paint.net und der Erweiterung für Icon Dateien. (Suche im Web nach "paint.net plugins")

Zitat von mumpel

Mir fehlen noch schöne Icons für "Ordner aufklappen" und "Ordner zuklappen

Gefällt dir hier was?

Arzo Icon

oder hier:

avXicons