Windows Aktivierung Status

AutoMit

Guten Abend,

wie kann ich für Windows 7, 8, 10 mit AutoIt ( API ) abfragen, ob Windows aktiviert ist oder nicht, wie lange die Testzeit ist und die GracePeriod?

Ich habe bei MS folgende Infos gefunden - das kann ich nicht in AutoIt umsetzen..

Für AutoIt konnte ich nichts finden, wie ich die folgenden Daten abfragen kann.

https://msdn.microsoft.com/en-us/library/…6(v=vs.85).aspx

Wscript.Echo "Activation Required: " & objWPA.ActivationRequired

Wscript.Echo "Remaining Evaluation Period: " & objWPA.RemainingEvaluationPeriod

Wscript.Echo "Remaining Grace Period: " & objWPA.RemainingGracePeriod

Ich möchte diese 3 Daten gerne als Info in einer MessageBox ausgeben.

Vielen Dank

**alpines**

Du kannst das WinMgmt auch in AutoIt callen mit ObjGet.

Das Script liefert mir für Windows 7 Home Premium x64 zwar keine Infos aber andere Queries (z.B. welches Service Pack installiert ist) funktionieren.

Vielleicht klappts ja bei dir und Win10. Ob das #RequireAdmin notwendig ist weiß ich nicht.

AutoIt

#RequireAdmin

$oWinMgmts = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & @ComputerName & "\root\cimv2")
$oQuery = $oWinMgmts.ExecQuery("SELECT * FROM Win32_WindowsProductActivation")

For $oObj In $oQuery
    MsgBox(64, "Info", "ActivationRequired" & $oObj.ActivationRequired & @CRLF & _
                       "RemainingEvaluationPeriod: " & $oObj.RemainingEvaluationPeriod & @CRLF & _
                       "GracePeriod: " & $oObj.RemainingGracePeriod & @CRLF)
Next

AutoMit

Guten Morgen Alpines,

Zitat von alpines

andere Queries (z.B. welches Service Pack installiert ist) funktionieren

~~kannst Du mir bitte dieses Script und ggf. zwei andere, die auch bei Dir funktionieren, hier reinstellen?~~

edit: habe einige ObjGet Beispiele testen können - das geht grundsätzlich - nur bringt es oft keine oder andere als erwartete Ergebnisse

Bei mir hat obiges Script unter Windows 8 / 64 nichts zurückgegeben.

Gibt es eine Möglichkeit, den kompletten Inhalt der Variable $oQuery anzuzeigen?

Mit einer einfachen arraydisplay und console hat es nicht geklappt.

#include <Array.au3>

_ArrayDisplay ( $oQuery , "Zeile " & @ScriptLineNumber )

Übrigens - das Beispiel 1 aus der Hilfe zu ObjGet

$oExcel.workbooks.add ; Eine neue Arbeitsmappe hinzufügen

... öffnet hier keine neue Arbeitsmappe sondern eine neue Excel-Datei.

Ein diffizieles und spannendes Thema.

Vielen Dank Alpines !!

Vielleicht kann jemand das Script von Alpines ( oder ein anderes ) unter Windows 8 / 64 testen ( vmware und System ), ob das eine Info ausgibt.

Danke !!

Sonderbaar

Alpines Script spuckt unter Windows 8.1 64-bit system (nix VM) nix aus... Script läuft aber einfach runter, kommt nur keine MsgBox

**BugFix**

Zitat von AutoMit

Gibt es eine Möglichkeit, den kompletten Inhalt der Variable $oQuery anzuzeigen?

Das ist eine Objektvariable. Die Abfrage erfolgt in der Schleife (selbst wenn nur ein Objekt in der Objektvariablen enthalten ist:

For $oObj In $oQuery ...

Alle enthaltenen Objekt-Eigenschaften siehst du hier bei MSDN.

AutoMit

Zitat von Sonderbaar

Alpines Script spuckt unter Windows 8.1 64-bit system (nix VM) nix aus... Script läuft aber einfach runter, kommt nur keine MsgBox

Danke Sonderbaar - ja - so ist es hier leider auch - keine Info über den Inhalt der Objektvariablen.

Bugfix, funktioniert bei Dir die Abfrage der Windows Aktivierungsdaten?

Zitat von BugFix

Die Abfrage erfolgt in der Schleife (selbst wenn nur ein Objekt in der Objektvariablen enthalten ist:

Hallo Bugfix, wie kann ich folgenden Code verändern, so dass ich für alle unter Windows verfügbaren Objektvariablen eine Ausgabe erhalte - und nicht nur für eine bestimmte Objektvariable?

So funktioniert es nicht - (1) und (2) müssen geändert werden.

Code

$oWinMgmts = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & @ComputerName & "\root\cimv2")

$oQuery = $oWinMgmts.ExecQuery("SELECT * FROM *")        ;    (1)

For $oObj In $oQuery
    ConsoleWrite (@ScriptLineNumber & @TAB & "$oQuery = " & $oObj & @CRLF)                    ;    (2)
Next

Danke und knacken wir die Nuss

**BugFix**

In der Schleife musst du die Properties von $oObj abfragen (Objektnotation: Objektvariable.Property), wie im Bsp. von alpines.

Also

...

ConsoleWrite( $oObj.ActivationRequired )

ConsoleWrite( $oObj.Caption )

usw.

...

gmmg

Hallo AutoMit,

schau mal hier im engl. Forum

https://www.autoitscript.com/forum/topic/14…7-is-activated/

Gruß gmmg

**BugFix**

Oder du rufst den Lizenzmanager auf, in allen Windowsversionen enthalten:

AutoIt

ShellExecute(@SystemDir & "\slmgr.vbs", "/dlv", @SystemDir)
$hScripthost = WinWait("Windows Script Host")
$sText = WinGetText($hScripthost)
WinClose($hScripthost)

ConsoleWrite($sText & @CRLF)

AutoMit

Vielen Dank gmmg, obigen Beitrag aus dem englischsprachigen Forum habe ich zwischenzeitlich auch gefunden, aber konnte nichts daraus unter Windows 8 / 64 / vmware erfolgreich ausführen.

Zitat von BugFix

ConsoleWrite( $oObj.Caption )

Ich habe das als Beispiel mal durchnummeriert. Bei der Druckerzeile erhalte ich 1 = Drucker x, 2 = Drucker y etc.

Bei der Abfrage mit der Zeile "Win32_WindowsProductActivation" wird per Console nur der Wert von "$counter = 0" angezeigt, in die "For $oObj In $oQuery" geht das Script nicht rein.

Mh - warum nur?

Code

#RequireAdmin

$oWinMgmts = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & @ComputerName & "\root\cimv2")

;~ $oQuery = $oWinMgmts.ExecQuery("SELECT * FROM Win32_WindowsProductActivation")        ;    Windows Aktivierung
$oQuery = $oWinMgmts.ExecQuery ("Select * From Win32_Printer")                                    ;    Drucker


$counter = 0
ConsoleWrite( $counter  & @CRLF)
    
For $oObj In $oQuery
    $counter = $counter + 1
    ConsoleWrite( $counter  & " = " & $oObj.Caption  & @CRLF)
Next

Alles anzeigen

PS: BugFix - Danke für Deinen Tipp zu slmgr eine gute Idee

gmmg

Beide Scripte geben bei mir eine Info zur Aktivierung von Windows zurück

(Windows 7 X64 )

Code

Global $ActiveCheck, $result

If @OSVersion = "WIN_2000" Or @OSVersion = "WIN_2003" Or @OSVersion = "WIN_XP" Or @OSVersion = "WIN_XPe" Then
$ActiveCheck = _XPActivationCheck()
Else
$ActiveCheck = _ActivationStatus()
EndIf

Func _ActivationStatus() ; Vista + Only ~ author trancexx
    Local $oWMIService = ObjGet("winmgmts:\\.\root\cimv2")
    If IsObj($oWMIService) Then
    Local $oCollection = $oWMIService.ExecQuery("SELECT Description, LicenseStatus, GracePeriodRemaining FROM SoftwareLicensingProduct WHERE PartialProductKey <> null")
    If IsObj($oCollection) Then
    For $oItem In $oCollection
    Switch $oItem.LicenseStatus
    Case 0, 2 To 4, 6
    $result = "Windows Is NOT Activated"
    Case 1
    $result = "Windows Is Activated"
    Case 5
    $result = "Possible Fixed Windows (Notification Mode)"
    EndSwitch
    ;~ Return ConsoleWrite( $result & @CRLF)
    Return MsgBox(0, "Activation Result", $result & @CRLF)
    Next
    EndIf
    EndIf
EndFunc ;==>_ActivationStatus

Func _XPActivationCheck() ; XP only
    Local $x = ObjGet("winmgmts:{impersonationLevel=impersonate}")
    Local $y = $x.InstancesOf("win32_WindowsProductActivation")
    For $Obj In $y
    If $Obj.ActivationRequired Then
    $result = 'Windows Is NOT Activated'
    Else
    $result = 'Windows Is Activated'
    EndIf
    Next
    ;~ Return ConsoleWrite( $result & @CRLF)
    Return MsgBox(0, "Activation Result", $result & @CRLF)
EndFunc ;==>_XPActivationCheck



$WMI = ObjGet("winmgmts:\\.\root\cimv2")
$aLicenses = $WMI.ExecQuery("Select * From SoftwareLicensingProduct")

   For $element In $aLicenses
      If StringInStr($element.Description, "Windows Operating System") Then
         If $element.GracePeriodRemaining = 0 Then
            MsgBox(0, "", "Product is Activated")
            ExitLoop
         Else
            ;Call SLMgr.vbs with your selected options
            ;http://technet.microsoft.com/en-us/library/ff793433.aspx
         EndIf
      EndIf
   Next

Alles anzeigen

Gruß gmmg

bazii

Es muss nur das Macro @OSVersion unter Windows 7 und / oder Windows 10 angepasst werden.

Code

Global $ActiveCheck, $result

If @OSVersion = "WIN_10" Then $ActiveCheck = _ActivationStatus()

Func _ActivationStatus() ; Vista + Only ~ author trancexx
    Local $oWMIService = ObjGet("winmgmts:\\.\root\cimv2")
    If IsObj($oWMIService) Then
    Local $oCollection = $oWMIService.ExecQuery("SELECT Description, LicenseStatus, GracePeriodRemaining FROM SoftwareLicensingProduct WHERE PartialProductKey <> null")
    If IsObj($oCollection) Then
    For $oItem In $oCollection
    Switch $oItem.LicenseStatus
    Case 0, 2 To 4, 6
    $result = "Windows Is NOT Activated"
    Case 1
    $result = "Windows Is Activated"
    Case 5
    $result = "Possible Fixed Windows (Notification Mode)"
    EndSwitch
    ;~ Return ConsoleWrite( $result & @CRLF)
    Return MsgBox(0, "Activation Result", $result & @CRLF)
    Next
    EndIf
    EndIf
EndFunc ;==>_ActivationStatus

Alles anzeigen

AutoMit

Vielen Dank für die zahlreichen Lösungsansätze - die einfachste scheint die von Bugfix zu sein, indem man aus dem Lizenzmanager den Text nimmt und die Zeilen ausliest.

Grünen Haken gesetzt

Einen sonnigen Tag Euch allen!

**bernd670**

Hallo,

wenn der Standardskripthost auf cscript umgestellt ist, funktioniert die Version von BugFix nicht mehr. Besser wäre es so

AutoIt

Run("wscript.exe slmgr.vbs /dlv", @SystemDir, @SW_HIDE)
$hScripthost = WinWait("Windows Script Host")
$sText = WinGetText($hScripthost)
WinClose($hScripthost)
ConsoleWrite($sText & @CRLF)

oder du nimmst gleich den Skripthost cscript, dann stört auch das Ausgabefenster von wscript nicht mehr

AutoIt

#include <AutoItConstants.au3>

$PID = Run("cscript.exe slmgr.vbs /dlv", @SystemDir, @SW_HIDE, $STDOUT_CHILD)

$sOutput = ""
While True
    $sOutput &= StdoutRead($PID)
    If @error Then ExitLoop
WEnd

$sOutput = _OemToChar($sOutput) ; damit Umlaute richtig dargestellt werden

ConsoleWrite($sOutput & @CRLF)

;===============================================================================
; Name:             _OemToChar
; Description:      Wandelt einen ASCII- in einen ANSI-String
; Parameter(s):     $szSrc = String der umgewandelt werden soll
; Requirement(s):   keine
; Return Value(s):  bei Erfolg: umgewandelter String
;                   bei Fehler: "" und @error = 1
; Author(s):        bernd670
;
;===============================================================================
Func _OemToChar($szSrc)
;~ Private Declare Function OemToChar Lib "user32.dll" Alias "OemToCharA" (ByVal lpszSrc As String, ByVal lpszDst As String) As Long

    Local $strSrc = DllStructCreate("char[" & StringLen($szSrc) + 1 & "]")
    Local $strDst = DllStructCreate("char[" & StringLen($szSrc) * 2 + 1 & "]")
    DllStructSetData($strSrc, 1, $szSrc)
    DllStructSetData($strDst, 1, 0)

    Local $lRetVal = DllCall("user32.dll", "long", "OemToChar", "ptr", DllStructGetPtr($strSrc), "ptr", DllStructGetPtr($strDst))
    If IsArray($lRetVal) And $lRetVal[0] = 1 Then
        Return SetError(0, 0, DllStructGetData($strDst, 1))
    EndIf

    Return SetError(1, 0, "")
EndFunc   ;==>_OemToChar

Alles anzeigen

AutoMit

Vielen Dank bernd670,

Zitat von bernd670

wenn der Standardskripthost auf cscript umgestellt ist

davon lese ich zum ersten Mal.

Was ist der Vorteil der Umstellung auf cscript? Standard scheint wscript zu sein? Ich kenn mich hier gar nicht aus.

Bringst Du bitte ein wenig Licht ins Dunkel, wie am einfachsten auf csript umgestellt wird, wie man erkennt, ob umgestellt wurde und welche Vorteile das in Kurzform bietet?

Danke

**bernd670**

Hallo,

ändern kann man den Scripthost mit dem Parameter //H: cscript //H:cscript aktiviert cscript und cscript //H:wscript aktiviert wscript als StandardScripthost. Alles weitere wird bei Windows Scripting FAQ recht gut erklärt.

**Bitnugger**

cscript vs wscript

Was unterscheidet wscript.exe und csript.exe?

WSH umfasst zwei eng verwandte Scripting Hosts: WScript und CScript. Beide sind hinsichtlich ihres Befehlsumfangs nahezu gleich. Sie unterscheiden sich lediglich darin, wohin die Ausgaben gehen. Außerdem sind die Intrinsic Objects von CScript ein klein wenig mächtiger als die von WScript.

WScript.exe

WScript ist der Standard; bei der Installation des WSH werden die WSH-Dateiextensionen mit WScript verknüpft.

Diese Verknüpfungen können in der Registry, in den Optionen des Windows Explorers oder mit der WSH-Kommandozeilenoption //H: geändert werden.

Bei WScript (implementiert in WScript.exe) erfolgt die Ausführung als Windows-Anwendung.

Alle Ausgaben werden in Form von Dialogboxen dargestellt. Wenn das Skript viele Ausgaben macht, kann dies sehr lästig sein, da jede Dialogbox einzeln bestätigt werden muss. Zudem ist jede Dialogbox modal: Das Skript hält an und wartet auf die Bestätigung. WScript eignet sich also für die unbeaufsichtigte Ausführung nur dann, wenn das Skript keine Ausgaben macht. Gut geeignet ist WScript jedoch dann, wenn der Benutzer über jeden einzelnen Schritt informiert werden und dabei die jeweils erfolgten Veränderungen überprüfen möchte (also beispielsweise beim Debugging von Skripten).

CScript.exe

Bei CScript (implementiert in CSCRIPT.EXE) erfolgt die Ausführung des Skripts im Kontext einer Kommandozeile (auch: Konsole oder DOS-Box).

Die Form der Ausgabe hängt von den verwendeten Ausgabebefehlen ab. Alle Ausgaben über die Methode Echo() aus dem WSH-Intrinsic Object WScript erfolgen in die DOS-Box. Alle Ausgaben über die spracheigenen Ausgabemethoden (z.B. MsgBox() in VBScript) werden weiterhin als modale Dialogboxen dargestellt.

Ein Vorteil von CScript ist, dass es mit der Methode WScript.StdIn.ReadLine() das Einlesen von Eingaben des Benutzers im DOS-Fenster unterstützt.

CScript hat außerdem den Vorteil, dass die Skriptausführung mit (STRG)+(C) jederzeit vom Benutzer abgebrochen werden kann. Bei WScript hilft – wenn modale Dialogboxen angezeigt werden – nur das Beenden der Anwendung mit dem Windows Task-Manager.

Quelle: https://db0xw.dc4fs.de/echolinkplus/WScriptOderCScript.htm

Hier noch eine kleine Demo, die zeigt wie der Standardskripthost via Registry ausgelesen bzw. geändert werden kann... das Script muss als Administrator ausgeführt werden.

Lizenzmanager_Demo

AutoIt

;-- TIME_STAMP   2018-04-24 10:47:55   v 0.1

;~ #RequireAdmin

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
;~ #AutoIt3Wrapper_Compile_Both=y
#AutoIt3Wrapper_UseX64=n
#AutoIt3Wrapper_Change2CUI=y
;~ #AutoIt3Wrapper_Res_requestedExecutionLevel=requireAdministrator
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#Region ;************ Includes ************
;~ #Include <AutoItConstants.au3>
;~ #include <WinAPIConv.au3> ; _WinAPI_CharToOem
;~ #include <WinAPIReg.au3>  ; _WinAPI_AssocQueryString
#include <WinAPIProc.au3>    ; _WinAPI_GetParentProcess
#include <Process.au3>       ; _ProcessGetName
#EndRegion ;************ Includes ************

Global $g_sGetParentProcess = _ProcessGetName(_WinAPI_GetParentProcess())

If Not IsAdmin() Then Exit $g_sGetParentProcess = 'cmd.exe' _
         ? ConsoleWrite(_WinAPI_CharToOem('! Du musst das Script als Administrator ausführen!') & @CRLF) _
         : MsgBox(64, @ScriptName, '! Du musst das Script als Administrator ausführen!' & @CRLF)

Global Const $g_sStandardskripthost = _GetStandardskripthost()
ConsoleWrite('> $g_sStandardskripthost = ' & $g_sStandardskripthost & @CRLF & _
        '======================================================================' & @CRLF & @CRLF)

OnAutoItExitRegister('_Exit')

_WScript()
_CScript()

; Funktioniert nur, wenn Standardskripthost = WScript.exe (Standard)
Func _WScript()
    _SetStandardskripthost('WScript')
    ConsoleWrite('> New Standardskripthost = ' & _GetStandardskripthost() & @CRLF & _
            '----------------------------------------------------------------------' & @CRLF)
    ShellExecute(@SystemDir & "\slmgr.vbs", "/dlv", @SystemDir, $SHEX_OPEN)
    Local $hWnd = WinWait("Windows Script Host", "", 3), $sText = _WinAPI_CharToOem(WinGetText($hWnd))
;~     Local $hWnd = WinWait("Windows Script Host", "", 3), $sText = WinGetText($hWnd)
    WinClose($hWnd)
    ConsoleWrite($sText & @CRLF)
EndFunc   ;==>_WScript

; Funktioniert nur, wenn Standardskripthost = CScript.exe
Func _CScript()
    _SetStandardskripthost('CScript')
    ConsoleWrite('> New Standardskripthost = ' & _GetStandardskripthost() & @CRLF & _
            '----------------------------------------------------------------------' & @CRLF)
    Local $iPID = Run(@ComSpec & ' /C ' & @SystemDir & '\slmgr.vbs /dlv', @SystemDir, @SW_HIDE, $STDOUT_CHILD)
    StdoutRead($iPID)
    ProcessWaitClose($iPID)
    Local $sText = StdoutRead($iPID)
    ConsoleWrite($sText & @CRLF)
EndFunc   ;==>_CScript

Func _GetStandardskripthost()
;~     Return StringRegExpReplace(_WinAPI_AssocQueryString('.vbs', $ASSOCSTR_EXECUTABLE), '.+([W|C].+)\.exe.+', '\1')
    Return StringRegExpReplace(RegRead('HKCR\VBSFile\Shell\' & RegRead('HKCR\VBSFile\Shell', '') & '\Command', ''), '.+([W|C].+)\.exe.+', '\1')
EndFunc   ;==>_GetStandardskripthost

Func _SetStandardskripthost($sSkripthost)
    Return RegWrite('HKCR\VBSFile\Shell\', '', 'REG_SZ', ($sSkripthost = 'WScript' ? 'Open' : 'Open2'))
EndFunc   ;==>_SetStandardskripthost

Func _WinAPI_CharToOem($sStr)
;~     Local $aRet = DllCall('user32.dll', 'bool', 'CharToOemW', 'wstr', $sStr, 'wstr', '')
    Local $aRet = DllCall('user32.dll', 'bool', 'CharToOem', 'str', $sStr, 'str', '')
    If @error Or Not $aRet[0] Then Return SetError(@error + 10, @extended, '')

    Return $aRet[2]
EndFunc   ;==>_WinAPI_CharToOem

Func _Exit()
    _SetStandardskripthost($g_sStandardskripthost)
    ConsoleWrite('> New Standardskripthost = ' & _GetStandardskripthost() & @CRLF & _
            '----------------------------------------------------------------------' & @CRLF & _
            'Fertig...' & @CRLF)

    If $g_sGetParentProcess <> 'cmd.exe' Then
        Local Const $iBitMask = 0x8000 ; a bit mask to strip the high word bits from the return of the function.
        Local $iCount, $aRet, $VK_ESCAPE = 0x1B, $hDll = DllOpen('user32.dll')
        ConsoleWrite(@CRLF & 'PRESS ESC FOR EXIT!' & @CRLF)
        Do
            Sleep(50)
            $aRet = DllCall($hDll, 'short', 'GetAsyncKeyState', 'int', $VK_ESCAPE)
        Until @error Or BitAND($aRet[0], $iBitMask) <> 0
        DllClose($hDll)
    EndIf
EndFunc   ;==>_Exit

Alles anzeigen

Edit: Auf ESC-Taste warten hinzugefügt, wenn das Script nicht in der Console gestartet wurde.