Zitat von autoBertja jetzt muß nur noch einer per Hand nach rechnen, nicht das Raupi Recht hat. Ich dachte, als das Thema eröffnet wurde, es sei ein 2. Account von Raupi (er hat mal in der SB eine Andeutung in diese Richtung Rift gemacht) und er ist nur zu faul.
Wat? Was für eine Andeutung?
Mein 2. Account ist der einzigste im Forum der von Anfang an genehmigt war. RaupiClient.
Das mit den Leerzeichen hab ich von Anfang an rausgefunden, deshalb habe ich ja StringStripWS benutz um die Leerzeichen zu killen.
Die Leerzeichen entstehen wenn in einer Zeile kein x zum splitten enthalten ist.
Habe gerade gesehen, dass autoBerts Lösung durch den Regex ca. 10x schneller ist als meine Lösung...
Also habe ich mal nachgerüstet 
(Sollte jetzt ca. 2x schneller sein als autoBerts Lösung)
#include <Array.au3>
Local $sRead = FileRead('log.txt')
Local $aLog = LogToArray($sRead)
_ArrayDisplay($aLog)
Func LogToArray($sLog)
Local $aSplit = StringRegExp(StringReplace(StringReplace($sLog, '[', '', 0, 1), ']', '', 0, 1), 'Ihr erhaltet: (.*)', 3), $iUbound = UBound($aSplit), $aRet[$iUbound][2], $aTmp, $iUboundCnt = $iUbound
For $i = 0 To $iUbound - 1 Step 1 ; Aufräumen und Zahlen finden
$aTmp = StringSplit($aSplit[$i], ' ')
$aRet[$i][1] = StringInStr($aSplit[$i], ' x ', 0, 1) ? $aTmp[$aTmp[0]] : 1
$aRet[$i][0] = StringStripWS($aRet[$i][1] > 1 ? StringLeft($aSplit[$i], StringInStr($aSplit[$i], ' x ', 0, 1)) : $aSplit[$i], 3)
Next
For $i = $iUbound - 1 To 0 Step -1 ; Zusammenfassen
For $ii = $i - 1 To 0 Step -1
If $aRet[$i][0] = $aRet[$ii][0] Then ; Doppelter Eintrag gefunden
$aRet[$ii][1] += $aRet[$i][1] ; Anzahl addieren
For $u = $i To $iUboundCnt - 2 Step 1 ; Quasi wie ArrayDelete für ein 2D Array mit [n][2]
$aRet[$u][0] = $aRet[$u + 1][0] ; Allerdings wird das Array nicht verkleinert, sodass
$aRet[$u][1] = $aRet[$u + 1][1] ; kein ReDim aufgerufen wird -> ReDim ist (relativ) langsam.
Next
$iUboundCnt -= 1 ; Der hier zeigt an wie groß das Array eigentlich sein sollte.
ExitLoop
EndIf
Next
Next
ReDim $aRet[$iUboundCnt][2] ; Nur 1x Redim
Return _ArraySort($aRet, 1, 0, 0, 1) ? $aRet : 0 ;Sortieren
EndFunclg
M
Stimmt der 2. Parameter ist ein Element des Arrays. $z wurde am Anfang der Func deklariert hat also beim 1. Duchlauf den Wert 0. da $z nach abarbeiten der Suche, evtl. aufaddieren und löschen um 1 erhöht wird jedesmal ein anderes Element abgearbeitet.
Hier einmal das Teilkonstrukt:
Do ;bedingte äußere Schleife
$aFound=_ArrayFindAll($aResult_u,$aResult_u[$z][0]);,0,0,0,2) ;ist Element $aResult_u[$z][0] noch öfters vorhanden?
ConsoleWrite($z & '. durchlauf: ' & $aResult_u&@TAB&$aResult_u[$z][0]&@CRLF) ;zu Verständniszwecken
_ArrayDisplay($aFound) ;zu Verständniszwecken
For $f=UBound($aFound)-1 to 1 Step -1 ;alle anderen Funde durchgegeh
$aResult_u[$z][1] += $aResult_u[$aFound[$f]][1] ;und dazuaddieren
_ArrayDelete($aResult_u,$aFound[$f]) ;danach doppelten Eintrag Löschen
Next
$z+=1 ;Zähler $z um 1 erhöhen
Until $z = UBound($aResult_u) ;solange bis alle 1. Vorkommen eines Elements abgearbeitet wurdenda $z nach abarbeiten der Suche, evtl. aufaddieren und löschen um 1 erhöht wird jedesmal ein anderes Element abgearbeitet.
Habe gerade gesehen, dass autoBerts Lösung durch den Regex ca. 10x schneller ist als meine Lösung...
Also habe ich mal nachgerüstetlg
M
Mit den gegbenen Daten bist du ca. 8 mal schneller. Ich bin aber der Meinung, daß mit zunehmender Datenmenge mein Skript aufholt und irgendwann überholt. Bin aber zu faul ein Testskript zu schreiben.
Ich bin ein bisschen erstaunt, erst wollte keiner helfen und nun gibt es ein Combat wer die beste Lösung hat. 
Wat? Was für eine Andeutung?
sorry hab mich wohl getäuscht (oder den Baum im Wald falsch zugeordnet 
)
Ich bin ein bisschen erstaunt, erst wollte keiner helfen und nun gibt es ein Combat wer die beste Lösung hat.
Wenn @BugFix mitmacht und das Dictionary-Object auspackt gehts mit Sicherheit noch schneller.
Wenn du die mal die Beispiele zu den beiden Funktionen anschaust, dann beantwortest du dir die Frage selbst 
Hab das Skript jetzt mal mit einer Log mit 20.000 Zeilen laufen lassen. 5760 Ergebnisse mit "Ihr erhaltet:". Dauer vom 3. Schritt, wo er das Array zusammen addiert ~100 Sek.
Problem war das _Arraydelete
Hab mich jetzt mal hingesetzt und mit Bekanntem was gebastelt - ohne ArrayDelete. Außerdem wird jetzt die Anzahl an Materialien zuerst ausgegeben
Func f1()
Local $a_split, $z
Local $aResult_u = StringRegExp($file_r, 'Ihr erhaltet: (.*)', 3)
If Not @error Then
_ArrayDisplay($aResult_u, "RegExp Ergebnis")
_ArrayColInsert($aResult_u,1)
For $h = 0 To UBound($aResult_u) - 1
$a_split = StringSplit($aResult_u[$h][0], "x")
$aResult_u[$h][1] = StringStripWS($a_split[1], 7)
If $a_split[0]>1 Then
$aResult_u[$h][0] = Int($a_split[2])
Else
$aResult_u[$h][0] = 1
EndIf
Next
_ArraySort($aResult_u, 1, 0 ,0 ,1)
_ArrayDisplay($aResult_u, '2D')
Dim $aResult_sum [UBound($aResult_u,$UBOUND_ROWS)][2]
$i=0
$zaehler=0
$item=$aResult_u[0][1]
For $j = 0 To UBound($aResult_u)-1
If $aResult_u[$j][1] == $item Then
$zaehler += $aResult_u[$j][0]
Else
$aResult_sum[$i][0]=$zaehler
$aResult_sum[$i][1]=$item
$zaehler=$aResult_u[$j][0]
$item=$aResult_u[$j][1]
$i+=1
EndIf
Next
$aResult_sum[$i][0]=$zaehler
$aResult_sum[$i][1]=$item
ReDim $aResult_sum[$i+1][2]
_ArraySort($aResult_sum, 1, 0 ,0 ,0)
_FileWriteFromArray($plog, $aResult_sum, Default, Default, " x ")
_ArrayDisplay($aResult_sum, "2D Array mit Summen")
EndFunc ;==>f1Nu braucht er zum Sortieren und Addieren nur noch 2 Sek für die über 5000 Zeilen
Problem war das _Arraydelete
Das ist die Problematik der UDF. Die Funktionen sind für einen einzelnen Vorgang konzipiert. Bei mehrfachem Aufruf werden dann unnützerweise immer wieder dieselben (zeitintensiven) Vorgänge gestartet. ReDim als native Funktion ist ebenfalls eine dieser Spaßbremsen. Oft ist es besser auf die UDF zu verzichten, bzw. zeitintensive Funktionen nur ganz gezielt einzusetzen.
2 Sekunden ? Da kann man noch was rausholen 
z.B. via Assoziativem Array incl Hashtable, wo die Labels den Items, und der Wert der Anzahl entspricht. Das müsste dann lineare Laufzeit beim Zusammenfassen ergeben. Aber 2 Sek ist schon passabel, daher werde ich hier nicht weiterbasteln
lg
M
Hab noch ein kleines Problem, hab mir überlegt, daß ich mir eine GUI bastel, in welcher die gesammelten Items immer "live" aktuallisiert werden. Sonst muß ich ständig die .txt öffnen, schließen...
Dachte, das ist so zu machen, klappt aber nicht... 
$Form1_1 = GUICreate($rndname, 345, 700, 306, 198)
$Group1 = GUICtrlCreateGroup($txtg1, 8, 15, 329, 685)
$Result_List = GUICtrlCreateListView("", 15, 28, 315, 670, BitOR($GUI_SS_DEFAULT_LIST,$LBS_DISABLENOSCROLL), $WS_EX_STATICEDGE)
_GUICtrlListView_AddArray($Result_List, $aResult_sum)
GUISetState(@SW_SHOW)
_auswertung()
func _auswertung
$log = @MyDocumentsDir & '\RIFT\log.txt'
$file_r = FileRead($log)
$file_r = StringReplace(StringReplace($file_r,'[',''),']','') ; [ ] entfernen
Local $a_split, $z
Local $aResult_u = StringRegExp($file_r, 'Ihr erhaltet: (.*)', 3)
If Not @error Then
;~ _ArrayDisplay($aResult_u, "RegExp Ergebnis")
_ArrayColInsert($aResult_u,1)
For $h = 0 To UBound($aResult_u) - 1
$a_split = StringSplit($aResult_u[$h][0], "x")
$aResult_u[$h][1] = StringStripWS($a_split[1], 7)
If $a_split[0]>1 Then
$aResult_u[$h][0] = Int($a_split[2])
Else
$aResult_u[$h][0] = 1
EndIf
Next
_ArraySort($aResult_u, 1, 0 ,0 ,1)
;~ _ArrayDisplay($aResult_u, '2D')
Dim $aResult_sum [UBound($aResult_u,$UBOUND_ROWS)][2]
$i=0
$zaehler=0
$item=$aResult_u[0][1]
For $j = 0 To UBound($aResult_u)-1
If $aResult_u[$j][1] == $item Then
$zaehler += $aResult_u[$j][0]
Else
$aResult_sum[$i][0]=$zaehler
$aResult_sum[$i][1]=$item
$zaehler=$aResult_u[$j][0]
$item=$aResult_u[$j][1]
$i+=1
EndIf
Next
$aResult_sum[$i][0]=$zaehler
$aResult_sum[$i][1]=$item
ReDim $aResult_sum[$i+1][2]
_ArraySort($aResult_sum, 1, 0 ,0 ,0)
for $k = 1 to ubound($aResult_sum) - 1
guictrlsetdata($Result_List,$aResult_sum[$k])
next
_FileWriteFromArray($plog, $aResult_sum, Default, Default, " x ")
;~ _ArrayDisplay($aResult_sum, "2D Array mit Summen")
EndIf
EndFuncZeile 3,4 & 48-50
Ist dafür Listview überhaupt der richtige Ansatz?
Ja. Allerdings werden bei Listviews, TreeViews,... Items hinzugefügt.
(s. Hilfe: GuiCtrlCreateListViewItem). Guck dir einfach unter GuiCtrlCreateListview die Beispiele in der Hilfe an.
_GuiCtrlListView_DeleteAllItems löscht alle Items, ansonsten Array durchgehen und _GuiCtrlListView_SetItem... ansehen.
Generell einfach in der Hilfe unter "User Defined Functions->Gui Reference->GuiListView management" mal Blättern. Die Listview hat nen haufen Befehle.
_GUICtrlListView_AddArray dürfte die effektivste Methode sein.
Damit bastel ich schon grade rum, hab folgendes in mein Skript eingefügt:
_GUICtrlListView_AddColumn($Result_List, "", 310)
_GUICtrlListView_AddArray($Result_List, $aResult_sum)
aber da gibt er mir nur die Linke Spalte im Fenster aus.
Mit:
_GUICtrlListView_AddColumn($Result_List, "", 310)
_GUICtrlListView_AddArray($Result_List, $aResult_sum[0] & $aResult_sum[1])
bekomm ich nen Error.
Such grade mal bei Dr. Google
Die Implementation deiner Auswertung in das Beispiel zu _GUICtrlListView_AddArray ist doch ganz einfach:
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
Global $log = 'log.txt'
Global $plog = @ScriptDir & "\pickup.txt"
Global $file = FileRead($log)
Global $idListview, $idRefresh, $iMsg
; Create GUI
GUICreate("ListView Add Array", 400, 310)
$idListview = GUICtrlCreateListView("Anzahl|Item", 2, 2, 394, 268)
$idRefresh = GUICtrlCreateButton('&Refresh', 2, 275, 394, 25)
GUISetState(@SW_SHOW)
Global $aItems = _GetStat($file)
_GUICtrlListView_AddArray($idListview, $aItems)
While 1
$iMsg = GUIGetMsg()
Switch $iMsg
Case $GUI_EVENT_CLOSE
ExitLoop
Case $idRefresh
_GUICtrlListView_DeleteAllItems($idListview)
$aItems = _GetStat($file)
_GUICtrlListView_AddArray($idListview, $aItems)
EndSwitch
WEnd
GUIDelete()
Func _GetStat($file_r)
$file_r = StringReplace(StringReplace($file, '[', ''), ']', '')
Local $a_split, $z
Local $aResult_u = StringRegExp($file_r, 'Ihr erhaltet: (.*)', 3)
If Not @error Then
;_ArrayDisplay($aResult_u, "RegExp Ergebnis")
_ArrayColInsert($aResult_u, 1)
For $h = 0 To UBound($aResult_u) - 1
$a_split = StringSplit($aResult_u[$h][0], "x")
$aResult_u[$h][1] = StringStripWS($a_split[1], 7)
If $a_split[0] > 1 Then
$aResult_u[$h][0] = Int($a_split[2])
Else
$aResult_u[$h][0] = 1
EndIf
Next
_ArraySort($aResult_u, 1, 0, 0, 1)
;_ArrayDisplay($aResult_u, '2D Array ohne Summen')
Dim $aResult_sum[UBound($aResult_u, $UBOUND_ROWS)][2]
$i = 0
$zaeler = 0
$item = $aResult_u[0][1]
For $j = 0 To UBound($aResult_u) - 1
If $aResult_u[$j][1] == $item Then
$zaeler += $aResult_u[$j][0]
Else
$aResult_sum[$i][0] = $zaeler
$aResult_sum[$i][1] = $item
$zaeler = $aResult_u[$j][0]
$item = $aResult_u[$j][1]
$i += 1
EndIf
Next
$aResult_sum[$i][0] = $zaeler
$aResult_sum[$i][1] = $item
_ArraySort($aResult_sum, 1, 0, 0, 0)
;_FileWriteFromArray($plog, $aResult_sum, Default, Default, " x ")
;_ArrayDisplay($aResult_sum, "2D Array mit Summen")
Return $aResult_sum
EndIf
EndFunc ;==>_GetStatZeilenfehler in Zeile 35 ???
$file_r = StringReplace(StringReplace($file, '[', ''), ']', '')
; wäre nicht folgendes richtig:
$file_r = StringReplace(StringReplace($file, '[', ')', ']', '')Zeilenfehler in Zeile 35 ???
AutoIt$file_r = StringReplace(StringReplace($file, '[', ''), ']', '') ; wäre nicht folgendes richtig: $file_r = StringReplace(StringReplace($file, '[', ')', ']', '')
Da ist kein Fehler drin.
Alina, das ist nur eine Kombination und sieht einzeln dann so aus:
$file_r = StringReplace($file, '[', '')
$file_r = StringReplace($file_r, ']', '')Das soll einfach [ und ] mit nichts ersetzen, sprich löschen.
Die Klammer ( ist nicht das Ersatzzeichen, sondern schließt den 2. Aufruf von StringReplace ab