Progressbar für Countdown rückwärtslaufen lassen

hipfzwirgel

Hallo AutoIT'ler,

hat jemand eine Idee wie ich folgenden Designfehler ändern kann

Code

;Global $Prozent = 100
$Progress1 = GUICtrlCreateProgress(8, 224, 513, 25)
;GUICtrlSetData($Progress1, $Prozent)

Ich habe mit KODA eine Progressbar(für einen Countdown) erstellt. Prop dabei ist, dass die Progressbar beim Starten der GUI leer ist. Wenn der Countdown beginnt(Buttonklick) füllt sie sich erst und leert sich dann.
Ich möchte aber dass die Progressbar beim Starten der Gui bereits 100% Füllung anzeigt. Mit oben (auskommentiertem) Code habe ich es versucht aber auch da wird beim Starten der GUI das Füllen angezeigt. Sieht echt blöd aus. Gibt es eine Möglichkeit eine gefüllte Progressbar beim Programmstart anzuzeigen, die sich dann beim Countdown leert?

p.s.: Ich will keine Progressbar die sich im Laufe des Countdown füllt

**Kanashius**

Das beste Workaround, das ich gefunden habe wäre dieses: Die Progressbar wird versteckt, dann gefüllt und erst danach angezeigt. Dadurch taucht (je nachdem, wo man das guisetstate hinpackt) die Progressbar entweder später auf, oder das gesamte Fenster.

AutoIt

#include <GUIConstantsEx.au3>
Global $iWidth=800,$iHeight=100

$hGui=GUICreate("",$iWidth,$iHeight)
$iProgressbar=GUICtrlCreateProgress(10,10,$iWidth-20,$iHeight-20)
GUICtrlSetState($iProgressbar,$GUI_HIDE)
GUICtrlSetData($iProgressbar,100)
Sleep(500)
GUICtrlSetState($iProgressbar,$GUI_SHOW)
GUISetState()

While Sleep(10)
    If GUIGetMsg()=-3 Then exit
WEnd

Alles anzeigen

Mit freundlichen Grüßen, Kanashius

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

hmmmm...

Koda macht das doch richtig?

-----------------------------------------------

#include <GUIConstantsEx.au3>

#include <ProgressConstants.au3>

#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=

$Form1 = GUICreate("Form1", 623, 449, 192, 114)

GUISetBkColor(0x00FF00)

$Progress2 = GUICtrlCreateProgress(128, 264, 388, 33)

GUICtrlSetLimit(-1, 100, 100)

GUICtrlSetData(-1, 100)

GUICtrlSetColor(-1, 0x808080)

GUISetState(@SW_SHOW)

#EndRegion ### END Koda GUI section ###

While 1

$nMsg = GUIGetMsg()

Switch $nMsg

Case $GUI_EVENT_CLOSE

Exit

EndSwitch

WEnd

-------------------------------------------

Die Progressbar Startet gefüllt.

Gruß

Peter

**alpines**

Peter S. Taler die ProgressBar füllt sich bei mir erst nach Start des Skriptes (W7).

**Oscar**

Wenn Du mit dem klassischen Stil auskommst, dann so:

AutoIt

#include <ProgressConstants.au3>

Global $iProgress = 100
Global $iTimer = TimerInit()
Global $hGui = GUICreate('Test', 640, 100)
DllCall('uxtheme.dll', 'none', 'SetThemeAppProperties', 'int', 0) ; auf den klassischen Style umschalten
Global $idProgress = GUICtrlCreateProgress(20, 30, 600, 20)
GUICtrlSetData(-1, $iProgress)
GUICtrlSetBkColor(-1, 0xCCCCCC)
GUICtrlSetColor(-1, 0x6666DD)
DllCall('uxtheme.dll', 'none', 'SetThemeAppProperties', 'int', 7) ; zurück zum Standard-Windowsstyle
GUISetState()
Do
    If TimerDiff($iTimer) > 50 Then
        $iTimer = TimerInit()
        $iProgress -= 1
        GUICtrlSetData($idProgress, $iProgress)
    EndIf
Until GUIGetMsg() = -3 Or  $iProgress < 0

Alles anzeigen

Tuxedo

Mit dem folgenden Script startet die Progressbar bei mir mit vollem Balken und läuft dann bis 0 zurück

Spoiler anzeigen

#include <GUIConstantsEx.au3>
Global $iWidth=320,$iHeight=100,$Progre = 100
$hGui=GUICreate("",$iWidth,$iHeight)
$iProgressbar=GUICtrlCreateProgress(10,10,$iWidth-20,$iHeight-20)
;GUICtrlSetState($iProgressbar,$GUI_HIDE)
GUICtrlSetData($iProgressbar,$Progre)
Sleep(500)
;GUICtrlSetState($iProgressbar,$GUI_SHOW)
GUISetState()
While 1
Sleep(50)
$Progre -= 1
GUICtrlSetData($iProgressbar, $Progre)
;If GUIGetMsg()=-3 Or $Progre = -10 Then exit MsgBox(4096, "Titel", $Progre, 5)
If GUIGetMsg()=-3 Or $Progre = 0 Then exit
WEnd

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

alpines

hmmm... bei mir popt das Fenster gefüllt auf. Kann das am Betriebssystem liegen? Win xp Sp 3 bei mir?

Anders ausgedrückt für mich sieht Kanashius Script und mein Koda Script vollmommen identisch aus - was den gefüllt Status anbelangt.
Leider habe ich z.Z. keine Win 7 Maschinen zur Hand um das zu Prüfen.

Edit: Ich habe das gerade auf einem 2008er Server nachgeprüft. da sieht die Optik tatsächlich ganz anders aus. Der Streifen ist dann vollständig in der Vordergrundfarbe - ohne Raster. Jedoch ist auch dieser sofort gefüllt.

Das scheint BS oder Grafikkartentreiber abhängig zu sein - kann das sein? Ich habe da mal 4 Dateien hochgeladen. Der Unterschied liegt nur in der Farbe der Scrollbalken. Screenshot von XP und Server 2008 anbei.

Gruß

Peter

**alpines**

Das wird vermutlich am OS liegen.

hipfzwirgel

Hallo AutoIT'ler,

ich bin überwältigt ob der großen Resonanz. Vielen lieben Dank an alle. Ich habe es jetzt so gelöst:

Ein einfaches Sleep(500) vor dem Showflag der Form. Dadurch wird die Progressbar "gefüllt" und erst dann die Form angezeigt.
Manchmal können Lösungen ganz einfach sein aber man sieht den Wald vor lauter Bäumen nicht.