Befehl "hidden" ausführen

AutoItler

Hallo,
um die Internetspuren zu löschen, verwende ich meinem Script folgende Anweisung:

AutoIt

ShellExecute('RunDll32.exe', 'InetCpl.cpl,ClearMyTracksByProcess 255', @SystemDir, 'open', @SW_HIDE)

Der Aufruf macht auch, was er machen soll. Nur leider wird immer das Fenster mit dem Fortschrittsbalken angezeigt, was ich eben nicht möchte.
Ich habe es mit dem 'Run'-Befehl, leider ebenso erfolglos, versucht.
Wie kann ich es anstellen, dass das Fenter mit dem Fortschritsbalken unsichtbar bleibt. Ich weiß, das ist nicht unbedingt für die Scriptausführung notwendig; ich möchte es halt nur eben so.

Ich bedanke mich schon mal für Eure Ideen.

Hingo

Versuchs mal mit nem Minimize:
WinSetState ( "title", "text", flag )

**BugFix**

Verwende Run - da bekommst du die PID und kannst damit das zugehörige Fenster ermitteln. Hast du das Fensterhandle, kannst du es ganz normal ausblenden.

AutoItler

(Hingo)
Also "WinSetState('Fenstertitel')" funktioniert leider nicht. Hab vergessen zu erwähnen, dass ich dies bereits probiert hatte. Entschuldigung.

(BugFix)
Die PID von "Run()" bezieht sich auf den Prozess 'RunDll32.exe'. RunDll32.exe ist bereits ein fensterloser Prozess.
Die Ansicht des Fensters mit dem Fortschrittsbalken muss aus dem Aufruf von 'InetCpl.cpl,ClearMyTracksByProcess xxx' kommen.

Leider funktioneren Eure Vorschläge in diesm Fall nicht. Trotzdem vielen Dank für die Mühen.

**alpines**

Wenn WinSetState nicht funktioniert kannst du es ja außerhalb des Sichtbereiches verschieben?

AutoItler

Vielen Dank "alpines". Nur leider bekomme ich (leider) aus dem Script heraus überhaupt keinen Zugriff auf dies Fenster mit dem Fortschrittsbalken.
Das heißt, ich kann das Fenster auch nicht verschieben - Es wäre übrigens eine glänzende Idee gewesen.

**alpines**

Vielleicht kannst du ja recherchieren was die Funktion exakt macht und die Änderungen selber übernehmen (FileDelete etc).

BananaJoe

Probier mal das:

AutoIt

Opt("WinTitleMatchMode", 2)


ShellExecute('RunDll32.exe', 'InetCpl.cpl,ClearMyTracksByProcess 255', @SystemDir, 'open', @SW_HIDE)


If Winwait('Browserverlauf', '', 10) <> 0 Then
	WinSetState('Browserverlauf', '', @SW_MINIMIZE)
EndIf

**Bitnugger**

AutoIt

Run('RunDll32.exe InetCpl.cpl,ClearMyTracksByProcess 255', @SystemDir, @SW_HIDE)
If WinSetState(WinWait('Browserverlauf'), '', @SW_MINIMIZE) = 0 Then ConsoleWrite('Fehler bei Run()!' & @CRLF)

**chesstiger**

@BananaJoe, @Bitnugger
Vorsicht bei solchen Lösungen. Das ist alles andere als sauber. Da nach einem Fenster mit Titel "Browserverlauf" gesucht wird, funktioniert diese Variante nur bei deutschsprachigen Windows-Installationen.

**alpines**

Zitat von chesstiger

Vorsicht bei solchen Lösungen. Das ist alles andere als sauber. Da nach einem Fenster mit Titel "Browserverlauf" gesucht wird, funktioniert diese Variante nur bei deutschsprachigen Windows-Installationen.

Ich denke, das ist das geringste aller Probleme.

**chesstiger**

@alpines
Sei dir da mal nicht so sicher... Ich habe da schon ziemlich schlechte Erfahrungen mit gemacht. Wir hatten in der Firma plötzlich mal ein englisches Windows, weil ein Mitarbeiter bei der Installation gepennt hat. Zack, Hälfte der Skripte zur Erleichterung des Arbeitsalltags läuft nicht mehr. Ich habe danach dann alles überarbeiten müssen, was mein Vorgänger auf diese Art und Weise realisiert hat. Deswegen bin ich da recht empfindlich. Und der Mehraufwand, eben mal per Window Info Tool die benötigten Daten auszulesen, ist ja nahezu null. Von daher...

**Bitnugger**

Zitat von chesstiger

Vorsicht bei solchen Lösungen. Das ist alles andere als sauber. Da nach einem Fenster mit Titel "Browserverlauf" gesucht wird, funktioniert diese Variante nur bei deutschsprachigen Windows-Installationen.

Damit hast du vollkommen Recht, zumindest dann, wenn das Script auch von anderen Leuten benutzt wird.

Hier also eine Lösung, bei der die Locale beachtet wird...

AutoIt

#include <WinAPI.au3>


Run('RunDll32.exe InetCpl.cpl,ClearMyTracksByProcess 255', @SystemDir, @SW_HIDE)
If WinSetState(WinWait('[CLASS:#32770; TITLE:' & _WinAPI_LoadString(_WinAPI_LoadLibraryEx(@SystemDir & '\InetCpl.cpl', $LOAD_LIBRARY_AS_DATAFILE), 1657) & ']', '', 5), '', @SW_MINIMIZE) = 0 Then _
	ConsoleWrite('Fehler bei Run()!' & @CRLF)

AutoItler

Vielen Dank für all Eure Gedanken und Hinweise.
Es ist tatsächlich so, dass dieses Script nur auf meinem PC (Laptop) laufen wird. Da beide Geräte deutschsprachig sind, besteht in dieser Richtung, wie von 'chesstiger' befürchtet, kein Problem.

Deine Lösung, 'Bitnugger' ist perfekt und funktioniert. Bloß, wie kommt man denn auf solche Lösungswege?.
Ehrfurchtsvoll stelle ich fest, dass ich noch 'ne Menge lernen muss.
Vielen Dank nochmals und einen schönen Tag für alle, die sich hier beteiligt haben.

**Bitnugger**

Zitat von AutoItler

Deine Lösung, 'Bitnugger' ist perfekt und funktioniert. Bloß, wie kommt man denn auf solche Lösungswege?

Das ist eigentlich sehr einfach... gesucht hatte ich in der Hilfe nach *locale* (Haken bei "Nur Titel suchen" setzen), um mir dann die gefunden WinAPI-Funktionen unter die Lupe zu nehmen. Direkt bei der ersten von mir ausgesuchten Funktion hatte ich dann bereits die Lösung vor Augen: _WinAPI_GetThreadLocale(). Das Beispiel anschauen... der Rest ist dann quasi selbsterklärend...

LoadString()

AutoIt

;-- TIME_STAMP   2017-03-21 13:14:56   v 0.1


#include <Array.au3>
#include <APILocaleConstants.au3>
#include <APIResConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPI.au3>
#include <WinAPILocale.au3>
#include <WinAPIRes.au3>
#include <WinAPISys.au3>


;~ #include <WinAPI.au3>


Local $hInstance = _WinAPI_LoadLibraryEx('InetCpl.cpl', $LOAD_LIBRARY_AS_DATAFILE)
If Not $hInstance Then
	MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Error', 'InetCpl.cpl not found.')
	Exit
EndIf


; Get the language (locale) identifier for the current process
Local $iPrev, $GetLocale, $SetLocale
;~ If _WinAPI_GetVersion() >= '6.0' Then <-- Was für ein Quatsch... denn bei einem Stringvergleich ist "10.0" < "6.0" und somit "Windows 10" < "Windows Longhorn"!!!
ConsoleWrite('! _WinAPI_GetVersion() liefert als Ergebnis: ' & VarGetType(_WinAPI_GetVersion()) & @CRLF & _
	'! Vergleichen werden muss also so:' & @CRLF & _
	'> If _WinAPI_GetVersion() >= 6.0 Then ' & @CRLF & _
	'> If ' & _WinAPI_GetVersion() & " >= " & 6.0 & ' Then' & @CRLF & @CRLF)
; Das kennst du ja bereits... ;-)
If _WinAPI_GetVersion() >= 6.0 Then
	$GetLocale = _WinAPI_GetThreadUILanguage
	$SetLocale = _WinAPI_SetThreadUILanguage
Else
	$GetLocale = _WinAPI_GetThreadLocale
	$SetLocale = _WinAPI_SetThreadLocale
EndIf
$iPrev = $GetLocale()


; Why is the resource name for the string with ID = 6000 is 376? 6000 / 16 + 1 = 376
Local $aData = _WinAPI_EnumResourceLanguages($hInstance, $RT_STRING, 376)
If Not @error Then
	For $i = 1 To $aData[0]
;~ 		If _WinAPI_GetVersion() >= '6.0' Then
;~ 			_WinAPI_SetThreadUILanguage($aData[$i])
;~ 		Else
;~ 			_WinAPI_SetThreadLocale($aData[$i])
;~ 		EndIf
		$SetLocale($aData[$i])
		ConsoleWrite(StringFormat('+ %-10s - %s', _WinAPI_GetLocaleInfo($aData[$i], $LOCALE_SENGLANGUAGE), _WinAPI_LoadString($hInstance, 6000)) & @CRLF)
		If $aData[$i] = 1031 Then	; German - International
			Local $j = -1, $idMatch = -1, $k = FileGetSize(@SystemDir & '\InetCpl.cpl')
			Do
				$j += 1
				If StringLeft(_WinAPI_LoadString($hInstance, $j), 22) = 'Browserverlauf löschen' Then $idMatch = $j
			Until $idMatch > -1 Or $j > $k
			ConsoleWrite('- Bingo... --> $idMatch = ' & $idMatch & ' --> "' & _WinAPI_LoadString($hInstance, $j) & '"' & @CRLF & @CRLF)
		EndIf
	Next
EndIf


; Restore the previous language for the current process
;~ If _WinAPI_GetVersion() >= '6.0' Then
;~ 	_WinAPI_SetThreadUILanguage($iPrev)
;~ Else
;~ 	_WinAPI_SetThreadLocale($iPrev)
;~ EndIf
$SetLocale($iPrev)

Alles anzeigen