Dienst - Suche - Programm, Verbesserungsvorschläge.

Stoani

Hallo ihr da draußen,

Zurzeit arbeite ich aus Laune und weil ich die Zeit gerade übrig hab an einem Programm, welches die Besetzung des Dienstplanes und die damit verbunden Suche nach Mitarbeitern erleichtern soll. Bisher war ein Zettel mit Telefonnummern dafür ausreichend, führt aber ab und zu zum Verlust der Übersicht und es entstehen Missverständnisse.

Vorweg möchte ich nochmal erwähnen, dass ich nie irgendetwas in die Richtung Computer, IT oder Software - Engineering professionell gelehrt bekommen habe, ich bitte daher um ein bisschen Verständnis für den Zustand meines Source-Codes

Dieser Thread soll mir wenn möglich dabei Helfen, die Abläufe zu optimieren, neue Ideen und Wege kennen zu lernen und Fehler im Code zu enttarnen.
Ich werde den Code updaten, wenn sich grundlegende Dinge verändert haben oder neue Funktionen entstanden sind.

Viel Spaß beim ausprobieren und danke für jede Sekunde die Ihr euch damit auseinandersetzt
Ps.: Es wurden keine externen #Includes eingebaut, sollte daher bei jedem mit Copy/Paste laufen.

Lg Stoani

;Edit1(ToDo Liste eingefügt):

- EInträge bearbeiten
- Anruf-Protokoll
- Suche SMS generate
- Nummern-Liste
-Suche erstellen

;Edit2(Schriftart):
Falls jemand das Original mit Dunant Schriftart ausprobieren möchte, Hier* ist ein Link zur Downloadseite. *(Link verweist auf: http://design.roteskreuz.at/vorlagen/vorla…emente/schrift/)

AutoIt: Dienstsuche_Programm

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiImageList.au3>
#include <Date.au3>
#include <GuiListView.au3>
#include <StructureConstants.au3>
#include <Array.au3>
#include <StaticConstants.au3>




#Region ### GRAPHICAL USER INTERFACE (PARENT) ###
$GUI = GUICreate("Dienstsuche OST - GMUNDEN", 1600, 900, -1, -1, BitOR($WS_MAXIMIZEBOX, $WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU))
$MenuItem1 = GUICtrlCreateMenu("Aktion")
$SubItem1_1 = GUICtrlCreateMenuItem("Dienstsuche starten", $MenuItem1)
$SubItem1_2 = GUICtrlCreateMenuItem("Sperren", $MenuItem1)
$SubItem1_3 = GUICtrlCreateMenuItem("Beenden", $MenuItem1)
$MenuItem2 = GUICtrlCreateMenu("Liste")
$SubItem2_1 = GUICtrlCreateMenuItem("Anzeigen", $MenuItem2)
$SubItem2_2 = GUICtrlCreateMenuItem("Bearbeiten", $MenuItem2)
$SubItem2_3 = GUICtrlCreateMenuItem("Exportieren", $MenuItem2)


$List1 = GUICtrlCreateListView("", 0, 0, 1600, 880, $LVS_SINGLESEL)
GUICtrlSetBkColor($List1, 0X292929)
GUICtrlSetFont($List1, 12, 300, -1, "Dunant Light", 5)
GUICtrlSetColor($List1, 0XFFFFFF)


$contextmenu = GUICtrlCreateContextMenu($List1)
$sofort = GUICtrlCreateMenuItem("Sofort", $contextmenu)
$dringend = GUICtrlCreateMenuItem("Dringend", $contextmenu)
$normal = GUICtrlCreateMenuItem("Normal", $contextmenu)
$erledigt = GUICtrlCreateMenuItem("Erledigt", $contextmenu)
GUICtrlCreateMenuItem("", $contextmenu)
$erstellen = GUICtrlCreateMenuItem("Eintrag erstellen", $contextmenu)
GUISetState(@SW_SHOWMAXIMIZED)
GUISetState(@SW_SHOW)
#EndRegion ### GRAPHICAL USER INTERFACE ###


_Setup_Scene()


While 1




	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $SubItem1_1 ;Dienstsuche starten




		Case $SubItem1_2 ;Sperren




		Case $SubItem1_3 ;Beenden
			Exit


		Case $SubItem2_1 ;Anzeigen




		Case $SubItem2_2 ;Bearbeiten




		Case $SubItem2_3 ;Exportieren




		Case $sofort ; PRIORITÄTEN werden definiert und eingetragen.
			$LastSelection = _GUICtrlListView_GetSelectionMark($List1)
			_GUICtrlListView_AddSubItem($List1, $LastSelection, "█ SOFORT █", 2)
			_GUICtrlListView_SetItemImage($List1, $LastSelection, 1)


		Case $dringend
			$LastSelection = _GUICtrlListView_GetSelectionMark($List1)
			_GUICtrlListView_AddSubItem($List1, $LastSelection, "DRINGEND", 2)
			_GUICtrlListView_SetItemImage($List1, $LastSelection, 2)


		Case $normal
			$LastSelection = _GUICtrlListView_GetSelectionMark($List1)
			_GUICtrlListView_AddSubItem($List1, $LastSelection, "Normal", 2)
			_GUICtrlListView_SetItemImage($List1, $LastSelection, 3)


		Case $erledigt
			$LastSelection = _GUICtrlListView_GetSelectionMark($List1)
			_GUICtrlListView_AddSubItem($List1, $LastSelection, "✔", 2)
			_GUICtrlListView_SetItemImage($List1, $LastSelection, 4)


		Case $erstellen


			GUISetState(@SW_DISABLE, $GUI) ; Parent-GUI wird disabled.




			#Region ### Setup Child GUI ###
			$cGUI = GUICreate("Eintrag erstellen", 400, 300, -1, -1, -1, $WS_EX_TOOLWINDOW, $GUI)
			$cBtn = GUICtrlCreateButton("Erstellen", 10, 270, 380, 30)
			GUICtrlSetFont($cBtn, 14, 300, -1, "Dunant Medium")


			GUICtrlCreateGraphic(200, 0, 1, 230, $SS_SUNKEN) ; Trennlinie




			;--------- TAGDIENST -------
			$cLable_TD = GUICtrlCreateLabel("Tagdienst ( 7 - 19 Uhr )", 10, 20, 180, 30, $SS_Center)
			GUICtrlSetFont($cLable_TD, 14, 300, -1, "Dunant Light")


			$cCheckBox_EL_TD = GUICtrlCreateCheckbox("Einsatzlenker", 10, 70, 130)
			$cCheckBox_TF_TD = GUICtrlCreateCheckbox("Transportführer", 10, 100, 130)
			$cCheckBox_AMD_TD = GUICtrlCreateCheckbox("Ambulanzdienst", 10, 130, 130)
			$cCheckBox_HEL_TD = GUICtrlCreateCheckbox("HÄND Lenker", 10, 160, 130)


			$cCombo_EL_TD = GUICtrlCreateCombo("", 140, 70, 50, 30)
			GUICtrlSetData($cCombo_EL_TD, "1|2|3|4|5|6|7|8|9|10")


			$cCombo_TF_TD = GUICtrlCreateCombo("", 140, 100, 50, 30)
			GUICtrlSetData($cCombo_TF_TD, "1|2|3|4|5|6|7|8|9|10")


			$cCombo_AMD_TD = GUICtrlCreateCombo("", 140, 130, 50, 30)
			GUICtrlSetData($cCombo_AMD_TD, "1|2|3|4|5|6|7|8|9|10")


			$cCombo_HEL_TD = GUICtrlCreateCombo("", 140, 160, 50, 30)
			GUICtrlSetData($cCombo_HEL_TD, "1|2|3|4|5|6|7|8|9|10")






			GUICtrlSetState($cCombo_EL_TD, 128)
			GUICtrlSetState($cCombo_TF_TD, 128)
			GUICtrlSetState($cCombo_AMD_TD, 128)
			GUICtrlSetState($cCombo_HEL_TD, 128)


			GUICtrlSetFont($cCheckBox_EL_TD, 12, 300, -1, "Dunant Light")
			GUICtrlSetFont($cCheckBox_TF_TD, 12, 300, -1, "Dunant Light")
			GUICtrlSetFont($cCheckBox_AMD_TD, 12, 300, -1, "Dunant Light")
			GUICtrlSetFont($cCheckBox_HEL_TD, 12, 300, -1, "Dunant Light")




			;--------- NACHTDIENST -------
			$cLable_ND = GUICtrlCreateLabel("Nachtdienst ( 19 - 7 Uhr )", 210, 20, 180, 30, $SS_Center)
			GUICtrlSetFont($cLable_ND, 14, 300, -1, "Dunant Light")


			$cCheckBox_EL_ND = GUICtrlCreateCheckbox("Einsatzlenker", 210, 70, 130)
			$cCheckBox_TF_ND = GUICtrlCreateCheckbox("Transportführer", 210, 100, 130)
			$cCheckBox_AMD_ND = GUICtrlCreateCheckbox("Ambulanzdienst", 210, 130, 130)
			$cCheckBox_HEL_ND = GUICtrlCreateCheckbox("HÄND Lenker", 210, 160, 130)


			$cCombo_EL_ND = GUICtrlCreateCombo("", 340, 70, 50, 30)
			GUICtrlSetData($cCombo_EL_ND, "1|2|3|4|5|6|7|8|9|10")


			$cCombo_TF_ND = GUICtrlCreateCombo("", 340, 100, 50, 30)
			GUICtrlSetData($cCombo_TF_ND, "1|2|3|4|5|6|7|8|9|10")


			$cCombo_AMD_ND = GUICtrlCreateCombo("", 340, 130, 50, 30)
			GUICtrlSetData($cCombo_AMD_ND, "1|2|3|4|5|6|7|8|9|10")


			$cCombo_HEL_ND = GUICtrlCreateCombo("", 340, 160, 50, 30)
			GUICtrlSetData($cCombo_HEL_ND, "1|2|3|4|5|6|7|8|9|10")






			$cLable_Bemerkung = GUICtrlCreateLabel("Bemerkung:", 10, 210, 180, 30, $SS_LEFT)
			GUICtrlSetFont($cLable_Bemerkung, 14, 300, -1, "Dunant Light")
			$cInput = GUICtrlCreateInput("", 10, 235, 380, 25)
			GUICtrlSetFont($cInput, 12, 300, -1, "Dunant Light")






			GUICtrlSetState($cCombo_EL_ND, 128)
			GUICtrlSetState($cCombo_TF_ND, 128)
			GUICtrlSetState($cCombo_AMD_ND, 128)
			GUICtrlSetState($cCombo_HEL_ND, 128)


			GUICtrlSetFont($cCheckBox_EL_ND, 12, 300, -1, "Dunant Light")
			GUICtrlSetFont($cCheckBox_TF_ND, 12, 300, -1, "Dunant Light")
			GUICtrlSetFont($cCheckBox_AMD_ND, 12, 300, -1, "Dunant Light")
			GUICtrlSetFont($cCheckBox_HEL_ND, 12, 300, -1, "Dunant Light")
			GUISetState(@SW_SHOW)
			#EndRegion ### Setup Child GUI ###


			While 1
				$nMsg = GUIGetMsg()
				Switch $nMsg
					Case $GUI_EVENT_CLOSE
						GUISetState(@SW_ENABLE, $GUI)
						GUIDelete($cGUI)
						ExitLoop


					Case $cBtn ; <------ BUTTON ERSTELLEN
						$LastSelection = _GUICtrlListView_GetSelectionMark($List1) ; Die letzte Auswahl des Listviews wird in eine Variable gespeichert.


						$EL_TD = "" ;Variablen müssen vorher als Leer definiert werden.
						$TF_TD = ""
						$AMD_TD = ""
						$HEL_TD = ""


						$EL_ND = ""
						$TF_ND = ""
						$AMD_ND = ""
						$HEL_ND = ""






						If GUICtrlRead($cCheckBox_EL_TD) = 1 Then ;Wenn die Checkbox aktiv ist, wird der Inhalt ausgelesen, sonst nicht. Gibts da keine schönere Variante?
							$EL_TD = "[" & GUICtrlRead($cCombo_EL_TD) & "-EL]"
						EndIf


						If GUICtrlRead($cCheckBox_TF_TD) = 1 Then
							$TF_TD = "[" & GUICtrlRead($cCombo_TF_TD) & "-TF]"
						EndIf


						If GUICtrlRead($cCheckBox_AMD_TD) = 1 Then
							$AMD_TD = "[" & GUICtrlRead($cCombo_AMD_TD) & "-AMD]"
						EndIf


						If GUICtrlRead($cCheckBox_HEL_TD) = 1 Then
							$HEL_TD = "[" & GUICtrlRead($cCombo_HEL_TD) & "-HÄND]"
						EndIf






						If GUICtrlRead($cCheckBox_EL_ND) = 1 Then
							$EL_ND = "[" & GUICtrlRead($cCombo_EL_ND) & "-EL]"
						EndIf


						If GUICtrlRead($cCheckBox_TF_ND) = 1 Then
							$TF_ND = "[" & GUICtrlRead($cCombo_TF_ND) & "-TF]"
						EndIf


						If GUICtrlRead($cCheckBox_AMD_ND) = 1 Then
							$AMD_ND = "[" & GUICtrlRead($cCombo_AMD_ND) & "-AMD]"
						EndIf


						If GUICtrlRead($cCheckBox_HEL_ND) = 1 Then
							$HEL_ND = "[" & GUICtrlRead($cCombo_HEL_ND) & "-HÄND]"
						EndIf




						$BEM = GUICtrlRead($cInput)


						_GUICtrlListView_AddSubItem($List1, $LastSelection, $BEM, 5) ;Bemerkung in Listview eintragen.


						_GUICtrlListView_AddSubItem($List1, $LastSelection, $EL_TD & $TF_TD & $AMD_TD & $HEL_TD, 3) ;Tagdienst Output in LV eintragen.
						_GUICtrlListView_AddSubItem($List1, $LastSelection, $EL_ND & $TF_ND & $AMD_ND & $HEL_ND, 4) ;Nachtdienst Output in LV eintragen.


						GUISetState(@SW_ENABLE, $GUI) ;Enabled Parent-GUI
						GUIDelete($cGUI) ;Löscht Child-GUI
						ExitLoop ;Tritt aus dem Loop des Child-GUI's aus um wieder in den Loop des Parent-GUI's zu gelangen.


;~ 						############### REGION TAGDIENST ###############
						;Wenn die Checkbox aktiv ist, wird die Combobox enabled, sonst disabled(standard).
					Case $cCheckBox_EL_TD ;<------------------- EINSATZLENKER
						If _IsChecked($cCheckBox_EL_TD) Then
							GUICtrlSetState($cCombo_EL_TD, 64)
						Else
							GUICtrlSetState($cCombo_EL_TD, 128)
						EndIf


					Case $cCheckBox_TF_TD ;<------------------- TRANSPORTFÜHRER
						If _IsChecked($cCheckBox_TF_TD) Then
							GUICtrlSetState($cCombo_TF_TD, 64)
						Else
							GUICtrlSetState($cCombo_TF_TD, 128)
						EndIf


					Case $cCheckBox_AMD_TD ;<------------------- AMBULANZDIENST
						If _IsChecked($cCheckBox_AMD_TD) Then
							GUICtrlSetState($cCombo_AMD_TD, 64)
						Else
							GUICtrlSetState($cCombo_AMD_TD, 128)
						EndIf


					Case $cCheckBox_HEL_TD ;<------------------- HÄND LENKER
						If _IsChecked($cCheckBox_HEL_TD) Then
							GUICtrlSetState($cCombo_HEL_TD, 64)
						Else
							GUICtrlSetState($cCombo_HEL_TD, 128)
						EndIf


;~ 						############### REGION NACHTDIENST ###############
					Case $cCheckBox_EL_ND ;<------------------- EINSATZLENKER
						If _IsChecked($cCheckBox_EL_ND) Then
							GUICtrlSetState($cCombo_EL_ND, 64)
						Else
							GUICtrlSetState($cCombo_EL_ND, 128)
						EndIf


					Case $cCheckBox_TF_ND ;<------------------- TRANSPORTFÜHRER
						If _IsChecked($cCheckBox_TF_ND) Then
							GUICtrlSetState($cCombo_TF_ND, 64)
						Else
							GUICtrlSetState($cCombo_TF_ND, 128)
						EndIf


					Case $cCheckBox_AMD_ND ;<------------------- AMBULANZDIENST
						If _IsChecked($cCheckBox_AMD_ND) Then
							GUICtrlSetState($cCombo_AMD_ND, 64)
						Else
							GUICtrlSetState($cCombo_AMD_ND, 128)
						EndIf


					Case $cCheckBox_HEL_ND ;<------------------- HÄND LENKER
						If _IsChecked($cCheckBox_HEL_ND) Then
							GUICtrlSetState($cCombo_HEL_ND, 64)
						Else
							GUICtrlSetState($cCombo_HEL_ND, 128)
						EndIf


				EndSwitch
			WEnd


	EndSwitch
WEnd




; ### FUNKTIONS SEKTION ###
; Hier werden alle Funktionen erstellt.


Func _IsChecked($idControlID)
	Return BitAND(GUICtrlRead($idControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked


Func _Setup_Scene()


	_GUICtrlListView_AddColumn($List1, "Wochentag", 100, 1)
	_GUICtrlListView_AddColumn($List1, "Datum", 100, 2)
	_GUICtrlListView_AddColumn($List1, "Priorität", 100, 2)
	_GUICtrlListView_AddColumn($List1, "Tagdienst 07:00 - 19:00", 250, 2)
	_GUICtrlListView_AddColumn($List1, "Nachtdienst 19:00 - 07:00", 250, 2)
	_GUICtrlListView_AddColumn($List1, "Bemerkung", 300, 2)


	$hImage = _GUIImageList_Create()
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0xFFFFFF, 16, 16)) ; Weiß
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0xFF0000, 16, 16)) ; Rot
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0xEC9A4C, 16, 16)) ;Orange
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0x00cbff, 16, 16)) ;Blau
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0x00FF00, 16, 16)) ;Grün


	_GUICtrlListView_SetImageList($List1, $hImage, 1)


	Global $Array[_DateDaysInMonth(@YEAR, @MON) - @MDAY + 1][5]


	For $i = 0 To _DateDaysInMonth(@YEAR, @MON) - @MDAY Step 1
		$Array[$i][1] = _DateTimeFormat(_DateAdd('d', $i, _NowCalcDate()), 2)
		$Array[$i][0] = _DateDayOfWeek(_DateToDayOfWeek(@YEAR, @MON, @MDAY + $i), 2)


	Next
	_GUICtrlListView_AddArray($List1, $Array)


EndFunc   ;==>_Setup_Scene

Alles anzeigen

Edit 3:

Projekt derzeit auf Eis gelegt, weil es einfach nicht wirklich umsetzbar ist, ohne auf die Datenbanken des Dienstplanes Zugriff zu haben.

Wenn sich dementsprechend mal was tut, werde ich mich gerne wieder damit beschäftigen!

Trotzdem danke an alle die hier ihren Beitrag geleistet haben!!!

Ihr seid die Besten

**Kanashius**

Was Übersicht angeht:
Die 2te Gui würde ich auf jedenfall in eine Funktion packen, das sorgt für mehr Übersichtlichkeit in der Hauptschleife.
Außerdem würde ich mit Arrays arbeiten. Damit würdest du viele Redundanzen beim abfragen der Comboboxen sparen (und beim setzen des Status,...)

Ich hab das hier mal umgesetzt. Das spart etwa 150 Zeilen, lohnt sich also. Auch weils dann Übersichtlicher ist. (Man kann bestimmt noch mehr verbessern, wenn man genau weiß, was passieren soll. Ich kanns auch momentan nicht ausführen, da ich auf Linux unterwegs bin :))

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiImageList.au3>
#include <Date.au3>
#include <GuiListView.au3>
#include <StructureConstants.au3>
#include <Array.au3>
#include <StaticConstants.au3>




#Region ### GRAPHICAL USER INTERFACE (PARENT) ###
$GUI = GUICreate("Dienstsuche OST - GMUNDEN", 1600, 900, -1, -1, BitOR($WS_MAXIMIZEBOX, $WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU))
$MenuItem1 = GUICtrlCreateMenu("Aktion")
$SubItem1_1 = GUICtrlCreateMenuItem("Dienstsuche starten", $MenuItem1)
$SubItem1_2 = GUICtrlCreateMenuItem("Sperren", $MenuItem1)
$SubItem1_3 = GUICtrlCreateMenuItem("Beenden", $MenuItem1)
$MenuItem2 = GUICtrlCreateMenu("Liste")
$SubItem2_1 = GUICtrlCreateMenuItem("Anzeigen", $MenuItem2)
$SubItem2_2 = GUICtrlCreateMenuItem("Bearbeiten", $MenuItem2)
$SubItem2_3 = GUICtrlCreateMenuItem("Exportieren", $MenuItem2)


$List1 = GUICtrlCreateListView("", 0, 0, 1600, 880, $LVS_SINGLESEL)
GUICtrlSetBkColor($List1, 0X292929)
GUICtrlSetFont($List1, 12, 300, -1, "Dunant Light", 5)
GUICtrlSetColor($List1, 0XFFFFFF)


$contextmenu = GUICtrlCreateContextMenu($List1)
$sofort = GUICtrlCreateMenuItem("Sofort", $contextmenu)
$dringend = GUICtrlCreateMenuItem("Dringend", $contextmenu)
$normal = GUICtrlCreateMenuItem("Normal", $contextmenu)
$erledigt = GUICtrlCreateMenuItem("Erledigt", $contextmenu)
GUICtrlCreateMenuItem("", $contextmenu)
$erstellen = GUICtrlCreateMenuItem("Eintrag erstellen", $contextmenu)
GUISetState(@SW_SHOWMAXIMIZED)
GUISetState(@SW_SHOW)
#EndRegion ### GRAPHICAL USER INTERFACE ###


_Setup_Scene()


While 1




	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $SubItem1_1 ;Dienstsuche starten


		Case $SubItem1_2 ;Sperren


		Case $SubItem1_3 ;Beenden
			Exit
		Case $SubItem2_1 ;Anzeigen


		Case $SubItem2_2 ;Bearbeiten


		Case $SubItem2_3 ;Exportieren


		Case $sofort ; PRIORITÄTEN werden definiert und eingetragen.
			_setPriority("█ SOFORT █",1)
		Case $dringend
			_setPriority("DRINGEND",2)
		Case $normal
			_setPriority("Normal",3)
		Case $erledigt
			_setPriority("✔",4)
		Case $erstellen
			_createNewEntry()
	EndSwitch
WEnd




; ### FUNKTIONS SEKTION ###
; Hier werden alle Funktionen erstellt.


Func _IsChecked($idControlID)
	Return BitAND(GUICtrlRead($idControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked


Func _Setup_Scene()


	_GUICtrlListView_AddColumn($List1, "Wochentag", 100, 1)
	_GUICtrlListView_AddColumn($List1, "Datum", 100, 2)
	_GUICtrlListView_AddColumn($List1, "Priorität", 100, 2)
	_GUICtrlListView_AddColumn($List1, "Tagdienst 07:00 - 19:00", 250, 2)
	_GUICtrlListView_AddColumn($List1, "Nachtdienst 19:00 - 07:00", 250, 2)
	_GUICtrlListView_AddColumn($List1, "Bemerkung", 300, 2)


	$hImage = _GUIImageList_Create()
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0xFFFFFF, 16, 16)) ; Weiß
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0xFF0000, 16, 16)) ; Rot
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0xEC9A4C, 16, 16)) ;Orange
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0x00cbff, 16, 16)) ;Blau
	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0x00FF00, 16, 16)) ;Grün


	_GUICtrlListView_SetImageList($List1, $hImage, 1)


	Global $Array[_DateDaysInMonth(@YEAR, @MON) - @MDAY + 1][5]


	For $i = 0 To _DateDaysInMonth(@YEAR, @MON) - @MDAY Step 1
		$Array[$i][1] = _DateTimeFormat(_DateAdd('d', $i, _NowCalcDate()), 2)
		$Array[$i][0] = _DateDayOfWeek(_DateToDayOfWeek(@YEAR, @MON, @MDAY + $i), 2)


	Next
	_GUICtrlListView_AddArray($List1, $Array)


EndFunc   ;==>_Setup_Scene


Func _setPriority($msg,$id)
	$LastSelection = _GUICtrlListView_GetSelectionMark($List1)
	_GUICtrlListView_AddSubItem($List1, $LastSelection, $msg, 2)
	_GUICtrlListView_SetItemImage($List1, $LastSelection, $id)
EndFunc


Func _createNewEntry()
	GUISetState(@SW_DISABLE, $GUI) ; Parent-GUI wird disabled.


	#Region ### Setup Child GUI ###
	;Checkbox,Combo
	local $arControls=[["Einsatzlenker",-1,-1,"-EL"],["Transportführer",-1,-1,"-TF"],["Ambulanzdienst",-1,-1,"-AMD"],["HÄND Lenker",-1,-1,"-HÄND"]]
	ReDim $arControls[Ubound($arControls)*2][Ubound($arControls,2)]
	$iControlCount=Ubound($arControls)/2
	for $i=$iControlCount to ubound($arControls)-1 step 1
		for $j=0 to ubound($arControls,2)-1 step 1
			$arControls[$i][$j]=$arControls[$i-$iControlCount][$j]
		next
	next
	$cGUI = GUICreate("Eintrag erstellen", 400, 300, -1, -1, -1, $WS_EX_TOOLWINDOW, $GUI)
	$cBtn = GUICtrlCreateButton("Erstellen", 10, 270, 380, 30)
	GUICtrlSetFont($cBtn, 14, 300, -1, "Dunant Medium")
	GUICtrlCreateGraphic(200, 0, 1, 230, $SS_SUNKEN) ; Trennlinie


	;--------- TAGDIENST -------
	$cLable_TD = GUICtrlCreateLabel("Tagdienst ( 7 - 19 Uhr )", 10, 20, 180, 30, $SS_Center)
	GUICtrlSetFont($cLable_TD, 14, 300, -1, "Dunant Light")
	for $i=0 to $iControlCount-1 step 1
		$arControls[$i][1]=GUICtrlCreateCheckbox($arControls[$i][0], 10, 70+$i*30, 130)
		GUICtrlSetFont($arControls[$i][1], 12, 300, -1, "Dunant Light")
		$arControls[$i][2]=GUICtrlCreateCombo("-", 140, 70+$i*30, 50, 30)
		GUICtrlSetData($arControls[$i][2], "1|2|3|4|5|6|7|8|9|10")
		GUICtrlSetState($arControls[$i][2], 128)
	next


	;--------- NACHTDIENST -------
	$cLable_ND = GUICtrlCreateLabel("Nachtdienst ( 19 - 7 Uhr )", 210, 20, 180, 30, $SS_Center)
	GUICtrlSetFont($cLable_ND, 14, 300, -1, "Dunant Light")


	for $i=$iControlCount to $iControlCount*2-1 step 1
		$arControls[$i][1]=GUICtrlCreateCheckbox($arControls[$i][0], 210, 70+($i-$iControlCount)*30, 130)
		GUICtrlSetFont($arControls[$i][1], 12, 300, -1, "Dunant Light")
		$arControls[$i][2]=GUICtrlCreateCombo("-", 340, 70+($i-$iControlCount)*30, 50, 30)
		GUICtrlSetData($arControls[$i][2], "1|2|3|4|5|6|7|8|9|10")
		GUICtrlSetState($arControls[$i][2], 128)
	next


	$cLable_Bemerkung = GUICtrlCreateLabel("Bemerkung:", 10, 210, 180, 30, $SS_LEFT)
	GUICtrlSetFont($cLable_Bemerkung, 14, 300, -1, "Dunant Light")
	$cInput = GUICtrlCreateInput("", 10, 235, 380, 25)
	GUICtrlSetFont($cInput, 12, 300, -1, "Dunant Light")


	GUISetState(@SW_SHOW)
	#EndRegion ### Setup Child GUI ###


	While 1
		$nMsg = GUIGetMsg()
		for $i=0 to ubound($arControls)-1 step 1
			if $nMsg=$arControls[$i][1] then
				If _IsChecked($arControls[$i][1]) Then
					GUICtrlSetState($arControls[$i][2], 64)
				Else
					GUICtrlSetState($arControls[$i][2], 128)
				EndIf
			endif
		next
		Switch $nMsg
			Case $GUI_EVENT_CLOSE
				GUISetState(@SW_ENABLE, $GUI)
				GUIDelete($cGUI)
				ExitLoop


			Case $cBtn ; <------ BUTTON ERSTELLEN
				$LastSelection = _GUICtrlListView_GetSelectionMark($List1) ; Die letzte Auswahl des Listviews wird in eine Variable gespeichert.
				local $arDienste[8]
				;Wenn die Checkbox aktiv ist, wird der Inhalt ausgelesen, sonst nicht. Gibts da keine schönere Variante?
				;Doch: Standartmäßig ist das Combo -, also prüfen ob - drinsteht
				for $i=0 to Ubound($arControls)-1 step 1
					if guictrlread($arControls[$i][2])<>"-" then
						$arDienste[$i]="[" & GUICtrlRead($arControls[$i][2]) &$arControls[$i][3]& "]"
					endif
				next
				$BEM = GUICtrlRead($cInput)
				_GUICtrlListView_AddSubItem($List1, $LastSelection, $BEM, 5) ;Bemerkung in Listview eintragen.
				_GUICtrlListView_AddSubItem($List1, $LastSelection, $arDienste[0]&$arDienste[1]&$arDienste[2]&$arDienste[3], 3) ;Tagdienst Output in LV eintragen.
				_GUICtrlListView_AddSubItem($List1, $LastSelection, $arDienste[4]&$arDienste[5]&$arDienste[6]&$arDienste[7], 4) ;Nachtdienst Output in LV eintragen.
				GUISetState(@SW_ENABLE, $GUI) ;Enabled Parent-GUI
				GUIDelete($cGUI) ;Löscht Child-GUI
				ExitLoop ;Tritt aus dem Loop des Child-GUI's aus um wieder in den Loop des Parent-GUI's zu gelangen.
		EndSwitch
	WEnd
EndFunc

Alles anzeigen

Falls du daran etwas nicht verstehst, gerne Fragen

MfG Kanashius

Stoani

Danke Kanashius, für die Mühe. Ich werds mir bei Gelegenheit durchsehen, wird aber ein bisschen dauern bis ich alles durchschaut hab

Hier ist ein neuer Ansatz, schöner und ordentlicher find ich.

Ist halt noch nicht designed und ohne irgendwelchen Schnickschnack.

Edit: Neue Einlese - Funktion fürs Datum. Es werden jetzt IMMER 30 Tage im voraus angezeigt.

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiImageList.au3>
#include <Date.au3>
#include <GuiListView.au3>
#include <StructureConstants.au3>
#include <Array.au3>
#include <StaticConstants.au3>
#include <EditConstants.au3>




#Region # # # # # # # # # # # # # # # # #		CREATE USER INTERFACE		# # # # # # # # # # # # # # # # #


$pGUI = GUICreate("Dienstsuche OST - GMUNDEN", 1600, 900, (@DesktopWidth / 2) - 800, (@DesktopHeight / 2) - 450) ;GUI erstellen und zentrieren


$pListView = GUICtrlCreateListView("", 0, 0, 1600, 600) ;ListView erstellen
_GUICtrlListView_SetExtendedListViewStyle($pListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_DOUBLEBUFFER)) ;Gitternetz für ListView


_GUICtrlListView_AddColumn($pListView, "Wochentag", 100, 1) ;Column: Wochentage
_GUICtrlListView_AddColumn($pListView, "Datum", 100, 2) ;Column: Datum
_GUICtrlListView_AddColumn($pListView, "Priorität", 100, 2) ;Column: Priorität
_GUICtrlListView_AddColumn($pListView, "Tagdienst", 100, 2) ;Column: Tagdienst
_GUICtrlListView_AddColumn($pListView, "Nachtdienst", 100, 2) ;Column: Nachtdienst
_GUICtrlListView_AddColumn($pListView, "Bemerkung", 300, 2) ;Column: Bemerkung


$hImage = _GUIImageList_Create() ;Erstellt eine IMG-Liste für $pListView
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($pListView, 0xD8D8D8, 16, 16)) ;Weiß
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($pListView, 0xFF0000, 16, 16)) ;Rot
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($pListView, 0xEC9A4C, 16, 16)) ;Orange
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($pListView, 0x00CBFF, 16, 16)) ;Blau
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($pListView, 0x00FF00, 16, 16)) ;Grün


_GUICtrlListView_SetImageList($pListView, $hImage, 1) ;Small - Images für hImage/pListView


;NEUE DATUM-EINLESEFUNKTION
Global $Array[31][5] ; Datum in ListView eintragen
For $i = 0 To 30 Step 1
	$Array[$i][1] = _DateTimeFormat(_DateAdd('d', $i, _NowCalcDate()), 2)
	$DateSplit = StringSplit($Array[$i][1],'.',2)
	$Array[$i][0] = _DateDayOfWeek( _DateToDayOfWeek($DateSplit[2],$DateSplit[1], $DateSplit[0]), 2)
Next




;Global $Array[_DateDaysInMonth(@YEAR, @MON) - @MDAY + 1][5] ; Datum in ListView eintragen
;For $i = 0 To _DateDaysInMonth(@YEAR, @MON) - @MDAY Step 1
;	$Array[$i][1] = _DateTimeFormat(_DateAdd('d', $i, ;_NowCalcDate()), 2)
;	$Array[$i][0] = _DateDayOfWeek(_DateToDayOfWeek(@YEAR, @MON, @MDAY + $i), 2)
;Next
_GUICtrlListView_AddArray($pListView, $Array)


#Region ContextMenu
$pListView_ContextMenu = GUICtrlCreateContextMenu($pListView) ;ContextMenu erstellen
$aContextMenu = GUICtrlCreateMenuItem("Sofort", $pListView_ContextMenu) ;Priorität = Sofort
$bContextMenu = GUICtrlCreateMenuItem("Dringend", $pListView_ContextMenu) ;Priorität = Sofort
$cContextMenu = GUICtrlCreateMenuItem("Normal", $pListView_ContextMenu) ;Priorität = Sofort
$dContextMenu = GUICtrlCreateMenuItem("Erledigt", $pListView_ContextMenu) ;Priorität = Sofort
$eContextMenu = GUICtrlCreateMenuItem("", $pListView_ContextMenu) ;Trennstrich erstellen ----


$fContextMenu = GUICtrlCreateMenu("Suche hinzufügen", $pListView_ContextMenu) ;Priorität = Sofort
$fContextMenu_1 = GUICtrlCreateMenu("Tagdienst", $fContextMenu) ;Tagdienst
$fContextMenu_2 = GUICtrlCreateMenu("Nachtdienst", $fContextMenu) ;Nachtdienst


$fContextMenu_1_a = GUICtrlCreateMenuItem("Einsatzlenker", $fContextMenu_1)
$fContextMenu_1_b = GUICtrlCreateMenuItem("Transportführer", $fContextMenu_1)
$fContextMenu_1_c = GUICtrlCreateMenuItem("Mannschaft", $fContextMenu_1)
$fContextMenu_1_d = GUICtrlCreateMenuItem("HÄND Lenker", $fContextMenu_1)


$fContextMenu_2_a = GUICtrlCreateMenuItem("Einsatzlenker", $fContextMenu_2)
$fContextMenu_2_b = GUICtrlCreateMenuItem("Transportführer", $fContextMenu_2)
$fContextMenu_2_c = GUICtrlCreateMenuItem("Mannschaft", $fContextMenu_2)
$fContextMenu_2_d = GUICtrlCreateMenuItem("HÄND Lenker", $fContextMenu_2)
#EndRegion ContextMenu
GUISetState(@SW_SHOW) ;Set Parent GUI visible


#EndRegion # # # # # # # # # # # # # # # # #		CREATE USER INTERFACE		# # # # # # # # # # # # # # # # #


#Region # # # # # # # # # # # # # # # # #		LOOP Parent		# # # # # # # # # # # # # # # # #
While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $aContextMenu ;Sofort
			_SetPriority("Sofort", 2, 1)
		Case $bContextMenu ;Dringend
			_SetPriority("Dringend", 2, 2)
		Case $cContextMenu ;Normal
			_SetPriority("Normal", 2, 3)
		Case $dContextMenu ;Erledigt
			_SetPriority("Erledigt", 2, 4)
		Case $fContextMenu_1_a ;EL Tagdienst
			_CreateSearch("Einsatzlenker")
	EndSwitch
WEnd
#EndRegion # # # # # # # # # # # # # # # # #		LOOP Parent		# # # # # # # # # # # # # # # # #


Func _CreateSearch($cType) ;Suche hinzufügen
	$cGUI = GUICreate("Suche hinzufügen", 200, 100, -1, -1, -1, $WS_EX_TOOLWINDOW)
	$cLabel = GUICtrlCreateLabel("Wieviel " & $cType & " wollen Sie" & @CR & " zur Suche hinzufügen?", 10, 10, 180, 30)
	$cInput = GUICtrlCreateInput("", 10, 50, 180, 20, $ES_NUMBER)
	$cButton_a = GUICtrlCreateButton("Hinzufügen", 100, 80, 100, 20)
	$cButton_b = GUICtrlCreateButton("Abbrechen", 0, 80, 100, 20)
	GUISetState(@SW_SHOW) ;Set Parent GUI visible
	While 1
		$nMsg = GUIGetMsg()
		Switch $nMsg
			Case $GUI_EVENT_CLOSE
				GUIDelete($cGUI) ;Löscht Child-GUI
				ExitLoop ;Tritt aus dem Loop des Child-GUI's aus um wieder in den Loop des Parent-GUI's zu gelangen.
		EndSwitch
	WEnd
EndFunc   ;==>_CreateSearch




Func _SetPriority($pText, $pColumn, $pImage)
	$LastSelection = _GUICtrlListView_GetSelectionMark($pListView) ;get last selection
	_GUICtrlListView_AddSubItem($pListView, $LastSelection, $pText, $pColumn) ;set text for priority
	_GUICtrlListView_SetItemImage($pListView, $LastSelection, $pImage) ;set image for priority
EndFunc   ;==>_SetPriority

Alles anzeigen

gmmg

Woher nimmst du die Daten, wer an welchem Tag in welcher Schicht arbeitet? Gibt es hier schon bestehende Quellen, die du anzapfen kannst?
Bisher hast du ja nur eine Grafische Oberfläche erstellt...

Eine richtige Schichtplansoftware ist da schon komplexer. http://www.schichtplaner.de/schichtplanung.htm

Also wenn du den Zettel abschaffen willst, musst du dir ja eine entsprechende Datei (Datenbank, Excel File) schaffen, wo die erstmal die Grundlegenden Dinge mit wenig aufwand pflegen kannst.

Gruß gmmg

**autoBert**

Zitat von Stoani

Zurzeit arbeite ich aus Laune und weil ich die Zeit gerade übrig hab an einem Programm, welches die Besetzung des Dienstplanes und die damit verbunden Suche nach Mitarbeitern erleichtern soll.

Wer im Auftrag eines Staates den Rettungssdienst organisiert und am Leben erhält, sollte auch von diesem das nötige Geld und die nötigen (von Profis) entwickelten Werkzeuge/Software bekommen. Es ist imho unnötig, daß sich im Rettungsdienst benötigte Personen an Selbstverständlichkeiten aufreiben.
Der Dienst allein schafft sorgt schon für genügend Belastungen.

Wenn du in einem 1/4 Jahr noch nicht weiter bist, schreib eine PN (das Projekt ist es jedenfalls Wert) bis dahin erbarmt sich hoffentlich @Oscar (mein selbstgewählter Lehrmeister hier) um dein Anliegen.

Stoani

Wow, danke Bert. Motivierende Worte.

Ich beschreibe die Situation mal ganz kurz zum besseren Verständnis.

Wir haben ein System, allerdings ist diese Software veraltet bzw. nicht für die aktive Suche nach Ressourcen zum Füllen der Löcher gedacht.
Man verwendet also insgesamt 3 Varianten der Dienstsuche:

SMS - Verteiler an alle eingetragenen Nummern (ca. 150) z.B.: "Für Samstag TD wird noch ein EL benötigt, bitte anrufen oder online eintragen."
Online Dienstplan: Hier können sich Mitarbeiter jederzeit in den "Pool" eintragen um eine offene Planposition zu besetzen. (https://dienstplan.o.roteskreuz.at) (RPS)
Der anstrengendste Weg und leider immer häufiger: Telefonliste aller Mitarbeiter durchtelefonieren um eine Planposition zu besetzen (wenn zb. 1-2 Tage vorher noch immer nichts besetzt ist)

Du hast es relativ gut auf den Punkt gebracht Bert. An einem Werktag kommt es bei uns nicht selten vor, dass wir von 12 Stunden bis zu 6 Stunden reine Fahrzeit (also die Zeit in der das Auto effektiv läuft, Übernahme und Übergeben von Patienten sowie Versorgung nicht mitgerechnet) haben. Es bleibt daher oftmals nicht gerade viel Zeit für Möglichkeit Nr.3 da diese bei über 150 Nummern ziemlich Zeitintensiv ist.
Bisher wird eine ausgedruckte Tabelle mit sechs Spalten verwendet.

Name(Nach. / Vor.)
Nummer
Leeres Feld für JA
Leeres Feld für NEIN
Leeres Feld für Nicht erreicht
Bemerkung

Jetzt kann man sich den Aufwand für 150 Nummern und 7 Tage die Woche ca. vorstellen. Nun wird diese arbeite oft durch Fahrten unterbrochen. Der nächste der Zeit hat macht dann wieder weiter wo der letzte aufgehört hat und es entwickelt sich ein Stille-Post-Spiel.

Die ideale Lösung wäre:

Ein Programm mit einem "Anruf" - Button und dazugehöriger Computer-Telefon-Verbindung. (Nicht umsetzbar, wird nicht genehmigt)
Das Echtzeit Einlesen von Dienstlöchern aus dem Dienstplan in diese Programm
Wird allerdings kaum umsetzbar sein, da es keine Offizielle Lösung ist und daher keinerlei Berechtigung oder Unterstützung erfährt. Das RPS-System ist nicht öffentlich einsehbar und ohne Anmeldung nicht verwendbar.

Veraltete Software ist leider oft ein Problem, da es zuviel Geld kosten würde diese für das gesamte Land oder Bundesland

@gmmg die Quelle einfach anzuzapfen wird kaum möglich sein, deshalb ist es erstmal manuell vorgesehen.

Es ist halt eine schwierige Thematik, da es auf keinen Fall durch einen "Mehraufwand" durch das Programm kommen soll...

Wie gesagt, ist einfach eine Idee von mir und weil ich gerade Zeit dazu habe, mache ich mir ein paar Gedanken darüber

**autoBert**

Ich habe leider aus privaten Gründen derzeit nicht die Zeit. Ich habe für einen Bekannten in den 80ern ein Programm geschrieben um den Schriftverkehr eines gemeinnützigen Verbandes zu optimierern. [Selbstlob]Jedes Werbeunternehmen und früher auch die Stasi hätten sich die Finger danach geleckt.[/Selbstlob]Das Programm habe ich das letzemal vor 4-5 Jahren aktualissiert, mittlerweile stellt der Dachverband eine mir unbekannte Lösung zur Verfügung. Da er aber Datenexport/-Import aus datenschutzrechtlichen Gründen verbietet sind mir die Hände gebunden und ohne Mehrarbeit kommt mein Bekannter nicht aus, will er mein Programm zuätzlich nutzen muss er 2 mal die Daten einpflegen.

**BugFix**

Zitat von autoBert

Datenexport/-Import aus datenschutzrechtlichen Gründen verbietet

OMG, wenn ich solch einen hanebüchenen Unsinn immer lese.
Da hat man wahrscheinlich den Hausmeister zum Datenschutzbeauftragten gedrängt, weil sich kein anderer fand. Und der, kraft seiner Wassersuppe, interpretiert mal eben das Datenschutzgesetz neu.
Wäre ja eine Katastrophe, wenn im DSG ein Passus wäre, der Datenexport/Import verbieten würde (dann wäre jede Datensicherung obsolet!). Ich kenne zwar nicht die Richtlinien aller Länder, aber weder in BaWü noch in SaAnh gibt es eine derartige Festlegung.

**autoiter**

Hallo @Stoani,

Zitat von Stoani

@gmmg die Quelle einfach anzuzapfen wird kaum möglich sein, deshalb ist es erstmal manuell vorgesehen.

Es ist natürlich schade, dass du diese Liste nicht mit den Daten aus euren vorhandenen Programmen füllen kannst oder darfst.
Dennoch wäre eine Datei, aus der beim Start Daten eingelesen und beim Beenden Daten abgespeichert werden, doch sehr sinnvoll. Was ist denn, wenn mal jemand das Programm beendet. Für den nächsten Kollegen wären dann alle schon erledigten Telefonate verloren und er müsste von vorne beginnen. Deine Kollegen würden doch sofort wieder die Papierliste wollen..

gmmg

Um etwas zu automatisieren, musst du dir erstmal eine Dateistruktur überlegen.
Diese könnte im ersten Step aus einer Excel Datei bestehen, mit den Feldern die du entsprechend benötigst.
Hier dann zum Befüllen der Felder eine GUI erstellen. Die Datenschutz relevanten Daten (Name, Adresse, Tel usw. )könnte man ja hier auch beim schreiben in die Excel entsprechend verschlüsseln.

Danach dann entsprechend die GUI für die Dienst Verwaltung erstellen.

Du hast ja oben die Tabelle mit den 6 Spalten angegeben.
Ich würde hier bei der Eingabe ein Dropdownfeld nehmen, wo du dann die 3 Einträge (Ja/Nein/nicht erreicht) zur Auswahl hast.
Und bei denen die schon angerufen worden sind, muss man ein entsprechendes Kennzeichen setzen, damit dann beim nächsten öffnen die Info verfügbar ist.

Entweder macht dann dann hier pro Tag oder schicht seperate Einträge oder man muss sich überlegen wie lange das Kennzeichen die gültigkeit behält.

gruß gmmg

Stoani

@autoiter hatte ich auch so geplant, einfach in einen Datei (z.b. ini, excel, txt. was auch immer) abspeichern und beim nächsten start die Möglichkeit zum laden geben.

@gmmg ich versuch mein bestes um einen zugang zu den Daten zu bekommen, ist halt von zu hause aus etwas schwer... Danke für den Vorschlag, werds mir ansehen.

bazii

Zitat von BugFix

OMG, wenn ich solch einen hanebüchenen Unsinn immer lese.

Thema Datenschutz.

@'BugFix: Mein AG mir auch vor Jahren in bestimmten Teilen den Datenschutz im Konzern anvertraut. Kenne mich daher ein wenig damit aus oder bilde es mir zumindest ein. Die Aussage an sich ist von autoBert richtig. Jeder der die Möglichkeit in einer Software für einen Datenexport mit datenschutzrelevanten Inhalten inne hat, könnte diese Daten missbrauchen.

Daher ist die Möglichkeit für einen Datenexport mit datenschutzrelevanten Inhalten auch bei uns im Konzern, an einen sehr begrenzten Personenkreis delegiert worden. Selbstverständlich können die Applikations-Betreuer das auch. Doch auch die mussten eine Datenschutzvereinbahrung bei uns unterschreiben. Von da her ist gerade bei Vereinen und sozialen Hilfeorganisationen und Rettungsdiensten, welche Spendengelder oder auch nur die Namen von Mitarbeitern verwalten, große Vorsicht angesagt, dass diese Daten nicht an die Öffentlichkeit gelangen können.

Selbst bei Berufsgenossenschafts-Software zur Hinterlegung von Gefährdungsbeurteilungen nur mit Daten einer öffentllichen Einrichtung, ist beim Daten-Export ein Benutzernamen und ein vordefiniertes Passwort anzugeben, damit die dort erfassten Daten nicht jeder Sachbearbeiter selbst mit den hinterlegten Daten auf einen Stick ziehen kann. Das Thema wird bei uns sehr ernst genommen.

Ob jetzt allerdings beim Threadsteller im Dienstplan zukünftig datenschutzrelevante Eintragungen stattfinden ....

**autoBert**

@BugFix: ich habe die Richtlinien dieses Verbandes selbst gelesen. Ich persönlich erfülle nicht die recht hohen Anforderungen um einen legalen Datenabgleich durch zu führen.
Bin der Meinung, daß BW- oder Bundesweit jeden Tag gegen diese Richtlinien verstoßen wird, bin aber nicht bereit mich daran zu beteiligen, sprich zusätzliche Zeit/Geld für eine Zertifizierung zu investieren. Mein Programm hat natürlich eine Im- Exportfunktion im CSV-Format, ob diese sinnvoll und besrimmungssgemäß benutzt wird ist mir egal.

**BugFix**

@autoBert: Da hast du mich vielleicht falsch verstanden. Dass unberechtigte Dritte nicht auf die Daten zugreifen dürfen ist ja auch korrekt. Jedoch hat das mit einer Import-/Exportmöglichkeit von Daten nichts zu tun und somit ist es auch irrsinnig sowas untersagen zu wollen.
Aber ich habe schon häufiger im Gespräch mit anderen Datenschutzbeauftragten festgestellt, dass oft die Gesetzesinhalte nicht verstanden werden und mit einer Art vorauseilendem Gehorsam statt der gesetzlich geforderten bestimmungsgemäßen Nutzung eine möglichst geringe Nutzung von sensiblen Daten angestrebt wird.

**Andy**

Hi,

Zitat von bazii

Jeder der die Möglichkeit in einer Software für einen Datenexport mit datenschutzrelevanten Inhalten inne hat, könnte diese Daten missbrauchen.

Man sollte sich diese Aussage, mit Hintergrund das der Ersteller in einem "Konzern" arbeitet mal PRAKTISCH vor Augen führen.
Die Mitarbeiter in diesem "Konzern" dürfen weder (personenbezogene) Daten aus E-mails auslesen und bspw. in einer Textverarbeitung weiterverwenden. Speichern dieser E-Mails und Textdokumente ist aus Datenschutzrechtlichen Gründen also auch verboten. Ausdrucke auf Papier sind auch verboten, außer man deponiert diese Ausdrucke im konzerneigenen Tresor mit Zutrittkontrolle NUR GENAU FÜR DEN MITARBEITER, DER DIESES DOKUMENT ERSTELLT HAT!
Fehldrucke werden sofort geshreddert.
Weiterleitung von Mails erfolgt erst nach freigegebener Prüfung durch einen Datenschutzbeauftragten, um unbeabsichtigte Datenweitergabe zu erkennen/unterbinden...
//EDIT da jeder Arbeitsplatz kameraüberwacht ist, soll ausgeschlossen werden, dass Mitarbeiter eine handschriftliche Abschrift des Bildschirminhalts erstellen können

Das ist nur ein kleiner Teil von Vorgängen, die BugFix nicht ohne Grund als "hanebüchen" beschrieben hat...
Es geht um "unberechtigte Dritte". Wenn ich als Mitarbeiter eines Unternehmens eine Software X benutze und mit einem AutoIt-Programm auf die Daten(bank) des Programms X zugreife, um Arbeitsabläufe zu automatisieren, dann ist das keine "Weitergabe von Daten an unberechtigte Dritte!"

[OT]Man sollte ehrlich sein...wieso wird einigen/vielen dabei unbehaglich, wenn jemand Zugriff auf große bzw. umfassende Datenmengen hat?!
Weil von vornherein unterstellt wird, dass beabsichtigt oder unbeabsichtigt "Unsinn" mit diesen Daten angestellt wird oder zumindest werden kann!
Mir wird ehrlich gesagt schlecht dabei, wenn es um Zusammenführung/Migration von Datenbanken geht. Und NOCH schlechter, wenn sog. "Spezialisten" versprechen, dass alles glatt läuft...[/OT]

Zitat von autoBert

Bin der Meinung, daß BW- oder Bundesweit jeden Tag gegen diese Richtlinien verstoßen wird, bin aber nicht bereit mich daran zu beteiligen, sprich zusätzliche Zeit/Geld für eine Zertifizierung zu investieren. Mein Programm hat natürlich eine Im- Exportfunktion im CSV-Format, ob diese sinnvoll und besrimmungssgemäß benutzt wird ist mir egal.

Genau so sieht es leider in der PRAXIS aus...

Ich hatte neulich Mitarbeiter in einem deutschlandweit bekannten Unternehmen geschult, welches auch noch an einen sog. Weltkonzern angeschlossen ist...
Es ging eigentlich um eine Produktschulung, aufgrund weiteren Interesses habe ich die Schulung ausgeweitet.
Essenz für mich nach einigen Stunden Diskussion: die Mitarbeiter dort haben KEINE Möglichkeit, sich Hilfsmittel in Form von Formularen/Protokollen/Tabellen selbst zu erstellen, da die Heeresleitung/EDV-Abteilung dies unterbindet/ablehnt. Externe Unternehmen damit zu beauftragen kommt auch nicht in Frage.
Ende vom Lied "...wir können doch so nicht arbeiten..."
Dass nur SEHR motivierte und gegen ihre Vorgesetzten gestählte Mitarbeiter sich Zuhause mit OpenOffice hinsetzen und die erforderlichen Hilfsmittel erstellen, kommt wohl garnicht oder nur selten vor. Daher hatte ich mich entschlossen, zu "helfen" und mal zu zeigen wie einfach es ist, sich solche Hilfsmittel zu erstellen. Auf meinem privaten Laptop wurde in Zusammenarbeit mit den dortigen Mitarbeitern ein auf die Bedürfnisse abgestimmtes Formular/Protokoll in OO erstellt. Per Beamer an die Wand geworfen, waren alle happy, aber das legte sich sehr schnell, als es darum ging, dieses Formular in Papierform baustellengerecht aufzuarbeiten.
Mein privater Laptop durfte nicht ans Firmennetz, USB-Stick natürlich genausowenig. Formular im odt, xls oder PDF-format per Mail an einen Verantwortlichen schicken geht, aber der sitzt mehrere hundert Kilometer entfernt und die Dateien müssen erst "geprüft" werden...
Ich wundere mich überhaupt nicht, wieso Deutschland keine Zuckerbergs, Gates, Otellinis uswusf. hervorbringt, denen wird schon in der Schule/Ausbildung ausgetrieben, PRODUKTIV zu arbeiten! Und im Berufsleben erst recht!

Zitat von bazii

Selbst bei Berufsgenossenschafts-Software zur Hinterlegung von Gefährdungsbeurteilungen nur mit Daten einer öffentllichen Einrichtung, ist beim Daten-Export ein Benutzernamen und ein vordefiniertes Passwort anzugeben, damit die dort erfassten Daten nicht jeder Sachbearbeiter selbst mit den hinterlegten Daten auf einen Stick ziehen kann. Das Thema wird bei uns sehr ernst genommen.

Berechtigterweise!

Zitat von bazii

Ob jetzt allerdings beim Threadsteller im Dienstplan zukünftig datenschutzrelevante Eintragungen stattfinden ....

...ist zumindest fraglich / diskussionswürdig. Wenn ich als Vorgesetzter allerdings einen motivierten Mitarbeiter aus "fadenscheinigen" Gründen ausbremse, muss ich mich um fehlende Produktivität nicht weiter wundern....

Für die "Datenschützer/beauftragten" hier noch einmal KLAR UND DEUTLICH die Aussage des TE im Startpost:
Stoani schrieb:

Zitat von Stoani

Bisher war ein Zettel mit Telefonnummern dafür ausreichend,

ein Zettel! Ein ZETTEL! OMFG, wirr haben völlig vergessen, dass die Mitarbeiter sich personenbezogene Daten AUFSCHREIBEN können, das muss aus datenschutzrechtlichen Gründen natürlich umgehend unterbunden werden...viel Spass dabei!

**autoBert**

Zitat von BugFix

mit einer Art vorauseilendem Gehorsam statt der gesetzlich geforderten bestimmungsgemäßen Nutzung eine möglichst geringe Nutzung von sensiblen Daten angestrebt wird.

Genau dieses hat dieser LandesVerband erfolgreich erreicht. Die meisten Punkte (Fachwissen etc.) würde ich zwar erfüllen, trotzdem kann ich nicht alles gewährleisten was gefordert wird. Das eine noch nötige Zertifikat würde eine Schulung von 3 Tagen bedeuten, das Problem ist nicht die Zeit sondern die Kursgebühr. Naja das Programm (angefangen bei MS-Dos 2.11 [mit Turbo Pascal programmiert] bis heute Win 7 aufwärts [mit AutoIt und SQLite programmiert] hatte eine lange Laufzeit. Ich denke aber ich habe mehr Zeit investiert als es insgeamt genutzt wurde. Es wird wohl, sollten noch einmal Änderungen nötig sein, sterben. Gerade für dieses Programm habe ich, auf der Suche nach einer kostenfreien Lösung, AutoIt gelernt. Zumindest dies habe ich bis heute nicht bereut.

Stoani

Zitat von Andy

ein Zettel! Ein ZETTEL! OMFG, wirr haben völlig vergessen, dass die Mitarbeiter sich personenbezogene Daten AUFSCHREIBEN können

Naja, wir haben auch alle eine umfassende Verschwiegenheitserklärung unterzeichnet, so ist es nicht

**autoiter**

Hey @Stoani,
lass die mal reden.
Ich habe hier noch nie gesehen, wie ein Thread so selbstverständlich von anderen gekapert wurde. Als ich @Andys [OT][/OT] gesehen habe, musste ich schon lachen, da das alles nichts mit deinem im ersten Beitrag geäußerten Anliegen zu tun hat.

Poste deine Fortschritte unter den gegebenen Bedingungen ruhig weiter. Das wird sicher übersichtlicher, als der alte Zettel