Ordner/Dateien verpacken mit Progressbar

dieselwiesel

Hi @all

Beschäftige mich seit langem mal wieder mit AutoIt und möchte eine Backup Funktion in ein Programm einbauen. Die soll "lediglich" ein paar Ordner/Dateien mit Progressbar in ein Archiv packen, welches sich möglichst mit Windows Bordmitteln entpacken lässt. Hab schon ein paar Bsp. gefunden, die entweder nicht funktioniert haben, oder sich nicht wie gewünscht integrieren lassen. Hat jmd. ne Idee nach was man so suchen kann? Danke im Voraus!

**Musashi**

Hallo @dieselwiesel !

Ich gehe mal davon aus, dass Du keine Progressbar im Stil 'marquee' (also das Zylonenauge) möchtest.

Ich habe mir für eine ähnliche Anforderung mal eine sehr einfache Lösung erstellt.

Das GUIElement wird erstellt über :
$idProgressbar = GUICtrlCreateProgress(10, 200, 500, 35) - Positionswerte bei Bedarf anpassen

Du kannst in einer Progressbar die Schrittweite angeben. Start ist bei 0, also 'leer'.

Voraussetzung für mein Beispiel ist, dass Du die Anzahl der Schritte vorher definiert hast (z.B. 10).
$iProgressStepMax = Max. Anzahl der Schritte

$iProgressStepCount = Aktueller Schritt

Nachdem der erste Schritt (z.B. das Kopieren eines Verzeichnisses) beendet ist, erhöhst Du den Schrittzähler um 1, und zeigst den neuen Zustand der Progressbar an :
$iProgressValue = Round ( (100/$iProgressStepMax) * $iProgressStepCount)

GUICtrlSetData($idProgressbar, $iProgressValue)
$iProgressStepCount = $iProgressStepCount + 1
usw.

Leider muss ich jetzt zu meiner Skatrunde.
Ich bin sicher, dass @alpines, @BugFix, @Bitnugger u. A. wesentlich bessere Beispiele liefern werden, oder, während ich hier schreibe, bereits geliefert haben .
Falls Du trotzdem noch genauere Infos zu meiner Variante benötigst, dann melde Dich ruhig.

Gruß Musahi

**alpines**

Zitat von Musashi

Nachdem der erste Schritt (z.B. das Kopieren eines Verzeichnisses) beendet ist, erhöhst Du den Schrittzähler um 1, und zeigst den neuen Zustand der Progressbar an :

Das kann bei großen Verzeichnissen den Eindruck erwecken, dass das Programm eingefroren ist.
Besser wäre es, wenn man nach jeder Datei die ProgressBar aktualisiert. Da muss man auch nicht eine Schrittweite oder ähnliches definieren sondern nimmt einfach die Anzahl der verarbeiteten Dateien geteilt durch die Anzahl aller Dateien.

**Bitnugger**

Oder so...

_CopyWhithProgress

AutoIt

;-- TIME_STAMP   2017-05-12 21:48:19


#Region    ;************ Includes ************
#include-once
#Include <FileConstants.au3>
#include <WinAPIShPath.au3>
#EndRegion ;************ Includes ************


Local $iCopy = Example()
If @error Then MsgBox(262160, '_CopyWhithProgress', "$iCopy --> " & $iCopy & @CRLF & "!@ " & @TAB & "#Error: " & @error & @TAB & "#Extended: " & @extended & @CRLF)


Func Example()
	Local $sCopyFrom = FileOpenDialog('Was soll kopiert werden?', @DesktopDir, 'All (*.*)', $FD_PATHMUSTEXIST) ; $hWnd)
	If @error Then Return SetError(@error +1, 1, '$sCopyFrom = ' & $sCopyFrom)
	Local $sCopyTo   = FileSaveDialog('Wohin soll es kopiert werden?', @DesktopDir, 'All (*.*)', $FD_PATHMUSTEXIST, StringInStr(FileGetAttrib($sCopyFrom), 'D') ? $sCopyFrom : _WinAPI_PathStripPath($sCopyFrom)) ; $hWnd)
	If @error Then Return SetError(@error +2, 2, '$sCopyTo = ' & $sCopyTo)


	_CopyWhithProgress($sCopyFrom, $sCopyTo)
	If @error Then Return SetError(@error +3, 3, '_FileCopy()')
EndFunc


; Windows - copy with progress
; Author - JdeB


;~    4 Do not display a progress dialog box.
;~    8 Give the file being operated on a new name in a move, copy, or rename operation if a file with the target name already exists.
;~   16 Respond with "Yes to All" for any dialog box that is displayed.
;~   64 Preserve undo information, if possible.
;~  128 Perform the operation on files only if a wildcard file name (*.*) is specified.
;~  256 Display a progress dialog box but do not show the file names.
;~  512 Do not confirm the creation of a new directory if the operation requires one to be created.
;~ 1024 Do not display a user interface if an error occurs.
;~ 2048 Version 4.71. Do not copy the security attributes of the file.
;~ 4096 Only operate in the local directory. Don't operate recursively into subdirectories.
;~ 8192 Version 5.0. Do not copy connected files as a group. Only copy the specified files.
Func _CopyWhithProgress($sCopyFrom, $sCopyTo)
    Local $FOF_RESPOND_YES = 16
    Local $FOF_SIMPLEPROGRESS = 256
    $oShell = ObjCreate("shell.application")
	If Not IsObj($oShell) Then Return SetError(3, 3, '$oShell = ' & $oShell)


	Local $iDirCreate, $sCopyTargetDir = StringInStr(FileGetAttrib($sCopyTo), 'D') ? $sCopyTo : _WinAPI_PathStripPath($sCopyTo)
	If Not FileExists($sCopyTargetDir) Then $iDirCreate = DirCreate($sCopyTargetDir)
	If $iDirCreate = 0 Then Return SetError(4, 4, '$iDirCreate = ' & $iDirCreate)


    $oShell.namespace($sCopyTo).CopyHere($sCopyFrom, $FOF_RESPOND_YES)


	Return True
EndFunc

Alles anzeigen

_CopyWhithProgress.png

**autoiter**

Hi @Bitnugger,
danke für den Code. Darüber freue ich mich auch.

dieselwiesel

Danke erstmal für Eure Antworten!!!

Ich habe ein Bsp. von UEZ gefunden, dass eigentlich recht gut funktioniert u. auch den Zweck erfüllt

Spoiler anzeigen

AutoIt

;coded by UEZ 2013


#include <Constants.au3>
Global Const $sPath7Zip = '"c:\Program Files\7-Zip\7z.exe"'
Global $sFiles = '"c:\Temp"'
Global $sArchive = '"c:\Test.7z"'


SevenZipAdd($sFiles, $sArchive)


Func SevenZipAdd($sFiles, $sArchive)
    Local $iMax = GetAmountFF($sFiles)
    Local $iPID = Run($sPath7Zip & " a " & $sArchive & " -r " & $sFiles, @ScriptDir, @SW_HIDE, $STDERR_MERGED)
    Sleep(50)
    Local $sConsole, $sLine, $iUB
    ProgressOn("Progress Meter", "Adding to archive", "0 % (0 / " & $iMax & ")")
    Do
        $sConsole &= StdoutRead($iPID)
        If @error Then ExitLoop
        $aResult = StringRegExp($sConsole, "(Compressing\h+.*)", 3)
        $iUB = UBound($aResult)
        $iPerc = Int($iUB / $iMax * 100)
        ProgressSet($iPerc, $iPerc & " % (" & UBound($aResult) & " / " & $iMax & ")")
    Until Not Sleep(10)
    ProgressOff()
EndFunc




Func GetAmountFF($sPath)
    Local $iPID = Run(@ComSpec & " /c dir /b /s " & $sPath, @ScriptDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
    Sleep(50)
    Local $sConsole
    Do
        $sConsole &= StdoutRead($iPID)
        If @error Then ExitLoop
    Until Not Sleep(10)
    StringReplace($sConsole, @CRLF, @CRLF)
    Return @extended + 1
EndFunc

Alles anzeigen

Allerdings hab ich noch ein Problem damit die Anzahl der Dateien für $iMax zu ermitteln, da ich nur 5 von 6 Ordnern sichern möchte. Dachte an _FileListToArrayRec() weil ich den einen Ordner übers Exclude auslassen kann, aber das liefert mir rund 250 Dateien weniger als es wirklich sind.

Spoiler anzeigen

AutoIt

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>
#include <Constants.au3>


	$ignorePath= "6" ;der Ordner den ich nicht brauche
Global $anzahl = _FileListToArrayRec("c:\myprog\", "*||" & $ignorePath, 0, 1, 1, 2)
	;_ArrayDisplay($anzahl)


;Global Const $sPath7Zip = '"c:\Program Files\7-Zip\7z.exe"' ;nicht sinvoll, besser 7z.exe (u. 7z.dll) per FileInstall in die @Systemdir bringen
Global $sFiles = 'c:\myprog\1 -i!c:\myprog\2 -i!c:\myprog\3 -i!c:\myprog\4 -i!c:\myprog\5'
Global $sArchive = '"c:\myprog.7z"'


SevenZipAdd($sFiles, $sArchive)


Func SevenZipAdd($sFiles, $sArchive)
    Local $iMax = $anzahl
    Local $iPID = Run("7z.exe a -r " & $sArchive & " " & $sFiles, @SystemDir, @SW_SHOW, $STDERR_MERGED)
    Sleep(50)
    Local $sConsole, $sLine, $iUB
    ProgressOn("Progress Meter", "Adding to archive", "0 % (0 / " & $iMax & ")")
    Do
        $sConsole &= StdoutRead($iPID)
        If @error Then ExitLoop
        $aResult = StringRegExp($sConsole, "(Compressing\h+.*)", 3)
        $iUB = UBound($aResult)
        $iPerc = Int($iUB / $iMax * 100)
        ProgressSet($iPerc, $iPerc & " % (" & UBound($aResult) & " / " & $iMax & ")")
    Until Not Sleep(10)
    ProgressOff()
EndFunc

Alles anzeigen

Irgendwelche Vorschläge?

dieselwiesel

So schauts jetzt aus, funktioniert auch...

Spoiler anzeigen

AutoIt

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>
#include <Constants.au3>




Local $sFolder = _FileListToArrayRec("c:\myprog", "*1;*2;*3;*4;*5||6", 2, 0, 1, 2) ;Prüfen welche von der vorgegebenen Ordnern überhaupt da sind bzw. der Auszuschließen ist
If @error Then
	MsgBox(0, "", "Keine Ordner gefunden.")
Else
	;_ArrayDisplay($sFolder)
	Local $aCount, $sInclude
	For $i = 1 To UBound($sFolder) - 1
		$sFiles = _FileListToArrayRec($sFolder[$i], "*", 1, 1, 1, 2) ; Anzahl der Dateien ermitteln
		;_ArrayDisplay($sFiles)
		If $sFiles[0] > Number("0") Then $aCount += $sFiles[0] ; Anzahl addieren
		$sInclude &= "-i!" & $sFolder[$i] & " " ; String für SevenZipAdd $aFiles erstellen
	Next


		If $aCount > Number("0") Then
			SevenZipAdd(StringTrimLeft($sInclude, 3), "C:\myprog.7z", $aCount)
		Else
			MsgBox(0,"", "Keine Dateien gefunden.")
		EndIf


EndIf




Func SevenZipAdd($aFiles, $sArchive, $sCount)
    Local $iMax = $sCount
    Local $iPID = Run("7z.exe a -r " & $sArchive & " " & $aFiles, @SystemDir, @SW_SHOW, $STDERR_MERGED)
    Sleep(50)
    Local $sConsole, $sLine, $iUB
    ProgressOn("Progress Meter", "Adding to archive", "0 % (0 / " & $iMax & ")")
    Do
        $sConsole &= StdoutRead($iPID)
        If @error Then ExitLoop
        $aResult = StringRegExp($sConsole, "(Compressing\h+.*)", 3)
        $iUB = UBound($aResult)
        $iPerc = Int($iUB / $iMax * 100)
        ProgressSet($iPerc, $iPerc & " % (" & UBound($aResult) & " / " & $iMax & ")")
    Until Not Sleep(10)
    ProgressOff()
EndFunc

Alles anzeigen

Verbesserungsvorschläge are welcome

**Bitnugger**

Zitat von dieselwiesel

Local $sFolder = _FileListToArrayRec("c:\myprog", "*1;*2;*3;*4;*5||6", 2, 0, 1, 2)

Wenn du bei $sMask die Verzeichnisse mit Include explizit angibst, ist es nicht nötig, ein Verzeichnis auf selber Ebene mit Exclude_Folders auszuschließen - sondern nur bei einem Unterverzeichnis innerhalb der Include.
Local $sFolder = _FileListToArrayRec("c:\myprog", "*1;*2;*3;*4;*5", 2, 0, 1, 2)

Sträflich ist jedoch: Du überprüfst gar nicht, ob 7z.exe einen Fehler meldet!

Hier mal eine etwas optimierte Version für dich...

_SevenZipAdd

AutoIt

#Region    ;************ Includes ************
#Include <File.au3>
#include <WinAPIShPath.au3>
#EndRegion ;************ Includes ************


;-- TIME_STAMP   2017-05-14 02:44:28   v 0.1


HotKeySet('{ESC}', '_Exit')


; Anzahl der zu archivierenden Dateien ermitteln
Local $sError, $aList = _FileListToArrayRec('c:\myprog', "*||*6", 1, 1, 1, 2)
If @error Then Exit MsgBox(262144, @ScriptName, '_FileListToArrayRec' & @CRLF & @CRLF & '#Error: ' & @error)
;~ _ArrayDisplay($aList, '$aList')


; ProgressBar einschalten
ProgressOn('Progress Meter', 'Adding to archive', StringFormat('%3i% (%3i / %3i)', 0, $aList[0]))
ProgressSet(0, StringFormat('%.2f%  (%3i / %3i)', 0, 0, $aList[0]))


; Dateien mit 7z.exe archivieren
For $i = 1 To $aList[0] Step 1
	; "c:\..." ? - unter Windows 10 kannst du hier als normaler User nicht schreiben...
	$sError = _SevenZipAdd($aList[$i], 'c:\myprog.7z', $aList[0])
	If @error Then Exit MsgBox(262144, @ScriptName, $sError)
Next


Sleep(3000)
ProgressOff()


Func _SevenZipAdd($sFile, $sArchiv, $iMax)
	Local Static $iPerc = 0, $iCount = 0


	$iPID = Run(StringFormat('7z.exe a -spf "%s" "%s"', $sArchiv, $sFile), '', @SW_HIDE, $STDERR_CHILD)
	ProcessWaitClose($iPID)
	Local $sError
	Do
		$sError &= StderrRead($iPID)
	Until @error
	If $sError <> '' Then Return SetError(1, 0, $sError)


	$iCount += 1
	$iPerc = 100 / $iMax * $iCount
	; Wenn du keine Nachkommastellen angezeigt haben willst, dann '%.2f%' in '%3i%' ändern!
	ProgressSet($iPerc, StringFormat('%.2f%  (%3i / %3i)', $iPerc, $iCount, $iMax), _WinAPI_PathCompactPath(WinGetHandle('[ACTIIVE]'), $sFile, 250))
;~ 	If $iPerc > 30 Then Exit
EndFunc


Func _Exit()
	Exit
EndFunc

Alles anzeigen

dieselwiesel

Ja, das Errorhandling und ich werden keine Freunde mehr Ich werd das von dir mal ausprobieren. Der -spf Befehl ist in dem 7z bei mir gar nicht gelistet und der packt dann auch "komisch" zusammen

**Musashi**

Zitat von dieselwiesel

Der -spf Befehl ist in dem 7z bei mir gar nicht gelistet und der packt dann auch "komisch" zusammen.

Hallo @dieselwiesel !

Mit dem '-spf' Switch wird der komplette Dateipfad inklusive Laufwerksbuchstabe im Archiv gespeichert, also der absolute Pfad, nicht der relative Pfad. Wenn Du die Zip-Datei per Doppelklick öffnest, dann fängt die Dateiliste mit dem Laufwerksbuchstaben an, also z.B. C:. Sieht etwas ungewohnt aus, vermeidet aber mögliche Probleme mit 'duplicate names'.
Ggf. kann man den Switch einfach weglassen, aber das soll @Bitnugger beurteilen.

Wenn '-spf' bei Dir nicht als Parameter aufgeführt ist, dann prüfe mal Deine Version von 7-Zip.
Der Switch '-spf' wurde lt. Changelog in Version 9.25 alpha (Sept. 2011) eingeführt.
Eventuell nutzt Du die ältere Version 9.20 (von 2010) - die ist immer noch recht verbreitet.

Aktuelle Version (stable) = 7-Zip 16.04 (04.10.2016) :
Beim Download von der 7-Zip Website den Link :
x86/x64 -> 7-Zip Extra: standalone console version, 7z DLL, Plugin for Far Manager
wählen.

Ich verwende die Variante 7za.exe (a=alone), also die 'standalone' Version von 7-Zip. Sie unterstützt zwar weniger Formate (7z, lzma, cab, zip, gzip, bzip2 und tar), benötigt dafür aber keine externen DLLs.
Das Kommandozeileninterface von 7za.exe und 7z.exe sind identisch.

@Bitnugger : Auch von mir ein Danke für das elegante Beispiel.

Gruß Musashi

dieselwiesel

Ja, das mit den absoluten Pfaden meinte ich mit komisch. Hab die 9.38 beta im Einsatz. Nutze sonst eig. WinRAR, aber ZIP Dateien kann man mit Windows Bordmitteln entpacken.

Das mit der 7za.exe ist ne sehr gute Idee, aber für was sind dann die 7za.dll und 7zxa.dll dabei? Gibts eigentlich auch nen Switch bei 7z das er keine Dateien überschreibt, wenn sie schon existieren?

Grad mal 7za.exe getestet, ist von der Niceigkeit her besser wie 7z.exe, da es bereits Informationen liefert, die vorher abgefragt werden müssen wie z.B. Anzahl der Dateien u. Ordner, es liefert auch eine Prozentangabe, die man evtl. über StdoutRead abfragen u. in eine Progressbar setzen kann?!

Code

C:\Windows\System32>7za a c:\myprog.7z c:\myprog


7-Zip (a) [32] 16.04 : Copyright (c) 1999-2016 Igor Pavlov : 2016-10-04


Scanning the drive:
4 folders, 676 files, 68636332 bytes (66 MiB)


Creating archive: c:\myprog.7z


Items to compress: 680


  2% 86 + MyProg\myprog.exe


Files read from disk: 675
Archive size: 23024614 bytes (22 MiB)
Everything is Ok

Alles anzeigen

**alpines**

Zitat von dieselwiesel

ist von der Niceigkeit her besser

Was?

Zitat von dieselwiesel

über StdoutRead abfragen u. in eine Progressbar setzen kann?!

Ja das kannst du so machen. Ich persönlich hatte oft Probleme den Stdout von Programmen zu lesen und habe es immer über einen Umweg gemacht:

Du startest das Programm einfach über die CMD und lässt die Ausgabe in eine Datei schreiben, in etwa so:
RunWait(@ComSpec & " /c ""program.exe -param1 -param2 >> out.txt""")

Bei der Methode musst du aber auf das Working-Directory aufpassen, weil die out.txt Datei dort hingeschrieben wird.

**Musashi**

Zitat von dieselwiesel

Gibts eigentlich auch nen Switch bei 7z das er keine Dateien überschreibt, wenn sie schon existieren?

Man unterscheidet zwischen 'commands' und 'switches'.
'commands' sind z.B. :
a für archivieren
x für extrahieren
'switches' gibt es reichlich, zum Teil auch kombinierbar.

-ao (Overwrite mode) Switch :
Legt fest, wie beim Extrahieren mit Dateien verfahren wird, die bereits auf der Festplatte existieren :
-aoa überschreibt alle Dateien
-aos überspringt das Extrahieren bereits bestehender Dateien
-aou automatische Umbennenung der Datei im Archiv (datei.txt -> datei_1.txt)
-aot automatische Umbennenung der Datei auf der Festplatte

In deinem Fall (kein Überschreiben bestehender Dateien) also : 7za x datei.zip -aos
Nützlich ist beim Extrahieren auch der switch -y. Dieser unterdrückt alle Abfragen, ob z.B. überschrieben werden soll.
Auf der 7-Zip Website habe ich auf die Schnelle keine Liste aller Parameter gefunden. Sollte aber mit Hilfe der Suchmaschine des Vertrauens kein Problem sein. Einen direkten Link zu der Quelle die ich verwende, möchte ich hier wg. Forenetikette nicht angeben. Schreibe mir eine PN.

Zum Thema 7za.dll :
Wenn Du den 7-Zip Download entpackst, dann findest Du eine 'readme.txt'. Dort wird, wenn auch nicht gerade superverständlich, beschrieben, welche einzelnen Komponenten enthalten sind.
Auszug : "7za.dll and 7zxa.dll arbeiten via COM Interface."

Du benötigst nur die 7za.exe !

Gruß Musashi

**Musashi**

@alpines

Zitat von dieselwiesel

ist von der Niceigkeit her besser

Zitat von alpines

Was?

Ich vermute mal, 'Niceigkeit' ist ein etwas verunglückter Anglizismus für Benutzerfreundlichkeit, abgeleitet von 'nice' für nett .

Gruß Musashi

dieselwiesel

Von der "Niceigkeit" her deshalb besser, weil 7za.exe mehr Infos liefert als die herkömmliche 7z.exe. Somit kann man sich doch ein paar "extra" Wege sparen - wenn ich von meinem Bsp. ausgehe

**alpines**

Zitat von Musashi

Ich vermute mal, 'Niceigkeit' ist ein etwas verunglückter Anglizismus für Benutzerfreundlichkeit, abgeleitet von 'nice' für nett .

Schon klar, aber der Begriff.... bähh...

dieselwiesel

Zitat von alpines

Schon klar, aber der Begriff.... bähh...

Nimm das Leben nicht so schwer, lutsch lieber einen Gummibär Der ist vong der Tastigkeit her lecker am been

Zitat

Du startest das Programm einfach über die CMD und lässt die Ausgabe in eine Datei schreiben, in etwa so:
RunWait(@ComSpec & " /c ""program.exe -param1 -param2 >> out.txt""")

Bei der Methode musst du aber auf das Working-Directory aufpassen, weil die out.txt Datei dort hingeschrieben wird.

D.h. es wird zu jeder Datei die out.txt neu erstellt u. das Script holt sich die Infos aus der out.txt und zeigt sie an? Hast du da evtl. ein kleines Bsp. dazu?

**BugFix**

Zitat von alpines

Bei der Methode musst du aber auf das Working-Directory aufpassen, weil die out.txt Datei dort hingeschrieben wird.

Das kannst du mit der Angabe eines fixen Pfades umgehen. Also z.B. ... >> c:\tempout\out.txt

**Bitnugger**

Jede Methode hat ihre eigenen Fallen... ein Umweg ist allerdings immer nur ein Umweg - und niemals eine Verbesserung/Erleichterung.

Mit einer Ausgabeumleitung in eine Datei schreibst du doch lediglich den Stdout in eine Datei - den du mit StdoutRead direkt in eine AutoIt-Variable kopieren kannst!

Vorteile von StdoutRead:

Du brauchst du dich nicht mit einer zusätzlichen Datei rumschlagen, aus der du die Daten dann erst noch einlesen musst.
Du hast keine Dateien, die du entsorgen musst.

Nachteile von StdoutRead:

Keine

Wenn du es so machst, brauchst du das Working-Directory nicht unbedingt setzen...

RunWait(@ComSpec & ' /c "program mit spaces im name.exe" -param1 -param2 > "f:\Umwege 2\out.txt"')

">>" Die aktuelle Ausgabe wird an das Ende einer bestehenden Datei angehangen.
">" Die aktuelle Ausgabe wird in eine vorhandene Datei geschrieben, bereits vorhandener Inhalt wird dabei überschrieben.

In beiden Fällen gilt: Falls die Datei nicht existiert, wird eine neue Datei erzeugt.

**Musashi**

@dieselwiesel (ggf. auch für Andere interessant)

7-Zip : Übersicht zu den Kommandozeilenoptionen der Konsolenvariante

Wie ich oben bereits beschrieben habe, kann man sich die standalone Variante von der 7-Zip Website unter folgendem Link herunterladen :
x86/x64 -> 7-Zip Extra: standalone console version
-> Entpacken. Die Datei '7za.exe' ist völlig ausreichend - sie kann an eine beliebige Stelle kopiert werden. Die DLLs etc. benötigt man im Normalfall nicht. Leider ist in dieser Zusammenstellung die offizielle Hilfedatei nicht enthalten (aktuelle Version : 16.04 vom 04.10.2016).

Um trotzdem an die Hilfe zu kommen, beim Download folgenden Link wählen :
32-bit x86 -> 7-Zip für 32-bit Windows (64-Bit geht auch)
Man erhält die Datei '7z1604.exe', also die Installationsvariante mit GUI etc.

Wichtig :
'7z1604.exe' NICHT STARTEN, sondern mit '7za.exe' entpacken. Unter den Dateien findet man jetzt die Hilfe '7-zip.chm'. Hilfe öffnen, und den Punkt 'User's Guide for command line version' wählen. Dieser enthält genaue Infos zu den verfügbaren Kommandos und Schaltern.
Ich hätte die Datei natürlich auch einfach hier anhängen können, aber dass ist lizenzrechtlich ggf. nicht zulässig.

Gruß Musashi