MsgBox ohne skript Pause

DasIch

Hallo zusammen,

ich habe ein Skript, das regelmäßig prüft, ob ein System Offline oder Online ist (über die Weboberfläche des Systemmonitorings). Da dem Kunden allerdings die Info per Email nicht reicht und er auf seinem Monitor per Popup informiert werden will, suche ich nach einer Möglichkeit, das umzusetzen. Autoit hat ja nun leider die Eigenart, dass eine MsgBox die Ausführung des Skriptes pausiert, bis das Popup verschwunden ist.

Ist es irgendwie machbar, dass das Skript auch bei einem Popup Fenster im Hintergrund weiter prüfen kann?

Hier ein CodeSnippet zu dem Thema:

AutoIt

#include <FF.au3>


_FFConnect()


Global $online = 0
Global $name = _FFXPath("/html/body/div/div[3]/div[3]/header/div[2]/div[1]/h2/span", "textContent", 9)


While 1
	Sleep(700)
	$status = _FFXPath("/html/body/div/div[3]/div[3]/header/div[2]/div[2]/div/span", "textcontent", 9)
	If $status Then
		If $online = 0 Then
			$start = @HOUR & ":" & @MIN & ":" & @SEC
			$monat = @MDAY & "." & @MON & "." & @YEAR
			$online = 1
		EndIf
	Else
		If $online = 1 Then
			$ende = @HOUR & ":" & @MIN & ":" & @SEC
			$online = 0
;>> Hier sollte das Popup kommen mit der Info. Dieses soll aber offen bleiben, bis es weggeklickt wird. 
;>>Allerdings ohne das Skript zu pausieren.
			FileWriteLine(@ScriptDir & "\online.txt", $name & @TAB & $monat  & @TAB & $start & " Bis " & $ende) ;Hier wird die Ausfallzeit zusätzlich in eine Datei geschrieben.
		EndIf
	EndIf


WEnd


_FFDisConnect()

Alles anzeigen

Vielen Dank vorab für eure Hilfe und LG,
der Robert

**alpines**

Alternativ tut es auch eine kleine GUI die per OnEventMode läuft.

DasIch

Hey alpines und lieben Dank für deinen Vorschlag.

Den Gedanken hatte ich auch schon, allerdings werden in dem Skript mehrere Systeme überwacht und deshalb wäre es einfacher pro Ausfall ein eigenes Popup zu haben, statt einem GUI, das für jeden Ausfall überschrieben werden müsste.

**UEZ**

Von hier: https://www.autoitscript.com/forum/topic/15…comment-1149008

Code

MessageBox("Text", "Caption", 64)
For $i = 0 To 10
	ConsoleWrite("Spleep" & @CRLF)
	Sleep(1000)
Next
Exit


Func MessageBox($sText, $sCaption, $uType, $hWnd = 0)
	Local $dwOpcodeSize = 50
	Local $dwTextSize = StringLen($sText) + 1
	Local $dwCaptionSize = StringLen($sCaption) + 1
	Local $dwSize = $dwOpcodeSize + $dwTextSize + $dwCaptionSize


	Local $pAddress = VirtualAlloc(0, $dwSize, 0x00001000, 0x40) ;MEM_COMMIT, PAGE_EXECUTE_READWRITE
	Local $hProcess = GetCurrentProcess()
	Local $pText = $pAddress + $dwOpcodeSize
	Local $tText = DllStructCreate("CHAR[" & $dwTextSize & "]")
	DllStructSetData($tText, 1, $sText)
	WriteProcessMemory($hProcess, $pText, DllStructGetPtr($tText, 1), $dwTextSize)


	Local $pCaption = $pText + $dwTextSize
	Local $tCaption = DllStructCreate("CHAR[" & $dwCaptionSize & "]")
	DllStructSetData($tCaption, 1, $sCaption)
	WriteProcessMemory($hProcess, $pCaption, DllStructGetPtr($tCaption, 1), $dwCaptionSize)


	Local $pMessageBoxA = GetProcAddress(GetModuleHandle("user32.dll"), "MessageBoxA")
	Local $pVirtualFree = GetProcAddress(GetModuleHandle("kernel32.dll"), "VirtualFree")


	Local $sOpcode = "0x"


	$sOpcode &= "68" & SwapEndian($uType) ;push uType
	$sOpcode &= "68" & SwapEndian($pCaption) ;push sCaption
	$sOpcode &= "68" & SwapEndian($pText) ;push sText
	$sOpcode &= "68" & SwapEndian($hWnd) ;push hWnd
	$sOpcode &= "B8" & SwapEndian($pMessageBoxA) ;mov eax, MessageBoxA
	$sOpcode &= "FFD0" ;call eax


	$sOpcode &= "68" & SwapEndian(0x8000) ;push MEM_RELEASE (dwFreeType)
	$sOpcode &= "68" & SwapEndian(0) ;push dwSize
	$sOpcode &= "68" & SwapEndian($pAddress) ;push pAddress
	$sOpcode &= "B8" & SwapEndian($pVirtualFree) ;mov eax, VirtualFree
	$sOpcode &= "FFD0" ;call eax


	$sOpcode &= "C3" ;ret


	Local $tOpcode = DllStructCreate("BYTE[50]", $pAddress)
	DllStructSetData($tOpcode, 1, $sOpcode)
	WriteProcessMemory($hProcess, $pAddress, DllStructGetPtr($tOpcode, 1), $dwOpcodeSize)


	Local $hThread = CreateThread(0, 0, $pAddress, 0, 0)
	CloseHandle($hThread)
EndFunc   ;==>MessageBox


Func VirtualAlloc($pAddress, $dwSize, $flAllocationType, $flProtect)
	Return DllCall("kernel32.dll", "ptr", "VirtualAlloc", _
			"ptr", $pAddress, _
			"DWORD", $dwSize, _
			"DWORD", $flAllocationType, _
			"DWORD", $flProtect)[0]
EndFunc   ;==>VirtualAlloc


Func CreateThread($pThreadAttributes, $dwStackSize, $pStartAddress, $pParameter, $dwCreationFlags)
	Return DllCall("kernel32.dll", "HANDLE", "CreateThread", _
			"ptr", $pThreadAttributes, _
			"DWORD", $dwStackSize, _
			"ptr", $pStartAddress, _
			"ptr", $pParameter, _
			"DWORD", $dwCreationFlags, _
			"ptr", 0)[0]
EndFunc   ;==>CreateThread


Func CloseHandle($hObject)
	Return DllCall("kernel32.dll", "BOOL", "CloseHandle", _
			"HANDLE", $hObject)[0]
EndFunc   ;==>CloseHandle


Func GetProcAddress($hModule, $sProcName)
	Return DllCall("kernel32.dll", "ptr", "GetProcAddress", _
			"HANDLE", $hModule, _
			"str", $sProcName)[0]
EndFunc   ;==>GetProcAddress


Func GetModuleHandle($sModuleName)
	Return DllCall("kernel32.dll", "HANDLE", "GetModuleHandle", _
			"str", $sModuleName)[0]
EndFunc   ;==>GetModuleHandle


Func WriteProcessMemory($hProcess, $lpAddress, $lpBuffer, $nSize)
	Return DllCall("kernel32.dll", "BOOL", "WriteProcessMemory", _
			"HANDLE", $hProcess, _
			"ptr", $lpAddress, _
			"ptr", $lpBuffer, _
			"DWORD", $nSize, _
			"ptr", 0)[0]
EndFunc   ;==>WriteProcessMemory


Func SwapEndian($dwValue)
	Return Hex(Binary($dwValue))
EndFunc   ;==>SwapEndian


Func GetCurrentProcess()
	Return DllCall("kernel32.dll", "HANDLE", "GetCurrentProcess")[0]
EndFunc   ;==>GetCurrentProcess

Alles anzeigen

Ich habe es nicht getestet!

**autoiter**

..oder einfach ein SplashTextOn

Yaerox

Zitat von DasIch

Hey alpines und lieben Dank für deinen Vorschlag.

Den Gedanken hatte ich auch schon, allerdings werden in dem Skript mehrere Systeme überwacht und deshalb wäre es einfacher pro Ausfall ein eigenes Popup zu haben, statt einem GUI, das für jeden Ausfall überschrieben werden müsste.

Du kannst auch für jeden Ausfall eine neue GUI erstellen. Das ist dir ja freigestellt. Ob das sinn ergibt, steht auf einem anderen Blatt geschrieben. Alternativ (meist meine Vorzugsweise) eine GUI strukturiert aufbauen, dass alle Informationen in einer GUI dargestellt werden können, und alles auf einem blick ist, ohne x-Popups durchklicken zu müssen, um zu wissen was Sache ist...

DasIch

Du meinst also, eine GUI zu verwenden, die sagen wir eine listview drin hat und in dieser listview dynamisch die Systeme einträgt, wann sie ausgefallen sind und wie sie heißen? und sobald sie wieder laufen, die logfile schreiben und aus der übersicht verschwinden? auch eine durchaus interessante idee. darauf bin ich noch nicht gekommen

Yaerox

Zitat von DasIch

Du meinst also, eine GUI zu verwenden, die sagen wir eine listview drin hat und in dieser listview dynamisch die Systeme einträgt, wann sie ausgefallen sind und wie sie heißen? und sobald sie wieder laufen, die logfile schreiben und aus der übersicht verschwinden? auch eine durchaus interessante idee. darauf bin ich noch nicht gekommen

Das ist ja immer die Frage des Anwendungsfalles ... ich habe eine Prozessüberwachung bei der ich eine GUI dauerhaft offen habe, dort dann einfach sinngemäß 2 vertikale Trennlinien gezogen habe und alles was so anfällt in ein Input (Multiline)-Control schreibe. Weil an dieser Stelle kommt massiv viel Text, den ich aber brauche und kopieren muss.

DasIch

Habe es jetzt so gelöst:

AutoIt

#include <FF.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>


$MainWindow = GUICreate("Kontakt Online!", 200, 40, -1, -1)
$lblMain = GUICtrlCreateLabel("", 8, 14, 180, 25, $SS_CENTER)


Global $online = 0
Global $name = _FFXPath("/html/body/div/div[3]/div[3]/header/div[2]/div[1]/h2/span", "textContent", 9)


While 1
	Sleep(700)
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			GUISetState(@SW_HIDE, $MainWindow)


	EndSwitch


	$status = _FFXPath("/html/body/div/div[3]/div[3]/header/div[2]/div[2]/div/span", "textcontent", 9)
	If $status Then
		If $online = 0 Then
			$start = @HOUR & ":" & @MIN & ":" & @SEC
			$monat = @MDAY & "." & @MON & "." & @YEAR
			GUICtrlSetData($lblMain, "System " & $name & " ist seit " & $start & " offline.")
			GUISetState(@SW_SHOW, $MainWindow)
			$online = 1
		EndIf
	Else
		If $online = 1 Then
			$ende = @HOUR & ":" & @MIN & ":" & @SEC
			GUISetState(@SW_HIDE, $MainWindow)
			$online = 0
			FileWriteLine(@ScriptDir & "\online.txt", $name & @TAB & $monat  & @TAB & $start & " Bis " & $ende) ;Hier wird die Ausfallzeit zusätzlich in eine Datei geschrieben.
		EndIf
	EndIf


WEnd


_FFDisConnect()

Alles anzeigen

Allerdings reagiert er nicht auf den "Schließen" Button im Fenster. Any Guesses, warum?

LG

autobert2

Zitat von alpines

Alternativ tut es auch eine kleine GUI die per OnEventMode läuft.

Der OnEnventMode verhält sich während der MessageBox-Anzeige genauso wie der GuiGetMsg-Mode.

Man könnte aber eine externe Exe mit Run starten, welche die Fehlermeldung ausgibt.

DasIch

Die .exe war eine super Idee! Danke dafür!

Das hier ist das Hauptprogramm:

Spoiler anzeigen

AutoIt: Main

#include <FF.au3>


_FFConnect()


Global $online = 0
Global $name = _FFXPath("/html/body/div/div[3]/div[3]/header/div[2]/div[1]/h2/span", "textContent", 9)


While 1
	Sleep(700)
	$status = _FFXPath("/html/body/div/div[3]/div[3]/header/div[2]/div[2]/div/span", "textcontent", 9)
	If $status Then
		If $online = 0 Then
			$start = @HOUR & ":" & @MIN & ":" & @SEC
			$monat = @MDAY & "." & @MON & "." & @YEAR
			Run(@ScriptDir & "\Msg.exe -Name:" & $name & " -Monat:" & $monat & " -Start:" & $start)
			$online = 1
		EndIf
	Else
		If $online = 1 Then
			$ende = @HOUR & ":" & @MIN & ":" & @SEC
			WinClose("System Offline!")
			$online = 0
			FileWriteLine(@ScriptDir & "\online.txt", $name & @TAB & $monat  & @TAB & $start & " Bis " & $ende) ;Hier wird die Ausfallzeit zusätzlich in eine Datei geschrieben.
		EndIf
	EndIf


WEnd


_FFDisConnect()

Alles anzeigen

und die Msg.exe wird dann entsprechend ausgeführt:

Spoiler anzeigen

AutoIt: Msg.exe

If $cmdline[0] > 0 Then
	For $i = 0 To $cmdline[0]
		;" -Name
		If StringRegExp($cmdline[$i], "(?i)^\-Name\:.*?$") Then $Name = StringRegExp($cmdline[$i], "(?i)^\-Name\:(.*?)$", 1)[0]
		;" -Monat
		If StringRegExp($cmdline[$i], "(?i)^\-Monat\:.*?$") Then $Monat = StringRegExp($cmdline[$i], "(?i)^\-Monat\:(.*?)$", 1)[0]
		;" -Start
		If StringRegExp($cmdline[$i], "(?i)^\-Start\:.*?$") Then $Start = StringRegExp($cmdline[$i], "(?i)^\-Start\:(.*?)$", 1)[0]
	Next
EndIf


MsgBox(0, "System Offline!", $name & " ist seit " & $start & " Offline.")

Alles anzeigen

So funktioniert es genau so wie ich es wollte Danke euch allen vielmals!

**alpines**

Zitat von autobert2

Der OnEnventMode verhält sich während der MessageBox-Anzeige genauso wie der GuiGetMsg-Mode.
Man könnte aber eine externe Exe mit Run starten, welche die Fehlermeldung ausgibt.

Ich hab nicht davon gesprochen die HauptGUI im OnEventMode zu betreiben sondern eine kleine MsgBoxGUI zu erstellen die im OnEventMode läuft.

BinDannMalWeg

Sehr viel einfacher geht das so:

AutoIt

ExecuteSeperated("MsgBox(0, 'Test', 'yolo', 5)")


Func ExecuteSeperated($sCodeLine)
        #pragma compile(AutoItExecuteAllowed, True)
	Return Run(@AutoItExe & ' /AutoIt3ExecuteLine "' & $sCodeLine & '"')
EndFunc   ;==>ExecuteSeperated

autobert2

Zitat von alpines

Ich hab nicht davon gesprochen die HauptGUI im OnEventMode zu betreiben sondern eine kleine MsgBoxGUI zu erstellen die im OnEventMode läuft.

Dies würde ich gerne sehen wie beide GUI's auf Eingaben reagieren ohne sich gegenseitig zu blockieren.

BinDannMalWeg

Zitat von autobert2

Dies würde ich gerne sehen wie beide GUI's auf Eingaben reagieren ohne sich gegenseitig zu blockieren.

Hier ein Beispiel:

Spoiler anzeigen

AutoIt

Opt("GuiOnEventMode", 1)


For $x = 0 To 2
	For $y = 0 To 2
		createGUI("0", $x * 200, $y * 200, 150, 150, "callback")
	Next
Next


While True
	Sleep(500)
WEnd




Func createGUI($sTitle, $iX, $iY, $iWidth, $iHeight, $sCallback)
	$hGUI = GUICreate($sTitle, $iWidth, $iHeight, $iX, $iY)
	GUISetOnEvent(-3, "close", $hGUI)
	GUICtrlCreateButton("Klick mich!", 0, 0, $iWidth, $iHeight)
	GUICtrlSetOnEvent(-1, $sCallback)
	GUISetState(@SW_SHOW, $hGUI)
EndFunc   ;==>createGUI


Func callback()
	WinSetTitle(@GUI_WinHandle, "", WinGetTitle(@GUI_WinHandle) + 1)
	GUICtrlSetBkColor(@GUI_CtrlId, Random(0x000000, 0xFFFFFF, 1))
EndFunc   ;==>callback


Func close()
	GUIDelete(@GUI_WinHandle)
EndFunc   ;==>close

Alles anzeigen

**chip**

Schau dir mal SplashTextOn an.