Ich dachte da an sowas wie if-else, falls kein "." vorkommt....
Ja, das ist auch ein vernünftiger Ansatz. Du solltest aber aufpassen, da bei einigen Strings mehrere Punkte vorkommen können und du dann die Sachen falsch splittest.
Splitte nach dem Punkt und schau ob das gesplittete Array zwei Funde beinhaltet, wenn ja, dann kannst du damit weiterarbeiten, wenn nicht, musst du was anderes damit machen.
Hallo Sumale.my !
Ich habe mein Skript mal etwas erweitert :
#include <Array.au3>
Opt('MustDeclareVars', 1) ; Variablen müssen vor der Verwendung deklariert werden
Global $aBIOSInfo = _GetBIOSInfo()
IF Not @error Then
_ArrayDisplay($aBIOSInfo)
Else
ConsoleWrite("Fehler in der Funktion _GetBIOSInfo" & @CRLF)
EndIf
; ----------------------------------------------
Func _GetBIOSInfo()
Local $objWMI, $colItems, $objItem
Local $sBIOSVersion, $sManufacturer, $sSerialNumber
Local $aReturn[5]
Local $sModelName = '', $sVersion = '' ; Werte aus $sBIOSVersion
Local $iPos
$objWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & @ComputerName & "\root\cimv2")
$colItems = $objWMI.ExecQuery("SELECT * FROM Win32_BIOS", "WQL", 0x10 + 0x20)
If IsObj($colItems) Then
For $objItem In $colItems
$sBIOSVersion = $objItem.BIOSVersion(0)
$sManufacturer = $objItem.Manufacturer
$sSerialNumber = StringReplace(StringReplace($objItem.SerialNumber, "SSN12345678901234567", "Nicht vorhanden !"), "na", "Nicht vorhanden !")
; ModelName und Version aus $sBIOSVersion ermitteln :
; ----------------------------------------------------
; Prüfen, ob in $sBIOSVersion ein Punkt vorkommt, also z.B. X751SA.705
; Falls ja :
; -> String von hinten auswerten, und beim ersten Vorkommen aufteilen
; Falls nicht :
; -> $sModelName mit $sBIOSVersion besetzen
; -> damit ist $sModelName zwar identisch wie $sBIOSVersion, aber egal.
; -> $sVersion leerlassen
$iPos = StringInStr($sBIOSVersion, '.', 0, -1)
If $iPos > 0 Then
$sModelName = StringLeft($sBIOSVersion, $iPos - 1)
$sVersion = StringRight($sBIOSVersion, StringLen($sBIOSVersion) - $iPos)
Else
$sModelName = $sBIOSVersion
EndIf
; Rückgabearray besetzen :
$aReturn[0] = $sBIOSVersion
$aReturn[1] = $sManufacturer
$aReturn[2] = $sSerialNumber
$aReturn[3] = $sModelName
$aReturn[4] = $sVersion
Return $aReturn
Next
Else
SetError(1)
EndIf
EndFunc ;==>_GetBIOSInfosiehe Kommentar im Skript -> ; ModelName und Version aus $sBIOSVersion ermitteln :
Da hier kein Array durch StringSplit mehr im Spiel ist, kann es auch nicht zu Range-Fehler etc. kommen.
Dieser Teil der Lösung ist in sofern etwas quick&dirty, da er voraussetzt, dass das Muster mind. einen Punkt enthält. Ansonsten wird $sBIOSVersion vollständig bei $sModelName eingetragen.
An dieser Stelle können weitere Verbesserungen (z.B. mit RegEx) vorgenommen werden, aber möglicherweise langt es für Dich ja bereits aus 
.
Gruß Musashi
Hallo Sumale.my !
Ich müsste dann aber "BIOSVersion(0)" mit "SMBIOSBIOSVersion" ersetzen, weil "SMBIOSBIOSVersion" immer "MODEL.VERSION" ausgibt.
Das Problem bei den ASUS Geräten ist, dass ich die Bios Version nur mit "SMBIOSBIOSVersion" auslesen kann mittels "MODEL.BIOSVERSION"s Muster.
Falls SMBIOSBIOSVersion die für deine Zwecke geeigneten Daten ausgibt, dann tue Dir keinen Zwang an 
.
Mein Skript sollte Dir ja nur ein Grundgerüst liefern. Solange Du also nicht wieder Variablen innerhalb einer Funktion mit Global deklarierst, kannst Du die Werte ändern oder erweitern wie Du möchtest .
Die Beschreibung der Klasse Win32_BIOS findest Du, wie bereits beschrieben, unter folgendem Link :
https://msdn.microsoft.com/en-us/library/…7(v=vs.85).aspx
Ich gehe davon aus, dass ich vom Code-Technischen her, deins nehmen sollte oder?
Also, es geht sicher eleganter, aber als Vorlage ist das Skript wohl ganz gut geeignet.
Der Wert SMBIOSBIOSVersion ist Teil der Klasse, also kannst Du $sBIOSVersion überall durch $sSMBIOSBIOSVersion ersetzten, und $sSMBIOSBIOSVersion =$objItem.SMBIOSBIOSVersion schreiben.
Gruß Musashi
Hallo Sumale.my !
Ich sehe, dass Du deinen Beitrag gerade editiert und eine Fehlerliste beigefügt hast.
Beispiel (nur Auszug) :
"C:\Users\Lenovo\Documents\ISN AutoIt Studio\Projects\Final Test Tools v3\functions.au3"(186,77) : warning: $getModelName: possibly used before declaration. $keydefus = @WorkingDir & "WTP\asus-wtp\bin\keydef\keydef" & $getModelName &
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^ "C:\Users\Lenovo\Documents\ISN AutoIt Studio\Projects\Final Test Tools v3\functions.au3"(234,36) : warning: $getSerial: possibly used before declaration.
$serial = StringStripWS($getSerial, ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
$keydefus = @WorkingDir & "WTP\asus-wtp\bin\keydef\keydef" & $getModelName &
usw.
Das zeigt mir, dass Du NICHT deinen kompletten Code gepostet hast !!!
Du hast wahrscheinlich die Anweisung :
Opt('MustDeclareVars', 1) ; Variablen müssen vor der Verwendung mit Global, Local oder Dim deklariert werden
übernommen, und die anderen Variablen in deinem Vollskript sind nicht durch Global/Local deklariert.
Entferne daher mal diese Zeile, falls vorhanden !
Gruß Musashi
Hallo Sumale.my
Ok, super und ja, es hilft enorm und es etwas zu verstehen.
Kannst du mir auch sagen wie und wo ich alle anderen Variablen nun mit "Dim, Local oder Global" setzen muss?
Wo muss ich z.B "Dim $getModelName" einfügen, damit der der Fehler (und weitere) nicht mehr auftauchen:
Hast Du bei Dir die Anweisung Opt('MustDeclareVars', 1) eingebaut ?
Das sind nur Warnungen, dass du einige Variablen abrufen könntest bevor du sie überhaupt erzeugt hast.
Sollte das Programm laufen, kannst du das ignorieren, ist aber kein guter Stil.
Du kannst die Warnungen mit einem Präprozessor abschalten oder einfach oben "Global $varname" hinschreiben.
Hallo Sumale.my !
Ich werde die besagte Zeile mal entfernen. Danke für die Info.
Die Anweisung Opt('MustDeclareVars', 1) hat grundsätzlich schon ihren Sinn. Wenn in einem langen Skript aber bisher keine Variablendeklarationen gemacht wurden, ist es recht nervig, das 'nachzurüsten'.
Kannst du mir auch sagen wie und wo ich alle anderen Variablen nun mit "Dim, Local oder Global" setzen muss?
Ja ! Dafür schlage ich aber vor, dass Du eine Konversation mit mir startest. Im Rahmen dieses Threads Ping-Pong mäßig sich überschneidende Beiträge 'rauszuhauen, ist nicht so produktiv. Innerhalb einer Konversation können wir das Thema in Ruhe besprechen. Falls dabei etwas herauskommt, das für die Allgemeinheit von Interesse sein könnte, kann man das Fazit hier posten.
Gruß Musashi
Hier mal eine Version von mir...
;-- TIME_STAMP 2017-10-20 00:21:02 v 0.1
#Region ;************ Includes ************
#include <Array.au3>
#EndRegion ;************ Includes ************
Opt('MustDeclareVars', 1) ; Variablen müssen vor der Verwendung deklariert werden
Global Enum $eBiosCharacteristics, $eBIOSVersion, $eBuildNumber, $eCaption, $eCodeSet, $eCurrentLanguage, $eDescription, $eEmbeddedControllerMajorVersion, $eEmbeddedControllerMinorVersion, $eIdentificationCode, $eInstallableLanguages, $eInstallDate, $eLanguageEdition, $eListOfLanguages, $eManufacturer, $eName, $eOtherTargetOS, $ePrimaryBIOS, $eReleaseDate, $eSerialNumber, $eSMBIOSBIOSVersion, $eSMBIOSMajorVersion, $eSMBIOSMinorVersion, $eSMBIOSPresent, $eSoftwareElementID, $eSoftwareElementState, $eStatus, $eSystemBiosMajorVersion, $eSystemBiosMinorVersion, $eTargetOperatingSystem, $eVersion, $eSizeOff
Global $g_aBIOSInfo = _GetBIOSInfo()
If @error Then
ConsoleWrite("! Fehler in der Funktion _GetBIOSInfo! Error = " & @error & @CRLF)
Else
For $i = 0 To $eSizeOff - 1 Step 1
ConsoleWrite(StringFormat('> %32s = %s\r', $g_aBIOSInfo[$i][0], $g_aBIOSInfo[$i][1]))
Next
ConsoleWrite(@CRLF)
Local $aSplit
$aSplit = _SplitStr($g_aBIOSInfo[$eSMBIOSBIOSVersion][1])
ConsoleWrite(StringFormat('! %32s = %s\r', 'SMBBIOSVersion Split 1', $aSplit[0]))
ConsoleWrite(StringFormat('! %32s = %s\r', 'SMBBIOSVersion Split 2', $aSplit[1]))
ConsoleWrite(@CRLF)
$aSplit = _SplitStr($g_aBIOSInfo[$eVersion][1])
ConsoleWrite(StringFormat('- %32s = %s\r', ' Version Split 1', $aSplit[0]))
ConsoleWrite(StringFormat('- %32s = %s\r', ' Version Split 2', $aSplit[1]))
ConsoleWrite(@CRLF)
ConsoleWrite(StringFormat('+ %32s = %s\r', ' Version Split 1', _SplitStr($g_aBIOSInfo[$eVersion][1])[0]))
ConsoleWrite(StringFormat('+ %32s = %s\r', ' Version Split 2', _SplitStr($g_aBIOSInfo[$eVersion][1])[1]))
ConsoleWrite(@CRLF)
ConsoleWrite(StringFormat('@ %32s = %s\r', $g_aBIOSInfo[$eManufacturer][0], $g_aBIOSInfo[$eManufacturer][1]))
_ArrayDisplay($g_aBIOSInfo)
EndIf
Func _GetBIOSInfo()
Local $objWMI, $colItems, $objItem, $wbemFlagReturnImmediately = 0x10, $wbemFlagForwardOnly = 0x20
Local $sBIOSVersion, $sManufacturer, $sSerialNumber
Local $aReturn[0][2]
Local $strBiosCharacteristics, $strBIOSVersion, $strListOfLanguages
$objWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & @ComputerName & "\root\cimv2")
$colItems = $objWMI.ExecQuery("SELECT * FROM Win32_BIOS", "WQL", BitOR($wbemFlagReturnImmediately, $wbemFlagForwardOnly))
If IsObj($colItems) Then
For $objItem In $colItems
With $objItem
$strBiosCharacteristics &= .BiosCharacteristics & ","
_ArrayAddItem($aReturn, "BiosCharacteristics", $strBiosCharacteristics)
$strBIOSVersion &= .BIOSVersion & ","
_ArrayAddItem($aReturn, "BIOSVersion", $strBIOSVersion)
_ArrayAddItem($aReturn, "BuildNumber", .BuildNumber)
_ArrayAddItem($aReturn, "Caption", .Caption)
_ArrayAddItem($aReturn, "CodeSet", .CodeSet)
_ArrayAddItem($aReturn, "CurrentLanguage", .CurrentLanguage)
_ArrayAddItem($aReturn, "Description", .Description)
_ArrayAddItem($aReturn, "EmbeddedControllerMajorVersion", .EmbeddedControllerMajorVersion)
_ArrayAddItem($aReturn, "EmbeddedControllerMinorVersion", .EmbeddedControllerMinorVersion)
_ArrayAddItem($aReturn, "IdentificationCode", .IdentificationCode)
_ArrayAddItem($aReturn, "InstallableLanguages", .InstallableLanguages)
_ArrayAddItem($aReturn, "InstallDate", .InstallDate)
_ArrayAddItem($aReturn, "LanguageEdition", .LanguageEdition)
$strListOfLanguages &= .ListOfLanguages & ","
_ArrayAddItem($aReturn, "ListOfLanguages", $strListOfLanguages)
_ArrayAddItem($aReturn, "Manufacturer", .Manufacturer)
_ArrayAddItem($aReturn, "Name", .Name)
_ArrayAddItem($aReturn, "OtherTargetOS", .OtherTargetOS)
_ArrayAddItem($aReturn, "PrimaryBIOS", .PrimaryBIOS)
_ArrayAddItem($aReturn, "ReleaseDate", .ReleaseDate)
_ArrayAddItem($aReturn, "SerialNumber", .SerialNumber)
_ArrayAddItem($aReturn, "SMBIOSBIOSVersion", .SMBIOSBIOSVersion)
_ArrayAddItem($aReturn, "SMBIOSMajorVersion", .SMBIOSMajorVersion)
_ArrayAddItem($aReturn, "SMBIOSMinorVersion", .SMBIOSMinorVersion)
_ArrayAddItem($aReturn, "SMBIOSPresent", .SMBIOSPresent)
_ArrayAddItem($aReturn, "SoftwareElementID", .SoftwareElementID)
_ArrayAddItem($aReturn, "SoftwareElementState", .SoftwareElementState)
_ArrayAddItem($aReturn, "Status", .Status)
_ArrayAddItem($aReturn, "SystemBiosMajorVersion", .SystemBiosMajorVersion)
_ArrayAddItem($aReturn, "SystemBiosMinorVersion", .SystemBiosMinorVersion)
_ArrayAddItem($aReturn, "TargetOperatingSystem", .TargetOperatingSystem)
_ArrayAddItem($aReturn, "Version", .Version)
EndWith
Next
Else
Return SetError(1)
EndIf
Return $aReturn
EndFunc ;==>_GetBIOSInfo
Func _ArrayAddItem(ByRef $aArray, $sName, $sItem)
Local $iDim = UBound($aArray) + 1
ReDim $aArray[$iDim][2]
$aArray[$iDim - 1][0] = $sName
$aArray[$iDim - 1][1] = $sItem
EndFunc ;==>_ArrayAddItem
Func _SplitStr($sStr)
Local $aSplit[2], $iSeperator = -1, $aSeperator = ['.', ' - ', '-', '']
Do
$iSeperator += 1
If $aSeperator[$iSeperator] = '' Or $sStr = '' Then
ReDim $aSplit[2]
$aSplit[0] = $sStr
$aSplit[1] = ''
ExitLoop
EndIf
$aSplit = StringRegExp($sStr, '(.+)\' & $aSeperator[$iSeperator] & '(.+)', 1)
Until UBound($aSplit) = 2
Return $aSplit
EndFunc ;==>_SplitStrHallo Bitnugger !
Schönes Skript , mehr geht natürlich immer !
Die Zeilen :
_ArrayAddItem($aReturn, "EmbeddedControllerMajorVersion", .EmbeddedControllerMajorVersion)
_ArrayAddItem($aReturn, "EmbeddedControllerMinorVersion", .EmbeddedControllerMinorVersion)
und
_ArrayAddItem($aReturn, "SystemBiosMajorVersion", .SystemBiosMajorVersion)
_ArrayAddItem($aReturn, "SystemBiosMinorVersion", .SystemBiosMinorVersion)
werfen, zumindest bei mir, aber den Error : ==> The requested action with this object has failed.
Laut Klassenbeschreibung sind das die uint8 Werte :
uint8 EmbeddedControllerMajorVersion;
uint8 EmbeddedControllerMinorVersion;
uint8 SystemBiosMajorVersion;
uint8 SystemBiosMinorVersion;
Gruß Musashi
werfen, zumindest bei mir, aber den Error : ==> The requested action with this object has failed.
Dito.
==> The requested action with this object has failed.
Dasselbe habe ich auch.
Übrigens erhalte ich nur für 18 Parameter überhaupt einen Wert, 13 bleiben leer.
Diese Werte werden befüllt:
"Caption"
"CurrentLanguage"
"Description"
"InstallableLanguages"
"Manufacturer"
"Name"
"PrimaryBIOS"
"ReleaseDate"
"SerialNumber"
"SMBIOSBIOSVersion"
"SMBIOSMajorVersion"
"SMBIOSMinorVersion"
"SMBIOSPresent"
"SoftwareElementID"
"SoftwareElementState"
"Status"
"TargetOperatingSystem"
"Version"
Hallo @Bitnugger !
Vorab : Ich möchte dein Skript hier keinesfalls schlecht reden !!
Es gibt aber einen Punkt, der für weniger versierte User kaum zu durchschauen ist :
Bei : Global Enum $eBiosCharacteristics, $eBIOSVersion, ... , $eSizeOff
wird $eSizeOff ja mit der Anzahl der Elemente der Aufzählung besetzt (hier 31).
Kommentiert der User jetzt aber z.B. Zeilen wie :
;_ArrayAddItem($aReturn, "EmbeddedControllerMajorVersion", .EmbeddedControllerMajorVersion)
;_ArrayAddItem($aReturn, "EmbeddedControllerMinorVersion", .EmbeddedControllerMinorVersion)
aus, dann wird bei :
For $i = 0 To $eSizeOff - 1 Step 1
ConsoleWrite(StringFormat('> %32s = %s\r', $g_aBIOSInfo[$i][0], $g_aBIOSInfo[$i][1]))
Next
trotzdem der Wert $eSizeOff=31 (Anzahl der Elemente der Aufzählung) verwendet. Das Array ist jetzt aber um 2 kürzer.
Ergebnis : ==> Array variable has incorrect number of subscripts or subscript dimension range exceeded
Gruß Musashi
Hier mal eine Version von mir...
Danke für die Mühe, da blicke ich erst einmal gar nicht durch 
Hier mal die Funktion von Bitnugger in einer von mir abgewandelten Version (Objektfehler werden abgefangen und das Array erst am Ende der Funktion erstellt:
;-- TIME_STAMP 2017-10-20 13:40:00 v 0.2
#Region ;************ Includes ************
#include <Array.au3>
#EndRegion ;************ Includes ************
Opt('MustDeclareVars', 1) ; Variablen müssen vor der Verwendung deklariert werden
Global $oErrorHandler = ObjEvent('AutoIt.Error', '_ErrFunc')
Global $g_aBIOSInfo = _GetBIOSInfo()
If @error Then
ConsoleWrite("! Fehler in der Funktion _GetBIOSInfo! Error = " & @error & @CRLF)
Else
_ArrayDisplay($g_aBIOSInfo)
EndIf
Func _ErrFunc($oError)
ConsoleWrite('! Zeile: ' & $oError.scriptline & ' ==> Error intercepted: ' & $oError.windescription & @CRLF)
EndFunc ;==>_ErrFunc
Func _GetBIOSInfo()
Local $objWMI, $colItems, $objItem, $wbemFlagReturnImmediately = 0x10, $wbemFlagForwardOnly = 0x20
Local $sOut, $strBiosCharacteristics, $strBIOSVersion, $strListOfLanguages
$objWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & @ComputerName & "\root\cimv2")
$colItems = $objWMI.ExecQuery("SELECT * FROM Win32_BIOS", "WQL", BitOR($wbemFlagReturnImmediately, $wbemFlagForwardOnly))
If IsObj($colItems) Then
For $objItem In $colItems
With $objItem
$sOut &= 'BiosCharacteristics|' & .BiosCharacteristics & @CRLF
$sOut &= 'BIOSVersion|' & .BIOSVersion & @CRLF
$sOut &= 'BuildNumber|' & .BuildNumber & @CRLF
$sOut &= 'Caption|' & .Caption & @CRLF
$sOut &= 'CodeSet|' & .CodeSet & @CRLF
$sOut &= 'CurrentLanguage|' & .CurrentLanguage & @CRLF
$sOut &= 'Description|' & .Description & @CRLF
$sOut &= 'EmbeddedControllerMajorVersion|' & .EmbeddedControllerMajorVersion & @CRLF
$sOut &= 'EmbeddedControllerMinorVersion|' & .EmbeddedControllerMinorVersion & @CRLF
$sOut &= 'IdentificationCode|' & .IdentificationCode & @CRLF
$sOut &= 'InstallableLanguages|' & .InstallableLanguages & @CRLF
$sOut &= 'InstallDate|' & .InstallDate & @CRLF
$sOut &= 'LanguageEdition|' & .LanguageEdition & @CRLF
$sOut &= 'ListOfLanguages|' & .ListOfLanguages & @CRLF
$sOut &= 'Manufacturer|' & .Manufacturer & @CRLF
$sOut &= 'Name|' & .Name & @CRLF
$sOut &= 'OtherTargetOS|' & .OtherTargetOS & @CRLF
$sOut &= 'PrimaryBIOS|' & .PrimaryBIOS & @CRLF
$sOut &= 'ReleaseDate|' & .ReleaseDate & @CRLF
$sOut &= 'SerialNumber|' & .SerialNumber & @CRLF
$sOut &= 'SMBIOSBIOSVersion|' & .SMBIOSBIOSVersion & @CRLF
$sOut &= 'SMBIOSMajorVersion|' & .SMBIOSMajorVersion & @CRLF
$sOut &= 'SMBIOSMinorVersion|' & .SMBIOSMinorVersion & @CRLF
$sOut &= 'SMBIOSPresent|' & .SMBIOSPresent & @CRLF
$sOut &= 'SoftwareElementID|' & .SoftwareElementID & @CRLF
$sOut &= 'SoftwareElementState|' & .SoftwareElementState & @CRLF
$sOut &= 'Status|' & .Status & @CRLF
$sOut &= 'SystemBiosMajorVersion|' & .SystemBiosMajorVersion & @CRLF
$sOut &= 'SystemBiosMinorVersion|' & .SystemBiosMinorVersion & @CRLF
$sOut &= 'TargetOperatingSystem|' & .TargetOperatingSystem & @CRLF
$sOut &= 'Version|' & .Version
EndWith
Next
Else
Return SetError(1)
EndIf
Return _StringSplit2D($sOut, @CRLF, '|')
EndFunc ;==>_GetBIOSInfo
Func _StringSplit2D($sData, $sRowDel, $sColDel)
Local $aRows = StringSplit($sData, $sRowDel, 3)
Local $aCol = StringSplit($aRows[0], $sColDel, 3)
Local $aOut[UBound($aRows)][UBound($aCol)], $aTmp
For $iRow = 0 To UBound($aRows) - 1
$aTmp = StringSplit($aRows[$iRow], $sColDel, 3)
For $iCol = 0 To UBound($aCol) - 1
$aOut[$iRow][$iCol] = ($aTmp[$iCol] = '' ? 'not available' : $aTmp[$iCol])
Next
Next
Return $aOut
EndFunc ;==>_StringSplit2D