Login mit Winhttp

blackcho

Hallo liebe Community,

Ich stehe gerade vor einem Problem wäre sehr dankbar für jede Hilfe.
Ich versuche zurzeit mir den umgang mit einer Seite zuvereinfachen.
Das Ziel ist es das Drucken von Guthaben-Karten zu beschleunigen, leider kann ich euch kein Test-Account anbieten
hoffe aber das ihr mir auch so helfen könnt.

Link:
https://autoit.de/www.gtlpins.com

Code:

Spoiler anzeigen

AutoIt

#include <WinHTTP.au3>
$HTTP_Host = "www.gtlpins.com"
$HTTP_Agent = _WinHttpOpen("Mozilla/5.0 (Windows NT 10.0; WOW64; rv:50.0) Gecko/20100101 Firefox/50.0")
$HTTP_Connect = _WinHttpConnect($HTTP_Agent, $HTTP_Host)
$hSession = _WinHttpOpen("Mozilla/5.0 (Windows NT 6.1; WOW64; rv:5.0) Gecko/20100101 Firefox/5.0")
$hConnect = _WinHttpConnect($hSession, "www.gtlpins.com")
$quelle = _Easy_WinHttp("GET", "/Aroma/Login.aspx")
$iresult1 = StringRegExp($quelle, '<input type="hidden" name="__VIEWSTATE" id="__VIEWSTATE" value="(.*?)" />', 3)
$iresult2 = StringRegExp($quelle, '<input type="hidden" name="__EVENTVALIDATION" id="__EVENTVALIDATION" value="(.*?)" />', 3)
$sHTML = _WinHttpSimpleRequest($hConnect, "POST", "/Aroma/Login.aspx", "http://www.gtlpins.com/Aroma/Login.aspx", "__EVENTTARGET=&__EVENTARGUMENT=&__VIEWSTATE="&$iresult1[0]&"&__EVENTVALIDATION="&$iresult2[0]&"&txtUserName=zensiert&txtPassword=zensiert&loginbtnlogin=Anmelden")
FileWrite("Test1.html", $sHTML)
_WinHttpCloseHandle($hConnect)
_WinHttpCloseHandle($hSession)
Func _Easy_WinHttp($sType = "GET", $sPage = "/", $sPost = "")
	$HTTP_Request = _WinHttpOpenRequest($HTTP_Connect, $sType, $sPage, "HTTP/1.1", $HTTP_Host)
	If StringLen($sPost) Then
		_WinHttpSendRequest($HTTP_Request, "Content-Type: application/x-www-form-urlencoded" & @CRLF, $sPost)
	Else
		_WinHttpSendRequest($HTTP_Request)
	EndIf
	_WinHttpReceiveResponse($HTTP_Request)
	$HTML = ""
	Do
		$HTML &= _WinHttpReadData($HTTP_Request)
	Until @error
	_WinHttpCloseHandle($HTTP_Request)
	Return $HTML
EndFunc   ;==>_Easy_WinHttp

Alles anzeigen

Quelltext vom Ergebnis:

Spoiler anzeigen

HTML: Test1

<!DOCTYPE html>
<html>
    <head>
        <title>Runtime Error</title>
        <meta name="viewport" content="width=device-width" />
        <style>
         body {font-family:"Verdana";font-weight:normal;font-size: .7em;color:black;} 
         p {font-family:"Verdana";font-weight:normal;color:black;margin-top: -5px}
         b {font-family:"Verdana";font-weight:bold;color:black;margin-top: -5px}
         H1 { font-family:"Verdana";font-weight:normal;font-size:18pt;color:red }
         H2 { font-family:"Verdana";font-weight:normal;font-size:14pt;color:maroon }
         pre {font-family:"Consolas","Lucida Console",Monospace;font-size:11pt;margin:0;padding:0.5em;line-height:14pt}
         .marker {font-weight: bold; color: black;text-decoration: none;}
         .version {color: gray;}
         .error {margin-bottom: 10px;}
         .expandable { text-decoration:underline; font-weight:bold; color:navy; cursor:hand; }
         @media screen and (max-width: 639px) {
          pre { width: 440px; overflow: auto; white-space: pre-wrap; word-wrap: break-word; }
         }
         @media screen and (max-width: 479px) {
          pre { width: 280px; }
         }
        </style>
    </head>
    <body bgcolor="white">
            <span><H1>Server Error in '/aroma' Application.<hr width=100% size=1 color=silver></H1>
            <h2> <i>Runtime Error</i> </h2></span>
            <font face="Arial, Helvetica, Geneva, SunSans-Regular, sans-serif ">
            <b> Description: </b>An application error occurred on the server. The current custom error settings for this application prevent the details of the application error from being viewed remotely (for security reasons). It could, however, be viewed by browsers running on the local server machine.
            <br><br>
            <b>Details:</b> To enable the details of this specific error message to be viewable on remote machines, please create a <customErrors> tag within a "web.config" configuration file located in the root directory of the current web application. This <customErrors> tag should then have its "mode" attribute set to "Off".<br><br>
            <table width=100% bgcolor="#ffffcc">
               <tr>
                  <td>
                      <code><pre>
<!-- Web.Config Configuration File -->
<configuration>
    <system.web>
        <customErrors mode="Off"/>
    </system.web>
</configuration></pre></code>
                  </td>
               </tr>
            </table>
            <br>
            <b>Notes:</b> The current error page you are seeing can be replaced by a custom error page by modifying the "defaultRedirect" attribute of the application's <customErrors> configuration tag to point to a custom error page URL.<br><br>
            <table width=100% bgcolor="#ffffcc">
               <tr>
                  <td>
                      <code><pre>
<!-- Web.Config Configuration File -->
<configuration>
    <system.web>
        <customErrors mode="RemoteOnly" defaultRedirect="mycustompage.htm"/>
    </system.web>
</configuration></pre></code>
                  </td>
               </tr>
            </table>
            <br>
    </body>
</html>

Alles anzeigen

Wenn ich noch irgendwas ergänzen solle einfach sagen

misterspeed

Eine mögliche Ursache könnte sein, dass dein Benutzername oder Passwort Zeichen enthält, welche mit der URI Syntax kolidieren. Das kaufmännische UND "&" wäre z.B. solch ein Zeichen, aber auch etliche andere Zeichen können Probleme bereiten. Deswegen solltest du deine variablen Strings wie Benutzername und Passwort zunächst sauber URL encoden.

Hier findest du z.B. einen Generator um manuell zu prüfen ob das dein Problem löst:
https://url-encoder.de/

Besser wäre es aber wenn du dir eine Funktion schreibst die diese Codierung übernimmt. Eine Tabelle der wichtigsten Zeichnersetzungen findest du z.B. hier:
http://www.user-archiv.de/url-escape-sequenzen.html

EDIT:
Außerdem solltest du Debugging betreiben, sprich lass dir auch mal den Quelltext der Loginseite ausgeben und das Ergebnis deiner RegEx Suche. Evtl. liegt ja auch da der Fehler.

blackcho

Danke dir für deine Antwort.
Also Debugging betreibe ich sowieso schon. Dort noch keinen Fehler finden können.

Habe es nun auch mit einem Encoder versucht Ergebnis bleibt das selbe
Finde ich echt Schade...
Neuer Versuch:

Spoiler anzeigen

C

#include <WinHTTP.au3>
#include <Array.au3>
Local $aChars[29][2] = [['?','%3F'], _
                       ['Ä','%C4'], _
                       ['Ü','%DC'], _
                       ['Ö','%D6'], _
                       ['ä','%E4'], _
                       ['ü','%FC'], _
                       ['ö','%F6'], _
                       ['ß','%DF'], _
                       [' ','+'], _
                       ['/','%2F'], _
                       [';','%3B'], _
                       ['"','%22'], _
                       ['(','('], _
                       [')',')'], _
                       ["'",'%2C'], _
                       ['.','%2E'], _
                       [':','%3A'], _
                       ['<','%3C'], _
                       ['>','%3E'], _
                       ['@','%40'], _
                       ['[','%5B'], _
					   ['=','%3D'], _
                       [']','%5D'], _
                       ['\','%5C'], _
                       ['^','%5E'], _
                       ['{','%7B'], _
                       ['}','%7D'], _
                       ['|','%7C'], _
                       ['#','%23']] ;
$HTTP_Host = "www.gtlpins.com"
$HTTP_Agent = _WinHttpOpen("Mozilla/5.0 (Windows NT 10.0; WOW64; rv:50.0) Gecko/20100101 Firefox/50.0")
$HTTP_Connect = _WinHttpConnect($HTTP_Agent, $HTTP_Host)
$hSession = _WinHttpOpen("Mozilla/5.0 (Windows NT 6.1; WOW64; rv:5.0) Gecko/20100101 Firefox/5.0")
$hConnect = _WinHttpConnect($hSession, "www.gtlpins.com")
$quelle = _Easy_WinHttp("GET", "/Aroma/Login.aspx")
$iresult1 = StringRegExp($quelle, '<input type="hidden" name="__VIEWSTATE" id="__VIEWSTATE" value="(.*?)" />', 3)
$iresult2 = StringRegExp($quelle, '<input type="hidden" name="__EVENTVALIDATION" id="__EVENTVALIDATION" value="(.*?)" />', 3)
For $i = 0 To UBound($aChars) - 1 Step 1
If StringRegExp($iresult1[0],$aChars[$i][0]) = 1 Then
   $iresult1[0] = StringReplace($iresult1[0],$aChars[$i][0], $aChars[$i][1])
EndIf
If StringRegExp($iresult2[0],$aChars[$i][0]) = 1 Then
   $iresult2[0] = StringReplace($iresult2[0],$aChars[$i][0], $aChars[$i][1])
EndIf
Next
$sString = "__EVENTTARGET=&__EVENTARGUMENT=&__VIEWSTATE="&$iresult1[0]&"&__EVENTVALIDATION="&$iresult2[0]&"&txtUserName=Zensur&txtPassword=Zensur&loginbtnlogin=Anmelden"
ClipPut($sString)
$sHTML = _WinHttpSimpleRequest($hConnect, "POST", "/Aroma/Login.aspx", "http://www.gtlpins.com/Aroma/Login.aspx",$sString)
FileWrite("Test1.html", $sHTML)
_WinHttpCloseHandle($hConnect)
_WinHttpCloseHandle($hSession)
Func _Easy_WinHttp($sType = "GET", $sPage = "/", $sPost = "")
	$HTTP_Request = _WinHttpOpenRequest($HTTP_Connect, $sType, $sPage, "HTTP/1.1", $HTTP_Host)
	If StringLen($sPost) Then
		_WinHttpSendRequest($HTTP_Request, "Content-Type: application/x-www-form-urlencoded" & @CRLF, $sPost)
	Else
		_WinHttpSendRequest($HTTP_Request)
	EndIf
	_WinHttpReceiveResponse($HTTP_Request)
	$HTML = ""
	Do
		$HTML &= _WinHttpReadData($HTTP_Request)
	Until @error
	_WinHttpCloseHandle($HTTP_Request)
	Return $HTML
EndFunc   ;==>_Easy_WinHttp

Alles anzeigen

misterspeed

Warum verwendest du eigentlich 2 verschiedene Browserkennungen und 2 Sessions? Sehr wahrscheinlich ändert sich beim erzeugen einer Session auch der Variable Wert beider Strings die du aus dem Quellcode der Loginseite kopierst. Deine "Session keys" aus dem Quellcode sind also vermutlich nicht mehr gültig wenn du dein Login Post mit der zweiten Session absendest.

Ein URL Encode dieser beiden Strings ist vermutlich nicht notwendig, da diese schon korrekt formatiert sein dürften. Meine Anmerkung bezog sich primär auf deine eigenen Daten, sprich Passwort und Benutzername.

blackcho

Ooo Stimmt.
Klappt leider trotzdem nicht.

gmmg

Benutze doch mal das Plugin HTTP Requester und schau dir das Tracking an.

hier kannst du auch mal schauen. HTTP Post absenden - WinHTTP.au3

Gruß gmmg

blackcho

Ne bekomme es einfach nicht auf die Reihe...

Aktueller AutoIT Code:

Spoiler anzeigen

AutoIt

#include <WinHTTP.au3>
#include <Array.au3>
Local $aChars[29][2] = [['?','%3F'], _
                       ['Ä','%C4'], _
                       ['Ü','%DC'], _
                       ['Ö','%D6'], _
                       ['ä','%E4'], _
                       ['ü','%FC'], _
                       ['ö','%F6'], _
                       ['ß','%DF'], _
                       [' ','+'], _
                       ['/','%2F'], _
                       [';','%3B'], _
                       ['"','%22'], _
                       ['(','('], _
                       [')',')'], _
                       ["'",'%2C'], _
                       ['.','%2E'], _
                       [':','%3A'], _
                       ['<','%3C'], _
                       ['>','%3E'], _
                       ['@','%40'], _
                       ['[','%5B'], _
					   ['=','%3D'], _
                       [']','%5D'], _
                       ['\','%5C'], _
                       ['^','%5E'], _
                       ['{','%7B'], _
                       ['}','%7D'], _
                       ['|','%7C'], _
                       ['#','%23']] ;
$oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
$oHTTP.Open("POST", "http://www.gtlpins.com/Aroma/Login.aspx", False)
$oHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")
$oHTTP.Send()
$oReceived = $oHTTP.ResponseText
$iresult1 = StringRegExp($oReceived, '<input type="hidden" name="__VIEWSTATE" id="__VIEWSTATE" value="(.*?)" />', 3)
$iresult2 = StringRegExp($oReceived, '<input type="hidden" name="__EVENTVALIDATION" id="__EVENTVALIDATION" value="(.*?)" />', 3)
For $i = 0 To UBound($aChars) - 1 Step 1
If StringRegExp($iresult1[0],$aChars[$i][0]) = 1 Then
   $iresult1[0] = StringReplace($iresult1[0],$aChars[$i][0], $aChars[$i][1])
EndIf
If StringRegExp($iresult2[0],$aChars[$i][0]) = 1 Then
   $iresult2[0] = StringReplace($iresult2[0],$aChars[$i][0], $aChars[$i][1])
EndIf
Next
$sString = "__EVENTTARGET=&__EVENTARGUMENT=&__VIEWSTATE="&$iresult1[0]&"&__EVENTVALIDATION="&$iresult2[0]&"&txtUserName=Zensur&txtPassword=Zensur&loginbtnlogin=Anmelden"
$oHTTP.Send($sString)
$oReceived2 = $oHTTP.ResponseText
If Not StringRegExp($oReceived2,"<span><H1>Server Error in '/aroma' Application.<hr width=100% size=1 color=silver></H1>")   = 1 Then
MsgBox(0,"t","t")
EndIf
$oStatusCode = $oHTTP.Status
;~ FileWrite($file, $oReceived)
FileWrite("Antwort.html", $oReceived2)
FileWrite("Antwort.html",$sString)
;~ ClipPut($sString)

Alles anzeigen

Ich weiß einfach nicht woran es liegt was ich falsch mache wieso es nicht klappt:(

**alpines**

Probiers mal hiermit, wenns nicht klappt kannst du mir gerne die Userdaten per PN zuschicken und ich bastel dir da einen Login dazu.
Eventuell musst du noch deinen URL-Formatierer hinzufügen aber ich glaube das WinHttp das automatisch encodet.

blackcho

Werde ich morgen testen
Danke

**alpines**

Ich habs nochmal ein bisschen verändert weil WinHttp das ganze doch nicht selbstständig kodiert.
Kannst dir ja mal meine Encode-Funktion anschauen, die nutzt den Trick mit einer For-Loop und der Ascii-Tabelle aus statt alle Zeichen per Hand einzutippen.

Der Code hier unten funktioniert, die HTML Datei die mir ausgespuckt wird sagt das der User Login nicht existiert (steht auch im Source). Ich denke mal wenn du deine Daten eintippst wird das schon funktionieren.

AutoIt

#include <WinHttp.au3>
#include <String.au3>


Global Const $S_USERNAME = "test", $S_PASSWORD = "1234"


$hSession = _WinHttpOpen()
$hConnect = _WinHttpConnect($hSession, "www.gtlpins.com")


$sHTML = _WinHttpSimpleRequest($hConnect, "GET", "Aroma/Login.aspx")


$aEventTarget = StringRegExp($sHTML, "<input type=""hidden"" name=""__EVENTTARGET"" id=""__EVENTTARGET"" value=""(.*?)"" \/>", 3)
$aEventArgument = StringRegExp($sHTML, "<input type=""hidden"" name=""__EVENTARGUMENT"" id=""__EVENTARGUMENT"" value=""(.*?)"" \/>", 3)
$aViewState = StringRegExp($sHTML, "<input type=""hidden"" name=""__VIEWSTATE"" id=""__VIEWSTATE"" value=""(.*?)"" \/>", 3)
$aEventValidation = StringRegExp($sHTML, "<input type=""hidden"" name=""__EVENTVALIDATION"" id=""__EVENTVALIDATION"" value=""(.*?)"" \/>", 3)


If Not UBound($aEventTarget) or Not UBound($aEventArgument) or Not UBound($aViewState) or Not UBound($aEventValidation) Then
	MsgBox(16, "Fehler", "Parameter für Post konnten nicht geparst werden!")
	Exit
EndIf


$sPostData = "__EVENTTARGET=" & _Http_StringToHex($aEventTarget[0]) & _
			 "&__EVENTARGUMENT=" & _Http_StringToHex($aEventArgument[0]) & _
			 "&__VIEWSTATE=" & _Http_StringToHex($aViewState[0]) & _
			 "&__EVENTVALIDATION=" & _Http_StringToHex($aEventValidation[0]) & _
			 "&txtUserName=" & _Http_StringToHex($S_USERNAME) & _
			 "&txtPassword=" & _Http_StringToHex($S_PASSWORD) & _
			 "&loginbtnlogin=Anmelden"


$sHTML = _WinHttpSimpleRequest($hConnect, "POST", "Aroma/Login.aspx", Default, $sPostData)


FileDelete("debug.html")
FileWrite("debug.html", $sHTML)


_WinHttpCloseHandle($hConnect)
_WinHttpCloseHandle($hSession)


Func _Http_StringToHex($sString, $iMode = 0)
	$sString = StringReplace($sString, "%", "%25")


	For $iChar = 32 To 126
		If $iChar = 37 Then ContinueLoop
		If $iChar = 48 Then $iChar = 58
		If $iChar = 65 Then $iChar = 91
		If $iChar = 97 Then $iChar = 123


		$sString = StringReplace($sString, Chr($iChar), "%" & _StringToHex(Chr($iChar)))
	Next


	Return $sString
EndFunc

Alles anzeigen

blackcho

Danke dir es hat geklappt.
Habe leider gerade nicht die Zeit zu aber werde mir später anschauen was ich falsch gemacht habe.
Bin dir wirklich sehr dankbar.

**alpines**

Gern geschehen, ich nehme mal an das es an der Kodierung lag. Setz doch bitte den grünen Haken damit dein Thread als [gelöst] gilt. (1. Beitrag bearbeiten)