Bräuchte Hilfe bei der Umsetzung meiner IP Abfrage

madd1n

Hi Leute, ich schreibe gerade nen VPN Handler, das VPN Programm an sich ist nicht auslesbar (d.h. ich könnte darüber nicht die aktuelle IP erfragen) also möchte ich das über eine externe Seite (whoer.net) machen.
VPN Connect Function:

Code

Func _HMAconnect()
	If ProcessExists ("HMA! Pro VPN.exe") Then														;~ Falls HMA läuft, beenden
		_HMAdisconnect()
	EndIf
	Sleep (1000)
	For $i = 1 to 5 Step 1
		If ProcessExists ("HMA! Pro VPN.exe") = 0 Then
			Run ($vpndir&"HMA! Pro VPN.exe")														;~ 5x HMA versuchen zu starten
			Sleep (1000)
			If $i = 5 Then
				_Error("HMA konnte nicht gestartet werden. Überprüfe den Pfad in der config.ini")	;~ HMA konnte nicht aufgerufen werden, Pfad Problem
					MsgBox (48,"VPN Problem","Writing error.log...",2)
				Exit
			EndIf
		EndIf
	Next
	If ProcessExists ("HMA! Pro VPN.exe") = 0 Then													;~ Falls HMA nicht geöffnet wurde, neu starten
		_HMAconnect()
	EndIf
	Sleep (2000)
	$sTitle = WinGetTitle ("HMA! Pro VPN")
	$i = 0
	Do
		$i += 1
		Sleep (1000)
		If $i = IniRead ("config.ini","Intern","VPN Wait","") Then
			_Error("HMA Connect Problem. HMA start dauert zu lange")
				MsgBox (48,"VPN Problem", "Writing error.log...",2)
			_HMAconnect()
		EndIf
	Until WinGetState($sTitle) = 15																	;~ warten bis HMA im Focus ist
	Sleep (1000)
	Do
		Sleep(250)
		WinActivate($sTitle)
	Until ControlCommand($sTitle, "", "[NAME:comboBoxVPNServer]", "IsEnabled")						;~ HMA in den Focus holen
	_IPFlush()																						;~ IP DNS Flush erneuern
	$sServ = Random (1,8,1)																			;~ Random Server auswahl
	If $sServ = 1 Then
		$sServer = "Germany, Bavaria, Munich (LOC 1)"
	EndIf
	If $sServ = 2 Then
		$sServer = "Germany, Bavaria, Munich (LOC 2)"
	EndIf
	If $sServ = 3 Then
		$sServer = "Germany, Bavaria, Nuremberg (LOC 1)"
	EndIf
	If $sServ = 4 Then
		$sServer = "Germany, Bavaria, Nuremberg (LOC 2)"
	EndIf
	If $sServ = 5 Then
		$sServer = "Germany, Bavaria, Nuremberg (LOC 3)"
	EndIf
	If $sServ = 6 Then
		$sServer = "Germany, Berlin (LOC 1)"
	EndIf
	If $sServ = 7 Then
		$sServer = "Germany, Dusseldorf (LOC 2)"
	EndIf
	If $sServ = 8 Then
		$sServer = "Germany, Hesse, Frankfurt (LOC 1)"
	EndIf
	Do
		_GUICtrlComboBox_SelectString(ControlGetHandle($sTitle, "", "[NAME:comboBoxVPNServer]"), $sServer)
		WinActivate($sTitle)
	Until ControlGetText($sTitle, "", "[NAME:comboBoxVPNServer]") = $sServer						;~ Server auswählen
	MouseMove(0, 0, 0)
	WinActivate($sTitle)
	ControlClick($sTitle, "", "[NAME:comboBoxVPNServer]")
	Sleep(200)
	WinActivate($sTitle)
	ControlClick($sTitle, "", "[NAME:comboBoxVPNServer]")
	Sleep (500)
	ControlClick($sTitle, "", "[NAME:buttonConnectToVPN]")											;~ Connecten
	$i = 0
	Do
		$i += 1
		Sleep (1000)
		If $i = IniRead ("config.ini","Intern","VPN Wait","") Then									;~ warten bis verbunden ist
			_Error("HMA Connect Problem. HMA connect dauert zu lange. Server: "&$sServer)
				MsgBox (48,"VPN Problem", "Writing error.log...",2)
			_HMAconnect()
		EndIf
	Until ControlCommand($sTitle, "", "[NAME:buttonDisconnectVPN]", "IsEnabled") and ControlGetText($sTitle, "", "[NAME:textBoxNewIPAddress]") <> "Loading..."
EndFunc ;~ HMA Connect

Alles anzeigen

Meine Function um mir meine aktuelle IP zu holen:

Code

Func _IP()
	$hSession = _WinHttpOpen ("Mozilla/5.0 (Windows NT 6.1; WOW64; rv:49.0) Gecko/20100101 Firefox/49.0")
	$sHost = "whoer.net"
	$hHoas = _WinHttpConnect ($hSession,$sHost)
	$sPaket = _WinHttpSimpleRequest($hHoas, "GET")
	$ip = _StringBetween ($sPaket,'title="Copy to clipboard">','</strong>')
		_WinHttpCloseHandle ($hSession)
		_WinHttpCloseHandle ($hHoas)
	Return $ip[0]
EndFunc

Jetzt habe ich folgendes Problem, Meine _IP() Function fliegt sporadisch auf die schnauze (ich glaube wenn die Verbindung zum VPN noch nicht besteht)
Bekomme ab und zu (nicht immer) die IP nicht via _StringBetween ausgelesen.

Gibt es evtl. eine möglichkeit via StringRegExp und könnte mir jemand das Pattern dafür schreiben?

Grüße =)

**alpines**

Zitat von madd1n

Jetzt habe ich folgendes Problem, Meine _IP() Function fliegt sporadisch auf die schnauze (ich glaube wenn die Verbindung zum VPN noch nicht besteht)
Bekomme ab und zu (nicht immer) die IP nicht via _StringBetween ausgelesen.

Zitat von madd1n

Gibt es evtl. eine möglichkeit via StringRegExp und könnte mir jemand das Pattern dafür schreiben?

Was soll dir das Pattern bringen wenn deine Funktion auf die Nase fällt?
Schreib doch eine Sicherung die erst den Server anpingt oder es x-mal versucht und ansonsten die VPN-Verbindung erneuert.

BLinz

Zitat von madd1n

Bekomme ab und zu (nicht immer) die IP nicht via _StringBetween ausgelesen.

Der erste Schritt für mich wäre ein Debugging ... was steht denn drin in $sPaket wenn es nicht klappt?
Und darauf hin, da hat alpines völlig recht, musst du dir eine Fehlerbehandlung bzw. einen Plan B im Programm bauen.

Meine fertigen Programme sind immer 3 mal so groß wie der ursprüngliche Prototyp ... Weil wich mich auf nichts verlasse. Nicht darauf das ein Array ein Array ist, nicht darauf das ein Auslesen etc. geklappt hat usw.

Ich baue mir immer eine "Debbugging" Funktion die ich per $B_Debug = True einschalten kann ... und in meinen Programm schreibe ich ich dann jedesmal wenn ich einen Wert bekomme eine Debug Zeile dazu.

AutoIt

Global $b_Debug = True


Func _PrintDebug($s_Message)
   MsgBox(0, "Debug", $s_Message)
EndFunc


...
...
$sPaket = _WinHttpSimpleRequest($hHoas, "GET")
_PrintDebug($sPaket)

Alles anzeigen

Meistens baue ich ein EditControl in meine GUIs it ein wo das dann ständig mit läuft - interessanter und informativer als ein Fortschrittsbalken - und nicht so nervig wie MsgBoxen.
Falls du den SciTE benutzt: mit dem Cursor auf die Variable gehen und STRG + SHIFT + D drücken! Das ist die kurze Methode

**alpines**

Zitat von BLinz

Der erste Schritt für mich wäre ein Debugging ... was steht denn drin in $sPaket wenn es nicht klappt?

Du kannst 100%ig davon ausgehen, das die Seite überhaupt nicht lädt. Folglich ist $sPaket leer und der Arrayzugriff auf [0] bricht dem Script die Beine.

Friesel

Hi!

1. Das was Alpines und BLinz schreiben...

2. Da Du nach einem Regex Pattern fragst...
_StringBetween selbst benutzt auch nur einen sehr simplen Regex Pattern, nämlich folgenden:

'(?i)title="Copy to clipboard">(.*?)' (case insensitive)

der Pattern (oder heißt es "das" Pattern?) lässt sich noch auf IP's anpassen, z.B. so:

'(?i)title="Copy to clipboard">(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})'

oder so:

'(?i)title="Copy to clipboard">((?:\d{1,3}\.){3}\d{1,3})'

Beide Pattern matchen einen Bereich von 0.0.0.0 (bzw. 000.000.000.000) bis 999.999.999.999, der Pattern von _StringBetween matcht ALLES was zwischen ...><... steht.
Das lässt sich natürlich noch weiter spezialisieren, in dem man wirklich ausschließlich den Bereich von 0.0.0.0 bis 255.255.255.255 abdeckt, ist aber hier meiner Meinung nach nicht nötig.

Der Nachteil bei allen diesen Pattern ist, sobald sich der Quelltext der Seite ändert, wird die IP darin nicht mehr gefunden. Man kann versuchen, dem entgegenzuwirken, in dem man den Pattern verallgemeinert. Etwa in dieser Art:
'(?i)title=".+">((?:\d{1,3}\.){3}\d{1,3})</.+>'
Jetzt kann sich sowohl der Titel, als auch das Attribut (strong) ändern, ohne das die IP "verloren" geht.

3. Hier noch ein Tipp, wenn du ganz unabhängig von Seiten wie whoer.net sein willst (ich selbst mache es auch so):
Besorg dir irgendeinen kostenlosen HTTP-Server (z.B. bei http://bplaced.net) und lade dort ein PHP-Script hoch, das die IP eines Besuchers anzeigt.

PHP

<?php
    echo $_SERVER['REMOTE_ADDR'];  
?>

Das obige Skript in eine Textdatei kopieren, diese in "index.php" umbenennen und ins Stammverzeichnis deines Servers hochladen.
Wenn jetzt jemand diese Seite (mit "deinName.bplaced.net") aufruft, wird nichts als dessen IP-Adresse angezeigt und du kannst dir _StringBetween oder reguläre Ausdrücke sparen, weil _WinHttpSimpleRequest nur die IP zurückgibt.

Viel Erfolg, Friesel

**alpines**

Zitat von Friesel

der Pattern

Das Pattern. Hört sich nicht nur besser an sondern passt auch mit dem deutschen Artikel zu 'das Muster'.

Zitat von Friesel

'(?i)title="Copy to clipboard">(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})'

Kann man so machen, dann kann man sich aber auch die \d-Teile sparen, weil es auf der Seite sicherlich nur einen Bereich mit title="Copy to clipboard"<ip> gibt.

Wenn man es unbedingt mit RegEx machen will sollte man auch die IP-Ranges betrachten und ins Pattern einpflegen, denn nach deiner Lösung wäre 999.999.999.999 akzeptiert.

Friesel

Zitat von alpines

Das Pattern. Hört sich nicht nur besser an sondern passt auch mit dem deutschen Artikel zu 'das Muster'.

Ja, hast recht. Hat mir mittlerweile auch MS Word bestätigt

Zitat von alpines

Kann man so machen, dann kann man sich aber auch die \d-Teile sparen, weil es auf der Seite sicherlich nur einen Bereich mit title="Copy to clipboard"<ip> gibt.
Wenn man es unbedingt mit RegEx machen will sollte man auch die IP-Ranges betrachten und ins Pattern einpflegen, denn nach deiner Lösung wäre 999.999.999.999 akzeptiert.

Du hast meinen Text nicht wirklich durchgelesen, oder?

Zitat von Friesel

Beide Pattern matchen einen Bereich von 0.0.0.0 (bzw. 000.000.000.000) bis 999.999.999.999, der Pattern von _StringBetween matcht ALLES was zwischen ...><... steht.
Das lässt sich natürlich noch weiter spezialisieren, in dem man wirklich ausschließlich den Bereich von 0.0.0.0 bis 255.255.255.255 abdeckt, ist aber hier meiner Meinung nach nicht nötig.

Weiterhin schreibe ich "Da Du nach einem Regex Pattern fragst..." und das _StringBetween auch nur einen regülären Ausdruck benutzt.
Zwischen den Zeilen kann man mit etwas gutem Willen durchaus erkennen, das ich Regex in diesem Fall nicht unbedingt für notwendig erachte (abgesehen vom letzten, verallgemeinerten Pattern, das halt auch diverse Änderungen im Quelltext berücksichtigen kann.

**alpines**

Zitat von Friesel

Du hast meinen Text nicht wirklich durchgelesen, oder?

Ich sollte um die Uhrzeit keine Beiträge mehr verfassen :x

**Bitnugger**

AutoIt

;-- TIME_STAMP   2017-05-18 05:45:51   v 0.1


#Region    ;************ Includes ************
#include <StringConstants.au3>
#include <Array.au3>
#include <WinHttp.au3>
#EndRegion ;************ Includes ************


Global $g_sSpacer, $g_IP


$g_IP = _ExtractIPFromSite('whoer.net')


Switch @error
	Case 1
		ConsoleWrite("_WinHttpOpen           #Error: " & @error & @TAB & "#Extended: " & @extended & @CRLF)
	Case 2
		ConsoleWrite("_WinHttpConnect        #Error: " & @error & @TAB & "#Extended: " & @extended & @CRLF)
	Case 4
		ConsoleWrite("_WinHttpSimpleRequest  #Error: " & @error & @TAB & "#Extended: " & @extended & @CRLF)
	Case 8
		ConsoleWrite("StringRegExp($sSource) #Error: " & @error & @TAB & "#Extended: " & @extended & @CRLF)
	Case 16
		ConsoleWrite("StringRegExp($IP)      #Error: " & @error & @TAB & "#Extended: " & @extended & @CRLF)
	Case Else
		$g_sSpacer = (@extended = 0) ? '! ~~~~~~~~~~~~~~~~~~~~~~~~~~' & @CRLF : '! ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' & @CRLF
		ConsoleWrite($g_sSpacer & '>    $IP = ' & $g_IP & @CRLF & $g_sSpacer)
EndSwitch


Func _ExtractIPFromSite($sHost)
	Local $hSession, $hConnect, $sSource, $IP, $aRes


	$hSession = _WinHttpOpen('Mozilla/5.0 (Windows NT 6.1; WOW64; rv:49.0) Gecko/20100101 Firefox/49.0')
	$hConnect = _WinHttpConnect($hSession, $sHost)
	$sSource  = _WinHttpSimpleRequest($hConnect, "GET")
	_WinHttpCloseHandle($hSession)
	_WinHttpCloseHandle($hConnect)


	If $hSession = 0  Then Return SetError(1)
	If $hConnect = 0  Then Return SetError(2)
	If $sSource  = '' Then Return SetError(4)


	$aRes = StringRegExp($sSource, '.*?clipboard">(.+)(?:<.*)', 1)	; eg. '87.149.209.188'
	If Not IsArray($aRes) Then Return SetError(8)


	$IP = $aRes[0]


;~	~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	; Wenn du nur auf IPv4 prüfen musst...
;~	~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	If Not StringRegExp($IP, '\b(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\b', $STR_REGEXPMATCH) Then Return SetError(16)


;~	~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	; Wenn du auch auf IPv6 prüfen musst...
;~	~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
;~ 	#include <FF.au3>
;~ 	$IP  = '2003:81:6e7e:5800:c816:2720:828c:c0f2'
;~ 	If Not __FFIsIP($IP) Then Return SetError(16)


	Return SetError(0, StringInStr($IP, ':'), $IP)
EndFunc   ;==>_ExtractIPFromSite


; #INTERNAL_USE_ONLY# ==========================================================
; Name ..........: __FFIsIP
; Description ...: IP4 check
; AutoIt Version : V3.3.0.0
; Syntax ........: __FFIsIP(ByRef $IP[, $bSubstring = False])
; Parameter(s): .: $IP          - IPV4 Address Or IPV6 (HexCompressed/6Hex4Dec/Hex4DecCompressed)
; Return Value ..: Success      - 1
;                  Failure      - 0
; Author(s) .....: Thorsten Willert
; Date ..........: Mon Sep 23 18:50:26 CEST 2013 @743 /Internet-Zeit/
; ==============================================================================
Func __FFIsIP(ByRef $IP, $bSubstring = False)


    Local $sStart = "", $sEnd = ""


    If Not $bSubstring Then
        $sStart = '^'
        $sEnd = "$"
    EndIf


    $IP = StringStripWS($IP, 3)


    Return StringRegExp($IP, $sStart & '(25[0-5]|2[0-4][0-9]|[0-1]{1}[0-9]{2}|[1-9]{1}[0-9]{1}|[1-9])\.(25[0-5]|2[0-4][0-9]|[0-1]{1}[0-9]{2}|[1-9]{1}[0-9]{1}|[1-9]|0)\.(25[0-5]|2[0-4][0-9]|[0-1]{1}[0-9]{2}|[1-9]{1}[0-9]{1}|[1-9]|0)\.(25[0-5]|2[0-4][0-9]|[0-1]{1}[0-9]{2}|[1-9]{1}[0-9]{1}|[0-9])' & $sEnd) Or _
    StringRegExp($IP, $sStart & '(?:[0-9a-fA-F]{1,4}:){7}[0-9a-fA-F]{1,4}' & $sEnd) Or _ ; IPV6
    StringRegExp($IP, $sStart & '((?:[0-9A-Fa-f]{1,4}(?::[0-9A-Fa-f]{1,4})*)?)::((?:[0-9A-Fa-f]{1,4}(?::[0-9A-Fa-f]{1,4})*)?)' & $sEnd) Or _ ; IPV6 HexCompressed
    StringRegExp($IP, $sStart & '((?:[0-9A-Fa-f]{1,4}:){6,6})(25[0-5]||2[0-4]\d||[0-1]?\d?\d)(\.(25[0-5]||2[0-4]\d||[0-1]?\d?\d)){3}' & $sEnd) Or _ ; IPV6 6Hex4Dec
    StringRegExp($IP, $sStart & '((?:[0-9A-Fa-f]{1,4}(?::[0-9A-Fa-f]{1,4})*)?) ::((?:[0-9A-Fa-f]{1,4}:)*)(25[0-5]||2[0-4]\d||[0-1]?\d?\d)(\.(25[0-5]||2[0-4]\d||[0-1]?\d?\d)){3}' & $sEnd) ; IPV6 Hex4DecCompressed


EndFunc   ;==>__FFIsIP

Alles anzeigen

**chesstiger**

Ein schöner Dienst zur Bestimmung der öffentlichen IP ist auch icanhazip.com. Da sparst du dir den RegEx-Kram komplett, da reicht InetRead und BinaryToString.

**alpines**

Zitat von chesstiger

Ein schöner Dienst zur Bestimmung der öffentlichen IP ist auch icanhazip.com. Da sparst du dir den RegEx-Kram komplett, da reicht InetRead und BinaryToString.

http://myexternalip.com/raw

**chesstiger**

Geht auch. Du musst aber zugeben, dass sich icanhazip.com cooler liest.

Friesel

Zitat von alpines

http://myexternalip.com/raw

Auf diesen Seiten ist sowas wie der PHP-Einzeiler aus meinem Tipp installiert

**alpines**

Zitat von Friesel

Auf diesen Seiten ist sowas wie der PHP-Einzeiler aus meinem Tipp installiert

Ich bin mir ziemlich sicher, dass alle deinen Rat beherzigt haben und nach deinem Vorbild die Seite aufgesetzt haben </satire>

Man könnte aber sich auch die ganzen eigenen UDFs sparen und die _GetIP nutzen.