Programm bei Mausbewegung sofort beenden

BLinz

Ich brauche mal wieder eine Idee.
Um den Energiesparmodus / Bildschirmschoner zu verhindern lasse ich regelmäßig die Maus bewegen.
Dazu dient das folgende 2 Minuten Programm:

AutoIt: MouseMove.au3

#NoTrayIcon
AutoItSetOption("MustDeclareVars",1)
Local $a_CurrentMousePosition = MouseGetPos()
Local $i_Movespeed = 50
If $CmdLine[0] > 0 Then
	$i_Movespeed = Round($CmdLine[1],0)
EndIf
If $i_Movespeed > 100 Then
	$i_Movespeed = 100
EndIf
If $i_Movespeed < 0 Then
	$i_Movespeed = 0
EndIf
If $i_Movespeed = 0 Then
	MouseMove($a_CurrentMousePosition[0] + 1, $a_CurrentMousePosition[1] + 1, 0)
	MouseMove($a_CurrentMousePosition[0], $a_CurrentMousePosition[1], 0)
Else
	MouseMove($a_CurrentMousePosition[0], $a_CurrentMousePosition[1] + 100, $i_Movespeed)
	MouseMove($a_CurrentMousePosition[0] + 100 , $a_CurrentMousePosition[1] + 100,$i_Movespeed)
	MouseMove($a_CurrentMousePosition[0] + 100 , $a_CurrentMousePosition[1],$i_Movespeed)
	MouseMove($a_CurrentMousePosition[0], $a_CurrentMousePosition[1], $i_Movespeed)
EndIf
Exit 0

Alles anzeigen

Einfach per F5 starten, wenn keine Parameter übergeben werden nimmt es Default-Werte. Ihr seht den Mauszeiger bewegen.

Ich habe das Programm kompiliert also .exe im gleichen Pfad wie mein Hauptprogramm liegen.
Das Hauptprogramm nutzt die Funktion _Timer_GetIdleTime() aus und startet ggf. per ShellExecute das obige Programm.

Damit meine Anwender sehen das was passiert bewege ich den Mauszeiger 100x100 Pixel im Quadrat.
Soweit, so gut.

Nun hätte ich gerne das sobald man die echte/reale Maus bewegt sich das Programm sofort beendet.

Blöd ist halt das wir ja den Mauszeiger gerade selbst bewegen ... ich hab es mal in einer Schleife mit Einzelschritten probiert ...
Ist natürlich ruckelig ... aber was Frage ich ab? Die Maus bewegt ja gerade das Programm ...
Ich könnte versuche eine Abweichung vom geplanten Pfad zu finden ... klingt aber nach Glückssache.

BLinz

**alpines**

Ich saß vor einiger Zeit an einem Projekt um die Eingaben von unterschiedlichen Geräten zu unterscheiden.
Anfänglich hatte ich es mit der RawInput.au3 geplant, mit der konnte ich für Tastatureingaben (und ich schätze auch für die Maus) das Eingabegerät anzeigen lassen.

Bei, von AutoIt gesendeten, Keystokres hat sich der Device Identifier geändert. Ich schätze, dass das selbe auch für die Maus möglich ist.
Auch wenn es anfänglich verwirrend und kompliziert erscheinen mag, schau dir mal die RawInput.au3 und ein paar Beispiele aus dem engl. Forum an.

**Oscar**

Wenn Du verhindern willst, dass der Bildschirmschoner "zuschlägt", warum deaktivierst Du ihn dann nicht?
Einfach in der Registry den Zeitwert auf Null setzen:

AutoIt

_DeActiveScreenSaver(True) ; Bildschirmschoner deaktivieren
_DeActiveScreenSaver(False) ; Bildschirmschoner aktivieren


Func _DeActiveScreenSaver($fDeactivate = True)
	Local Const $sRegPath = 'HKEY_CURRENT_USER\Control Panel\Desktop'
	Local Static $iOldScreenSaveTimeOut = 0
	If $fDeactivate Then
		$iOldScreenSaveTimeOut = RegRead($sRegPath, 'ScreenSaveTimeOut')
		RegWrite($sRegPath, 'ScreenSaveTimeOut', 0)
	Else
		RegWrite($sRegPath, 'ScreenSaveTimeOut', $iOldScreenSaveTimeOut)
	EndIf
EndFunc

Alles anzeigen

BLinz

Zitat von Oscar

Wenn Du verhindern willst, dass der Bildschirmschoner "zuschlägt", warum deaktivierst Du ihn dann nicht?

Weil der Benutzer das nicht darf

Ist per Gruppenrichtlinie gesetzt, die Programme laufen alle nur mit den Rechten eines normalen Benutzers - und darf fast gar nichts (außer ein paar lokale Programme zu starten oder eine Citrix-Sitzung zu starten)

Das ist jetzt kein dramatisches Problem ... ich würde es nur cool finden es gelöst zu haben.

Ich bin in der Hilfe auf _WinAPI_RegisterRawInputDevices gestoßen - im Beispiel wird auf die Mausdaten zugegriffen.
Leider reagiert das Programm auch bei MouseMove ... AutoIt ist einfach zu gut

BLinz

Zitat von BLinz

Ich bin in der Hilfe auf _WinAPI_RegisterRawInputDevices gestoßen - im Beispiel wird auf die Mausdaten zugegriffen.
Leider reagiert das Programm auch bei MouseMove ... AutoIt ist einfach zu gut

LOL ... ausgerechnet die Mauskoordinaten werden mit der normalen AutoIt Function ausgelesen, den ganzen Rest holen holen die woanders her.

**Oscar**

Wenn das unbedingt mit den Mausbewegungen sein soll, dann bewege die Maus immer nur einen Schritt und sieh nach, ob die Maus sich danach wirklich dort befindet.
Wenn nicht, dann hat der Benutzer die Maus zusätzlich bewegt und das Programm kann beendet werden:

AutoIt

#NoTrayIcon
Global $iStartX = @DesktopWidth / 2, $iStartY = @DesktopHeight / 2
Global $iMouseSpeed = 5, $aMousePos, $iX = $iStartX, $iY = $iStartY, $iWay = 0
MouseMove($iStartX, $iStartY, 0)
Do
	Switch $iWay
		Case 0
			$iX += 1
			If $iX = $iStartX + 50 Then $iWay = 1
		Case 1
			$iY += 1
			If $iY = $iStartY + 50 Then $iWay = 2
		Case 2
			$iX -= 1
			If $iX = $iStartX - 50 Then $iWay = 3
		Case 3
			$iY -= 1
			If $iY = $iStartY - 50 Then $iWay = 0
	EndSwitch
	MouseMove($iX, $iY, $iMouseSpeed)
	$aMousePos = MouseGetPos()
Until $aMousePos[0] <> $iX Or $aMousePos[1] <> $iY
Exit

Alles anzeigen

**autoiter**

Hallo @BLinz,
Oscars Vorschlag sticht sicher. Aber ich frage mich, ob du nicht einfach statt per Mausbewegung in Schleife eine Taste drücken kannst (F2 oder eine der diversen Funktions-/Sondertasten auf die bei dir nichts reagiert). Dann wäre die Mausbewegung als Identifikation wieder eindeutig.

EDIT: Ist mir eben noch aufgegangen. Man erstellt für dieses Programm eine GUI außerhalb des Bildbereichs oder nicht sichtbar und sendet mit ControlSend an das Fenster. Dann geht auch Up oder Down und man hat sicher keine negativen Effekte.

Floops

Zitat von autoiter

Hallo @BLinz,
Oscars Vorschlag sticht sicher. Aber ich frage mich, ob du nicht einfach statt per Mausbewegung in Schleife eine Taste drücken kannst (F2 oder eine der diversen Funktions-/Sondertasten auf die bei dir nichts reagiert). Dann wäre die Mausbewegung als Identifikation wieder eindeutig.

Das halte ich auch für eine bessere Lösung. Ich würde als Tasten entweder Scroll-Lock oder Pause vorschlagen.

Yaerox

Ich bin mal so frei und werfe meine Gedanken mit in den Raum.

Wenn Benutzer eingeschränkte Berechtigungen haben, hat das (meist) einen Grund.
Berechtigungen können sinnvoll via GPOs oder Gruppen geregelt werden. Vielleicht magst du ja mal ausschmücken, was die Ursache dafür ist, das einschalten des Bildschirmschoners zu verhindern.

Angenommen es nervt dich, dass du jedes mal ein Kennwort zur Entsperrung eingeben musst.
Da macht dein Arbeitgeber alles richtig. Es ist wichtig seinen Arbeitsplatz sicher zu halten.
Wenn es andere gründe gibt, z.B. eine starke Beeinträchtigung in deinen Arbeitsabläufen, da glaube ich kaum, dass dein Vorgesetzer sagen wird "Es bleibt hier alles so wie es ist! ".
Wenn es dich und andere Kollegen betrifft, kann man euch als Abteilung ggf. eine Berechtigung mehr geben, oder halt die Einstellung anders setzen (deaktivieren/höher setzen).

Wenn dein Programm sich beenden soll, sobald der Mauszeiger "wirklich" bewegt wird, musst du das Programm ja auch jedes mal starten, sobald du "AFK" gehst. Wie ich finde, keine schöne Lösung.

PS: "Und das Kinderzimmer bleibt auch so wie es ist! ".

**Oscar**

Zitat von autoiter

und sendet mit ControlSend an das Fenster

Bist Du sicher, das ein ControlSend das einschalten des Bildschirmschoners verhindert?
Generell würde ich keine Tasten-Emulation verwenden, denn wenn der Anwender gerade einen Editor oder so benutzt und einen Text eingeben will, dann kommst Du ihm damit ins Gehege.
Eine Maus-Bewegung hingegen ist weniger kritisch.

**autoiter**

Zitat von Oscar

Bist Du sicher, das ein ControlSend das einschalten des Bildschirmschoners verhindert?

Nein, @Oscar. Ich weiß es nicht und habe weder ControlSend noch Send getestet und müsste es bei Bedarf selbst erst ausprobieren.
Für sehr kritisch halte ich Tastendruck-Emulation in diesem Fall zwar eigentlich nicht (es geht ja nicht um eine allgemeine Lösung, sondern auf eine spezielle für eine Umgebung). Aber stimmt, es ist immer besser gar keine programmsteuernde Eingabe vorzunehmen. Deine Lösung wäre für mich auch eindeutig genug.

BLinz

So, ich spare mir mal das einzelne Zitieren und antworte pauschal:

Gruppenrichtlinien:
Na klar hat das seinen Grund, alle Einwände von euch sind berechtigt. Moralisch bin ich da ganz bei euch.
Aber ...
Ich nutze das bei einem Kunden mit ca. 4.000 Arbeitsplätzen weltweit. Die Rechner sind alle gleich, alle haben unter anderem diese Richtlinie für den Bildschirmschoner und sogar ein Firmeneigenes Energieprofil.
Und in diesem Netzwerk verteilt sind nun 12 Test-Arbeitsplätze auf denen automatisiert Performancetest verschiedener Anwendungen durchgeführt werden (Diverse Branchensoftware / Sharepoint usw).
Diese Rechner stehen da irgendwo ohne Maus, Tastatur und Bildschirm - hoffentlich sicher verschlossen.

Selbstverständlich sind das die gleichen Rechner mit den gleichen Richtlinien wie alle anderen - das soll ja auch so damit das Ergebnis realistischer ist. Die bekommen die selben Updates und Programme per Softwareverteilung wie alle anderen. Ausnahme ist eine zusätzliche Richtlinie welche eine automatische Anmeldung ausführt und das Testprogramm startet (prüfe gerade das als Dienst zu realisieren)

Die Lösung für dieses "Problem" such ich nur ... weil ich wissen will ob es machbar ist.
Und weil sich der Mauszeiger natürlich immer dann gerade bewegt wenn ich gerade was mit der Maus an dem einen Testrechner machen will der bei mir am Schreibtisch steht.

ControlSend
Muss ich noch testen aber ich meine das wird ignoriert - sprich das reicht nicht. Teste ich aber Dienstag noch mal. Aber siehe auch nächsten Abschnitt.

Taste statt Mauszeiger:
Müsste ich testen ... aber das ist gar nicht mein Problem. Wie man oben im Code sehen kann, kann man auch die Zeit 0 übergeben. Das schiebt er die Maus einen Pixel hin und her. Das reicht völlig und keiner merkt im Normalfall etwas.

Die Maus bewege ich unter anderem so "großzügig" damit man es sieht. Mein lokaler Testrechner läuft den ganzen Tag mit einem eigenen Bildschirm hier. Alle Naselang kommt einer aus den Fachabteilung und schaut wie weit ich bin. Weshalb mein ganzes Testprogramm auf dem Bildschirm die ganze Zeit blitzt, blinkt und funkelt wie ein Rapper mit Goldketten und LED-Armbänder in weißen Shorts in einer Disco mit Schwarzlicht und Lasershow.
Am liebsten würde ich das auch noch eine farbige Mausspur hinterziehen lassen die dann verblasst.

Gruß,
BLinz

PS: Ich forsche gerade an dem hier: 2 Mauszeiger ... gibt es irgendwo einen Leitfaden wie das mit den ganzen DllStruct etc. genau funktioniert? Sprich wie ich mir das selbst anhand einer Information X herleite?

Yaerox

Hab grad den Überblick verloren. Hat schon jemand ein Hotkey zum beenden vorgeschlagen?

AutoIt

HotKeySet("{ESC}", "_Exit")


While 1
	MouseMove(10, 10)
	Sleep(1000)
	MouseMove(10, 100)
	Sleep(1000)
	MouseMove(100, 100)
	Sleep(1000)
	MouseMove(100, 10)
	Sleep(1000)
WEnd


Func _Exit()
	Exit
EndFunc

Alles anzeigen

Update:

Den Ablauf mit der Mausposition würde ich mir logisch so vorstellen:

AutoIt

HotKeySet("{ESC}", "_Exit")


Local $iX = 0
Local $iy = 0


While 1
	MouseMove(10, 10)
	Sleep(1000)


	$iX = MouseGetPos(0)
	$iY = MouseGetPos(1)


	If ( $iX <> 10 Or $iY <> 10 ) Then
		MsgBox(0, "", "User moved mouse ...")
		_Exit()
	EndIf


	MouseMove(10, 100)
	Sleep(1000)


	$iX = MouseGetPos(0)
	$iY = MouseGetPos(1)


	If ( $iX <> 10 Or $iY <> 100 ) Then
		MsgBox(0, "", "User moved mouse ...")
		_Exit()
	EndIf


	MouseMove(100, 100)
	Sleep(1000)


	$iX = MouseGetPos(0)
	$iY = MouseGetPos(1)


	If ( $iX <> 100 Or $iY <> 100 ) Then
		MsgBox(0, "", "User moved mouse ...")
		_Exit()
	EndIf


	MouseMove(100, 10)
	Sleep(1000)


	$iX = MouseGetPos(0)
	$iY = MouseGetPos(1)


	If ( $iX <> 100 Or $iY <> 10 ) Then
		MsgBox(0, "", "User moved mouse ...")
		_Exit()
	EndIf
WEnd


Func _Exit()
	Exit
EndFunc

Alles anzeigen

Deine Rap-Effekte kann man da natürlich noch überall einbauen

**alpines**

Zitat von Yaerox

Den Ablauf mit der Mausposition würde ich mir logisch so vorstellen:

Wenn bei einem MouseMove bewegt wird, registriert AutoIt das nicht.
Du müsstest die Intervalle zum checken viel kleiner machen, da man ansonsten am Anfang eine "zähe" Maus hat.

BLinz

So, hier nun eine funktionierende Version.
Sieht unter Windows 10 auch schön flüssig aus (unter Windows 7 je nach Rechner mal smooth, mal ruckelig)

AutoIt: MouseMove_V2.au3

#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=Icon256-32.ico
#AutoIt3Wrapper_Outfile=MouseMove.exe
#AutoIt3Wrapper_Res_Comment=2017 (c) Bernhard Linz
#AutoIt3Wrapper_Res_Description=MouseMove.exe
#AutoIt3Wrapper_Res_Fileversion=1.0.0.7
#AutoIt3Wrapper_Res_Fileversion_AutoIncrement=y
#AutoIt3Wrapper_Res_SaveSource=y
#AutoIt3Wrapper_Res_Language=1031
#AutoIt3Wrapper_Add_Constants=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <Timers.au3>
AutoItSetOption("MustDeclareVars",1)
Global $a_OriginalMousePosition = MouseGetPos()
Global $i_Movespeed = 5
Global $i_PixelToMove = 200


; Prüft ob die Maus sich auf einer unerwarteten Koordinate befindet. Wenn ja wird das Programm beendet
Func _CheckUnexpectedMouseMove($a_ExpectedMousePositionX, $a_ExpectedMousePositionY)
	Local $a_CurrentMousePosition = MouseGetPos()
	If $a_ExpectedMousePositionX <> $a_CurrentMousePosition[0] Or $a_ExpectedMousePositionY <> $a_CurrentMousePosition[1] Then
		Exit 1
	EndIf
EndFunc


; Prüfen ob uns Parameter zu Zeigergschwindigkeit per Commandline übergeben wurden
If $CmdLine[0] > 0 Then
	$i_Movespeed = Round($CmdLine[1],0)
EndIf
If $i_Movespeed > 100 Then
	$i_Movespeed = 100
EndIf
If $i_Movespeed < 0 Then
	$i_Movespeed = 0
EndIf


; Wenn die Geschwindigkeit mit 0 übergeben wird bewegen wir den Mauszeiger "unsichtar"
If $i_Movespeed = 0 Then
	MouseMove($a_OriginalMousePosition[0] + 1, $a_OriginalMousePosition[1] + 1, 0)
	MouseMove($a_OriginalMousePosition[0], $a_OriginalMousePosition[1], 0)
	Exit 0
EndIf


; Ok, wir sind bis hierher gekommen, also schön Sichtbar den Mauszeiger spazieren fahren:
For $i = 0 To $i_PixelToMove Step 1
	; 1. Mauszeiger um einen Pixel bewegen
	MouseMove($a_OriginalMousePosition[0], $a_OriginalMousePosition[1] + $i, 0)
	; 2. kurze Pause damit der Benutzer Zeit hat die Maus zu bewegen - und der Zeiger sich langsam bewegt
	Sleep($i_Movespeed)
	; 3. prüfen ob der Zeiger noch dort ist wo er sein sollte
	_CheckUnexpectedMouseMove($a_OriginalMousePosition[0], $a_OriginalMousePosition[1] + $i)
Next
For $i = 0 To $i_PixelToMove Step 1
	MouseMove($a_OriginalMousePosition[0] + $i, $a_OriginalMousePosition[1] + $i_PixelToMove, 0)
	Sleep($i_Movespeed)
	_CheckUnexpectedMouseMove($a_OriginalMousePosition[0] + $i, $a_OriginalMousePosition[1] + $i_PixelToMove)
Next
For $i = $i_PixelToMove To 0 Step -1
	MouseMove($a_OriginalMousePosition[0] + $i_PixelToMove, $a_OriginalMousePosition[1] + $i, 0)
	Sleep($i_Movespeed)
	_CheckUnexpectedMouseMove($a_OriginalMousePosition[0] + $i_PixelToMove, $a_OriginalMousePosition[1] + $i)
Next
For $i = $i_PixelToMove To 0 Step -1
	MouseMove($a_OriginalMousePosition[0] + $i, $a_OriginalMousePosition[1], 0)
	Sleep($i_Movespeed)
	_CheckUnexpectedMouseMove($a_OriginalMousePosition[0] + $i, $a_OriginalMousePosition[1])
Next
MouseMove($a_OriginalMousePosition[0], $a_OriginalMousePosition[1], 0)
Exit 0

Alles anzeigen

Die Idee hatte ich schon vorher, hatte aber unnötige Sorgen wegen des Overkills an MausPosition Abfragen.

Ich setz das Thema mal auf gelöst ... auch wenn der "rote Zauberschweif" des Mauszeigers noch fehlt ... (wie mache ich eigentlich einen Kreis ....)

**Oscar**

Hast Du mein Script aus Post#6 mal ausprobiert.
Das funktioniert nämlich viel einfacher.

BLinz

Zitat von Oscar

Hast Du mein Script aus Post#6 mal ausprobiert.
Das funktioniert nämlich viel einfacher.

Jepp, um einiges eleganter ... und funktioniert genauso gut.

Wenn ich jetzt noch den roten Zauberschweif bekommen nehme ich dein statt mein Script

**Oscar**

Zitat von BLinz

Wenn ich jetzt noch den roten Zauberschweif bekommen nehme ich dein statt mein Script

Für Zauberschweif ist UEZ (GDI+ Meister) zuständig.
Von mir kannst Du einen "WanderingBug" bekommen:

AutoIt

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>


Opt('GUIOnEventMode', 1)


_GDIPlus_Startup()
Global $bBug = _bug()
Global $iPoint = 150, $iStartX = @DesktopWidth / 2, $iStartY = @DesktopHeight / 2
$hGui = GUICreate('WanderingBug', 32, 32, $iStartX - 8, $iStartY - 8, $WS_POPUP, $WS_EX_TOOLWINDOW + $WS_EX_LAYERED + $WS_EX_TOPMOST)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
GUISetBkColor(0xABCDEF)
GUISetCursor(16, $GUI_CURSOR_OVERRIDE, $hGui)
GUISetState()
_WinAPI_SetLayeredWindowAttributes($hGui, 0xABCDEF)
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
$hImage = _GDIPlus_BitmapCreateFromMemory($bBug)
$iWidth = _GDIPlus_ImageGetWidth($hImage)
$iHeight = _GDIPlus_ImageGetHeight($hImage)
$hMatrix = _GDIPlus_MatrixCreate()
_GDIPlus_MatrixTranslate($hMatrix, $iWidth / 2, $iHeight / 2)
GUIRegisterMsg($WM_PAINT, 'WM_PAINT')
_GDIPlus_MatrixRotate($hMatrix, 0, 'False')
_GDIPlus_GraphicsSetTransform($hGraphic, $hMatrix)
_GDIPlus_GraphicsDrawImage($hGraphic, $hImage, -$iWidth / 2, -$iHeight / 2)
Global $aMousePos, $aWinPos = WinGetPos($hGui), $iStepX, $iStepY, $iAngle = 0
Global $iMouseSpeed = 1, $aMousePos, $iWay = 0
Global $iX = $iStartX, $iY = $iStartY
MouseMove($iStartX, $iStartY, 0)
_RotateBug(90)
Do
	Switch $iWay
		Case 0
			$iStepX = 1
			$iStepY = 0
			$iX += 1
			If $iX = $iStartX + $iPoint Then
				$iWay = 1
				_RotateBug(90)
			EndIf
		Case 1
			$iStepX = 0
			$iStepY = 1
			$iY += 1
			If $iY = $iStartY + $iPoint Then
				$iWay = 2
				_RotateBug(90)
			EndIf
		Case 2
			$iStepX = -1
			$iStepY = 0
			$iX -= 1
			If $iX = $iStartX - $iPoint Then
				$iWay = 3
				_RotateBug(90)
			EndIf
		Case 3
			$iStepX = 0
			$iStepY = -1
			$iY -= 1
			If $iY = $iStartY - $iPoint Then
				$iWay = 0
				_RotateBug(90)
			EndIf
	EndSwitch
	MouseMove($iX, $iY, $iMouseSpeed)
	$aMousePos = MouseGetPos()
	$aWinPos[0] += $iStepX
	$aWinPos[1] += $iStepY
	WinMove($hGui, '', $aWinPos[0], $aWinPos[1])
Until $aMousePos[0] <> $iX Or $aMousePos[1] <> $iY
_CloseGui()


Func _CloseGui()
	_GDIPlus_MatrixDispose($hMatrix)
	_GDIPlus_ImageDispose($hImage)
	_GDIPlus_GraphicsDispose($hGraphic)
	_GDIPlus_Shutdown()
	Exit
EndFunc   ;==>_CloseGui


Func _RotateBug($iAngle)
	_GDIPlus_MatrixRotate($hMatrix, $iAngle, 'False')
	_GDIPlus_GraphicsSetTransform($hGraphic, $hMatrix)
	_GDIPlus_GraphicsClear($hGraphic, 0xFFABCDEF)
	_GDIPlus_GraphicsDrawImage($hGraphic, $hImage, -$iWidth / 2, -$iHeight / 2)
EndFunc   ;==>_RotateBug


Func WM_PAINT($hWnd, $Msg, $wParam, $lParam)
	_GDIPlus_MatrixRotate($hMatrix, 0, 'False')
	_GDIPlus_GraphicsSetTransform($hGraphic, $hMatrix)
	_GDIPlus_GraphicsClear($hGraphic)
	_GDIPlus_GraphicsDrawImage($hGraphic, $hImage, -$iWidth / 2, -$iHeight / 2)
EndFunc   ;==>WM_PAINT


;Code below was generated by: 'File to Base64 String' Code Generator v1.20 Build 2015-09-19


Func _bug($bSaveBinary = False, $sSavePath = @ScriptDir)
	Local $bug
	$bug &= '4LVIAAABABAgIAFwIAAAqBAAABYAAMwAKAAYAJAAQAAYAVwNAQCAAGylARwcHLcDgQGLCmYPABZ2XQAAF3e0ABh4zPAABC3/ggHBAsEEwQYHwQjeEeIftB0dHf8ABwcHTgAAVQwAABh3jQAZePYAABt8/wAgjf+AACSc/wANWsMA/8ECwQTBBsEIwQrADMEOwRADwRLtHxQUFCYBAQAB/gEDHd8AHAB73gAhiv8AKQCk/wAwuf8ANADF/wA2y/8AHP6rwwDBAsEEwQbBCMEKwAxwAQcf3MEQwRLxYAEADS/JACB//wAAKp7/ADO7/wBAOc7/ADzUwADV+cMAHrbDAMUDwQbBCMEKD8EMwA7CEDEAH4shAAAnkOsAMKj/AAA3uf8KLYH/CgQuhMAXs/8AQdn5wwAgvcMA5QFgA2EEYQU/YQZiB2EIYQkfAAgAVQMAACybxgAypv8ADihm/xsdIf8IGxsbZgAOK3D/gABF3f8AI8NjAP9gAWECaQRhBmEHYQhiCWEKAx8AAwA0p1QAOa8w/xAoXWsKZAAZHQAl/wBL4f8AJf7KYwBgAWECcQVhCGEJYgoDHwBjHzuw1QBExBD/GR4ocwovbf+AAFDl/wAo0mMA/2ABYQJyFWAIYQliCn8gALYAtzwARMD/AE4g2P8RM3fuCRMwAGz/AFPf/wBV/ulgTGA+YQBhAWACYQPtBUdhCGEJYgo9tj/dDwIARsCKA0/Q/wUAV+T/Blvs/w4ASbn/Ez2T/xBAQqD/C1HRYALt+WYAACzgEGAAaQJhBGEFH2EGYQdhCGEJYQoCSMACiv0PCFDNxg1XAN3/EF7s/xBg4vF6AAAv52IA/QRhCQdhCmEL/Q8QVdjqFgBe6P8XY/H/FwRk9XoAAi7c/wJ8L9/+BGEJYQphC/0PGQBd4fkdZvL/HxRp+GAA+XIAHlbGEP8dKERmPBwrTTD/HlrSvwI2APj/DzEFsQUfBwsAGyM1/wAfPoD/I2jw/wgjbPs/AGny/xvEICt+Jh0nP78CNQAfsAQxBbEFHwcLABogLwL98QQfN2//J28C/T4AKG35/x0l4jz+Bx4uVf8CNACxBI8xArEFHwf8DypO8jIFwB4i/ypx/z8AMACAKGXi/yE5cDBHAi0wADH/ITx7//gpaeu/AjQAsQQyBbAFhx8HBwDwckkaMGLyBwAhOnD/LXP//wAvdP//VYX//wBukf//fpn//0CLof//magzAJP+mjMA9QCxATECsQIxA7ED/zEEsQTyD7AFMQafB3OCsAEA/wocRP0jQYQA/y1w9v9Gfv8A/4mf/P9ve7wA/09Xhv81O1wA/x4hNf8CAgL/PwAwALEBMQKxAjEDsQMxBL+xBDEFsQUxBv+I8ge9cHogtwYMHiugZNIrAHL//3GG2v8lwCg5/w0NDT8APwD/PgCxAzEEsQQxBbEFMQaxBkMfEAcAIWr5VHErOvw+WD9dPwA/ADgAMQSxBA8xBZ8GDwADAKoDEmIA8cYoKCz/KSn+KT8APwA/ADQAMQSxBDEFB38GDwAGAE3oIVZoAHv8lbO8/7nfAOv/rM7Y/3GE8In/NTUwHj8ANgAxAv+xAjEDsQMxBLEEDwYPAAkAAAYGBoNRZ3n+AI+uuP+kxtL/ALvh7v/F7fr/gIqgp/9BQUE/APEwAIOYnzICsQIxA7ED3zEEsQQfBg8AuCgtsRswLQDveJCc0X6ZoQD/kbC5/6fL1gD/rtHc/0hISAD/SUlJ/0pKSscyALEAMQGu0d0yArECwzEDsQMEBATuMlowBQefBg8AMlAaGoEeHgwe/3EA8QB2iZiPAHeSm/x3kZn/AHyWn/86Ojr/gD8/P/9CQkIyAP+xADEBsQExArECMQO/BA8AYw8AMFAbG9IxAz0LdQCImoFWZ3/VLwAzSvIxMzv8MjgyMv8xALEAMQFUZPx81DECvRSxBDEFnwYPAP00A34xAJ8BDwAPAA8A/wT/DwAPAA8ADwAPAA8ADwAPAA8P'
	$bug &= 'AA8ADwADAESwCgA6AP8IAPzgBz8I/AAAAgb+AAB/IQEO+AAAHwEG8AAEAA8dBuAAAAfAeAAAAwEDBTcFTwIPgAABH/jgBx/5/wT/nwVz'
	$bug = _WinAPI_Base64Decode($bug)
	If @error Then Return SetError(1, 0, 0)
	Local $tSource = DllStructCreate('byte[' & BinaryLen($bug) & ']')
	DllStructSetData($tSource, 1, $bug)
	Local $tDecompress
	_WinAPI_LZNTDecompress($tSource, $tDecompress, 4286)
	If @error Then Return SetError(3, 0, 0)
	$tSource = 0
	Local Const $bString = Binary(DllStructGetData($tDecompress, 1))
	If $bSaveBinary Then
		Local Const $hFile = FileOpen($sSavePath & "\bug.ico", 18)
		If @error Then Return SetError(2, 0, $bString)
		FileWrite($hFile, $bString)
		FileClose($hFile)
	EndIf
	Return $bString
EndFunc   ;==>_bug


Func _WinAPI_Base64Decode($sB64String)
	Local $aCrypt = DllCall("Crypt32.dll", "bool", "CryptStringToBinaryA", "str", $sB64String, "dword", 0, "dword", 1, "ptr", 0, "dword*", 0, "ptr", 0, "ptr", 0)
	If @error Or Not $aCrypt[0] Then Return SetError(1, 0, "")
	Local $bBuffer = DllStructCreate("byte[" & $aCrypt[5] & "]")
	$aCrypt = DllCall("Crypt32.dll", "bool", "CryptStringToBinaryA", "str", $sB64String, "dword", 0, "dword", 1, "struct*", $bBuffer, "dword*", $aCrypt[5], "ptr", 0, "ptr", 0)
	If @error Or Not $aCrypt[0] Then Return SetError(2, 0, "")
	Return DllStructGetData($bBuffer, 1)
EndFunc   ;==>_WinAPI_Base64Decode


Func _WinAPI_LZNTDecompress(ByRef $tInput, ByRef $tOutput, $iBufferSize)
	$tOutput = DllStructCreate("byte[" & $iBufferSize & "]")
	If @error Then Return SetError(1, 0, 0)
	Local $aRet = DllCall("ntdll.dll", "uint", "RtlDecompressBuffer", "ushort", 0x0002, "struct*", $tOutput, "ulong", $iBufferSize, "struct*", $tInput, "ulong", DllStructGetSize($tInput), "ulong*", 0)
	If @error Then Return SetError(2, 0, 0)
	If $aRet[0] Then Return SetError(3, $aRet[0], 0)
	Return $aRet[6]
EndFunc   ;==>_WinAPI_LZNTDecompress

Alles anzeigen