Hi,
erstelle einen "öffentlichen" Ordner auf deinem FTP-Server mit Benutzerrechten, die nur für diesen Ordner gelten (Nur Dateien runterladen, keine Hochladen, sonst keine Rechte!)
Kopiere eine Dummy-Textdatei rein und sende mal die Zugangsdaten per PN, ich schaue mir das mal an, wenn du willst...
FTP ist eigentlich völlig problemfrei, habe da seit Jahren keinerlei Stress.
@Andy ich glube dabei könnte es probleme geben, weil ich glaube das die erste version von dem server nicht öffentlich ftpzugänglich ist. Bin mir zwar nicht ganz sicher aber fast.
Hallo,
lass mich mal raten, du hast die Änderungen an der FTPEx.au3 nicht wieder rückgängig gemacht oder. Deshalb wird nämlich UNKNOWN status = 40 ausgegeben. Die Werte die du geändert hast habe nichts mit Timeouts zu tun, das sind einfach nur die Statuscodes.
Hier noch ein leicht abgewandeltes Script...
#include <Debug.au3>
#include <Misc.au3>
#include <FTPEx.au3>
#cs
2 Beispiele eines FTP Downloads mit externem Progressfenster zur Demostration der Fortschrittsanzeige mit einer Benutzerfunktion
#ce
Global $hFTPSession, $hFTPConnect, $sServerName, $sUsername, $sPassword, $iPassive, $sLocalFile, $sRemoteFile
_DebugSetup('MyFTP Control', True)
_Demo1()
_DebugOut("~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~")
_DebugOut("~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~")
_DebugOut("~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~")
_Demo2()
Func _Demo1()
; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
; Beispiel 1
; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
$hFTPSession = -1
$hFTPConnect = -1
$sServerName = "ftp.mozilla.org" ; das ist ein real existierender Server - lol, ja was denn sonst?
$sUsername = "" ; Annonyme Verbindung
$sPassword = "" ; ohne Username und/oder Passwort
$iPassive = 1 ; passives FTP nutzen (empfohlen)
If FileExists("M:\TEMP\") Then ; M: ist meine RAMDISK
$sLocalFile = "M:\TEMP\Firefox Setup 39.0b5.exe"
Else
$sLocalFile = @TempDir & "\Firefox Setup 39.0b5.exe"
EndIf
$sRemoteFile = "/pub/firefox/releases/39.0b5/win64/de/Firefox Setup 39.0b5.exe"
If FileExists($sLocalFile) Then
FileDelete($sLocalFile) ; alte Datei löschen
_DebugOut("alte Datei gelöscht...")
EndIf
_myFTP_ProgressDownload()
EndFunc ;==>_Demo1
Func _Demo2()
; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
; Beispiel 2
; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
$hFTPSession = -1
$hFTPConnect = -1
$sServerName = "192.168.0.111"
$sUsername = "XXXX"
$sPassword = "XXXXXXXX"
$sLocalFile = @TempDir & "\Drucken.txt"
$sRemoteFile = "/var/usbstick/Drucken.txt" ; Backslashes '\' sind hier sicher falsch!!!
If FileExists($sLocalFile) Then
FileDelete($sLocalFile) ; alte Datei löschen
_DebugOut("alte Datei gelöscht...")
EndIf
_myFTP_ProgressDownload()
EndFunc ;==>_Demo2
Func _myFTP_ProgressDownload()
Local $iError = 0, $iExtended = 0, $sMessage = ""
; FTP Sitzung eröffnen
$hFTPSession = _FTP_Open("myFTP")
If @error Then
$iError = @error
$iExtended = @extended
$sMessage = ""
_DebugOut("Error: _FTP_Open()" & @CRLF & _
" $hFTPSession = " & $hFTPSession & @CRLF & _
" _FTP_GetLastResponseInfo = " & _FTP_GetLastResponseInfo($iError, $sMessage) & @CRLF & _
" @error = " & $iError & @CRLF & _
" @extended = " & $iExtended)
_CloseFTP()
;_Exit(1)
EndIf
_DebugOut("OK: _FTP_Open() --> " & $hFTPSession)
; set up a status callback function
Local $pCallback = _FTP_SetStatusCallback($hFTPSession, 'FTPStatusCallbackHandler')
; mit FTP Server verbinden
$hFTPConnect = _FTP_Connect($hFTPSession, $sServerName, $sUsername, $sPassword, $iPassive, $INTERNET_DEFAULT_FTP_PORT, $INTERNET_SERVICE_FTP, 0, $pCallback)
If @error Then
$iError = @error
$iExtended = @extended
$sMessage = ""
_DebugOut("Error: _FTP_Connect()" & @CRLF & _
" $hFTPSession = " & $hFTPSession & @CRLF & _
" $hFTPConnect = " & $hFTPConnect & @CRLF & _
" $sServerName = " & $sServerName & @CRLF & _
" $sUsername = " & $sUsername & @CRLF & _
" $sPassword = " & $sPassword & @CRLF & _
" $iPassive = " & $iPassive & @CRLF & _
" _FTP_GetLastResponseInfo = " & _FTP_GetLastResponseInfo($iError, $sMessage) & @CRLF & _
" @error = " & $iError & @CRLF & _
" @extended = " & $iExtended)
_CloseFTP()
;_Exit(2)
EndIf
_DebugOut("OK: _FTP_Connect() --> " & $hFTPConnect)
; ProgressDownload
#cs
Der Funktionsname darf nicht, so wie es in der AutoIt-Hilfe gezeigt wird,
in "" gesetzt werden!!!
Falsch: Local $sFunctionToCall = "_UpdateProgress" <-- String
Richtig: Local $sFunctionToCall = _UpdateProgress <-- UserFunction
#ce
Local $sFunctionToCall = _UpdateProgress
ProgressOn("Downloading from: " & $sServerName, "..." & StringRight($sRemoteFile,35), "Status: 0%")
_FTP_ProgressDownload($hFTPConnect, $sLocalFile, $sRemoteFile, $sFunctionToCall)
If @error Then
$iError = @error
$iExtended = @extended
$sMessage = ""
ProgressOff()
Switch $iError
Case -1
$sError = "Local file couldn't be created"
Case -2
$sError = "Unable to get RemoteFile size"
Case -3
$sError = "Open RemoteFile failed"
Case -4
$sError = "Read from Remotefile failed"
Case -5
$sError = "Close RemoteFile failed"
Case -6
$sError = "Download aborted by PercentageFunc and Return of Called Function"
Case -7
$sError = "Local file write failed"
Case Else
$sError = "Wow, ich bin ein Genie... lol"
EndSwitch
_DebugOut( _
"Error: _FTP_ProgressDownload()" & @CRLF & _
" $hFTPSession = " & $hFTPSession & @CRLF & _
" $hFTPConnect = " & $hFTPConnect & @CRLF & _
" $sLocalFile = " & $sLocalFile & @CRLF & _
" $sRemoteFile = " & $sRemoteFile & @CRLF & _
" $sError = " & $sError & @CRLF & _
" _FTP_GetLastResponseInfo = " & _FTP_GetLastResponseInfo($iError, $sMessage) & @CRLF & _
" @error = " & $iError & @CRLF & _
" @extended = " & $iExtended)
_CloseFTP()
;_Exit(3)
EndIf
ProgressOff()
_DebugOut("OK: _FTP_ProgressDownload() - Download complete" & @CRLF & _
"From: " & $sRemoteFile & @CRLF & _
" To: " & $sLocalFile & @CRLF)
Return 1 ; OK
EndFunc ;==>_myFTP_ProgressDownload
Func _UpdateProgress($iPercent)
;ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & " var: $iPercent --> " & $iPercent & @LF)
; Set the "subtext" and "maintext" of the progress bar window.
Local $iInt = Int($iPercent)
If $iInt < 100 Then
ProgressSet($iInt, "Status: " & $iInt & "%") ; percent [, "subtext" [, "maintext"]]
Else
ProgressSet(100, "Done", "Download complete")
Sleep(1000)
EndIf
If _IsPressed("77") Then Return 0 ; Abbruch bei F8
Return 1 ; bei 1 Download fortsetzen
EndFunc ;==>_UpdateProgress
Func FTPStatusCallbackHandler($hInternet, $iContext, $iInternetStatus, $pStatusInformation, $iStatusInformationLength)
#forceref $hInternet, $iContext
If $iInternetStatus = $INTERNET_STATUS_REQUEST_SENT Or $iInternetStatus = $INTERNET_STATUS_RESPONSE_RECEIVED Then
Local $iBytesRead
Local $tSize = DllStructCreate('dword')
_WinAPI_ReadProcessMemory(_WinAPI_GetCurrentProcess(), $pStatusInformation, DllStructGetPtr($tSize), $iStatusInformationLength, $iBytesRead)
_DebugOut(_FTP_DecodeInternetStatus($iInternetStatus) & ' | Size = ' & DllStructGetData($tSize, 1) & ' Bytes Bytes read = ' & $iBytesRead)
Else
_DebugOut(_FTP_DecodeInternetStatus($iInternetStatus))
EndIf
EndFunc ;==>FTPStatusCallbackHandler
Func _CloseFTP()
If IsDeclared("hFTPConnect") Then _FTP_Close($hFTPConnect) ; Verbindung zum Server trennen
If IsDeclared("hFTPSession") Then _FTP_Close($hFTPSession) ; FTP Session schließen
EndFunc ;==>_CloseFTP
Func _Exit($err = 0)
Exit $err
EndFunc ;==>_ExitKann sich mein Script mal jemand ansehen?
In dieser Zeile fehlt ein Backslash:
_FTP_ProgressDownload($l_FTPSession, @ScriptDir & "Drucken.txt", "\var\usbstick\Drucken.txt", "_UpdateProgress")
das müsste so aussehen:
_FTP_ProgressDownload($l_FTPSession, @ScriptDir & "\Drucken.txt", "\var\usbstick\Drucken.txt", "_UpdateProgress")Schalte bitte mal deine Firewall aus und probiere es noch einmal.
Bei manchen Firewall-Konfigurationen sind eingehende Verbindungen gesperrt. Das kann den beschriebenen Effekt haben.
Fällt niemand mehr etwas ein woran es noch liegen könnte? 
Naja es ist eigentlich klar, es liegt an deinem Server. Der ist (vor allem bei der Startmeldung) sehr langsam.
Wenn wir einen Timeout verändern könnten, was durchaus eigentlich möglich sein sollte, dann würde es funktionieren.
Das problem ist wir können es nur schwer testen, da wir ja keinen zugriff auf den server haben...
Kann es sein, dass Dakumente die auf dem Server 'nicht existieren' trotzdem heruntergeladen werden und dann leer sind.
Oder der download ist durch andere Probleme fehlerhaft.
Das heißt, entweder ist die Verbindung ohnehin fehlerhaft (sprich an deinem Problem hat sich nichts geändert!!!) oder es stimmt was anderes nicht.
Das ist keine eingehende Verbindung - sein FTP-Server ist im LAN!
Hm, du bist aber eine harte Nuss... lol
Irgendwas machst du da falsch...
Error: _FTP_Connect()
Du bekommst ja nicht mal einen Connect hin... der Rest ist dann zwangsweise auch nicht erfolgreich.
Da KEINE Verbindung zum Server hegestellt werden konnte, wurde somit ergo auch KEINE Datei heruntergeladen, sondern lediglich eine Datei zur Vorbereitung des Downloads von _FTP_ProgressDownload() lokal auf deinem PC geöffnet...
Local $hFile = FileOpen($s_LocalFile, $FO_OVERWRITE + $FO_BINARY)
...was die Ursache dafür ist, dass im Fehlerfall nach Beenden des Programms eine leere Datei zurückbleibt. Die Datei kann man dann natürlich getrost löschen... aber weitaus intelligenter ist es, solche Fehler von vornherein zu vermeiden, indem erst eine Verzeichnisliste vom Server geholt wird, um sie dann mit _ArraySearch() zu durchsuchen, bevor ein File gedownloadet werden soll, dass es gar nicht gibt. Wurde der Dateiname im Array mit "no case sensitive" gefunden, kann man den Dateiname aus dem Array verwenden, um den Download zu starten, ohne weiter über die richtige Schreibweise (klein GROSS oder mIxEd???) nachdenken zu müssen.
...
Local $aRemoteFiles = _FTP_ListToArray($hFTPSession, 0)
If $aRemoteFiles[0] = 0 Then _Error() ; Abbruch, Exit oder Bier holen... ;-)
If _ArraySearch($aRemoteFiles, $sLocalFileName, 1, 0, 0, 1) Then _Download($aRemoteFiles[0], $sLocalPath)
...
Natürlich gibt es noch zig andere Ursachen, warum ein Download nicht klappt... z. B. wegen fehlender Berechtigungen... 'jens' meldet sich am Server an und will eine Datei downloaden, doch die gehört leider dem User 'root'. 
Nun habe ich ein weiteres Test-Programm für dich erstellt... ein etwas ausgefeilteres... ist aber noch nicht ganz fertig. 
Darin setze ich vorab dann auch den Maximalwert für 'CONNECT_TIMEOUT' & 'RECEIVE_TIMEOUT' - der Wert für CONNECT und RECEIVE und auch die Anzahl der Verbindungsversuche ist natürlich einstellbar, ebenso die Pause(n) dazwischen, wobei aber klar sein sollte, dass veränderte TIMEOUT-Werte keine Auswirkungen auf das Verhalten des Servers haben... was u. A. auch an den extremen Zeitunterschieden bis zum Erscheinen einer Fehlermeldung erkennbar ist, je nachdem, welcher Server gerade mit im Spiel ist. Bei einem im LAN installierten FTP-Server kam die Rückmeldung so schnell, dass ich nicht einmal genügend Zeit hatte, meinen Stinkefinger von der F5-Taste zu nehmen. 
So gesehen bedeutet dies im positiven Sinne aber auch, dass der Server bereit ist und auf Anfragen reagiert... falls nicht, dann liegt oder sitzt der Fehler eindeutig auf der Seite des Clients - ca. 20 - 60 cm vor dem Monitor. 
Es werden noch etliche andere Dinge überprüft... z. B. ob der $sServername (Name oder IP) korrekt angegeben wurden und ob auf ein Ping geantwortet wird.
Desweiteren habe ich in der FTPEx.au3 ein paar sehr markante und interessante Stellen gefunden, die mir aufgezeigt haben, dass ich die Fehlerbehandlung in meinem neuen Script noch wesentlich verbessern kann - das will ich erst noch alles checken... und dank BugFix habe ich jetzt so allmählich auch den Durchblick mit DllCall's. 
Ich werde schätzungweise Morgen im Laufe des Tages damit fertig sein... mal schauen... ich schiebe es hoch, sobald es fertig ist.
Poste dann anschließend die Ausgabe von Debug() wieder hier... aber bitte setze sie in einen Spoiler!
Nachtrag: Hast du denn mit FileZilla und/oder Co. eine Verbindung herstellen können?
Nachtrag: Hast du denn mit FileZilla und/oder Co. eine Verbindung herstellen können?
Oh ja das hat er, mit erfolg, wenn er den timeout auf 60 sekunden stellte. in dieser situation waren wir bereits 
