sortieren nach IP

casi4712

Hallo allerseits, ich habe ein kleines script was mir ein Logfile auswerten soll, dieses Logfile hat folgende Struktur:

Code

2024/06/23 18:02:36 - Client connected
2024/06/23 18:02:36 - action=login pcname=N210708_b mac=5C61994A3157 ip=192.168.178.22 time=18:02:36
2024/06/23 18:06:55 - Client connected
2024/06/23 18:06:55 - action=logout pcname=N210708_B mac=5C61994A3157 ip=192.168.178.22 time=18:06:55
2024/06/23 18:10:30 - Client connected
2024/06/23 18:10:30 - action=login pcname=N210708_B mac=5C61994A3157 ip=192.168.178.22 time=18:10:30
2024/06/23 18:13:50 - Client connected
2024/06/23 18:13:50 - action=logout pcname=N210708_B mac=5C61994A3157 ip=192.168.178.22 time=18:13:50
2024/06/23 18:18:20 - Server started and listening on port 8085

Mir ist es inzwischen geglückt die Sortierfunktion zum Laufen zu bringen. Das einzige Problem was ich habe ist die Sortierung der IPS, hat da jemand ne Idee? Für sachdienliche Hinweise wär ich sehr dankbar

AutoIt

#include <Array.au3>
#include <File.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <StructureConstants.au3>
#include <WinAPI.au3>
#include <ListViewConstants.au3>


;only one Instance
$g_szVersion = "My OnlineReader"
If WinExists($g_szVersion) Then
    Exit
EndIf
AutoItWinSetTitle($g_szVersion)

Global $sFilePath = "\\192.168.100.166\C$\windows\logfile.txt"
Global $csvFilePath = "\\cms.lch-bln.de\freigaben\inv2\Summary_Short.csv"
Global $aLines, $iLines
Global $csvData
Global $loggedInPCs[1][5] ; 2d Array initialisieren
Global $sortOrder = True ; True = Ascending, False = Descending
Global $lastSortedColumn = -1

; Create the GUI
Global $hGUI = GUICreate("Online PCs", 600, 400)
Global $hListView = GUICtrlCreateListView("PC Name|MAC Address|IP Address|Bezeichnung", 10, 10, 580, 300, $LVS_REPORT)
Global $hButton = GUICtrlCreateButton("Update", 250, 320, 100, 30)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
Global $B_DESCENDING[_GUICtrlListView_GetColumnCount($hListView)]


; CSV dazuladen
_LoadCSVData()

; Listview erzeugen
_UpdateListView()

; Register WM_NOTIFY handler
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY_Handler")

; Event loop
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $hButton
            ; Clear and update the ListView when the button is clicked
            _GUICtrlListView_DeleteAllItems($hListView)
            _UpdateListView()
    EndSwitch
WEnd

Func _LoadCSVData()
    ; Check if the CSV file exists
    If Not FileExists($csvFilePath) Then
        MsgBox(0, "Error", "CSV file not found: " & $csvFilePath)
        Exit
    EndIf

    ; Read the CSV file into an array
    If _FileReadToArray($csvFilePath, $csvData) = 0 Then
        MsgBox(0, "Error", "Failed to read CSV file: " & $csvFilePath)
        Exit
    EndIf
EndFunc

Func _UpdateListView()
    ; Reset the loggedInPCs array
    ReDim $loggedInPCs[1][5]
    $loggedInPCs[0][0] = ""
    $loggedInPCs[0][1] = ""
    $loggedInPCs[0][2] = ""
    $loggedInPCs[0][3] = ""
    $loggedInPCs[0][4] = False

    ; Check if the file exists
    If Not FileExists($sFilePath) Then
        MsgBox(0, "Error", "File not found: " & $sFilePath)
        Return
    EndIf

    ; Read the file into an array
    If _FileReadToArray($sFilePath, $aLines) = 0 Then
        MsgBox(0, "Error", "Failed to read file: " & $sFilePath)
        Return
    EndIf

    $iLines = UBound($aLines)

    ; jede Zeile im log durchgehen
    For $i = 1 To $iLines - 1
        ; Check "action=login"
			If StringInStr($aLines[$i], "action=login") Then
				Local $pcname = _GetParameter($aLines[$i], "pcname")
				Local $mac = _FormatMAC(_GetParameter($aLines[$i], "mac"))
				Local $ip = _GetParameter($aLines[$i], "ip")
				_SetPCStatus($pcname, $mac, $ip, True)
			ElseIf StringInStr($aLines[$i], "action=logout") Then
				Local $pcname = _GetParameter($aLines[$i], "pcname")
				; PC logged out
				_SetPCStatus($pcname, "", "", False)
			EndIf
    Next

    ; Liste von Onlien PC erstellen
    For $i = 0 To UBound($loggedInPCs) - 1
        If $loggedInPCs[$i][4] Then
            ; Bezeichnung von externer CSV einlesen
            Local $bezeichnung = _GetBezeichnung($loggedInPCs[$i][0])
            GUICtrlCreateListViewItem($loggedInPCs[$i][0] & "|" & $loggedInPCs[$i][1] & "|" & $loggedInPCs[$i][2] & "|" & $bezeichnung, $hListView)
        EndIf
    Next
EndFunc

Func _GetParameter($sLine, $sParam)
    Local $iStart = StringInStr($sLine, $sParam & "=")
    If $iStart = 0 Then Return ""
    $iStart += StringLen($sParam) + 1
    Local $iEnd = StringInStr($sLine, " ", 0, 1, $iStart)
    If $iEnd = 0 Then $iEnd = StringLen($sLine) + 1
    Return StringMid($sLine, $iStart, $iEnd - $iStart)
EndFunc

Func _FormatMAC($mac)
    $mac = StringReplace($mac, "-", ":")
    $mac = StringRegExpReplace($mac, "(..)(..)(..)(..)(..)(..)", "\1:\2:\3:\4:\5:\6")
    Return $mac
EndFunc

Func _SetPCStatus($pcname, $mac, $ip, $status)
		For $i = 0 To UBound($loggedInPCs) - 1
			If $loggedInPCs[$i][0] = $pcname Then
				$loggedInPCs[$i][1] = $mac
				$loggedInPCs[$i][2] = $ip
				$loggedInPCs[$i][4] = $status
				Return
			EndIf
		Next
	
;neuen PC hinzufügen
		If $loggedInPCs[0][0] = "" Then
			$loggedInPCs[0][0] = $pcname
			$loggedInPCs[0][1] = $mac
			$loggedInPCs[0][2] = $ip
			$loggedInPCs[0][3] = ""
			$loggedInPCs[0][4] = $status
		Else
			ReDim $loggedInPCs[UBound($loggedInPCs) + 1][5]
			$loggedInPCs[UBound($loggedInPCs) - 1][0] = $pcname
			$loggedInPCs[UBound($loggedInPCs) - 1][1] = $mac
			$loggedInPCs[UBound($loggedInPCs) - 1][2] = $ip
			$loggedInPCs[UBound($loggedInPCs) - 1][3] = ""
			$loggedInPCs[UBound($loggedInPCs) - 1][4] = $status
		EndIf
EndFunc

Func _GetBezeichnung($pcname)
    For $i = 1 To UBound($csvData) - 1 ; Kopfpalte überspringen
        Local $csvLine = StringSplit($csvData[$i], ";", 1)
        Local $csvPCName = StringStripWS($csvLine[1], 3) ; 
        If StringReplace($csvPCName, '"', '') = $pcname Then
            Local $csvBezeichnung = StringStripWS($csvLine[2], 3) 
            Return StringReplace($csvBezeichnung, '"', '')
        EndIf
    Next
    Return ""
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
#forceref $hWnd, $iMsg, $iwParam
Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
$hWndListView = $hListView
		If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)
		$tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
		$hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
		$iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
		$iCode = DllStructGetData($tNMHDR, "Code")
		If ($hWndFrom = $hWndListView) And ($iCode = $LVN_COLUMNCLICK) Then
		$tInfo = DllStructCreate($tagNMLISTVIEW, $ilParam)
		_GUICtrlListView_SimpleSort($hWndListView, $B_DESCENDING, DllStructGetData($tInfo, "SubItem"))
		EndIf
EndFunc ;==>WM_NOTIFY

Func _SortListView($iCol)
    Local $aListViewData[0]
    Local $iItemCount = _GUICtrlListView_GetItemCount($hListView)

    ; Listview in Array lesen
    For $i = 0 To $iItemCount - 1
        Local $sRow = ""
        For $j = 0 To _GUICtrlListView_GetColumnCount($hListView) - 1
            $sRow &= _GUICtrlListView_GetItemText($hListView, $i, $j)
            If $j < _GUICtrlListView_GetColumnCount($hListView) - 1 Then $sRow &= "|"
        Next
        _ArrayAdd($aListViewData, $sRow)
    Next

    ; Array sortieren
    _ArraySort($aListViewData, $sortOrder, $iCol)

    ; Liste löschen und neu befüllen
    _GUICtrlListView_DeleteAllItems($hListView)
    For $i = 0 To UBound($aListViewData) - 1
        Local $aRow = StringSplit($aListViewData[$i], "|")
        GUICtrlCreateListViewItem($aRow[1] & "|" & $aRow[2] & "|" & $aRow[3] & "|" & $aRow[4], $hListView)
    Next

    ; Umschalten Sortierreihenfolge
    If $lastSortedColumn = $iCol Then
        $sortOrder = Not $sortOrder
    Else
        $sortOrder = True ; Start with ascending order for new column
    EndIf
    $lastSortedColumn = $iCol
EndFunc

Alles anzeigen

lg und eine schöne Woche noch

**AspirinJunkie**

IPs sind in AutoIt einfach nur Strings.
Strings werden in AutoIt, wenn sie mit den eingebauten Funktionalitäten (">", "<", "=", "==", StringCompare) verglichen werden, zeichenweise verglichen.
Die Sortierfunktion _ArraySort() verwendet lediglich die eingebauten Vergleichsfunktionen während der Sortierung.

Bei IP-Adressen führt ein Zeichenweiser Vergleich jedoch nicht zum gewünschten Ergebnis.

Es gibt da mehrere Ansätze:

Ansatz 1: weitere Spalte mit Datenkonvertierung:

Dem Array eine weitere Spalte hinzufügen (per ReDim)
Nun zeilenweise durchgehen
Dabei die gewünschte Eigenschaft (hier Spalte 3) so konvertieren, dass AutoIt-Bordvergleiche diese wie gewünscht behandeln.
Im Falle von IP-Adressen könnte man z.B. den 32 Bit-Integer-Wert, welchen sie repräsentieren, ableiten (eigene Funktion hierfür schreiben).
Nun das Array mit _ArraySort() nach dieser letzten Spalte sortieren.
Die letzte Spalte wieder löschen (ReDim)
Fertig

Ansatz 2: Sortierfunktion mit nutzerdefinierter Vergleichsfunktion nutzen:

Es gibt Funktionen, welche es zulassen, dass die Vergleichsfunktion für die Sortierung vom Nutzer definiert werden kann.
Eine dieser findest du in der >>ArrayPlus-UDF<<. Und deine Aufgabe lässt sich damit dann folgdendermaßen lösen:

AutoIt

#include "ArrayPlus.au3"

; Ausgangsarray:
Local $aListViewData[10][4] = [ _
    ["PC-001", "00:1A:2B:3C:4D:5E", "192.168.23.145", "Büro 101"], _
    ["PC-002", "00:2B:3C:4D:5E:6F", "10.0.15.87", "Empfang"], _
    ["PC-003", "00:3C:4D:5E:6F:7G", "172.16.78.209", "Besprechungsraum"], _
    ["PC-004", "00:4D:5E:6F:7G:8H", "192.168.1.3", "Buchhaltung"], _
    ["PC-005", "00:5E:6F:7G:8H:9I", "10.10.55.201", "Marketing"], _
    ["PC-006", "00:6F:7G:8H:9I:0J", "172.20.100.50", "Entwicklung 1"], _
    ["PC-007", "00:7G:8H:9I:0J:1K", "192.168.0.11", "Entwicklung 2"], _
    ["PC-008", "00:8H:9I:0J:1K:2L", "10.1.1.254", "Personalabteilung"], _
    ["PC-009", "00:9I:0J:1K:2L:3M", "172.31.255.1", "Kantine"], _
    ["PC-010", "00:0J:1K:2L:3M:4N", "192.168.100.100", "Serverraum"] _
]

; sortiere Array mit eigener Vergleichsfunktion
_ArraySortFlexible($aListViewData, _sortIPColumn3)
; alternativ kann auch direkt die Funktionalität als String eingetragen werden (dann braucht es keine extra Funktionsdefinition):
;~ _ArraySortFlexible($aListViewData, "__ap_cb_comp_Natural($A[2], $B[2])")

; sortiertes Array ausgeben lassen
_ArrayDisplay($aListViewData, "Sortiert")

; eigene Vergleichsfunktion, welcher die jeweils 3. Spalten zweier Elemente per NaturalCompare vergleicht
Func _sortIPColumn3($A, $B)
	Return __ap_cb_comp_Natural($A[2], $B[2])
EndFunc

Alles anzeigen

**Moombas**

Ich würde die IP in ihre 4 Teile gesplittet in ein Array legen und dann sortieren mit der Funktion von UEZ :

AutoIt

Opt('MustDeclareVars', 1)

#include <Array.au3>

Global $aIPs[10][5] = [ _
    [192, 168,  23, 145, "Büro 101"], _
    [ 10,   0,  15,  87, "Empfang"], _
    [172,  16,  78, 209, "Besprechungsraum"], _
    [192, 168,   1,   3, "Buchhaltung"], _
    [ 10,  10,  55, 201, "Marketing"], _
    [172,  20, 100,  50, "Entwicklung 1"], _
    [192, 168,   0,  11, "Entwicklung 2"], _
    [ 10,   1,   1, 254, "Personalabteilung"], _
    [172,  31, 255,   1, "Kantine"], _
    [192, 168, 100, 100, "Serverraum"]]
Global $aI[4] = [0, 1, 2, 3]

_ArrayDisplay($aIPs, 'Before:')
_ArraySort_MultiColumn($aIPs, $aI, 0, 0)
_ArrayDisplay($aIPs, 'After:')

; #FUNCTION# =============================================================================
; Name.............:    _ArraySort_MultiColumn
; Description ...:      sorts an array at given colums (multi colum sort)
; Syntax...........:    _ArraySort_MultiColumn(ByRef $aSort, ByRef $aIndices)
; Parameters ...:       $aSort - array to sort
;                       $aIndices - array with colum indices which should be sorted in specified order - zero based
;                       $oDir/$iDir - sort direction - if set to 1, sort descendingly else ascendingly
; Author .........:     UEZ
; Version ........:     v0.70 build 2013-11-20 Beta
; =========================================================================================
Func _ArraySort_MultiColumn(ByRef $aSort, ByRef $aIndices, $oDir = 0, $iDir = 0)
    If Not IsArray($aIndices) Or Not IsArray($aSort) Then Return SetError(1, 0, 0) ;checks if $aIndices is an array
    If UBound($aIndices) > UBound($aSort, 2) Then Return SetError(2, 0, 0) ;check if $aIndices array is greater the $aSort array
    Local $1st, $2nd, $x, $j, $k, $l = 0
    For $x = 0 To UBound($aIndices) - 1 ;check if array content makes sense
        If Not IsInt($aIndices[$x]) Then Return SetError(3, 0, 0) ;array content is not numeric
    Next
    If UBound($aIndices) = 1 Then Return _ArraySort($aSort, $oDir, 0, 0, $aIndices[0]) ;check if only one index is given
    _ArraySort($aSort, $oDir, 0, 0, $aIndices[0])
    Do
        $1st = $aIndices[$l]
        $2nd = $aIndices[$l + 1]
        $j = 0
        $k = 1
        While $k < UBound($aSort)
            If $aSort[$j][$1st] <> $aSort[$k][$1st] Then
                If $k - $j > 1  Then
                    _ArraySort($aSort, $iDir , $j, $k - 1, $2nd)
                    $j = $k
                Else
                    $j = $k
                EndIf
            EndIf
            $k += 1
        WEnd
        If $k - $j > 1 Then _ArraySort($aSort, $iDir, $j, $k, $2nd)
        $l += 1
    Until $l = UBound($aIndices) - 1
    Return 1
EndFunc

Alles anzeigen

casi4712

okidoki danke für das Feedback Leudde, Moombas, das klingt nach nem Plan das hatte ich auch schon versucht, weil ich das schon von Excel her kenne, kam aber nicht so recht weiter. Dann schaue ich mir mal Deinen Ansatz an.

Danke noch mal und

schönen Tag noch

**Moombas**

Denk dran, wenn du die IP splittest das beim Eintragen ins Array gleich explizit in eine Zahl umzuwandeln, damit er nicht nachher meint es wäre text, sonst kommt nämlich nicht das richtige Ergebnis raus (z.B. 100 nach der 1 aber vor der 2 etc.)

casi4712

Ähm ich hab das gerade versucht auf mein Script anzuwenden, aber habe gesehen du ersgtellst ja ein Array, wo die NUmmern schon von vornherein getrennt sind, [192, 168, 23, 145, "Büro 101"], _ , bei mir sind es ja komplette IPs im Logfile, also 192.168.100.10 usw. Kann die Funktion damit auch umgehen?

**Moombas**

Naja das splitten ist halt nochmal ein separater Schritt.

Ich schaue das ich ein QuD dafür bereit stelle auf basis deines oberen eintrags.

**Moombas**

Hier das QuD sample:

AutoIt

Opt('MustDeclareVars', 1)

#include <Array.au3>

Global $aI[4] = [1, 2, 3, 4]
Global $String = '2024/06/23 18:02:36 - action=login pcname=N210708_b mac=5C61994A3157 ip=192.168.178.22 time=18:02:36' & @CRLF & _
				 '2024/06/23 18:06:55 - action=logout pcname=N210708_B mac=5C61994A3157 ip=192.168.178.21 time=18:06:55'
$String = StringSplit($String, @CR)
$String = Transform($String)
_ArraySort_MultiColumn($String, $aI, 0, 0)
_ArrayDisplay($String)

Func Transform($aText)
Local $aReturn[0][5], $Name, $IP
	For $Row = 1 to $aText[0]
		$IP = Stringsplit(StringRegExp($aText[$Row], '\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}', $STR_REGEXPARRAYMATCH)[0], '.')
		_ArrayAdd($aReturn, StringRegExp($aText[$Row], 'pcname=(\S{6,})', $STR_REGEXPARRAYMATCH)[0] & '|' & Number($IP[1]) & '|' & Number($IP[2]) & '|' & Number($IP[3]) & '|' & Number($IP[4]))
	Next
	Return $aReturn
EndFunc


; #FUNCTION# =============================================================================
; Name.............:    _ArraySort_MultiColumn
; Description ...:      sorts an array at given colums (multi colum sort)
; Syntax...........:    _ArraySort_MultiColumn(ByRef $aSort, ByRef $aIndices)
; Parameters ...:       $aSort - array to sort
;                       $aIndices - array with colum indices which should be sorted in specified order - zero based
;                       $oDir/$iDir - sort direction - if set to 1, sort descendingly else ascendingly
; Author .........:     UEZ
; Version ........:     v0.70 build 2013-11-20 Beta
; =========================================================================================
Func _ArraySort_MultiColumn(ByRef $aSort, ByRef $aIndices, $oDir = 0, $iDir = 0)
	If Not IsArray($aIndices) Or Not IsArray($aSort) Then Return SetError(1, 0, 0) ;checks if $aIndices is an array
	If UBound($aIndices) > UBound($aSort, 2) Then Return SetError(2, 0, 0) ;check if $aIndices array is greater the $aSort array
	Local $1st, $2nd, $x, $j, $k, $l = 0
	For $x = 0 To UBound($aIndices) - 1 ;check if array content makes sense
		If Not IsInt($aIndices[$x]) Then Return SetError(3, 0, 0) ;array content is not numeric
	Next
	If UBound($aIndices) = 1 Then Return _ArraySort($aSort, $oDir, 0, 0, $aIndices[0]) ;check if only one index is given
	_ArraySort($aSort, $oDir, 0, 0, $aIndices[0])
	Do
		$1st = $aIndices[$l]
		$2nd = $aIndices[$l + 1]
		$j = 0
		$k = 1
		While $k < UBound($aSort)
			If $aSort[$j][$1st] <> $aSort[$k][$1st] Then
				If $k - $j > 1 Then
					_ArraySort($aSort, $iDir, $j, $k - 1, $2nd)
					$j = $k
				Else
					$j = $k
				EndIf
			EndIf
			$k += 1
		WEnd
		If $k - $j > 1 Then _ArraySort($aSort, $iDir, $j, $k, $2nd)
		$l += 1
	Until $l = UBound($aIndices) - 1
	Return 1
EndFunc   ;==>_ArraySort_MultiColumn

Alles anzeigen

casi4712

okidoki, suoper danke, dann kann ich ja im Prinzip meine bisherige Sortfunktion rausschmeissen, denk ich mal

recht herzlichen Dank noch mal

lg

**Moombas**

Erstmal ausgiebig testen bevor du das machst

Bei meinen QuD kann sich auch mal ein (Denk-)Fehler einschleichen

btw.: time hast du doppelt drinne (vorne und hinten) in deinem log

casi4712

das stimmt, hatte ich ganz übersehen, danke;)

**Kanashius**

Ich werf noch mal eine andere Lösung in den Ring, die auch den Ansatz von AspirinJunkie verfolgt: Sortieren nach der IP als Zahl. Wobei ich den BinaryString nehme, weil die Zahl manchmal negativ wäre.

AutoIt

Local $sLogData = 	"2024/06/23 18:02:36 - Client connected"&@crlf& _
				"2024/06/23 18:02:36 - action=login pcname=N210708_b mac=5C61994A3157 ip=192.168.178.22 time=18:02:36"&@crlf& _
				"2024/06/23 18:06:55 - Client connected"&@crlf& _
				"2024/06/23 18:06:55 - action=logout pcname=N210708_B mac=5C61994A3157 ip=192.168.178.22 time=18:06:55"&@crlf& _
				"2024/06/23 18:10:30 - Client connected"&@crlf& _
				"2024/06/23 18:10:30 - action=login pcname=N210708_B mac=5C61994A3157 ip=192.168.178.22 time=18:10:30"&@crlf& _
				"2024/06/23 18:13:50 - Client connected"&@crlf& _
				"2024/06/23 18:13:50 - action=logout pcname=N210708_B mac=5C61994A3157 ip=192.168.178.22 time=18:13:50"&@crlf& _
				"2024/06/23 18:18:20 - Server started and listening on port 8085"

Local $arLogData = _parseLog($sLogData)

; Example for reading the data
For $i = 0 to UBound($arLogData)-1 Step 1
	ConsoleWrite(($i+1)&". For sorting: "&$arLogData[$i][0]&@crlf)
	ConsoleWrite(($i+1)&". LogDate: "&$arLogData[$i][1].logDate&@crlf)
	ConsoleWrite(($i+1)&". LogTime: "&$arLogData[$i][1].logTime&@crlf)
	ConsoleWrite(($i+1)&". Action: "&$arLogData[$i][1].action&@crlf)
	ConsoleWrite(($i+1)&". PCName: "&$arLogData[$i][1].pcname&@crlf)
	ConsoleWrite(($i+1)&". Mac: "&$arLogData[$i][1].mac&@crlf)
	ConsoleWrite(($i+1)&". IP: "&$arLogData[$i][1].ip&@crlf)
	ConsoleWrite(($i+1)&". Time: "&$arLogData[$i][1].time&@crlf)
Next

Func _parseLog($sLog)
	Local $arData = StringRegExp($sLog, "(?<date>\d{4}\/\d{2}\/\d{2})\s(?<time>\d{2}:\d{2}:\d{2}\s)-\saction=(?<action>\S+)\spcname=(?<pcname>\S+)\smac=(?<mac>\S+)\sip=(?<ip>(?<ip1>\d+)\.(?<ip2>\d+)\.(?<ip3>\d+)\.(?<ip4>\d+))\stime=(?<time2>\d{2}:\d{2}:\d{2})", 3)
	Local $arResult[UBound($arData)/11][2] ; intIp, dataMap
	For $i=0 to UBound($arData)-1 Step 11
		Local $mData[]
		$mData.logDate = $arData[$i]
		$mData.logTime = $arData[$i+1]
		$mData.action = $arData[$i+2]
		$mData.pcname = $arData[$i+3]
		$mData.mac = $arData[$i+4]
		$mData.ip = $arData[$i+5]
		$mData.time = $arData[$i+10]
		Local $iUnsignedIntIp = BitOR(BitShift(Int($arData[$i+6]), -24), BitShift(Int($arData[$i+7]), -16), BitShift(Int($arData[$i+8]), -8), Int($arData[$i+9]))
		$arResult[$i/11][0] = _toBinaryString($iUnsignedIntIp)
		$arResult[$i/11][1] = $mData
	Next
	return $arResult
EndFunc

Func _toBinaryString($iNumber)
	Local $sBinaryNumber = ""
	For $i=31 to 0 Step -1
		$sBinaryNumber&=BitAND(BitShift($iNumber, $i), 1)
	Next
	return $sBinaryNumber
EndFunc

Alles anzeigen

Du bekommst also nach dem parsen ein Array mit 2 Werten, dem BinaryString der IP zum sortieren und eine Map mit allen Werten.

casi4712

also nur noch mal zum Verständnis von Lösung A, im Grunde macht das aber nichst anders wie meine Lösung, Einzelspalten, den String sortieren, mein Problem wird jetzt also sein die IP Spalte erst mal auf 4 Einzelstrings zu teilen, vor dem sortieren udn dannn weider zusammenzusetzten, richtig? Und dann solte mein Sortieralgorhitmus ja auch funktionieren

ich schau mir mal deinen zweiten Vorschlag an @Kana;)

Danke noch mal

casi4712

Also ich habs mal durchlaufne lassen und hab in der Logdef mal eine IP auf 192.168.100.5 gesetzt, diese würde ich bei der IP Sortierung aufsteigend auch oben erwarten und nicht unten, denke wir haben uns da missverstanden;)

lg

1. For sorting: 11000000101010001011001000010110
1. LogDate: 2024/06/23
1. LogTime: 18:02:36
1. Action: login
1. PCName: N210708_b
1. Mac: 5C61994A3157
1. IP: 192.168.178.22
1. Time: 18:02:36
2. For sorting: 11000000101010001011001000010110
2. LogDate: 2024/06/23
2. LogTime: 18:06:55
2. Action: logout
2. PCName: N210708_B
2. Mac: 5C61994A3157
2. IP: 192.168.178.22
2. Time: 18:06:55
3. For sorting: 11000000101010001011001000010110
3. LogDate: 2024/06/23
3. LogTime: 18:10:30
3. Action: login
3. PCName: N210708_B
3. Mac: 5C61994A3157
3. IP: 192.168.178.22
3. Time: 18:10:30
4. For sorting: 11000000101010001011001000000101
4. LogDate: 2024/06/23
4. LogTime: 18:13:50
4. Action: logout
4. PCName: N210708_B
4. Mac: 5C61994A3157
4. IP: 192.168.178.5
4. Time: 18:13:50

**Schnuffel**

ich würde die IP Blöcke alle auf 3 stellen jeweils links mit Nullen auffüllen, die Blöcke zu einer 12-stelligen Zahl zusammensetzen,

in eineZahl umwandeln und dann sortieren.

**Kanashius**

Zitat von casi4712

Also ich habs mal durchlaufne lassen und hab in der Logdef mal eine IP auf 192.168.100.5 gesetzt, diese würde ich bei der IP Sortierung aufsteigend auch oben erwarten und nicht unten, denke wir haben uns da missverstanden;)

Die Sortierung hab ich auch gar nicht implementiert, ich hab nur die Daten aufbereitet.

Dafür brauchst du aber auch nur ein _ArraySort($arLogData) in Zeile 17 nach dem Local $arLogData = _parseLog($sLogData) einfügen. (Und das #include<Array.au3> natürlich)

MfG Kanashius

**Oscar**

Dann will ich auch noch eine Möglichkeit beisteuern (vom Prinzip her wie bei Kanashius, nur mit 32Bit UINT):

AutoIt

#include <Array.au3>
Local $aListViewData[10][4] = [ _
    ["PC-001", "00:1A:2B:3C:4D:5E", "192.168.23.145", "Büro 101"], _
    ["PC-002", "00:2B:3C:4D:5E:6F", "10.0.15.87", "Empfang"], _
    ["PC-003", "00:3C:4D:5E:6F:7G", "172.16.78.209", "Besprechungsraum"], _
    ["PC-004", "00:4D:5E:6F:7G:8H", "192.168.1.3", "Buchhaltung"], _
    ["PC-005", "00:5E:6F:7G:8H:9I", "10.10.55.201", "Marketing"], _
    ["PC-006", "00:6F:7G:8H:9I:0J", "172.20.100.50", "Entwicklung 1"], _
    ["PC-007", "00:7G:8H:9I:0J:1K", "192.168.0.11", "Entwicklung 2"], _
    ["PC-008", "00:8H:9I:0J:1K:2L", "10.1.1.254", "Personalabteilung"], _
    ["PC-009", "00:9I:0J:1K:2L:3M", "172.31.255.1", "Kantine"], _
    ["PC-010", "00:0J:1K:2L:3M:4N", "192.168.100.100", "Serverraum"] _
]

For $i = 0 To UBound($aListViewData) - 1
	$aListViewData[$i][2] = _IPaddrToUInt($aListViewData[$i][2])
Next
_ArraySort($aListViewData, 1, 0, 0, 2)
For $i = 0 To UBound($aListViewData) - 1
	$aListViewData[$i][2] = _UIntToIPaddr($aListViewData[$i][2])
Next
_ArrayDisplay($aListViewData)

Func _IPaddrToUInt($sIP)
	Local $tAddr = DllStructCreate('uint IP')
	Local $aTmp = StringSplit($sIP, '.', 2)
	Local $iAddr = BitOR(BitShift(Int($aTmp[0]), -24), BitShift(Int($aTmp[1]), -16), BitShift(Int($aTmp[2]), -8), Int($aTmp[3]))
	$tAddr.IP = $iAddr
	Return $tAddr.IP
EndFunc

Func _UIntToIPaddr($iAddr)
	Local $tAddr = DllStructCreate('uint IP')
	$tAddr.IP = $iAddr
	Local $tIP = DllStructCreate('byte D;byte C;byte B;byte A', DllStructGetPtr($tAddr))
	Return $tIP.A & '.' & $tIP.B & '.' & $tIP.C & '.' & $tIP.D
EndFunc

Alles anzeigen

Wenn man die Daten gleich im UINT-Format speichert, braucht man sie nur bei der Anzeige zurückwandeln.

**AspirinJunkie**

Ich interpretiere das mal so, dass meine 2. Variante keine Rolle mehr spielt - nun gut.
Dann halt auch mal mein Vorschlag für Variante 1:
Als sortierbaren Wert nehme ich die IP-Adresse aber alle Teile sind immer 3 Stellen lang (mit 0 aufgefüllt):

AutoIt

#include <Array.au3>

; Ausgangsarray:
Local $aListViewData[10][4] = [ _
    ["PC-001", "00:1A:2B:3C:4D:5E", "192.168.23.145", "Büro 101"], _
    ["PC-002", "00:2B:3C:4D:5E:6F", "10.0.15.87", "Empfang"], _
    ["PC-003", "00:3C:4D:5E:6F:7G", "172.16.78.209", "Besprechungsraum"], _
    ["PC-004", "00:4D:5E:6F:7G:8H", "192.168.1.3", "Buchhaltung"], _
    ["PC-005", "00:5E:6F:7G:8H:9I", "10.10.55.201", "Marketing"], _
    ["PC-006", "00:6F:7G:8H:9I:0J", "172.20.100.50", "Entwicklung 1"], _
    ["PC-007", "00:7G:8H:9I:0J:1K", "192.168.0.11", "Entwicklung 2"], _
    ["PC-008", "00:8H:9I:0J:1K:2L", "10.1.1.254", "Personalabteilung"], _
    ["PC-009", "00:9I:0J:1K:2L:3M", "172.31.255.1", "Kantine"], _
    ["PC-010", "00:0J:1K:2L:3M:4N", "192.168.100.100", "Serverraum"] _
]

; Spalte hinzufügen
Local $iRows = UBound($aListViewData), $iCols = UBound($aListViewData, 2)
Redim $aListViewData[$iRows][$iCols + 1]

; Spalte mit einem sortierbaren Wert (hier mit Nullen aufgefüllte IP-Adresse) füllen:
For $i = 0 To $iRows - 1
	$aListViewData[$i][$iCols] = Execute(StringRegExpReplace($aListViewData[$i][2], '^(\d+)\.(\d+)\.(\d+)\.(\d+)$', 'StringFormat("%03d.%03d.%03d.%03d",$1,$2,$3,$4)'))
Next

; nach dieser Spalte sortieren
_ArraySort($aListViewData, 0, 0, 0, $iCols)

; letzte Spalte wieder löschen:
Redim $aListViewData[$iRows][$iCols]

; Ergebnis ausgeben
_ArrayDisplay($aListViewData)

Alles anzeigen

**funkey**

Hier noch meine 2Cents

AutoIt

#include <Array.au3>

; Ausgangsarray:
Local $aListViewData[10][4] = [ _
    ["PC-001", "00:1A:2B:3C:4D:5E", "192.168.23.145", "Büro 101"], _
    ["PC-002", "00:2B:3C:4D:5E:6F", "10.0.15.87", "Empfang"], _
    ["PC-003", "00:3C:4D:5E:6F:7G", "172.16.78.209", "Besprechungsraum"], _
    ["PC-004", "00:4D:5E:6F:7G:8H", "192.168.1.3", "Buchhaltung"], _
    ["PC-005", "00:5E:6F:7G:8H:9I", "10.10.55.201", "Marketing"], _
    ["PC-006", "00:6F:7G:8H:9I:0J", "172.20.100.50", "Entwicklung 1"], _
    ["PC-007", "00:7G:8H:9I:0J:1K", "192.168.0.11", "Entwicklung 2"], _
    ["PC-008", "00:8H:9I:0J:1K:2L", "10.1.1.254", "Personalabteilung"], _
    ["PC-009", "00:9I:0J:1K:2L:3M", "172.31.255.1", "Kantine"], _
    ["PC-010", "00:0J:1K:2L:3M:4N", "192.168.100.100", "Serverraum"] _
]

; Spalte hinzufügen
Local $iRows = UBound($aListViewData), $iCols = UBound($aListViewData, 2)
Redim $aListViewData[$iRows][$iCols + 1]

; Spalte mit einem sortierbaren Wert (hier mit Nullen aufgefüllte IP-Adresse) füllen:
For $i = 0 To $iRows - 1
	$aListViewData[$i][$iCols] = _htonl(_inet_addr($aListViewData[$i][2]))
Next

; nach dieser Spalte sortieren
_ArraySort($aListViewData, 0, 0, 0, $iCols)

; letzte Spalte wieder löschen:
Redim $aListViewData[$iRows][$iCols]

; Ergebnis ausgeben
_ArrayDisplay($aListViewData)

Func _inet_addr($sIP)
	Local $aRet = DllCall("ws2_32.dll", "ULONG", "inet_addr", "str", $sIP)
	Return $aRet[0]
EndFunc   ;==>_inet_addr


;host byte order to network byte order (long)
Func _htonl($value)
	Local $aRet = DllCall("ws2_32.dll", "ULONG", "htonl", "ULONG", $value)
	Return $aRet[0]
EndFunc   ;==>_htonl

Alles anzeigen

casi4712

So wollte mich mal wieder melden, bin leider noch nicht so ganz weitergekommen, werde noch wahnsinnig darüber;) Vielen Dank noch mal für die vielen Ansätzte.

@Aspirin: Das mit der plus udf finde ich ganz interessant, das Problem ist nur wo und an welcher Stelle sollte ich dies einabuen, die Listview kann ich ja anscheinend nicht damit auslesen. Brauche ich dazu noch die Standard Array.udf? Oder soltle ich besser die Sortierfunktionalitär in ie WM Notify eibauen? oder behindert das wieder die normale Funktionalität mit dem Sortieren auf den Spaltenkopf?

Ich habe noch mal mein Script was nun sonst 99%ig funktioniert zusammengestellt.

AutoIt

;#include <Array.au3>
#include "ArrayPlus.au3"
#include <File.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <StructureConstants.au3>
#include <WinAPI.au3>
#include <ListViewConstants.au3>
#include <Constants.au3>
#include <MsgBoxConstants.au3>
#include "GIFAnimation.au3"
HotKeySet("{ESC}", "ExitScript")
FileInstall("C:\SC\ICO\Spinner-3.gif", @TempDir & "\GIFS\Spinner-3.gif", 1)

;only one Instance
	$g_szVersion = "My NetworkBrowser"
	If WinExists($g_szVersion) Then
		Exit
	EndIf
	AutoItWinSetTitle($g_szVersion)


Global $sFilePath = "\\share\logs\logfile.txt"
Global $csvFilePath = "\\share\logs\Summary_Short.csv"
Global $aLines, $iLines
Global $csvData
Global $loggedInPCs[1][6] ; Anpassen der Dimension, um die neue Spalte aufzunehmen
Global $sortOrder = True
Global $lastSortedColumn = -1

; GUI erstellen
Global $hGUI = GUICreate("LARCH-Network Browser", 600, 400)
Global $hListView = GUICtrlCreateListView("PC Name|MAC Address|IP Address|Bezeichnung|Share Path", 10, 10, 580, 300, $LVS_REPORT) ; Hinzufügen der neuen Spalte
Global $btnCheckPCs = GUICtrlCreateButton("Aktualisieren", 10, 320, 100, 30)
GUISetState(@SW_SHOW)

_LoadCSVData()
_UpdateListView()
_SortListViewByColumn($hListView, 0, True)
_CheckAndPingOnlinePCs() ; Check beim Start ausführen

; Haupt-Event-Loop
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY_Handler")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $btnCheckPCs
            _RescanLog()
            _CheckAndPingOnlinePCs()
    EndSwitch
WEnd

Func _LoadCSVData()
    If Not FileExists($csvFilePath) Then
        MsgBox(0, "Error", "CSV file not found: " & $csvFilePath)
        Exit
    EndIf
    If Not _FileReadToArray($csvFilePath, $csvData) Then
        MsgBox(0, "Error", "Failed to read CSV file: " & $csvFilePath)
        Exit
    EndIf
EndFunc

Func _UpdateListView()
;_LoadingGUI()
    ReDim $loggedInPCs[1][6] ; Anpassen der Dimension, um die neue Spalte aufzunehmen
    $loggedInPCs[0][0] = ""
    $loggedInPCs[0][1] = ""
    $loggedInPCs[0][2] = ""
    $loggedInPCs[0][3] = ""
    $loggedInPCs[0][4] = ""
    $loggedInPCs[0][5] = False

    If Not FileExists($sFilePath) Then
        MsgBox(0, "Error", "File not found: " & $sFilePath)
        Return
    EndIf

    If Not _FileReadToArray($sFilePath, $aLines) Then
        MsgBox(0, "Error", "Failed to read file: " & $sFilePath)
        Return
    EndIf
    $iLines = UBound($aLines)

    For $i = 1 To $iLines - 1 ; jede Zeile im CSV Array ausgenommen erste Zeile
        If StringInStr($aLines[$i], "action=login") Then
            Local $pcname = _GetParameter($aLines[$i], "pcname")
            Local $mac = _FormatMAC(_GetParameter($aLines[$i], "mac"))
            Local $ip = _GetParameter($aLines[$i], "ip")
            _SetPCStatus($pcname, $mac, $ip, True)
        ElseIf StringInStr($aLines[$i], "action=logout") Then
            Local $pcname = _GetParameter($aLines[$i], "pcname")
            _SetPCStatus($pcname, "", "", False)
        EndIf
    Next
    _GenerateOnlineStatus()
EndFunc

Func _GetParameter($sLine, $sParam)
    Local $iStart = StringInStr($sLine, $sParam & "=")
    If $iStart = 0 Then Return ""
    $iStart += StringLen($sParam) + 1
    Local $iEnd = StringInStr($sLine, " ", 0, 1, $iStart)
    If $iEnd = 0 Then $iEnd = StringLen($sLine) + 1
    Return StringMid($sLine, $iStart, $iEnd - $iStart)
EndFunc

Func _FormatMAC($mac)
    $mac = StringReplace($mac, "-", ":")
    $mac = StringRegExpReplace($mac, "(..)(..)(..)(..)(..)(..)", "\1:\2:\3:\4:\5:\6")
    Return $mac
EndFunc

Func _SetPCStatus($pcname, $mac, $ip, $status)
    For $i = 0 To UBound($loggedInPCs) - 1
        If $loggedInPCs[$i][0] = $pcname Then
            $loggedInPCs[$i][1] = $mac
            $loggedInPCs[$i][2] = $ip
            $loggedInPCs[$i][5] = $status
            Return
        EndIf
    Next
    If $loggedInPCs[0][0] = "" Then
        $loggedInPCs[0][0] = $pcname
        $loggedInPCs[0][1] = $mac
        $loggedInPCs[0][2] = $ip
        $loggedInPCs[0][3] = ""
        $loggedInPCs[0][4] = "\\ " & $pcname & "\c$" ; Hinzufügen des Share Path
        $loggedInPCs[0][5] = $status
    Else
        ReDim $loggedInPCs[UBound($loggedInPCs) + 1][6] ; Anpassen der Dimension, um die neue Spalte aufzunehmen
        $loggedInPCs[UBound($loggedInPCs) - 1][0] = $pcname
        $loggedInPCs[UBound($loggedInPCs) - 1][1] = $mac
        $loggedInPCs[UBound($loggedInPCs) - 1][2] = $ip
        $loggedInPCs[UBound($loggedInPCs) - 1][3] = ""
        $loggedInPCs[UBound($loggedInPCs) - 1][4] = "\\ " & $pcname & "\c$" ; Hinzufügen des Share Path
        $loggedInPCs[UBound($loggedInPCs) - 1][5] = $status
    EndIf
EndFunc

Func _GenerateOnlineStatus()
    _GUICtrlListView_DeleteAllItems($hListView)
	;_ArrayDisplay($loggedInPCs)
    For $i = 0 To UBound($loggedInPCs) - 1
        If $loggedInPCs[$i][5] Then
            Local $bezeichnung = _GetBezeichnung($loggedInPCs[$i][0])
            GUICtrlCreateListViewItem($loggedInPCs[$i][0] & "|" & $loggedInPCs[$i][1] & "|" & $loggedInPCs[$i][2] & "|" & $bezeichnung & "|" & $loggedInPCs[$i][4], $hListView) ; Hinzufügen der neuen Spalte
        EndIf
    Next
	;GUIDelete($hGui) ; Ladebildschirm schließen
EndFunc

Func _GetBezeichnung($pcname)
    For $i = 1 To UBound($csvData) - 1
        Local $csvLine = StringSplit($csvData[$i], ";", 1)
        Local $csvPCName = StringStripWS($csvLine[1], 3)
        If StringReplace($csvPCName, '"', '') = $pcname Then
            Local $csvBezeichnung = StringStripWS($csvLine[2], 3)
            Return StringReplace($csvBezeichnung, '"', '')
        EndIf
    Next
    Return ""
EndFunc

Func _SortListViewByColumn($hListView, $iColumn, $bAscending)
    _GUICtrlListView_SimpleSort($hListView, Not $bAscending, $iColumn)
EndFunc

Func _CheckAndPingOnlinePCs()
    Local $aPCToPing[1]
    For $i = 0 To UBound($loggedInPCs) - 1
        If $loggedInPCs[$i][5] Then
            _ArrayAdd($aPCToPing, $loggedInPCs[$i][0])
        EndIf
    Next
    If UBound($aPCToPing) > 1 Then
        ;MsgBox(64, "Ping PCs", "Pinging PCs: " & _ArrayToString($aPCToPing, ", ", 1))
    EndIf

    _Recall()
EndFunc

Func _RescanLog()
    _UpdateListView()
    _GenerateOnlineStatus()
EndFunc

Func _Recall()
    Local $aListViewItems = _GUICtrlListView_GetItemCount($hListView)
    Local $aItemsToRemove[1]

    Local $sMessage = "Pinge folgende PCs:" & @CRLF
    For $i = 0 To $aListViewItems - 1
        Local $pcName = _GUICtrlListView_GetItemText($hListView, $i, 0)
        $sMessage &= $pcName & @CRLF
    Next
    ;MsgBox(64, "Ping Vorbereitung", $sMessage)
    ;Local $hProgress = SplashTextOn("Ping Fortschritt", "Ich aktualisiere...", 300, 100, -1, -1, 1, "", 16)
_LoadingGUI() ; Zeige Ladebildschirm während des Pings
    ; Parallelisieren der Pings für angemeldete PCs
    For $i = 0 To $aListViewItems - 1
        Local $pcName = StringStripWS(_GUICtrlListView_GetItemText($hListView, $i, 0), 3)
        If $pcName <> "" Then
            If Not _PingPCName($pcName) Then
                _ArrayAdd($aItemsToRemove, $i)
            EndIf
        EndIf
    Next
    ;SplashOff()

    For $j = UBound($aItemsToRemove) - 1 To 1 Step -1  ; Entfernen der nicht erreichbaren PCs
        _GUICtrlListView_DeleteItem($hListView, $aItemsToRemove[$j])
    Next
    GUIDelete($hGui) ; Ladebildschirm schließen
EndFunc

Func _PingPCName($pcName)
    Local $iPID = Run(@ComSpec & ' /c ping ' & $pcName & ' -n 1', "", @SW_HIDE, $STDOUT_CHILD)
    Local $sOutput = ""
    While 1
        $sOutput &= StdoutRead($iPID)
        If @error Then ExitLoop
    WEnd
    If StringInStr($sOutput, "TTL=") Then
        Return True
    Else
        Return False
    EndIf
EndFunc

Func _LoadingGUI()
    Global $sTempFolder = @TempDir & "\GIFS"
    DirCreate($sTempFolder)

    Global $sFile = $sTempFolder & "\Spinner-3.gif"

    Global $aGIFDimension = _GIF_GetDimension($sFile)
    Global $hGUI = GUICreate("GIF Animation", $aGIFDimension[0], $aGIFDimension[1], -1, -1, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TOPMOST))
    Global $hGIF = _GUICtrlCreateGIF($sFile, "", 0, 0)
    GUICtrlSetTip(-1, "ESC to exit")
    GUISetBkColor(0xABCDEF) ; Hintergrundfarbe ändern
    _WinAPI_SetLayeredWindowAttributes($hGUI, 0xABCDEF, 255)
    _WinAPI_SetParent($hGUI, 0)
    GUISetState(@SW_SHOW)
EndFunc

Func WM_NOTIFY_Handler($hWnd, $iMsg, $iwParam, $ilParam)
    Local $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    Local $iCode = DllStructGetData($tNMHDR, "Code")

    If $hWndFrom = GUICtrlGetHandle($hListView) And $iCode = $LVN_COLUMNCLICK Then
        Local $tInfo = DllStructCreate($tagNMLISTVIEW, $ilParam)
        Local $iColumn = DllStructGetData($tInfo, "SubItem")

        If $iColumn = $lastSortedColumn Then  ; Toggle sort order if clicking the same column, otherwise reset to ascending
            $sortOrder = Not $sortOrder
        Else
            $sortOrder = True
        EndIf

        $lastSortedColumn = $iColumn
        _SortListViewByColumn($hListView, $iColumn, $sortOrder)
    EndIf

    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

Vielen Dank noch mal und

einen schönen Rest Sonntag

sortieren nach IP

Ähnliche Themen

Ordnerverzeichnis auslesen und in Array speichern, anschließendes weiterverarbeiten

Array über Programmdauer hinweg speichern

Datei-Anzeige